elisp/geiser-repl.el

   1 ;;; geiser-repl.el --- Geiser's REPL
   2
   3 ;; Copyright (C) 2009, 2010, 2011, 2012 Jose Antonio Ortega Ruiz
   4
   5 ;; This program is free software; you can redistribute it and/or
   6 ;; modify it under the terms of the Modified BSD License. You should
   7 ;; have received a copy of the license along with this program. If
   8 ;; not, see <http://www.xfree86.org/3.3.6/COPYRIGHT2.html#5>.
   9
  10 \f
  11
  12 (require 'geiser-company)
  13 (require 'geiser-compile)
  14 (require 'geiser-doc)
  15 (require 'geiser-autodoc)
  16 (require 'geiser-edit)
  17 (require 'geiser-completion)
  18 (require 'geiser-impl)
  19 (require 'geiser-eval)
  20 (require 'geiser-connection)
  21 (require 'geiser-menu)
  22 (require 'geiser-image)
  23 (require 'geiser-custom)
  24 (require 'geiser-base)
  25
  26 (require 'comint)
  27 (require 'compile)
  28 (require 'scheme)
  29
  30 \f
  31 ;;; Customization:
  32
  33 (defgroup geiser-repl nil
  34   "Interacting with the Geiser REPL."
  35   :group 'geiser)
  36
  37 (geiser-custom--defcustom geiser-repl-use-other-window t
  38   "Whether to Use a window other than the current buffer's when
  39 switching to the Geiser REPL buffer."
  40   :type 'boolean
  41   :group 'geiser-repl)
  42
  43 (geiser-custom--defcustom geiser-repl-window-allow-split t
  44   "Whether to allow window splitting when switching to the Geiser
  45 REPL buffer."
  46   :type 'boolean
  47   :group 'geiser-repl)
  48
  49 (geiser-custom--defcustom geiser-repl-history-filename
  50     (expand-file-name "~/.geiser_history")
  51   "File where REPL input history is saved, so that it persists between sessions.
  52
  53 This is actually the base name: the concrete Scheme
  54 implementation name gets appended to it."
  55   :type 'filename
  56   :group 'geiser-repl)
  57
  58 (geiser-custom--defcustom geiser-repl-history-size comint-input-ring-size
  59   "Maximum size of the saved REPL input history."
  60   :type 'integer
  61   :group 'geiser-repl)
  62
  63 (geiser-custom--defcustom geiser-repl-history-no-dups-p t
  64    "Whether to skip duplicates when recording history."
  65    :type 'boolean
  66    :group 'geiser-repl)
  67
  68 (geiser-custom--defcustom geiser-repl-autodoc-p t
  69   "Whether to enable `geiser-autodoc-mode' in the REPL by default."
  70   :type 'boolean
  71   :group 'geiser-repl)
  72
  73 (geiser-custom--defcustom geiser-repl-company-p t
  74   "Whether to use company-mode for completion, if available."
  75   :group 'geiser-mode
  76   :type 'boolean)
  77
  78 (geiser-custom--defcustom geiser-repl-read-only-prompt-p t
  79   "Whether the REPL's prompt should be read-only."
  80   :type 'boolean
  81   :group 'geiser-repl)
  82
  83 (geiser-custom--defcustom geiser-repl-auto-indent-p t
  84   "Whether newlines for incomplete sexps are autoindented."
  85   :type 'boolean
  86   :group 'geiser-repl)
  87
  88 (geiser-custom--defcustom geiser-repl-forget-old-errors-p t
  89   "Whether to forget old errors upon entering a new expression.
  90
  91 When on (the default), every time a new expression is entered in
  92 the REPL old error messages are flushed, and using \\[next-error]
  93 afterwards will jump only to error locations produced by the new
  94 expression, if any."
  95   :type 'boolean
  96   :group 'geiser-repl)
  97
  98 (geiser-custom--defcustom geiser-repl-query-on-exit-p nil
  99   "Whether to prompt for confirmation on \\[geiser-repl-exit]."
 100   :type 'boolean
 101   :group 'geiser-repl)
 102
 103 (geiser-custom--defcustom geiser-repl-default-host "localhost"
 104   "Default host when connecting to remote REPLs."
 105   :type 'string
 106   :group 'geiser-repl)
 107
 108 (geiser-custom--defcustom geiser-repl-default-port 37146
 109   "Default port for connecting to remote REPLs."
 110   :type 'integer
 111   :group 'geiser-repl)
 112
 113 (geiser-custom--defcustom geiser-repl-startup-time 10000
 114   "Time, in milliseconds, to wait for Racket to startup.
 115 If you have a slow system, try to increase this time."
 116   :type 'integer
 117   :group 'geiser-repl)
 118
 119 (geiser-custom--defcustom geiser-repl-inline-images-p t
 120   "Whether to display inline images in the REPL."
 121   :type 'boolean
 122   :group 'geiser-repl)
 123
 124 (geiser-custom--defcustom geiser-repl-auto-display-images-p t
 125   "Whether to automatically invoke the external viewer to display
 126 images popping up in the REPL.
 127
 128 See also `geiser-debug-auto-display-images-p'."
 129   :type 'boolean
 130   :group 'geiser-repl)
 131
 132 (geiser-custom--defface repl-input
 133   'comint-highlight-input geiser-repl "evaluated input highlighting")
 134
 135 (geiser-custom--defface repl-prompt
 136   'comint-highlight-prompt geiser-repl "REPL prompt")
 137
 138
 139 \f
 140 ;;; Implementation-dependent parameters
 141
 142 (geiser-impl--define-caller geiser-repl--binary binary ()
 143   "A variable or function returning the path to the scheme binary
 144 for this implementation.")
 145
 146 (geiser-impl--define-caller geiser-repl--arglist arglist ()
 147   "A function taking no arguments and returning a list of
 148 arguments to be used when invoking the scheme binary.")
 149
 150 (geiser-impl--define-caller geiser-repl--prompt-regexp prompt-regexp ()
 151   "A variable (or thunk returning a value) giving the regular
 152 expression for this implementation's geiser scheme prompt.")
 153
 154 (geiser-impl--define-caller
 155     geiser-repl--debugger-prompt-regexp debugger-prompt-regexp ()
 156   "A variable (or thunk returning a value) giving the regular
 157 expression for this implementation's debugging prompt.")
 158
 159 (geiser-impl--define-caller geiser-repl--startup repl-startup (remote)
 160   "Function taking no parameters that is called after the REPL
 161 has been initialised. All Geiser functionality is available to
 162 you at that point.")
 163
 164 (geiser-impl--define-caller geiser-repl--enter-cmd enter-command (module)
 165   "Function taking a module designator and returning a REPL enter
 166 module command as a string")
 167
 168 (geiser-impl--define-caller geiser-repl--import-cmd import-command (module)
 169   "Function taking a module designator and returning a REPL import
 170 module command as a string")
 171
 172 (geiser-impl--define-caller geiser-repl--exit-cmd exit-command ()
 173   "Function returning the REPL exit command as a string")
 174
 175 \f
 176 ;;; Geiser REPL buffers and processes:
 177
 178 (defvar geiser-repl--repls nil)
 179 (defvar geiser-repl--closed-repls nil)
 180
 181 (make-variable-buffer-local
 182  (defvar geiser-repl--repl nil))
 183
 184 (defsubst geiser-repl--set-this-buffer-repl (r)
 185   (setq geiser-repl--repl r))
 186
 187 (defun geiser-repl--live-p ()
 188   (and geiser-repl--repl
 189        (get-buffer-process geiser-repl--repl)))
 190
 191 (defun geiser-repl--repl/impl (impl &optional repls)
 192   (catch 'repl
 193     (dolist (repl (or repls geiser-repl--repls))
 194       (when (buffer-live-p repl)
 195         (with-current-buffer repl
 196           (when (eq geiser-impl--implementation impl)
 197             (throw 'repl repl)))))))
 198
 199 (defun geiser-repl--set-up-repl (impl)
 200   (or (and (not impl) geiser-repl--repl)
 201       (setq geiser-repl--repl
 202             (let ((impl (or impl
 203                             geiser-impl--implementation
 204                             (geiser-impl--guess))))
 205               (when impl (geiser-repl--repl/impl impl))))))
 206
 207 (defun geiser-repl--active-impls ()
 208   (let ((act))
 209     (dolist (repl geiser-repl--repls act)
 210       (with-current-buffer repl
 211         (add-to-list 'act geiser-impl--implementation)))))
 212
 213 (defsubst geiser-repl--repl-name (impl)
 214   (format "%s REPL" (geiser-impl--impl-str impl)))
 215
 216 (defsubst geiser-repl--buffer-name (impl)
 217   (format "* %s *" (geiser-repl--repl-name impl)))
 218
 219 (defun geiser-repl--switch-to-buffer (buffer)
 220   (unless (eq buffer (current-buffer))
 221     (let ((pop-up-windows geiser-repl-window-allow-split))
 222       (if geiser-repl-use-other-window
 223           (switch-to-buffer-other-window buffer)
 224         (switch-to-buffer buffer)))))
 225
 226 (defun geiser-repl--to-repl-buffer (impl)
 227   (unless (and (eq major-mode 'geiser-repl-mode)
 228                (eq geiser-impl--implementation impl)
 229                (not (get-buffer-process (current-buffer))))
 230     (let* ((old (geiser-repl--repl/impl impl geiser-repl--closed-repls))
 231            (old (and (buffer-live-p old)
 232                      (not (get-buffer-process old))
 233                      old)))
 234       (geiser-repl--switch-to-buffer
 235        (or old (generate-new-buffer (geiser-repl--buffer-name impl))))
 236       (unless old
 237         (geiser-repl-mode)
 238         (geiser-impl--set-buffer-implementation impl)))))
 239
 240 (defun geiser-repl--read-impl (prompt &optional active)
 241   (geiser-impl--read-impl prompt (and active (geiser-repl--active-impls))))
 242
 243 (defsubst geiser-repl--only-impl-p ()
 244   (and (null (cdr geiser-active-implementations))
 245        (car geiser-active-implementations)))
 246
 247 (defun geiser-repl--get-impl (prompt)
 248   (or (geiser-repl--only-impl-p)
 249       (and (eq major-mode 'geiser-repl-mode) geiser-impl--implementation)
 250       (geiser-repl--read-impl prompt)))
 251
 252 \f
 253 ;;; REPL connections
 254
 255 (make-variable-buffer-local
 256  (defvar geiser-repl--address nil))
 257
 258 (make-variable-buffer-local
 259  (defvar geiser-repl--connection nil))
 260
 261 (defun geiser-repl--remote-p () geiser-repl--address)
 262
 263 (defsubst geiser-repl--host () (car geiser-repl--address))
 264 (defsubst geiser-repl--port () (cdr geiser-repl--address))
 265
 266 (defun geiser-repl--read-address (&optional host port)
 267   (let ((defhost (or (geiser-repl--host) geiser-repl-default-host))
 268         (defport (or (geiser-repl--port) geiser-repl-default-port)))
 269     (cons (or host
 270               (read-string (format "Host (default %s): " defhost)
 271                            nil nil defhost))
 272           (or port (read-number "Port: " defport)))))
 273
 274 (defun geiser-repl--autodoc-mode (n)
 275   (when (or geiser-repl-autodoc-p (< n 0))
 276     (geiser--save-msg (geiser-autodoc-mode n))))
 277
 278 (defun geiser-repl--save-remote-data (address)
 279   (setq geiser-repl--address address)
 280   (setq header-line-format (and address
 281                                 (format "Host: %s   Port: %s"
 282                                         (geiser-repl--host)
 283                                         (geiser-repl--port)))))
 284
 285 (defun geiser-repl--output-filter (txt)
 286   (geiser-con--connection-update-debugging geiser-repl--connection txt)
 287   (geiser-image--replace-images geiser-repl-inline-images-p
 288                                 geiser-repl-auto-display-images-p)
 289   (when (string-match-p (geiser-con--connection-prompt geiser-repl--connection)
 290                         txt)
 291     (geiser-autodoc--disinhibit-autodoc)))
 292
 293 (defun geiser-repl--start-repl (impl address)
 294   (message "Starting Geiser REPL for %s ..." impl)
 295   (geiser-repl--to-repl-buffer impl)
 296   (sit-for 0)
 297   (goto-char (point-max))
 298   (geiser-repl--autodoc-mode -1)
 299   (let* ((prompt-rx (geiser-repl--prompt-regexp impl))
 300          (deb-prompt-rx (geiser-repl--debugger-prompt-regexp impl))
 301          (prompt (geiser-con--combined-prompt prompt-rx deb-prompt-rx)))
 302     (unless prompt-rx
 303       (error "Sorry, I don't know how to start a REPL for %s" impl))
 304     (geiser-repl--save-remote-data address)
 305     (geiser-repl--start-scheme impl address prompt)
 306     (geiser-repl--quit-setup)
 307     (geiser-repl--history-setup)
 308     (add-to-list 'geiser-repl--repls (current-buffer))
 309     (geiser-repl--set-this-buffer-repl (current-buffer))
 310     (setq geiser-repl--connection
 311           (geiser-con--make-connection (get-buffer-process (current-buffer))
 312                                        prompt-rx
 313                                        deb-prompt-rx))
 314     (geiser-repl--startup impl address)
 315     (geiser-repl--autodoc-mode 1)
 316     (geiser-company--setup geiser-repl-company-p)
 317     (add-hook 'comint-output-filter-functions
 318               'geiser-repl--output-filter
 319               nil
 320               t)
 321     (message "%s up and running!" (geiser-repl--repl-name impl))))
 322
 323 (defun geiser-repl--start-scheme (impl address prompt)
 324   (setq comint-prompt-regexp prompt)
 325   (let* ((name (geiser-repl--repl-name impl))
 326          (buff (current-buffer))
 327          (args (if address (list address)
 328                  `(,(geiser-repl--binary impl)
 329                    nil
 330                    ,@(geiser-repl--arglist impl)))))
 331     (condition-case err
 332         (apply 'make-comint-in-buffer `(,name ,buff ,@args))
 333       (error (insert "Unable to start REPL:\n"
 334                      (error-message-string err)
 335                      "\n")
 336              (error "Couldn't start Geiser")))
 337     (geiser-repl--wait-for-prompt geiser-repl-startup-time)))
 338
 339 (defun geiser-repl--wait-for-prompt (timeout)
 340   (let ((p (point)) (seen) (buffer (current-buffer)))
 341     (while (and (not seen)
 342                 (> timeout 0)
 343                 (get-buffer-process buffer))
 344       (sleep-for 0.1)
 345       (setq timeout (- timeout 100))
 346       (goto-char p)
 347       (setq seen (re-search-forward comint-prompt-regexp nil t)))
 348     (goto-char (point-max))
 349     (unless seen (error "%s" "No prompt found!"))))
 350
 351 (defun geiser-repl--is-debugging ()
 352   (let ((dp (geiser-con--connection-debug-prompt geiser-repl--connection)))
 353     (and dp
 354          comint-last-prompt-overlay
 355          (save-excursion
 356            (goto-char (overlay-start comint-last-prompt-overlay))
 357            (re-search-forward dp
 358                               (overlay-end comint-last-prompt-overlay)
 359                               t)))))
 360
 361 (defun geiser-repl--connection ()
 362   (let ((buffer (geiser-repl--set-up-repl geiser-impl--implementation)))
 363     (or (and (buffer-live-p buffer)
 364              (get-buffer-process buffer)
 365              (with-current-buffer buffer geiser-repl--connection))
 366         (error "No Geiser REPL for this buffer (try M-x run-geiser)"))))
 367
 368 (setq geiser-eval--default-connection-function 'geiser-repl--connection)
 369
 370 (defun geiser-repl--prepare-send ()
 371   (geiser-autodoc--inhibit-autodoc)
 372   (geiser-con--connection-deactivate geiser-repl--connection))
 373
 374 (defun geiser-repl--send (cmd)
 375   (when (and cmd (eq major-mode 'geiser-repl-mode))
 376     (geiser-repl--prepare-send)
 377     (goto-char (point-max))
 378     (comint-kill-input)
 379     (insert cmd)
 380     (let ((comint-input-filter (lambda (x) nil)))
 381       (comint-send-input nil t))))
 382
 383 \f
 384 ;;; REPL history
 385
 386 (defconst geiser-repl--history-separator "\n\0\n")
 387
 388 (defsubst geiser-repl--history-file ()
 389   (format "%s.%s" geiser-repl-history-filename geiser-impl--implementation))
 390
 391 (defun geiser-repl--read-input-ring ()
 392   (let ((comint-input-ring-file-name (geiser-repl--history-file))
 393         (comint-input-ring-separator geiser-repl--history-separator))
 394     (comint-read-input-ring t)))
 395
 396 (defun geiser-repl--write-input-ring ()
 397   (let ((comint-input-ring-file-name (geiser-repl--history-file))
 398         (comint-input-ring-separator geiser-repl--history-separator))
 399     (comint-write-input-ring)))
 400
 401 (defun geiser-repl--history-setup ()
 402   (set (make-local-variable 'comint-input-ring-size) geiser-repl-history-size)
 403   (set (make-local-variable 'comint-input-filter) 'geiser-repl--input-filter)
 404   (geiser-repl--read-input-ring))
 405
 406 \f
 407 ;;; Cleaning up on quit
 408
 409 (defun geiser-repl--on-quit ()
 410   (geiser-repl--write-input-ring)
 411   (let ((cb (current-buffer))
 412         (impl geiser-impl--implementation)
 413         (comint-prompt-read-only nil))
 414     (geiser-con--connection-deactivate geiser-repl--connection t)
 415     (geiser-con--connection-close geiser-repl--connection)
 416     (setq geiser-repl--repls (remove cb geiser-repl--repls))
 417     (dolist (buffer (buffer-list))
 418       (when (buffer-live-p buffer)
 419         (with-current-buffer buffer
 420           (when (and (eq geiser-impl--implementation impl)
 421                      (equal cb geiser-repl--repl))
 422             (geiser-repl--set-up-repl geiser-impl--implementation)))))))
 423
 424 (defun geiser-repl--sentinel (proc event)
 425   (let ((pb (process-buffer proc)))
 426     (when (buffer-live-p pb)
 427       (with-current-buffer pb
 428         (let ((comint-prompt-read-only nil)
 429               (comint-input-ring-file-name (geiser-repl--history-file))
 430               (comint-input-ring-separator geiser-repl--history-separator))
 431           (geiser-repl--on-quit)
 432           (push pb geiser-repl--closed-repls)
 433           (goto-char (point-max))
 434           (comint-kill-region comint-last-input-start (point))
 435           (insert "\nIt's been nice interacting with you!\n")
 436           (insert "Press C-c C-z to bring me back.\n" ))))))
 437
 438 (defun geiser-repl--on-kill ()
 439   (geiser-repl--on-quit)
 440   (setq geiser-repl--closed-repls
 441         (remove (current-buffer) geiser-repl--closed-repls)))
 442
 443 (defun geiser-repl--input-filter (str)
 444   (not (or (geiser-repl--is-debugging)
 445            (string-match "^\\s *$" str)
 446            (string-match "^,quit *$" str))))
 447
 448 (defun geiser-repl--old-input ()
 449   (save-excursion
 450     (let ((end (point)))
 451       (backward-sexp)
 452       (buffer-substring (point) end))))
 453
 454 (defun geiser-repl--quit-setup ()
 455   (add-hook 'kill-buffer-hook 'geiser-repl--on-kill nil t)
 456   (set-process-sentinel (get-buffer-process (current-buffer))
 457                         'geiser-repl--sentinel))
 458
 459 \f
 460 ;;; geiser-repl mode:
 461
 462 (defun geiser-repl--bol ()
 463   (interactive)
 464   (when (= (point) (comint-bol)) (beginning-of-line)))
 465
 466 (defun geiser-repl--beginning-of-defun ()
 467   (save-restriction
 468     (when comint-last-prompt-overlay
 469       (narrow-to-region (overlay-end comint-last-prompt-overlay) (point)))
 470     (let ((beginning-of-defun-function nil))
 471       (beginning-of-defun))))
 472
 473 (defun geiser-repl--module-function (&optional module)
 474   (if (and module geiser-eval--get-impl-module)
 475       (funcall geiser-eval--get-impl-module module)
 476       :f))
 477
 478 (defun geiser-repl--doc-module ()
 479   (interactive)
 480   (let ((geiser-eval--get-module-function
 481          (geiser-impl--method 'find-module geiser-impl--implementation)))
 482     (geiser-doc-module)))
 483
 484 (defun geiser-repl--newline-and-indent ()
 485   (interactive)
 486   (save-restriction
 487     (narrow-to-region comint-last-input-start (point-max))
 488     (insert "\n")
 489     (lisp-indent-line)))
 490
 491 (defun geiser-repl--last-prompt-end ()
 492   (if comint-last-prompt-overlay
 493       (overlay-end comint-last-prompt-overlay)
 494     (save-excursion (geiser-repl--bol) (point))))
 495
 496 (defun geiser-repl--last-prompt-start ()
 497   (if comint-last-prompt-overlay
 498       (overlay-start comint-last-prompt-overlay)
 499     (save-excursion (geiser-repl--bol) (point))))
 500
 501 (defun geiser-repl--nesting-level ()
 502   (save-restriction
 503     (narrow-to-region (geiser-repl--last-prompt-end) (point-max))
 504     (geiser-syntax--nesting-level)))
 505
 506 (defun geiser-repl--send-input ()
 507   (let* ((proc (get-buffer-process (current-buffer)))
 508          (pmark (and proc (process-mark proc)))
 509          (intxt (and pmark (buffer-substring pmark (point)))))
 510     (when intxt
 511       (and geiser-repl-forget-old-errors-p
 512            (not (geiser-repl--is-debugging))
 513            (compilation-forget-errors))
 514       (geiser-repl--prepare-send)
 515       (comint-send-input)
 516       (when (string-match "^\\s-*$" intxt)
 517         (comint-send-string proc (geiser-eval--scheme-str '(:ge no-values)))
 518         (comint-send-string proc "\n")))))
 519
 520 (defun geiser-repl--maybe-send ()
 521   (interactive)
 522   (let ((p (point)))
 523     (cond ((< p (geiser-repl--last-prompt-start))
 524            (ignore-errors (compile-goto-error)))
 525           ((progn (end-of-line) (<= (geiser-repl--nesting-level) 0))
 526            (geiser-repl--send-input))
 527           (t (goto-char p)
 528              (if geiser-repl-auto-indent-p
 529                  (geiser-repl--newline-and-indent)
 530                (insert "\n"))))))
 531
 532 (defun geiser-repl-tab-dwim (n)
 533   "If we're after the last prompt, complete symbol or indent (if
 534 there's no symbol at point). Otherwise, go to next error in the REPL
 535 buffer."
 536   (interactive "p")
 537   (if (>= (point) (geiser-repl--last-prompt-end))
 538       (or (completion-at-point) (lisp-indent-line))
 539     (compilation-next-error n)))
 540
 541 (defun geiser-repl--previous-error (n)
 542   "Go to previous error in the REPL buffer."
 543   (interactive "p")
 544   (compilation-next-error (- n)))
 545
 546
 547 (define-derived-mode geiser-repl-mode comint-mode "REPL"
 548   "Major mode for interacting with an inferior scheme repl process.
 549 \\{geiser-repl-mode-map}"
 550   (scheme-mode-variables)
 551   (set (make-local-variable 'face-remapping-alist)
 552        '((comint-highlight-prompt geiser-font-lock-repl-prompt)
 553          (comint-highlight-input geiser-font-lock-repl-input)))
 554   (set (make-local-variable 'mode-line-process) nil)
 555   (set (make-local-variable 'comint-use-prompt-regexp) t)
 556   (set (make-local-variable 'comint-prompt-read-only)
 557        geiser-repl-read-only-prompt-p)
 558   (set (make-local-variable 'beginning-of-defun-function)
 559        'geiser-repl--beginning-of-defun)
 560   (set (make-local-variable 'comint-input-ignoredups)
 561        geiser-repl-history-no-dups-p)
 562   (setq geiser-eval--get-module-function 'geiser-repl--module-function)
 563   (geiser-completion--setup t)
 564   (setq geiser-smart-tab-mode-string "")
 565   (geiser-smart-tab-mode t)
 566   ;; enabling compilation-shell-minor-mode without the annoying highlighter
 567   (compilation-setup t))
 568
 569 (define-key geiser-repl-mode-map "\C-d" 'delete-char)
 570 (define-key geiser-repl-mode-map "\C-m" 'geiser-repl--maybe-send)
 571 (define-key geiser-repl-mode-map [return] 'geiser-repl--maybe-send)
 572 (define-key geiser-repl-mode-map "\C-j" 'geiser-repl--newline-and-indent)
 573 (define-key geiser-repl-mode-map (kbd "TAB") 'geiser-repl-tab-dwim)
 574 (define-key geiser-repl-mode-map [backtab] 'geiser-repl--previous-error)
 575
 576 (define-key geiser-repl-mode-map "\C-a" 'geiser-repl--bol)
 577 (define-key geiser-repl-mode-map (kbd "<home>") 'geiser-repl--bol)
 578
 579 (geiser-menu--defmenu repl geiser-repl-mode-map
 580   ("Complete symbol" ((kbd "M-TAB"))
 581    completion-at-point :enable (geiser--symbol-at-point))
 582   ("Complete module name" ((kbd "C-.") (kbd "M-`"))
 583    geiser-completion--complete-module :enable (geiser--symbol-at-point))
 584   ("Edit symbol" "\M-." geiser-edit-symbol-at-point
 585    :enable (geiser--symbol-at-point))
 586   --
 587   ("Switch to module..." "\C-c\C-m" switch-to-geiser-module)
 588   ("Import module..." "\C-c\C-i" geiser-repl-import-module)
 589   ("Add to load path..." "\C-c\C-r" geiser-add-to-load-path)
 590   --
 591   ("Previous matching input" "\M-p" comint-previous-matching-input-from-input
 592    "Previous input matching current")
 593   ("Next matching input" "\M-n" comint-next-matching-input-from-input
 594    "Next input matching current")
 595   ("Previous input" "\C-c\M-p" comint-previous-input)
 596   ("Next input" "\C-c\M-n" comint-next-input)
 597   --
 598   (mode "Autodoc mode" ("\C-c\C-da" "\C-c\C-d\C-a") geiser-autodoc-mode)
 599   ("Symbol documentation" ("\C-c\C-dd" "\C-c\C-d\C-d")
 600    geiser-doc-symbol-at-point
 601    "Documentation for symbol at point" :enable (geiser--symbol-at-point))
 602   ("Lookup symbol in manul" ("\C-c\C-di" "\C-c\C-d\C-i")
 603    geiser-doc-look-up-manual
 604    "Documentation for symbol at point" :enable (geiser--symbol-at-point))
 605   ("Module documentation" ("\C-c\C-dm" "\C-c\C-d\C-m") geiser-repl--doc-module
 606    "Documentation for module at point" :enable (geiser--symbol-at-point))
 607   --
 608   ("Kill Scheme interpreter" "\C-c\C-q" geiser-repl-exit
 609    :enable (geiser-repl--live-p))
 610   ("Restart" "\C-c\C-z" switch-to-geiser :enable (not (geiser-repl--live-p)))
 611   --
 612   (custom "REPL options" geiser-repl))
 613
 614 (define-key geiser-repl-mode-map [menu-bar completion] 'undefined)
 615
 616 \f
 617 ;;; User commands
 618
 619 (defun run-geiser (impl)
 620   "Start a new Geiser REPL."
 621   (interactive
 622    (list (geiser-repl--get-impl "Start Geiser for scheme implementation: ")))
 623   (let ((buffer (current-buffer)))
 624     (geiser-repl--start-repl impl nil)
 625     (geiser-repl--maybe-remember-scm-buffer buffer)))
 626
 627 (defalias 'geiser 'run-geiser)
 628
 629 (defun geiser-connect (impl &optional host port)
 630   "Start a new Geiser REPL connected to a remote Scheme process."
 631   (interactive
 632    (list (geiser-repl--get-impl "Connect to Scheme implementation: ")))
 633   (let ((buffer (current-buffer)))
 634     (geiser-repl--start-repl impl
 635                              (geiser-repl--read-address host port))
 636     (geiser-repl--maybe-remember-scm-buffer buffer)))
 637
 638 (make-variable-buffer-local
 639  (defvar geiser-repl--last-scm-buffer nil))
 640
 641 (defun geiser-repl--maybe-remember-scm-buffer (buffer)
 642   (when (and buffer
 643              (eq 'scheme-mode (with-current-buffer buffer major-mode))
 644              (eq major-mode 'geiser-repl-mode))
 645     (setq geiser-repl--last-scm-buffer buffer)))
 646
 647 (defun switch-to-geiser (&optional ask impl buffer)
 648   "Switch to running Geiser REPL.
 649 With prefix argument, ask for which one if more than one is running.
 650 If no REPL is running, execute `run-geiser' to start a fresh one."
 651   (interactive "P")
 652   (let* ((impl (or impl geiser-impl--implementation))
 653          (in-repl (eq major-mode 'geiser-repl-mode))
 654          (in-live-repl (and in-repl (get-buffer-process (current-buffer))))
 655          (repl (cond ((and (not ask)
 656                            (not impl)
 657                            (not in-repl)
 658                            (or geiser-repl--repl (car geiser-repl--repls))))
 659                      ((and (not ask)
 660                            (not in-repl)
 661                            impl
 662                            (geiser-repl--repl/impl impl))))))
 663     (cond ((or in-live-repl
 664                (and (eq (current-buffer) repl) (not (eq repl buffer))))
 665            (when (buffer-live-p geiser-repl--last-scm-buffer)
 666              (geiser-repl--switch-to-buffer geiser-repl--last-scm-buffer)))
 667           (repl (geiser-repl--switch-to-buffer repl))
 668           ((geiser-repl--remote-p) (geiser-connect impl))
 669           (t (run-geiser impl)))
 670     (geiser-repl--maybe-remember-scm-buffer buffer)))
 671
 672 (defun switch-to-geiser-module (&optional module buffer)
 673   "Switch to running Geiser REPL and try to enter a given module."
 674   (interactive)
 675   (let* ((module (or module
 676                      (geiser-completion--read-module
 677                       "Switch to module (default top-level): ")))
 678          (cmd (and module
 679                    (geiser-repl--enter-cmd geiser-impl--implementation
 680                                            module))))
 681     (unless (eq major-mode 'geiser-repl-mode)
 682       (switch-to-geiser nil nil (or buffer (current-buffer))))
 683     (geiser-repl--send cmd)))
 684
 685 (defun geiser-repl-import-module (&optional module)
 686   "Import a given module in the current namespace of the REPL."
 687   (interactive)
 688   (let* ((module (or module
 689                      (geiser-completion--read-module "Import module: ")))
 690          (cmd (and module
 691                    (geiser-repl--import-cmd geiser-impl--implementation
 692                                             module))))
 693     (switch-to-geiser nil nil (current-buffer))
 694     (geiser-repl--send cmd)))
 695
 696 (defun geiser-repl-exit (&optional arg)
 697   "Exit the current REPL.
 698 With a prefix argument, force exit by killing the scheme process."
 699   (interactive "P")
 700   (when (or (not geiser-repl-query-on-exit-p)
 701             (y-or-n-p "Really quit this REPL? "))
 702     (geiser-con--connection-deactivate geiser-repl--connection t)
 703     (let ((cmd (and (not arg)
 704                     (geiser-repl--exit-cmd geiser-impl--implementation))))
 705       (if cmd
 706           (when (stringp cmd) (geiser-repl--send cmd))
 707         (comint-kill-subjob)))))
 708
 709 \f
 710 ;;; Unload:
 711
 712 (defun geiser-repl--repl-list ()
 713   (let (lst)
 714     (dolist (repl geiser-repl--repls lst)
 715       (when (buffer-live-p repl)
 716         (with-current-buffer repl
 717           (push (cons geiser-impl--implementation
 718                       geiser-repl--address)
 719                 lst))))))
 720
 721 (defun geiser-repl--restore (impls)
 722   (dolist (impl impls)
 723     (when impl
 724       (condition-case err
 725           (geiser-repl--start-repl (car impl) (cdr impl))
 726         (error (message (error-message-string err)))))))
 727
 728 (defun geiser-repl-unload-function ()
 729   (dolist (repl geiser-repl--repls)
 730     (when (buffer-live-p repl)
 731       (with-current-buffer repl
 732         (let ((geiser-repl-query-on-exit-p nil)) (geiser-repl-exit))
 733         (sit-for 0.05)
 734         (kill-buffer)))))
 735
 736 \f
 737 (provide 'geiser-repl)