elisp/geiser-racket.el

   1 ;; geiser-racket.el -- geiser support for Racket scheme
   2
   3 ;; Copyright (C) 2009, 2010, 2011, 2012 Jose Antonio Ortega Ruiz
   4
   5 ;; This program is free software; you can redistribute it and/or
   6 ;; modify it under the terms of the Modified BSD License. You should
   7 ;; have received a copy of the license along with this program. If
   8 ;; not, see <http://www.xfree86.org/3.3.6/COPYRIGHT2.html#5>.
   9
  10 ;; Start date: Sat Apr 25, 2009 21:13
  11
  12 \f
  13
  14 (require 'geiser-edit)
  15 (require 'geiser-doc)
  16 (require 'geiser-eval)
  17 (require 'geiser-syntax)
  18 (require 'geiser-custom)
  19 (require 'geiser-base)
  20
  21 \f
  22 ;;; Customization:
  23
  24 (defgroup geiser-racket nil
  25   "Customization for Geiser's Racket flavour."
  26   :group 'geiser)
  27
  28 (geiser-custom--defcustom geiser-racket-binary
  29   (cond ((eq system-type 'windows-nt) "Racket.exe")
  30         (t "racket"))
  31   "Name to use to call the racket executable when starting a REPL."
  32   :type '(choice string (repeat string))
  33   :group 'geiser-racket)
  34
  35 (geiser-custom--defcustom geiser-racket-gracket-binary
  36   (cond ((eq system-type 'windows-nt) "GRacket-text.exe")
  37         (t "gracket-text"))
  38   "Name to use to call the gracket executable when starting a REPL.
  39 This executable is used by `run-gracket', and, if
  40 `geiser-racket-use-gracket-p' is set to t, by `run-racket'."
  41   :type '(choice string (repeat string))
  42   :group 'geiser-racket)
  43
  44 (geiser-custom--defcustom geiser-racket-collects nil
  45   "A list of paths to be added to racket's collection directories."
  46   :type '(repeat file)
  47   :group 'geiser-racket)
  48
  49 (geiser-custom--defcustom geiser-racket-init-file "~/.racket-geiser"
  50   "Initialization file with user code for the racket REPL."
  51   :type 'string
  52   :group 'geiser-racket)
  53
  54 (geiser-custom--defcustom geiser-racket-use-gracket-p nil
  55   "Whether to use the gracket binary to start Racket REPLs."
  56   :type 'boolean
  57   :group 'geiser-racket)
  58
  59 (geiser-custom--defcustom geiser-racket-extra-keywords
  60     '("define-syntax-rule" "provide" "require"
  61       "unless" "when" "with-handlers")
  62   "Extra keywords highlighted in Racket buffers."
  63   :type '(repeat string)
  64   :group 'geiser-racket)
  65
  66 (geiser-custom--defcustom geiser-racket-image-cache-directory nil
  67   "The directory where temporary image files generated by Racket are stored.
  68 If set to nil, the default system temp dir is used."
  69   :type 'file
  70   :group 'geiser-racket)
  71
  72 \f
  73 ;;; REPL support:
  74
  75 (defsubst geiser-racket--real-binary ()
  76   (if geiser-racket-use-gracket-p
  77       geiser-racket-gracket-binary
  78     geiser-racket-binary))
  79
  80 (defun geiser-racket--binary ()
  81   (let ((binary (geiser-racket--real-binary)))
  82     (if (listp binary) (car binary) binary)))
  83
  84 (defun geiser-racket--parameters ()
  85   "Return a list with all parameters needed to start racket.
  86 This function uses `geiser-racket-init-file' if it exists."
  87   (let ((init-file (and (stringp geiser-racket-init-file)
  88                         (expand-file-name geiser-racket-init-file)))
  89         (binary (geiser-racket--real-binary))
  90         (rackdir (expand-file-name "racket/" geiser-scheme-dir)))
  91     `("-i" "-q"
  92       "-S" ,rackdir
  93       ,@(apply 'append (mapcar (lambda (p) (list "-S" p))
  94                                geiser-racket-collects))
  95       ,@(and (listp binary) (cdr binary))
  96       ,@(and init-file (file-readable-p init-file) (list "-f" init-file))
  97       "-f" ,(expand-file-name "geiser/startup.rkt" rackdir))))
  98
  99 (defconst geiser-racket--prompt-regexp "\\(mzscheme\\|racket\\)@[^ ]*?> ")
 100
 101 (defun geiser-racket--startup (remote)
 102   (if geiser-racket-image-cache-directory
 103       (geiser-eval--send/wait (format ",set-image-cache %S\n'done"
 104                                       geiser-racket-image-cache-directory))
 105     (setq geiser-racket-image-cache-directory
 106           (geiser-eval--send/result '(:eval (image-cache) geiser/user)))))
 107
 108 \f
 109 ;;; Remote REPLs
 110
 111 (defun connect-to-racket ()
 112   "Start a Racket REPL connected to a remote process.
 113
 114 The remote process needs to be running a REPL server started
 115 using start-geiser, a procedure in the geiser/server module."
 116   (interactive)
 117   (geiser-connect 'racket))
 118
 119
 120 \f
 121 ;;; Evaluation support:
 122
 123 (defun geiser-racket--language ()
 124   (save-excursion
 125     (goto-char (point-min))
 126     (if (re-search-forward
 127          "^\\(?:#lang\\|(module +[^ ]+?\\) +\\([^ ]+?\\|([^)]+)\\) *$" nil t)
 128         (car (geiser-syntax--read-from-string (match-string-no-properties 1)))
 129       "#f")))
 130
 131 (defun geiser-racket--enter-command (module)
 132   (when (stringp module)
 133     (cond ((zerop (length module)) ",enter #f")
 134           ((file-name-absolute-p module) (format ",enter %S" module))
 135           (t (format ",enter %s" module)))))
 136
 137 (defun geiser-racket--geiser-procedure (proc &rest args)
 138   (case proc
 139     ((eval compile)
 140      (format ",geiser-eval %s %s %s"
 141              (or (car args) "#f")
 142              (geiser-racket--language)
 143              (mapconcat 'identity (cdr args) " ")))
 144     ((load-file compile-file)
 145      (format ",geiser-eval geiser/main racket (geiser:%s %s)"
 146              proc (car args)))
 147     ((no-values) ",geiser-no-values")
 148     (t (format ",apply geiser:%s (%s)" proc (mapconcat 'identity args " ")))))
 149
 150 (defconst geiser-racket--module-re
 151   "^(module +\\([^ ]+\\)")
 152
 153 (defun geiser-racket--explicit-module ()
 154   (save-excursion
 155     (goto-char (point-min))
 156     (and (re-search-forward geiser-racket--module-re nil t)
 157          (ignore-errors
 158            (car (geiser-syntax--read-from-string
 159                  (match-string-no-properties 1)))))))
 160
 161 (defsubst geiser-racket--implicit-module ()
 162   (save-excursion
 163     (goto-char (point-min))
 164     (if (re-search-forward "^#lang " nil t)
 165         (buffer-file-name)
 166       :f)))
 167
 168 (defun geiser-racket--get-module (&optional module)
 169   (cond ((and (null module) (buffer-file-name)))
 170         ;; (geiser-racket--explicit-module)
 171         ((null module) (geiser-racket--implicit-module))
 172         ((symbolp module) module)
 173         ((and (stringp module) (file-name-absolute-p module)) module)
 174         ((stringp module) (make-symbol module))
 175         (t nil)))
 176
 177 (defun geiser-racket--symbol-begin (module)
 178   (save-excursion (skip-syntax-backward "^-()>") (point)))
 179
 180 (defun geiser-racket--import-command (module)
 181   (and (stringp module)
 182        (not (zerop (length module)))
 183        (format "(require %s)" module)))
 184
 185 (defun geiser-racket--exit-command ()
 186   (comint-send-eof)
 187   (get-buffer-process (current-buffer)))
 188
 189 (defconst geiser-racket--binding-forms
 190   '("for" "for/list" "for/hash" "for/hasheq" "for/and" "for/or"
 191     "for/lists" "for/first" "for/last" "for/fold"
 192     "for:" "for/list:" "for/hash:" "for/hasheq:" "for/and:" "for/or:"
 193     "for/lists:" "for/first:" "for/last:" "for/fold:"
 194     "define-syntax-rule"))
 195
 196 (defconst geiser-racket--binding-forms*
 197   '("for*" "for*/list" "for*/lists" "for*/hash" "for*/hasheq" "for*/and"
 198     "for*/or" "for*/first" "for*/last" "for*/fold"
 199     "for*:" "for*/list:" "for*/lists:" "for*/hash:" "for*/hasheq:" "for*/and:"
 200     "for*/or:" "for*/first:" "for*/last:" "for*/fold:"))
 201 \f
 202 ;;; External help
 203
 204 (defsubst geiser-racket--get-help (symbol module)
 205   (geiser-eval--send/wait
 206    `(:eval (get-help ',symbol '(:module ,module)) geiser/autodoc)))
 207
 208 (defun geiser-racket--external-help (id module)
 209   (message "Looking up manual for '%s'..." id)
 210   (let ((out (geiser-eval--retort-output
 211               (geiser-racket--get-help id module))))
 212     (when (and out (string-match " but provided by:\n +\\(.+\\)\n" out))
 213       (geiser-racket--get-help id (match-string 1 out))))
 214   (minibuffer-message "%s done" (current-message))
 215   t)
 216
 217 \f
 218 ;;; Error display
 219
 220 (defconst geiser-racket--file-rxs
 221   '(nil
 222     "path:\"?\\([^>\"\n]+\\)\"?>"
 223     "module: \"\\([^>\"\n]+\\)\""))
 224
 225 (defconst geiser-racket--geiser-file-rx
 226   (format "^%s/?racket/geiser" (regexp-quote geiser-scheme-dir)))
 227
 228 (defun geiser-racket--purge-trace ()
 229   (save-excursion
 230     (while (re-search-forward geiser-racket--geiser-file-rx nil t)
 231       (kill-whole-line))))
 232
 233 (defun geiser-racket--display-error (module key msg)
 234   (when key
 235     (insert "Error: ")
 236     (geiser-doc--insert-button key nil 'racket)
 237     (newline 2))
 238   (when msg
 239     (let ((p (point)))
 240       (insert msg)
 241       (let ((end (point)))
 242         (goto-char p)
 243         (when key (geiser-racket--purge-trace))
 244         (mapc 'geiser-edit--buttonize-files geiser-racket--file-rxs)
 245         (goto-char end)
 246         (newline))))
 247   (or key (not (zerop (length msg)))))
 248
 249 \f
 250 ;;; Trying to ascertain whether a buffer is mzscheme scheme:
 251
 252 (defun geiser-racket--guess ()
 253   (or (save-excursion
 254         (goto-char (point-min))
 255         (re-search-forward "#lang " nil t))
 256       (geiser-racket--explicit-module)))
 257
 258 \f
 259 ;;; Keywords and syntax
 260 (defun geiser-racket--keywords ()
 261   (append '(("^#lang\\>" . 0)
 262             ("\\[\\(else\\)\\>" . 1))
 263           (when geiser-racket-extra-keywords
 264             `((,(format "[[(]%s\\>" (regexp-opt geiser-racket-extra-keywords 1))
 265                . 1)))))
 266
 267 (geiser-syntax--scheme-indent
 268  (splicing-let 1)
 269  (splicing-letrec 1)
 270  (splicing-let-values 1)
 271  (splicing-letrec-values 1)
 272  (splicing-let-syntax 1)
 273  (splicing-letrec-syntax 1)
 274  (splicing-let-syntaxes 1)
 275  (splicing-letrec-syntaxes 1)
 276  (splicing-letrec-syntaxes+values 1)
 277  (splicing-local 1)
 278  (for 1)
 279  (for/and 1)
 280  (for/first 1)
 281  (for/fold 2)
 282  (for/hash 1)
 283  (for/hasheq 1)
 284  (for/hasheqv 1)
 285  (for/last 1)
 286  (for/list 1)
 287  (for/lists 2)
 288  (for/or 1)
 289  (for/product 1)
 290  (for/sum 1)
 291  (for/vector 1)
 292  (for* 1)
 293  (for*/and 1)
 294  (for*/first 1)
 295  (for*/fold 2)
 296  (for*/hash 1)
 297  (for*/hasheq 1)
 298  (for*/hasheqv 1)
 299  (for*/last 1)
 300  (for*/list 1)
 301  (for*/lists 2)
 302  (for*/or 1)
 303  (for*/product 1)
 304  (for*/sum 1)
 305  (for*/vector 1))
 306
 307
 308 \f
 309 ;;; Implementation definition:
 310
 311 (define-geiser-implementation racket
 312   (unsupported-procedures '(callers callees generic-methods))
 313   (binary geiser-racket--binary)
 314   (arglist geiser-racket--parameters)
 315   (repl-startup geiser-racket--startup)
 316   (prompt-regexp geiser-racket--prompt-regexp)
 317   (marshall-procedure geiser-racket--geiser-procedure)
 318   (find-module geiser-racket--get-module)
 319   (enter-command geiser-racket--enter-command)
 320   (import-command geiser-racket--import-command)
 321   (exit-command geiser-racket--exit-command)
 322   (find-symbol-begin geiser-racket--symbol-begin)
 323   (display-error geiser-racket--display-error)
 324   (external-help geiser-racket--external-help)
 325   (check-buffer geiser-racket--guess)
 326   (keywords geiser-racket--keywords)
 327   (binding-forms geiser-racket--binding-forms)
 328   (binding-forms* geiser-racket--binding-forms*))
 329
 330 (geiser-impl--add-to-alist 'regexp "\\.ss$" 'racket t)
 331 (geiser-impl--add-to-alist 'regexp "\\.rkt$" 'racket t)
 332
 333 (defun run-gracket ()
 334   "Start the Racket REPL using gracket instead of plain racket."
 335   (interactive)
 336   (let ((geiser-racket-use-gracket-p t))
 337     (run-racket)))
 338
 339 \f
 340 (provide 'geiser-racket)