elisp/geiser-racket.el

   1 ;; geiser-racket.el -- geiser support for Racket scheme
   2
   3 ;; Copyright (C) 2009, 2010, 2011, 2012 Jose Antonio Ortega Ruiz
   4
   5 ;; This program is free software; you can redistribute it and/or
   6 ;; modify it under the terms of the Modified BSD License. You should
   7 ;; have received a copy of the license along with this program. If
   8 ;; not, see <http://www.xfree86.org/3.3.6/COPYRIGHT2.html#5>.
   9
  10 ;; Start date: Sat Apr 25, 2009 21:13
  11
  12 \f
  13
  14 (require 'geiser-edit)
  15 (require 'geiser-doc)
  16 (require 'geiser-eval)
  17 (require 'geiser-syntax)
  18 (require 'geiser-custom)
  19 (require 'geiser-base)
  20
  21 \f
  22 ;;; Customization:
  23
  24 (defgroup geiser-racket nil
  25   "Customization for Geiser's Racket flavour."
  26   :group 'geiser)
  27
  28 (geiser-custom--defcustom geiser-racket-binary
  29   (cond ((eq system-type 'windows-nt) "Racket.exe")
  30         (t "racket"))
  31   "Name to use to call the racket executable when starting a REPL."
  32   :type '(choice string (repeat string))
  33   :group 'geiser-racket)
  34
  35 (geiser-custom--defcustom geiser-racket-gracket-binary
  36   (cond ((eq system-type 'windows-nt) "GRacket-text.exe")
  37         (t "gracket-text"))
  38   "Name to use to call the gracket executable when starting a REPL.
  39 This executable is used by `run-gracket', and, if
  40 `geiser-racket-use-gracket-p' is set to t, by `run-racket'."
  41   :type '(choice string (repeat string))
  42   :group 'geiser-racket)
  43
  44 (geiser-custom--defcustom geiser-racket-collects nil
  45   "A list of paths to be added to racket's collection directories."
  46   :type '(repeat file)
  47   :group 'geiser-racket)
  48
  49 (geiser-custom--defcustom geiser-racket-init-file "~/.racket-geiser"
  50   "Initialization file with user code for the racket REPL."
  51   :type 'string
  52   :group 'geiser-racket)
  53
  54 (geiser-custom--defcustom geiser-racket-use-gracket-p nil
  55   "Whether to use the gracket binary to start Racket REPLs."
  56   :type 'boolean
  57   :group 'geiser-racket)
  58
  59 (geiser-custom--defcustom geiser-racket-extra-keywords
  60     '("define-syntax-rule" "provide" "require"
  61       "unless" "when" "with-handlers")
  62   "Extra keywords highlighted in Racket buffers."
  63   :type '(repeat string)
  64   :group 'geiser-racket)
  65
  66 (geiser-custom--defcustom geiser-racket-image-cache-directory nil
  67   "The directory where temporary image files generated by Racket are stored.
  68 If set to nil, the default system temp dir is used."
  69   :type 'file
  70   :group 'geiser-racket)
  71
  72 \f
  73 ;;; REPL support:
  74
  75 (defsubst geiser-racket--real-binary ()
  76   (if geiser-racket-use-gracket-p
  77       geiser-racket-gracket-binary
  78     geiser-racket-binary))
  79
  80 (defun geiser-racket--binary ()
  81   (let ((binary (geiser-racket--real-binary)))
  82     (if (listp binary) (car binary) binary)))
  83
  84 (defun geiser-racket--parameters ()
  85   "Return a list with all parameters needed to start racket.
  86 This function uses `geiser-racket-init-file' if it exists."
  87   (let ((init-file (and (stringp geiser-racket-init-file)
  88                         (expand-file-name geiser-racket-init-file)))
  89         (binary (geiser-racket--real-binary))
  90         (rackdir (expand-file-name "racket/" geiser-scheme-dir)))
  91     `("-i" "-q"
  92       "-S" ,rackdir
  93       ,@(apply 'append (mapcar (lambda (p) (list "-S" p))
  94                                geiser-racket-collects))
  95       ,@(and (listp binary) (cdr binary))
  96       ,@(and init-file (file-readable-p init-file) (list "-f" init-file))
  97       "-f" ,(expand-file-name "geiser/startup.rkt" rackdir))))
  98
  99 (defconst geiser-racket--prompt-regexp "\\(mzscheme\\|racket\\)@[^ ]*?> ")
 100
 101 (defun geiser-racket--startup (remote)
 102   (when geiser-racket-image-cache-directory
 103     (geiser-eval--send/wait
 104      (format ",set-image-cache %S\n'done"
 105              geiser-racket-image-cache-directory))))
 106
 107 \f
 108 ;;; Remote REPLs
 109
 110 (defun connect-to-racket ()
 111   "Start a Racket REPL connected to a remote process.
 112
 113 The remote process needs to be running a REPL server started
 114 using start-geiser, a procedure in the geiser/server module."
 115   (interactive)
 116   (geiser-connect 'racket))
 117
 118
 119 \f
 120 ;;; Evaluation support:
 121
 122 (defun geiser-racket--language ()
 123   (save-excursion
 124     (goto-char (point-min))
 125     (if (re-search-forward
 126          "^\\(?:#lang\\|(module +[^ ]+?\\) +\\([^ ]+?\\|([^)]+)\\) *$" nil t)
 127         (car (geiser-syntax--read-from-string (match-string-no-properties 1)))
 128       "#f")))
 129
 130 (defun geiser-racket--enter-command (module)
 131   (when (stringp module)
 132     (cond ((zerop (length module)) ",enter #f")
 133           ((file-name-absolute-p module) (format ",enter %S" module))
 134           (t (format ",enter %s" module)))))
 135
 136 (defun geiser-racket--geiser-procedure (proc &rest args)
 137   (case proc
 138     ((eval compile)
 139      (format ",geiser-eval %s %s %s"
 140              (or (car args) "#f")
 141              (geiser-racket--language)
 142              (mapconcat 'identity (cdr args) " ")))
 143     ((load-file compile-file)
 144      (format ",geiser-eval geiser/main racket (geiser:%s %s)"
 145              proc (car args)))
 146     ((no-values) ",geiser-no-values")
 147     (t (format ",apply geiser:%s (%s)" proc (mapconcat 'identity args " ")))))
 148
 149 (defconst geiser-racket--module-re
 150   "^(module +\\([^ ]+\\)")
 151
 152 (defun geiser-racket--explicit-module ()
 153   (save-excursion
 154     (goto-char (point-min))
 155     (and (re-search-forward geiser-racket--module-re nil t)
 156          (ignore-errors
 157            (car (geiser-syntax--read-from-string
 158                  (match-string-no-properties 1)))))))
 159
 160 (defsubst geiser-racket--implicit-module ()
 161   (save-excursion
 162     (goto-char (point-min))
 163     (if (re-search-forward "^#lang " nil t)
 164         (buffer-file-name)
 165       :f)))
 166
 167 (defun geiser-racket--get-module (&optional module)
 168   (cond ((and (null module) (buffer-file-name)))
 169         ;; (geiser-racket--explicit-module)
 170         ((null module) (geiser-racket--implicit-module))
 171         ((symbolp module) module)
 172         ((and (stringp module) (file-name-absolute-p module)) module)
 173         ((stringp module) (make-symbol module))
 174         (t nil)))
 175
 176 (defun geiser-racket--symbol-begin (module)
 177   (save-excursion (skip-syntax-backward "^-()>") (point)))
 178
 179 (defun geiser-racket--import-command (module)
 180   (and (stringp module)
 181        (not (zerop (length module)))
 182        (format "(require %s)" module)))
 183
 184 (defun geiser-racket--exit-command ()
 185   (comint-send-eof)
 186   (get-buffer-process (current-buffer)))
 187
 188 (defconst geiser-racket--binding-forms
 189   '("for" "for/list" "for/hash" "for/hasheq" "for/and" "for/or"
 190     "for/lists" "for/first" "for/last" "for/fold"
 191     "for:" "for/list:" "for/hash:" "for/hasheq:" "for/and:" "for/or:"
 192     "for/lists:" "for/first:" "for/last:" "for/fold:"
 193     "define-syntax-rule"))
 194
 195 (defconst geiser-racket--binding-forms*
 196   '("for*" "for*/list" "for*/lists" "for*/hash" "for*/hasheq" "for*/and"
 197     "for*/or" "for*/first" "for*/last" "for*/fold"
 198     "for*:" "for*/list:" "for*/lists:" "for*/hash:" "for*/hasheq:" "for*/and:"
 199     "for*/or:" "for*/first:" "for*/last:" "for*/fold:"))
 200 \f
 201 ;;; External help
 202
 203 (defsubst geiser-racket--get-help (symbol module)
 204   (geiser-eval--send/wait
 205    `(:eval (get-help ',symbol '(:module ,module)) geiser/autodoc)))
 206
 207 (defun geiser-racket--external-help (id module)
 208   (message "Looking up manual for '%s'..." id)
 209   (let ((out (geiser-eval--retort-output
 210               (geiser-racket--get-help id module))))
 211     (when (and out (string-match " but provided by:\n +\\(.+\\)\n" out))
 212       (geiser-racket--get-help id (match-string 1 out))))
 213   (minibuffer-message "%s done" (current-message))
 214   t)
 215
 216 \f
 217 ;;; Error display
 218
 219 (defconst geiser-racket--file-rxs
 220   '(nil
 221     "path:\"?\\([^>\"\n]+\\)\"?>"
 222     "module: \"\\([^>\"\n]+\\)\""))
 223
 224 (defconst geiser-racket--geiser-file-rx
 225   (format "^%s/?racket/geiser" (regexp-quote geiser-scheme-dir)))
 226
 227 (defun geiser-racket--purge-trace ()
 228   (save-excursion
 229     (while (re-search-forward geiser-racket--geiser-file-rx nil t)
 230       (kill-whole-line))))
 231
 232 (defun geiser-racket--display-error (module key msg)
 233   (when key
 234     (insert "Error: ")
 235     (geiser-doc--insert-button key nil 'racket)
 236     (newline 2))
 237   (when msg
 238     (let ((p (point)))
 239       (insert msg)
 240       (let ((end (point)))
 241         (goto-char p)
 242         (when key (geiser-racket--purge-trace))
 243         (mapc 'geiser-edit--buttonize-files geiser-racket--file-rxs)
 244         (goto-char end)
 245         (newline))))
 246   (or key (not (zerop (length msg)))))
 247
 248 \f
 249 ;;; Trying to ascertain whether a buffer is mzscheme scheme:
 250
 251 (defun geiser-racket--guess ()
 252   (or (save-excursion
 253         (goto-char (point-min))
 254         (re-search-forward "#lang " nil t))
 255       (geiser-racket--explicit-module)))
 256
 257 \f
 258 ;;; Keywords and syntax
 259 (defun geiser-racket--keywords ()
 260   (append '(("^#lang\\>" . 0)
 261             ("\\[\\(else\\)\\>" . 1))
 262           (when geiser-racket-extra-keywords
 263             `((,(format "[[(]%s\\>" (regexp-opt geiser-racket-extra-keywords 1))
 264                . 1)))))
 265
 266 (geiser-syntax--scheme-indent
 267  (splicing-let 1)
 268  (splicing-letrec 1)
 269  (splicing-let-values 1)
 270  (splicing-letrec-values 1)
 271  (splicing-let-syntax 1)
 272  (splicing-letrec-syntax 1)
 273  (splicing-let-syntaxes 1)
 274  (splicing-letrec-syntaxes 1)
 275  (splicing-letrec-syntaxes+values 1)
 276  (splicing-local 1)
 277  (for 1)
 278  (for/and 1)
 279  (for/first 1)
 280  (for/fold 2)
 281  (for/hash 1)
 282  (for/hasheq 1)
 283  (for/hasheqv 1)
 284  (for/last 1)
 285  (for/list 1)
 286  (for/lists 2)
 287  (for/or 1)
 288  (for/product 1)
 289  (for/sum 1)
 290  (for/vector 1)
 291  (for* 1)
 292  (for*/and 1)
 293  (for*/first 1)
 294  (for*/fold 2)
 295  (for*/hash 1)
 296  (for*/hasheq 1)
 297  (for*/hasheqv 1)
 298  (for*/last 1)
 299  (for*/list 1)
 300  (for*/lists 2)
 301  (for*/or 1)
 302  (for*/product 1)
 303  (for*/sum 1)
 304  (for*/vector 1))
 305
 306
 307 \f
 308 ;;; Implementation definition:
 309
 310 (define-geiser-implementation racket
 311   (unsupported-procedures '(callers callees generic-methods))
 312   (binary geiser-racket--binary)
 313   (arglist geiser-racket--parameters)
 314   (repl-startup geiser-racket--startup)
 315   (prompt-regexp geiser-racket--prompt-regexp)
 316   (marshall-procedure geiser-racket--geiser-procedure)
 317   (find-module geiser-racket--get-module)
 318   (enter-command geiser-racket--enter-command)
 319   (import-command geiser-racket--import-command)
 320   (exit-command geiser-racket--exit-command)
 321   (find-symbol-begin geiser-racket--symbol-begin)
 322   (display-error geiser-racket--display-error)
 323   (external-help geiser-racket--external-help)
 324   (check-buffer geiser-racket--guess)
 325   (keywords geiser-racket--keywords)
 326   (binding-forms geiser-racket--binding-forms)
 327   (binding-forms* geiser-racket--binding-forms*))
 328
 329 (geiser-impl--add-to-alist 'regexp "\\.ss$" 'racket t)
 330 (geiser-impl--add-to-alist 'regexp "\\.rkt$" 'racket t)
 331
 332 (defun run-gracket ()
 333   "Start the Racket REPL using gracket instead of plain racket."
 334   (interactive)
 335   (let ((geiser-racket-use-gracket-p t))
 336     (run-racket)))
 337
 338 \f
 339 (provide 'geiser-racket)