elisp/geiser-mode.el

   1 ;; geiser-mode.el -- minor mode for scheme buffers
   2
   3 ;; Copyright (C) 2009, 2010, 2011, 2012, 2013, 2014, 2015, 2016, 2017 Jose Antonio Ortega Ruiz
   4
   5 ;; This program is free software; you can redistribute it and/or
   6 ;; modify it under the terms of the Modified BSD License. You should
   7 ;; have received a copy of the license along with this program. If
   8 ;; not, see <http://www.xfree86.org/3.3.6/COPYRIGHT2.html#5>.
   9
  10 ;; Start date: Sun Feb 08, 2009 15:13
  11
  12 \f
  13
  14 (require 'geiser-repl)
  15 (require 'geiser-menu)
  16 (require 'geiser-doc)
  17 (require 'geiser-compile)
  18 (require 'geiser-completion)
  19 (require 'geiser-company)
  20 (require 'geiser-xref)
  21 (require 'geiser-edit)
  22 (require 'geiser-autodoc)
  23 (require 'geiser-debug)
  24 (require 'geiser-syntax)
  25 (require 'geiser-impl)
  26 (require 'geiser-eval)
  27 (require 'geiser-popup)
  28 (require 'geiser-custom)
  29 (require 'geiser-base)
  30
  31 \f
  32 ;;; Customization:
  33
  34 (defgroup geiser-mode nil
  35   "Mode enabling Geiser abilities in Scheme buffers &co.."
  36   :group 'geiser)
  37
  38 (geiser-custom--defcustom geiser-mode-auto-p t
  39   "Whether `geiser-mode' should be active by default in all scheme buffers."
  40   :group 'geiser-mode
  41   :type 'boolean)
  42
  43 (geiser-custom--defcustom geiser-mode-start-repl-p nil
  44   "Whether a REPL should be automatically started if one is not
  45 active when `geiser-mode' is activated in a buffer."
  46   :group 'geiser-mode
  47   :type 'boolean)
  48
  49 (geiser-custom--defcustom geiser-mode-autodoc-p t
  50   "Whether `geiser-autodoc-mode' gets enabled by default in Scheme buffers."
  51   :group 'geiser-mode
  52   :group 'geiser-autodoc
  53   :type 'boolean)
  54
  55 (geiser-custom--defcustom geiser-mode-company-p t
  56   "Whether to use company-mode for completion, if available."
  57   :group 'geiser-mode
  58   :type 'boolean)
  59
  60 (geiser-custom--defcustom geiser-mode-smart-tab-p nil
  61   "Whether `geiser-smart-tab-mode' gets enabled by default in Scheme buffers."
  62   :group 'geiser-mode
  63   :type 'boolean)
  64
  65 (geiser-custom--defcustom geiser-mode-eval-last-sexp-to-buffer nil
  66   "Whether `eval-last-sexp' prints results to buffer"
  67   :group 'geiser-mode
  68   :type 'boolean)
  69
  70 (geiser-custom--defcustom geiser-mode-eval-to-buffer-prefix " "
  71   "When `geiser-mode-eval-last-sexp-to-buffer', the prefix string which will prepend to results"
  72   :group 'geiser-mode
  73   :type 'string)
  74
  75 (geiser-custom--defcustom geiser-mode-eval-to-buffer-transformer nil
  76   "When `geiser-mode-eval-last-sexp-to-buffer', the result will be transformed using this function
  77 default behavior is just prepend with `geiser-mode-eval-to-buffer-prefix'
  78 takes two arguments: `msg' and `is-error?'
  79 `msg' is the result string going to be transformed,
  80 `is-error?' is a bool indicate whether the result is an error msg
  81 "
  82   :group 'geiser-mode
  83   :type 'function)
  84
  85
  86 \f
  87 ;;; Evaluation commands:
  88
  89 (defun geiser--go-to-repl ()
  90   (switch-to-geiser nil nil (current-buffer))
  91   (push-mark)
  92   (goto-char (point-max)))
  93
  94 (defun geiser-eval-region (start end &optional and-go raw nomsg)
  95   "Eval the current region in the Geiser REPL.
  96
  97 With prefix, goes to the REPL buffer afterwards (as
  98 `geiser-eval-region-and-go')"
  99   (interactive "rP")
 100   (save-restriction
 101     (narrow-to-region start end)
 102     (check-parens))
 103   (geiser-debug--send-region nil
 104                              start
 105                              end
 106                              (and and-go 'geiser--go-to-repl)
 107                              (not raw)
 108                              nomsg))
 109
 110 (defun geiser-eval-region-and-go (start end)
 111   "Eval the current region in the Geiser REPL and visit it afterwads."
 112   (interactive "r")
 113   (geiser-eval-region start end t))
 114
 115 (geiser-impl--define-caller geiser-eval--bounds eval-bounds ()
 116   "A pair with the bounds of a buffer to be evaluated, defaulting
 117   to (cons (point-min) . (point-max)).")
 118
 119 (defun geiser-eval-buffer (&optional and-go raw nomsg)
 120   "Eval the current buffer in the Geiser REPL.
 121
 122 With prefix, goes to the REPL buffer afterwards (as
 123 `geiser-eval-buffer-and-go')"
 124   (interactive "P")
 125   (let* ((bounds (geiser-eval--bounds geiser-impl--implementation))
 126          (from (or (car bounds) (point-min)))
 127          (to (or (cdr bounds) (point-max))))
 128     (geiser-eval-region from to and-go raw nomsg)))
 129
 130 (defun geiser-eval-buffer-and-go ()
 131   "Eval the current buffer in the Geiser REPL and visit it afterwads."
 132   (interactive)
 133   (geiser-eval-buffer t))
 134
 135 (defun geiser-eval-definition (&optional and-go)
 136   "Eval the current definition in the Geiser REPL.
 137
 138 With prefix, goes to the REPL buffer afterwards (as
 139 `geiser-eval-definition-and-go')"
 140   (interactive "P")
 141   (save-excursion
 142     (end-of-defun)
 143     (let ((end (point)))
 144       (beginning-of-defun)
 145       (geiser-eval-region (point) end and-go t))))
 146
 147 (defun geiser-eval-definition-and-go ()
 148   "Eval the current definition in the Geiser REPL and visit it afterwads."
 149   (interactive)
 150   (geiser-eval-definition t))
 151
 152 (defun geiser-eval-last-sexp (print-to-buffer-p)
 153   "Eval the previous sexp in the Geiser REPL.
 154
 155 With a prefix, revert the effect of `geiser-mode-eval-last-sexp-to-buffer' "
 156   (interactive "P")
 157   (let* (bosexp
 158          (eosexp (save-excursion (backward-sexp)
 159                                  (setq bosexp (point))
 160                                  (forward-sexp)
 161                                  (point)))
 162          (ret-transformer (or geiser-mode-eval-to-buffer-transformer
 163                               (lambda (msg is-error?)
 164                                 (format "%s%s%s" geiser-mode-eval-to-buffer-prefix
 165                                         (if is-error? "ERROR" "") msg))))
 166          (ret (save-excursion
 167                 (geiser-eval-region bosexp ;beginning of sexp
 168                                     eosexp ;end of sexp
 169                                     nil
 170                                     t
 171                                     print-to-buffer-p)))
 172          (err (geiser-eval--retort-error ret))
 173          (will-eval-to-buffer (if print-to-buffer-p
 174                                   (not geiser-mode-eval-last-sexp-to-buffer)
 175                                 geiser-mode-eval-last-sexp-to-buffer))
 176          (str (geiser-eval--retort-result-str ret (when will-eval-to-buffer ""))))
 177     (cond  ((not will-eval-to-buffer) str)
 178            (err (insert (funcall ret-transformer (geiser-eval--error-str err) t)))
 179            ((string= "" str))
 180            (t (push-mark)
 181               (insert (funcall ret-transformer str nil))))))
 182
 183 (defun geiser-compile-definition (&optional and-go)
 184   "Compile the current definition in the Geiser REPL.
 185
 186 With prefix, goes to the REPL buffer afterwards (as
 187 `geiser-eval-definition-and-go')"
 188   (interactive "P")
 189   (save-excursion
 190     (end-of-defun)
 191     (let ((end (point)))
 192       (beginning-of-defun)
 193       (geiser-debug--send-region t
 194                                  (point)
 195                                  end
 196                                  (and and-go 'geiser--go-to-repl)
 197                                  t))))
 198
 199 (defun geiser-compile-definition-and-go ()
 200   "Compile the current definition in the Geiser REPL and visit it afterwads."
 201   (interactive)
 202   (geiser-compile-definition t))
 203
 204 (defun geiser-expand-region (start end &optional all raw)
 205   "Macro-expand the current region and display it in a buffer.
 206 With prefix, recursively macro-expand the resulting expression."
 207   (interactive "rP")
 208   (geiser-debug--expand-region start end all (not raw)))
 209
 210 (defun geiser-expand-definition (&optional all)
 211   "Macro-expand the current definition.
 212
 213 With prefix, recursively macro-expand the resulting expression."
 214   (interactive "P")
 215   (save-excursion
 216     (end-of-defun)
 217     (let ((end (point)))
 218       (beginning-of-defun)
 219       (geiser-expand-region (point) end all t))))
 220
 221 (defun geiser-expand-last-sexp (&optional all)
 222   "Macro-expand the previous sexp.
 223
 224 With prefix, recursively macro-expand the resulting expression."
 225   (interactive "P")
 226   (geiser-expand-region (save-excursion (backward-sexp) (point))
 227                         (point)
 228                         all
 229                         t))
 230
 231 (defun geiser-set-scheme ()
 232   "Associates current buffer with a given Scheme implementation."
 233   (interactive)
 234   (geiser-syntax--remove-kws)
 235   (let ((impl (geiser-impl--read-impl)))
 236     (geiser-impl--set-buffer-implementation impl)
 237     (geiser-repl--set-up-repl impl)
 238     (geiser-syntax--add-kws)
 239     (geiser-syntax--fontify)))
 240
 241 (defun geiser-mode-switch-to-repl (arg)
 242   "Switches to Geiser REPL.
 243
 244 With prefix, try to enter the current buffer's module."
 245   (interactive "P")
 246   (if arg
 247       (switch-to-geiser-module (geiser-eval--get-module) (current-buffer))
 248     (switch-to-geiser nil nil (current-buffer))))
 249
 250 (defun geiser-mode-switch-to-repl-and-enter ()
 251   "Switches to Geiser REPL and enters current buffer's module."
 252   (interactive)
 253   (geiser-mode-switch-to-repl t))
 254
 255 (defun geiser-restart-repl ()
 256   "Restarts the REPL associated with the current buffer."
 257   (interactive)
 258   (let ((b (current-buffer)))
 259     (geiser-mode-switch-to-repl nil)
 260     (comint-kill-subjob)
 261     (sit-for 0.1) ;; ugly hack; but i don't care enough to fix it
 262     (call-interactively 'run-geiser)
 263     (sit-for 0.2) ;; ditto
 264     (goto-char (point-max))
 265     (pop-to-buffer b)))
 266
 267 (defun geiser-squarify (n)
 268   "Toggle between () and [] for current form.
 269
 270 With numeric prefix, perform that many toggles, forward for
 271 positive values and backward for negative."
 272   (interactive "p")
 273   (let ((pared (and (boundp 'paredit-mode) paredit-mode))
 274         (fwd (> n 0))
 275         (steps (abs n)))
 276     (when (and pared (fboundp 'paredit-mode)) (paredit-mode -1))
 277     (unwind-protect
 278         (save-excursion
 279           (unless (looking-at-p "\\s(") (backward-up-list))
 280           (while (> steps 0)
 281             (let ((p (point))
 282                   (round (looking-at-p "(")))
 283               (forward-sexp)
 284               (backward-delete-char 1)
 285               (insert (if round "]" ")"))
 286               (goto-char p)
 287               (delete-char 1)
 288               (insert (if round "[" "("))
 289               (setq steps (1- steps))
 290               (backward-char)
 291               (condition-case nil
 292                   (progn (when fwd (forward-sexp 2))
 293                          (backward-sexp))
 294                 (error (setq steps 0))))))
 295       (when (and pared (fboundp 'paredit-mode)) (paredit-mode 1)))))
 296
 297 (defun geiser-insert-lambda (&optional full)
 298   "Insert λ at point.  With prefix, inserts (λ ())."
 299   (interactive "P")
 300   (if (not full)
 301       (insert (make-char 'greek-iso8859-7 107))
 302     (insert "(" (make-char 'greek-iso8859-7 107) " ())")
 303     (backward-char 2)))
 304
 305 \f
 306 ;;; Geiser mode:
 307
 308 (make-variable-buffer-local
 309  (defvar geiser-mode-string nil
 310    "Modeline indicator for geiser-mode"))
 311
 312 (defun geiser-mode--lighter ()
 313   (or geiser-mode-string
 314       (format " %s" (or (geiser-impl--impl-str) "G"))))
 315
 316 (defvar geiser-mode-map (make-sparse-keymap))
 317
 318 (define-minor-mode geiser-mode
 319   "Toggle Geiser's mode.
 320
 321 With no argument, this command toggles the mode.
 322 Non-null prefix argument turns on the mode.
 323 Null prefix argument turns off the mode.
 324
 325 When Geiser mode is enabled, a host of nice utilities for
 326 interacting with the Geiser REPL is at your disposal.
 327 \\{geiser-mode-map}"
 328   :init-value nil
 329   :lighter (:eval (geiser-mode--lighter))
 330   :group 'geiser-mode
 331   :keymap geiser-mode-map
 332   (when geiser-mode (geiser-impl--set-buffer-implementation nil t))
 333   (setq geiser-autodoc-mode-string "/A")
 334   (setq geiser-smart-tab-mode-string "/T")
 335   (geiser-company--setup (and geiser-mode geiser-mode-company-p))
 336   (geiser-completion--setup geiser-mode)
 337   (when geiser-mode-autodoc-p
 338     (geiser-autodoc-mode (if geiser-mode 1 -1)))
 339   (when geiser-mode-smart-tab-p
 340     (geiser-smart-tab-mode (if geiser-mode 1 -1)))
 341   (geiser-syntax--add-kws)
 342   (when (and geiser-mode
 343              geiser-mode-start-repl-p
 344              (not (geiser-syntax--font-lock-buffer-p))
 345              (not (geiser-repl--connection*)))
 346     (save-window-excursion (run-geiser geiser-impl--implementation))))
 347
 348 (defun turn-on-geiser-mode ()
 349   "Enable `geiser-mode' (in a Scheme buffer)."
 350   (interactive)
 351   (geiser-mode 1))
 352
 353 (defun turn-off-geiser-mode ()
 354   "Disable `geiser-mode' (in a Scheme buffer)."
 355   (interactive)
 356   (geiser-mode -1))
 357
 358 (defun geiser-mode--maybe-activate ()
 359   (when (and geiser-mode-auto-p (eq major-mode 'scheme-mode))
 360     (turn-on-geiser-mode)))
 361
 362 \f
 363 ;;; Keys:
 364
 365 (geiser-menu--defmenu geiserm geiser-mode-map
 366   ("Eval sexp before point" "\C-x\C-e" geiser-eval-last-sexp)
 367   ("Eval definition" ("\M-\C-x" "\C-c\C-c") geiser-eval-definition)
 368   ("Eval definition and go" ("\C-c\M-e" "\C-c\M-e")
 369    geiser-eval-definition-and-go)
 370   ("Eval region" "\C-c\C-r" geiser-eval-region :enable mark-active)
 371   ("Eval region and go" "\C-c\M-r" geiser-eval-region-and-go
 372    geiser-eval-region :enable mark-active)
 373   ("Eval buffer" "\C-c\C-b" geiser-eval-buffer)
 374   ("Eval buffer and go" "\C-c\M-b" geiser-eval-buffer-and-go)
 375   ("Load scheme file..." "\C-c\C-l" geiser-load-file)
 376   (menu "Macroexpand"
 377         ("Sexp before point" ("\C-c\C-m\C-e" "\C-c\C-me")
 378          geiser-expand-last-sexp)
 379         ("Region" ("\C-c\C-m\C-r" "\C-c\C-mr") geiser-expand-region)
 380         ("Definition" ("\C-c\C-m\C-x" "\C-c\C-mx") geiser-expand-definition))
 381   --
 382   ("Symbol documentation" ("\C-c\C-d\C-d" "\C-c\C-dd")
 383    geiser-doc-symbol-at-point :enable (geiser--symbol-at-point))
 384   ("Short symbol documentation" ("\C-c\C-d\C-s" "\C-c\C-ds")
 385    geiser-autodoc-show :enable (geiser--symbol-at-point))
 386   ("Module documentation" ("\C-c\C-d\C-m" "\C-c\C-dm") geiser-doc-module)
 387   ("Symbol manual lookup" ("\C-c\C-d\C-i" "\C-c\C-di")
 388    geiser-doc-look-up-manual :enable (geiser-doc--manual-available-p))
 389   (mode "Autodoc mode" ("\C-c\C-d\C-a" "\C-c\C-da") geiser-autodoc-mode)
 390   --
 391   ("Compile buffer" "\C-c\C-k" geiser-compile-current-buffer)
 392   ("Switch to REPL" "\C-c\C-z" geiser-mode-switch-to-repl)
 393   ("Switch to REPL and enter module" "\C-c\C-a"
 394    geiser-mode-switch-to-repl-and-enter)
 395   ("Set Scheme..." "\C-c\C-s" geiser-set-scheme)
 396   --
 397   ("Edit symbol at point" "\M-." geiser-edit-symbol-at-point
 398    :enable (geiser--symbol-at-point))
 399   ("Go to previous definition" "\M-," geiser-pop-symbol-stack)
 400   ("Complete symbol" ((kbd "M-TAB")) completion-at-point
 401    :enable (geiser--symbol-at-point))
 402   ("Complete module name" ((kbd "M-`") (kbd "C-."))
 403    geiser-completion--complete-module)
 404   ("Edit module" ("\C-c\C-e\C-m" "\C-c\C-em") geiser-edit-module)
 405   ("Add to load path..." ("\C-c\C-e\C-l" "\C-c\C-el") geiser-add-to-load-path)
 406   ("Toggle ()/[]" ("\C-c\C-e\C-[" "\C-c\C-e[") geiser-squarify)
 407   ("Insert λ" ("\C-c\\" "\C-c\C-\\") geiser-insert-lambda)
 408   --
 409   ("Callers" ((kbd "C-c <")) geiser-xref-callers
 410    :enable (and (geiser-eval--supported-p 'callers)
 411                 (geiser--symbol-at-point)))
 412   ("Callees" ((kbd "C-c >")) geiser-xref-callees
 413    :enable (and (geiser-eval--supported-p 'callees)
 414                 (geiser--symbol-at-point)))
 415   --
 416   (mode "Smart TAB mode" nil geiser-smart-tab-mode)
 417   --
 418   (custom "Customize Geiser mode" geiser-mode))
 419
 420 (define-key geiser-mode-map [menu-bar scheme] 'undefined)
 421
 422 ;; (geiser-mode--triple-chord ?x ?m 'geiser-xref-generic-methods)
 423
 424 \f
 425 ;;; Reload support:
 426
 427 (defun geiser-mode--buffers ()
 428   (let ((buffers))
 429     (dolist (buffer (buffer-list))
 430       (when (buffer-live-p buffer)
 431         (set-buffer buffer)
 432         (when geiser-mode
 433           (push (cons buffer geiser-impl--implementation) buffers))))
 434     buffers))
 435
 436 (defun geiser-mode--restore (buffers)
 437   (dolist (b buffers)
 438     (when (buffer-live-p (car b))
 439       (set-buffer (car b))
 440       (when (cdr b)
 441         (geiser-impl--set-buffer-implementation (cdr b)))
 442       (geiser-mode 1))))
 443
 444 (defun geiser-mode-unload-function ()
 445   (dolist (b (geiser-mode--buffers))
 446     (with-current-buffer (car b) (geiser-mode nil))))
 447
 448 \f
 449 (provide 'geiser-mode)