elisp/geiser-syntax.el

   1 ;;; geiser-syntax.el -- utilities for parsing scheme syntax
   2
   3 ;; Copyright (C) 2009, 2010, 2011, 2012, 2013 Jose Antonio Ortega Ruiz
   4
   5 ;; This program is free software; you can redistribute it and/or
   6 ;; modify it under the terms of the Modified BSD License. You should
   7 ;; have received a copy of the license along with this program. If
   8 ;; not, see <http://www.xfree86.org/3.3.6/COPYRIGHT2.html#5>.
   9
  10 ;; Start date: Sun Feb 08, 2009 15:03
  11
  12 \f
  13
  14 (require 'geiser-impl)
  15 (require 'geiser-popup)
  16 (require 'geiser-base)
  17
  18 (require 'scheme)
  19
  20 (eval-when-compile (require 'cl))
  21
  22 \f
  23 ;;; Indentation:
  24
  25 (defmacro geiser-syntax--scheme-indent (&rest pairs)
  26   `(progn ,@(mapcar (lambda (p)
  27                       `(put ',(car p) 'scheme-indent-function ',(cadr p)))
  28                     pairs)))
  29
  30 (geiser-syntax--scheme-indent
  31  (case-lambda 0)
  32  (catch defun)
  33  (class defun)
  34  (dynamic-wind 0)
  35  (let*-values 1)
  36  (letrec* 1)
  37  (letrec-values 1)
  38  (let-values 1)
  39  (let/ec 1)
  40  (match defun)
  41  (opt-lambda 1)
  42  (parameterize 1)
  43  (parameterize* 1)
  44  (receive 2)
  45  (syntax-case 2)
  46  (unless 1)
  47  (when 1)
  48  (while 1)
  49  (with-error-to-port 1)
  50  (with-syntax 1))
  51
  52 \f
  53 ;;; Extra syntax keywords
  54 (defconst geiser-syntax--keywords
  55   '(("\\[\\(else\\)\\>" . 1)
  56     ("(\\(parameterize\\)\\>" . 1)))
  57
  58 (font-lock-add-keywords 'scheme-mode geiser-syntax--keywords)
  59
  60 (geiser-impl--define-caller geiser-syntax--impl-kws keywords ()
  61   "A variable (or thunk returning a value) giving additional,
  62 implementation-specific entries for font-lock-keywords.")
  63
  64 (geiser-impl--define-caller geiser-syntax--case-sensitive case-sensitive ()
  65   "A flag saying whether keywords are case sensitive.")
  66
  67 (defun geiser-syntax--add-kws ()
  68   (when (not (and (boundp 'quack-mode) quack-mode))
  69     (let ((kw (geiser-syntax--impl-kws geiser-impl--implementation))
  70           (cs (geiser-syntax--case-sensitive geiser-impl--implementation)))
  71       (when kw (font-lock-add-keywords nil kw))
  72       (setq font-lock-keywords-case-fold-search (not cs)))))
  73
  74 \f
  75 ;;; A simple scheme reader
  76
  77 (defvar geiser-syntax--read/buffer-limit nil)
  78
  79 (defsubst geiser-syntax--read/eos ()
  80   (or (eobp)
  81       (and geiser-syntax--read/buffer-limit
  82            (<= geiser-syntax--read/buffer-limit (point)))))
  83
  84 (defsubst geiser-syntax--read/next-char ()
  85   (unless (geiser-syntax--read/eos)
  86     (forward-char)
  87     (char-after)))
  88
  89 (defsubst geiser-syntax--read/token (token)
  90   (geiser-syntax--read/next-char)
  91   (if (listp token) token (list token)))
  92
  93 (defsubst geiser-syntax--read/elisp ()
  94   (ignore-errors (read (current-buffer))))
  95
  96 (defun geiser-syntax--read/symbol ()
  97   (with-syntax-table scheme-mode-syntax-table
  98     (when (re-search-forward "\\(\\sw\\|\\s_\\)+" nil t)
  99       (make-symbol (match-string-no-properties 0)))))
 100
 101 (defun geiser-syntax--read/matching (open close)
 102   (let ((count 1)
 103         (p (1+ (point))))
 104     (while (and (> count 0)
 105                 (geiser-syntax--read/next-char))
 106       (cond ((looking-at-p open) (setq count (1+ count)))
 107             ((looking-at-p close) (setq count (1- count)))))
 108     (buffer-substring-no-properties p (point))))
 109
 110 (defsubst geiser-syntax--read/unprintable ()
 111   (geiser-syntax--read/token
 112    (cons 'unprintable (geiser-syntax--read/matching "<" ">"))))
 113
 114 (defun geiser-syntax--read/skip-comment ()
 115   (while (and (geiser-syntax--read/next-char)
 116               (nth 8 (syntax-ppss))))
 117   (geiser-syntax--read/next-token))
 118
 119 (defun geiser-syntax--read/next-token ()
 120   (skip-syntax-forward "->")
 121   (if (geiser-syntax--read/eos) '(eob)
 122     (case (char-after)
 123       (?\; (geiser-syntax--read/skip-comment))
 124       ((?\( ?\[) (geiser-syntax--read/token 'lparen))
 125       ((?\) ?\]) (geiser-syntax--read/token 'rparen))
 126       (?. (if (memq (car (syntax-after (1+ (point)))) '(0 11 12))
 127               (geiser-syntax--read/token 'dot)
 128             (cons 'atom (geiser-syntax--read/elisp))))
 129       (?\# (case (geiser-syntax--read/next-char)
 130              ('nil '(eob))
 131              (?| (geiser-syntax--read/skip-comment))
 132              (?: (if (geiser-syntax--read/next-char)
 133                      (cons 'kwd (geiser-syntax--read/symbol))
 134                    '(eob)))
 135              (?\\ (cons 'char (geiser-syntax--read/elisp)))
 136              (?\( (geiser-syntax--read/token 'vectorb))
 137              (?\< (geiser-syntax--read/unprintable))
 138              ((?' ?` ?,) (geiser-syntax--read/next-token))
 139              (t (let ((tok (geiser-syntax--read/symbol)))
 140                   (cond ((equal (symbol-name tok) "t") '(boolean . :t))
 141                         ((equal (symbol-name tok) "f") '(boolean . :f))
 142                         (tok (cons 'atom tok))
 143                         (t (geiser-syntax--read/next-token)))))))
 144       (?\' (geiser-syntax--read/token '(quote . quote)))
 145       (?\` (geiser-syntax--read/token
 146             `(backquote . ,backquote-backquote-symbol)))
 147       (?, (if (eq (geiser-syntax--read/next-char) ?@)
 148               (geiser-syntax--read/token
 149                `(splice . ,backquote-splice-symbol))
 150             `(unquote . ,backquote-unquote-symbol)))
 151       (?\" (cons 'string (geiser-syntax--read/elisp)))
 152       (t (cons 'atom (geiser-syntax--read/symbol))))))
 153
 154 (defsubst geiser-syntax--read/match (&rest tks)
 155   (let ((token (geiser-syntax--read/next-token)))
 156     (if (memq (car token) tks) token
 157       (error "Unexpected token: %s" token))))
 158
 159 (defsubst geiser-syntax--read/skip-until (&rest tks)
 160   (let (token)
 161     (while (and (not (memq (car token) tks))
 162                 (not (eq (car token) 'eob)))
 163       (setq token (geiser-syntax--read/next-token)))
 164     token))
 165
 166 (defsubst geiser-syntax--read/try (&rest tks)
 167   (let ((p (point))
 168         (tk (ignore-errors (apply 'geiser-syntax--read/match tks))))
 169     (unless tk (goto-char p))
 170     tk))
 171
 172 (defun geiser-syntax--read/list ()
 173   (cond ((geiser-syntax--read/try 'dot)
 174          (let ((tail (geiser-syntax--read)))
 175            (geiser-syntax--read/skip-until 'eob 'rparen)
 176            tail))
 177         ((geiser-syntax--read/try 'rparen 'eob) nil)
 178         (t (cons (geiser-syntax--read)
 179                  (geiser-syntax--read/list)))))
 180
 181 (defun geiser-syntax--read ()
 182   (let ((token (geiser-syntax--read/next-token))
 183         (max-lisp-eval-depth (max max-lisp-eval-depth 3000)))
 184     (case (car token)
 185       (eob nil)
 186       (lparen (geiser-syntax--read/list))
 187       (vectorb (apply 'vector (geiser-syntax--read/list)))
 188       ((quote backquote unquote splice) (list (cdr token)
 189                                               (geiser-syntax--read)))
 190       (kwd (make-symbol (format ":%s" (cdr token))))
 191       (unprintable (format "#<%s>" (cdr token)))
 192       ((char string atom) (cdr token))
 193       (boolean (cdr token))
 194       (t (error "Reading scheme syntax: unexpected token: %s" token)))))
 195
 196 (defun geiser-syntax--read-from-string (string &optional start end)
 197   (when (stringp string)
 198     (let* ((start (or start 0))
 199            (end (or end (length string)))
 200            (max-lisp-eval-depth (min 20000
 201                                      (max max-lisp-eval-depth (- end start)))))
 202       (with-temp-buffer
 203         (save-excursion (insert string))
 204         (cons (ignore-errors (geiser-syntax--read)) (point))))))
 205
 206 (defun geiser-syntax--form-from-string (s)
 207   (car (geiser-syntax--read-from-string s)))
 208
 209 (defsubst geiser-syntax--form-after-point (&optional boundary)
 210   (let ((geiser-syntax--read/buffer-limit (and (numberp boundary) boundary)))
 211     (save-excursion (values (geiser-syntax--read) (point)))))
 212
 213 (defun geiser-syntax--mapconcat (fun lst sep)
 214   (cond ((null lst) "")
 215         ((not (listp lst)) (format ".%s%s" sep (funcall fun lst)))
 216         ((null (cdr lst)) (format "%s" (funcall fun (car lst))))
 217         (t (format "%s%s%s"
 218                    (funcall fun (car lst))
 219                    sep
 220                    (geiser-syntax--mapconcat fun (cdr lst) sep)))))
 221
 222 (defun geiser-syntax--display (a)
 223   (cond ((null a) "()")
 224         ((eq a :t) "#t")
 225         ((eq a :f) "#f")
 226         ((geiser-syntax--keywordp a) (format "#%s" a))
 227         ((symbolp a) (format "%s" a))
 228         ((equal a "...") "...")
 229         ((stringp a) (format "%S" a))
 230         ((and (listp a) (symbolp (car a))
 231               (equal (symbol-name (car a)) "quote"))
 232          (format "'%s" (geiser-syntax--display (cadr a))))
 233         ((listp a)
 234          (format "(%s)"
 235                  (geiser-syntax--mapconcat 'geiser-syntax--display a " ")))
 236         (t (format "%s" a))))
 237
 238 \f
 239 ;;; Code parsing:
 240
 241 (defsubst geiser-syntax--symbol-at-point ()
 242   (and (not (nth 8 (syntax-ppss)))
 243        (car (geiser-syntax--read-from-string (thing-at-point 'symbol)))))
 244
 245 (defsubst geiser-syntax--skip-comment/string ()
 246   (let ((pos (nth 8 (syntax-ppss))))
 247     (goto-char (or pos (point)))
 248     pos))
 249
 250 (defsubst geiser-syntax--nesting-level ()
 251   (or (nth 0 (syntax-ppss)) 0))
 252
 253 (defsubst geiser-syntax--in-string-p ()
 254   (nth 3 (syntax-ppss)))
 255
 256 (defsubst geiser-syntax--pair-length (p)
 257   (if (cdr (last p)) (1+ (safe-length p)) (length p)))
 258
 259 (defun geiser-syntax--shallow-form (boundary)
 260   (when (looking-at-p "\\s(")
 261     (save-excursion
 262       (forward-char)
 263       (let ((elems))
 264         (ignore-errors
 265           (while (< (point) boundary)
 266             (skip-syntax-forward "-<>")
 267             (when (<= (point) boundary)
 268               (forward-sexp)
 269               (let ((s (thing-at-point 'symbol)))
 270                 (unless (equal "." s)
 271                   (push (car (geiser-syntax--read-from-string s)) elems))))))
 272         (nreverse elems)))))
 273
 274 (defsubst geiser-syntax--keywordp (s)
 275   (and s (symbolp s) (string-match "^:.+" (symbol-name s))))
 276
 277 (defsubst geiser-syntax--symbol-eq (s0 s1)
 278   (and (symbolp s0) (symbolp s1) (equal (symbol-name s0) (symbol-name s1))))
 279
 280 (defun geiser-syntax--scan-sexps (&optional begin)
 281   (let* ((fst (geiser-syntax--symbol-at-point))
 282          (smth (or fst (not (looking-at-p "[\s \s)\s>\s<\n]"))))
 283          (path (and fst `((,fst 0)))))
 284     (save-excursion
 285       (while (not (zerop (geiser-syntax--nesting-level)))
 286         (let ((boundary (point)))
 287           (geiser-syntax--skip-comment/string)
 288           (backward-up-list)
 289           (let ((form (geiser-syntax--shallow-form boundary)))
 290             (when (and (listp form) (car form) (symbolp (car form)))
 291               (let* ((len (geiser-syntax--pair-length form))
 292                      (pos (if smth (1- len) (progn (setq smth t) len)))
 293                      (prev (and (> pos 1) (nth (1- pos) form)))
 294                      (prev (and (geiser-syntax--keywordp prev)
 295                                 (list prev))))
 296                 (push `(,(car form) ,pos ,@prev) path)))))))
 297     (mapcar (lambda (e)
 298               (cons (substring-no-properties (format "%s" (car e))) (cdr e)))
 299             (nreverse path))))
 300
 301 (defsubst geiser-syntax--binding-form-p (bfs sbfs f)
 302   (and (symbolp f)
 303        (let ((f (symbol-name f)))
 304          (or (member f '("define" "define*" "define-syntax"
 305                          "syntax-rules" "lambda" "case-lambda"
 306                          "let" "let*" "let-values" "let*-values"
 307                          "letrec" "letrec*" "parameterize"))
 308              (member f bfs)
 309              (member f sbfs)))))
 310
 311 (defsubst geiser-syntax--binding-form*-p (sbfs f)
 312   (and (symbolp f)
 313        (let ((f (symbol-name f)))
 314          (or (member f '("let*" "let*-values" "letrec" "letrec*"))
 315              (member f sbfs)))))
 316
 317 (defsubst geiser-syntax--if-symbol (x) (and (symbolp x) x))
 318 (defsubst geiser-syntax--if-list (x) (and (listp x) x))
 319
 320 (defsubst geiser-syntax--normalize (vars)
 321   (mapcar (lambda (i)
 322             (let ((i (if (listp i) (car i) i)))
 323               (and (symbolp i) (symbol-name i))))
 324           vars))
 325
 326 (defun geiser-syntax--linearize (form)
 327   (cond ((not (listp form)) (list form))
 328         ((null form) nil)
 329         (t (cons (car form) (geiser-syntax--linearize (cdr form))))))
 330
 331 (defun geiser-syntax--scan-locals (bfs sbfs form nesting locals)
 332   (if (or (null form) (not (listp form)))
 333       (geiser-syntax--normalize locals)
 334     (if (not (geiser-syntax--binding-form-p bfs sbfs (car form)))
 335         (geiser-syntax--scan-locals bfs sbfs
 336                                     (car (last form))
 337                                     (1- nesting) locals)
 338       (let* ((head (car form))
 339              (name (geiser-syntax--if-symbol (cadr form)))
 340              (names (if name (geiser-syntax--if-list (caddr form))
 341                       (geiser-syntax--if-list (cadr form))))
 342              (bns (and name
 343                        (geiser-syntax--binding-form-p bfs sbfs (car names))))
 344              (rest (if (and name (not bns)) (cdddr form) (cddr form)))
 345              (use-names (and (or rest
 346                                  (< nesting 1)
 347                                  (geiser-syntax--binding-form*-p sbfs head))
 348                              (not bns))))
 349         (when name (push name locals))
 350         (when (geiser-syntax--symbol-eq head 'case-lambda)
 351           (dolist (n (and (> nesting 0) (caar (last form))))
 352             (when n (push n locals)))
 353           (setq rest (and (> nesting 0) (cdr form)))
 354           (setq use-names nil))
 355         (when (geiser-syntax--symbol-eq head 'syntax-rules)
 356           (dolist (n (and (> nesting 0) (cdaar (last form))))
 357             (when n (push n locals)))
 358           (setq rest (and (> nesting 0) (cdr form))))
 359         (when use-names
 360           (dolist (n (geiser-syntax--linearize names))
 361             (let ((xs (if (and (listp n) (listp (car n))) (car n) (list n))))
 362               (dolist (x xs) (when x (push x locals))))))
 363         (dolist (f (butlast rest))
 364           (when (and (listp f)
 365                      (geiser-syntax--symbol-eq (car f) 'define)
 366                      (cadr f))
 367             (push (cadr f) locals)))
 368         (geiser-syntax--scan-locals bfs sbfs
 369                                     (car (last (or rest names)))
 370                                     (1- nesting)
 371                                     locals)))))
 372
 373 (defun geiser-syntax--locals-around-point (bfs sbfs)
 374   (when (eq major-mode 'scheme-mode)
 375     (save-excursion
 376       (let ((sym (unless (geiser-syntax--skip-comment/string)
 377                    (thing-at-point 'symbol))))
 378         (skip-syntax-forward "->")
 379         (let ((boundary (point))
 380               (nesting (geiser-syntax--nesting-level)))
 381           (while (not (zerop (geiser-syntax--nesting-level)))
 382             (backward-up-list))
 383           (multiple-value-bind (form end)
 384               (geiser-syntax--form-after-point boundary)
 385             (delete sym
 386                     (geiser-syntax--scan-locals bfs
 387                                                 sbfs
 388                                                 form
 389                                                 (1- nesting)
 390                                                 '()))))))))
 391
 392 \f
 393 ;;; Fontify strings as Scheme code:
 394
 395 (defun geiser-syntax--font-lock-buffer ()
 396   (let ((name " *geiser font lock*"))
 397     (or (get-buffer name)
 398         (let ((buffer (get-buffer-create name)))
 399           (set-buffer buffer)
 400           (let ((geiser-default-implementation
 401                  (or geiser-default-implementation
 402                      (car geiser-active-implementations))))
 403             (scheme-mode))
 404           buffer))))
 405
 406 (defun geiser-syntax--scheme-str (str)
 407   (save-current-buffer
 408     (set-buffer (geiser-syntax--font-lock-buffer))
 409     (erase-buffer)
 410     (insert str)
 411     (let ((font-lock-verbose nil)) (font-lock-fontify-buffer))
 412     (buffer-string)))
 413
 414 \f
 415 (provide 'geiser-syntax)