elisp/geiser-syntax.el

   1 ;;; geiser-syntax.el -- utilities for parsing scheme syntax
   2
   3 ;; Copyright (C) 2009, 2010, 2011, 2012, 2013, 2014, 2015, 2016 Jose Antonio Ortega Ruiz
   4
   5 ;; This program is free software; you can redistribute it and/or
   6 ;; modify it under the terms of the Modified BSD License. You should
   7 ;; have received a copy of the license along with this program. If
   8 ;; not, see <http://www.xfree86.org/3.3.6/COPYRIGHT2.html#5>.
   9
  10 ;; Start date: Sun Feb 08, 2009 15:03
  11
  12 \f
  13
  14 (require 'geiser-impl)
  15 (require 'geiser-popup)
  16 (require 'geiser-base)
  17
  18 (require 'scheme)
  19
  20 (eval-when-compile (require 'cl))
  21
  22 \f
  23 ;;; Indentation:
  24
  25 (defmacro geiser-syntax--scheme-indent (&rest pairs)
  26   `(progn ,@(mapcar (lambda (p)
  27                       `(put ',(car p) 'scheme-indent-function ',(cadr p)))
  28                     pairs)))
  29
  30 (geiser-syntax--scheme-indent
  31  (and-let* 1)
  32  (case-lambda 0)
  33  (catch defun)
  34  (class defun)
  35  (dynamic-wind 0)
  36  (guard 1)
  37  (let*-values 1)
  38  (let-values 1)
  39  (let/ec 1)
  40  (letrec* 1)
  41  (match 1)
  42  (match-lambda 0)
  43  (match-lambda* 0)
  44  (match-let scheme-let-indent)
  45  (match-let* 1)
  46  (match-letrec 1)
  47  (opt-lambda 1)
  48  (parameterize 1)
  49  (parameterize* 1)
  50  (receive 2)
  51  (require-extension 0)
  52  (syntax-case 2)
  53  (test-approximate 1)
  54  (test-assert 1)
  55  (test-eq 1)
  56  (test-equal 1)
  57  (test-eqv 1)
  58  (test-group-with-cleanup 1)
  59  (test-runner-on-bad-count! 1)
  60  (test-runner-on-bad-end-name! 1)
  61  (test-runner-on-final! 1)
  62  (test-runner-on-group-begin! 1)
  63  (test-runner-on-group-end! 1)
  64  (test-runner-on-test-begin! 1)
  65  (test-runner-on-test-end! 1)
  66  (test-with-runner 1)
  67  (unless 1)
  68  (when 1)
  69  (while 1)
  70  (with-exception-handler 1)
  71  (with-syntax 1))
  72
  73 \f
  74 ;;; Extra syntax keywords
  75
  76 (defconst geiser-syntax--builtin-keywords
  77   '("and-let*"
  78     "cut"
  79     "cute"
  80     "define-condition-type"
  81     "define-immutable-record-type"
  82     "define-record-type"
  83     "define-values"
  84     "letrec*"
  85     "match"
  86     "match-lambda"
  87     "match-lambda*"
  88     "match-let"
  89     "match-let*"
  90     "match-letrec"
  91     "parameterize"
  92     "receive"
  93     "require-extension"
  94     "set!"
  95     "syntax-case"
  96     "test-approximate"
  97     "test-assert"
  98     "test-begin"
  99     "test-end"
 100     "test-eq"
 101     "test-equal"
 102     "test-eqv"
 103     "test-error"
 104     "test-group"
 105     "test-group-with-cleanup"
 106     "test-with-runner"
 107     "unless"
 108     "when"
 109     "with-exception-handler"
 110     "with-input-from-file"
 111     "with-output-to-file"))
 112
 113 (defun geiser-syntax--simple-keywords (keywords)
 114   "Return `font-lock-keywords' to highlight scheme KEYWORDS.
 115 KEYWORDS should be a list of strings."
 116   (when keywords
 117     `((,(format "[[(]%s\\>" (regexp-opt keywords 1)) . 1))))
 118
 119 (defun geiser-syntax--keywords ()
 120   (append
 121    (geiser-syntax--simple-keywords geiser-syntax--builtin-keywords)
 122    `(("\\[\\(else\\)\\>" . 1)
 123      (,(rx "(" (group "define-syntax-rule") eow (* space)
 124            (? "(") (? (group (1+ word))))
 125       (1 font-lock-keyword-face)
 126       (2 font-lock-function-name-face nil t)))))
 127
 128 (font-lock-add-keywords 'scheme-mode (geiser-syntax--keywords))
 129
 130 (geiser-impl--define-caller geiser-syntax--impl-kws keywords ()
 131   "A variable (or thunk returning a value) giving additional,
 132 implementation-specific entries for font-lock-keywords.")
 133
 134 (geiser-impl--define-caller geiser-syntax--case-sensitive case-sensitive ()
 135   "A flag saying whether keywords are case sensitive.")
 136
 137 (defun geiser-syntax--add-kws (&optional global-p)
 138   (unless (bound-and-true-p quack-mode)
 139     (let ((kw (geiser-syntax--impl-kws geiser-impl--implementation))
 140           (cs (geiser-syntax--case-sensitive geiser-impl--implementation)))
 141       (when kw (font-lock-add-keywords nil kw))
 142       (when global-p (font-lock-add-keywords nil (geiser-syntax--keywords)))
 143       (setq font-lock-keywords-case-fold-search (not cs)))))
 144
 145 (defun geiser-syntax--remove-kws ()
 146   (unless (bound-and-true-p quack-mode)
 147     (let ((kw (geiser-syntax--impl-kws geiser-impl--implementation)))
 148       (when kw
 149         (font-lock-remove-keywords nil kw)))))
 150
 151 \f
 152 ;;; A simple scheme reader
 153
 154 (defvar geiser-syntax--read/buffer-limit nil)
 155
 156 (defsubst geiser-syntax--read/eos ()
 157   (or (eobp)
 158       (and geiser-syntax--read/buffer-limit
 159            (<= geiser-syntax--read/buffer-limit (point)))))
 160
 161 (defsubst geiser-syntax--read/next-char ()
 162   (unless (geiser-syntax--read/eos)
 163     (forward-char)
 164     (char-after)))
 165
 166 (defsubst geiser-syntax--read/token (token)
 167   (geiser-syntax--read/next-char)
 168   (if (listp token) token (list token)))
 169
 170 (defsubst geiser-syntax--read/elisp ()
 171   (ignore-errors (read (current-buffer))))
 172
 173 (defun geiser-syntax--read/symbol ()
 174   (with-syntax-table scheme-mode-syntax-table
 175     (when (re-search-forward "\\(\\sw\\|\\s_\\)+" nil t)
 176       (make-symbol (match-string-no-properties 0)))))
 177
 178 (defun geiser-syntax--read/matching (open close)
 179   (let ((count 1)
 180         (p (1+ (point))))
 181     (while (and (> count 0)
 182                 (geiser-syntax--read/next-char))
 183       (cond ((looking-at-p open) (setq count (1+ count)))
 184             ((looking-at-p close) (setq count (1- count)))))
 185     (buffer-substring-no-properties p (point))))
 186
 187 (defsubst geiser-syntax--read/unprintable ()
 188   (geiser-syntax--read/token
 189    (cons 'unprintable (geiser-syntax--read/matching "<" ">"))))
 190
 191 (defun geiser-syntax--read/skip-comment ()
 192   (while (and (geiser-syntax--read/next-char)
 193               (nth 8 (syntax-ppss))))
 194   (geiser-syntax--read/next-token))
 195
 196 (defun geiser-syntax--read/next-token ()
 197   (skip-syntax-forward "->")
 198   (if (geiser-syntax--read/eos) '(eob)
 199     (case (char-after)
 200       (?\; (geiser-syntax--read/skip-comment))
 201       ((?\( ?\[) (geiser-syntax--read/token 'lparen))
 202       ((?\) ?\]) (geiser-syntax--read/token 'rparen))
 203       (?. (if (memq (car (syntax-after (1+ (point)))) '(0 11 12))
 204               (geiser-syntax--read/token 'dot)
 205             (cons 'atom (geiser-syntax--read/elisp))))
 206       (?\# (case (geiser-syntax--read/next-char)
 207              ('nil '(eob))
 208              (?| (geiser-syntax--read/skip-comment))
 209              (?: (if (geiser-syntax--read/next-char)
 210                      (cons 'kwd (geiser-syntax--read/symbol))
 211                    '(eob)))
 212              (?\\ (cons 'char (geiser-syntax--read/elisp)))
 213              (?\( (geiser-syntax--read/token 'vectorb))
 214              (?\< (geiser-syntax--read/unprintable))
 215              ((?' ?` ?,) (geiser-syntax--read/next-token))
 216              (t (let ((tok (geiser-syntax--read/symbol)))
 217                   (cond ((equal (symbol-name tok) "t") '(boolean . :t))
 218                         ((equal (symbol-name tok) "f") '(boolean . :f))
 219                         (tok (cons 'atom tok))
 220                         (t (geiser-syntax--read/next-token)))))))
 221       (?\' (geiser-syntax--read/token '(quote . quote)))
 222       (?\` (geiser-syntax--read/token
 223             `(backquote . ,backquote-backquote-symbol)))
 224       (?, (if (eq (geiser-syntax--read/next-char) ?@)
 225               (geiser-syntax--read/token
 226                `(splice . ,backquote-splice-symbol))
 227             `(unquote . ,backquote-unquote-symbol)))
 228       (?\" (cons 'string (geiser-syntax--read/elisp)))
 229       (t (cons 'atom (geiser-syntax--read/symbol))))))
 230
 231 (defsubst geiser-syntax--read/match (&rest tks)
 232   (let ((token (geiser-syntax--read/next-token)))
 233     (if (memq (car token) tks) token
 234       (error "Unexpected token: %s" token))))
 235
 236 (defsubst geiser-syntax--read/skip-until (&rest tks)
 237   (let (token)
 238     (while (and (not (memq (car token) tks))
 239                 (not (eq (car token) 'eob)))
 240       (setq token (geiser-syntax--read/next-token)))
 241     token))
 242
 243 (defsubst geiser-syntax--read/try (&rest tks)
 244   (let ((p (point))
 245         (tk (ignore-errors (apply 'geiser-syntax--read/match tks))))
 246     (unless tk (goto-char p))
 247     tk))
 248
 249 (defun geiser-syntax--read/list ()
 250   (cond ((geiser-syntax--read/try 'dot)
 251          (let ((tail (geiser-syntax--read)))
 252            (geiser-syntax--read/skip-until 'eob 'rparen)
 253            tail))
 254         ((geiser-syntax--read/try 'rparen 'eob) nil)
 255         (t (cons (geiser-syntax--read)
 256                  (geiser-syntax--read/list)))))
 257
 258 (defun geiser-syntax--read ()
 259   (let ((token (geiser-syntax--read/next-token))
 260         (max-lisp-eval-depth (max max-lisp-eval-depth 3000)))
 261     (case (car token)
 262       (eob nil)
 263       (lparen (geiser-syntax--read/list))
 264       (vectorb (apply 'vector (geiser-syntax--read/list)))
 265       ((quote backquote unquote splice) (list (cdr token)
 266                                               (geiser-syntax--read)))
 267       (kwd (make-symbol (format ":%s" (cdr token))))
 268       (unprintable (format "#<%s>" (cdr token)))
 269       ((char string atom) (cdr token))
 270       (boolean (cdr token))
 271       (t (error "Reading scheme syntax: unexpected token: %s" token)))))
 272
 273 (defun geiser-syntax--read-from-string (string &optional start end)
 274   (when (stringp string)
 275     (let* ((start (or start 0))
 276            (end (or end (length string)))
 277            (max-lisp-eval-depth (min 20000
 278                                      (max max-lisp-eval-depth (- end start)))))
 279       (with-temp-buffer
 280         (save-excursion (insert string))
 281         (cons (ignore-errors (geiser-syntax--read)) (point))))))
 282
 283 (defun geiser-syntax--form-from-string (s)
 284   (car (geiser-syntax--read-from-string s)))
 285
 286 (defsubst geiser-syntax--form-after-point (&optional boundary)
 287   (let ((geiser-syntax--read/buffer-limit (and (numberp boundary) boundary)))
 288     (save-excursion (values (geiser-syntax--read) (point)))))
 289
 290 (defun geiser-syntax--mapconcat (fun lst sep)
 291   (cond ((null lst) "")
 292         ((not (listp lst)) (format ".%s%s" sep (funcall fun lst)))
 293         ((null (cdr lst)) (format "%s" (funcall fun (car lst))))
 294         (t (format "%s%s%s"
 295                    (funcall fun (car lst))
 296                    sep
 297                    (geiser-syntax--mapconcat fun (cdr lst) sep)))))
 298
 299 \f
 300 ;;; Code parsing:
 301
 302 (defsubst geiser-syntax--symbol-at-point ()
 303   (and (not (nth 8 (syntax-ppss)))
 304        (car (geiser-syntax--read-from-string (thing-at-point 'symbol)))))
 305
 306 (defsubst geiser-syntax--skip-comment/string ()
 307   (let ((pos (nth 8 (syntax-ppss))))
 308     (goto-char (or pos (point)))
 309     pos))
 310
 311 (defsubst geiser-syntax--nesting-level ()
 312   (or (nth 0 (syntax-ppss)) 0))
 313
 314 (defun geiser-syntax--pop-to-top ()
 315   (ignore-errors
 316     (while (> (geiser-syntax--nesting-level) 0) (backward-up-list))))
 317
 318 (defsubst geiser-syntax--in-string-p ()
 319   (nth 3 (syntax-ppss)))
 320
 321 (defsubst geiser-syntax--pair-length (p)
 322   (if (cdr (last p)) (1+ (safe-length p)) (length p)))
 323
 324 (defun geiser-syntax--shallow-form (boundary)
 325   (when (looking-at-p "\\s(")
 326     (save-excursion
 327       (forward-char)
 328       (let ((elems))
 329         (ignore-errors
 330           (while (< (point) boundary)
 331             (skip-syntax-forward "-<>")
 332             (when (<= (point) boundary)
 333               (forward-sexp)
 334               (let ((s (thing-at-point 'symbol)))
 335                 (unless (equal "." s)
 336                   (push (car (geiser-syntax--read-from-string s)) elems))))))
 337         (nreverse elems)))))
 338
 339 (defsubst geiser-syntax--keywordp (s)
 340   (and s (symbolp s) (string-match "^:.+" (symbol-name s))))
 341
 342 (defsubst geiser-syntax--symbol-eq (s0 s1)
 343   (and (symbolp s0) (symbolp s1) (equal (symbol-name s0) (symbol-name s1))))
 344
 345 (defun geiser-syntax--scan-sexps (&optional begin)
 346   (let* ((fst (geiser-syntax--symbol-at-point))
 347          (smth (or fst (not (looking-at-p "[\s \s)\s>\s<\n]"))))
 348          (path (and fst `((,fst 0)))))
 349     (save-excursion
 350       (while (> (or (geiser-syntax--nesting-level) 0) 0)
 351         (let ((boundary (point)))
 352           (geiser-syntax--skip-comment/string)
 353           (backward-up-list)
 354           (let ((form (geiser-syntax--shallow-form boundary)))
 355             (when (and (listp form) (car form) (symbolp (car form)))
 356               (let* ((len (geiser-syntax--pair-length form))
 357                      (pos (if smth (1- len) (progn (setq smth t) len)))
 358                      (prev (and (> pos 1) (nth (1- pos) form)))
 359                      (prev (and (geiser-syntax--keywordp prev)
 360                                 (list prev))))
 361                 (push `(,(car form) ,pos ,@prev) path)))))))
 362     (mapcar (lambda (e)
 363               (cons (substring-no-properties (format "%s" (car e))) (cdr e)))
 364             (nreverse path))))
 365
 366 (defsubst geiser-syntax--binding-form-p (bfs sbfs f)
 367   (and (symbolp f)
 368        (let ((f (symbol-name f)))
 369          (or (member f '("define" "define*" "define-syntax"
 370                          "syntax-rules" "lambda" "case-lambda"
 371                          "let" "let*" "let-values" "let*-values"
 372                          "letrec" "letrec*" "parameterize"))
 373              (member f bfs)
 374              (member f sbfs)))))
 375
 376 (defsubst geiser-syntax--binding-form*-p (sbfs f)
 377   (and (symbolp f)
 378        (let ((f (symbol-name f)))
 379          (or (member f '("let*" "let*-values" "letrec" "letrec*"))
 380              (member f sbfs)))))
 381
 382 (defsubst geiser-syntax--if-symbol (x) (and (symbolp x) x))
 383 (defsubst geiser-syntax--if-list (x) (and (listp x) x))
 384
 385 (defsubst geiser-syntax--normalize (vars)
 386   (mapcar (lambda (i)
 387             (let ((i (if (listp i) (car i) i)))
 388               (and (symbolp i) (symbol-name i))))
 389           vars))
 390
 391 (defun geiser-syntax--linearize (form)
 392   (cond ((not (listp form)) (list form))
 393         ((null form) nil)
 394         (t (cons (car form) (geiser-syntax--linearize (cdr form))))))
 395
 396 (defun geiser-syntax--scan-locals (bfs sbfs form nesting locals)
 397   (if (or (null form) (not (listp form)))
 398       (geiser-syntax--normalize locals)
 399     (if (not (geiser-syntax--binding-form-p bfs sbfs (car form)))
 400         (geiser-syntax--scan-locals bfs sbfs
 401                                     (car (last form))
 402                                     (1- nesting) locals)
 403       (let* ((head (car form))
 404              (name (geiser-syntax--if-symbol (cadr form)))
 405              (names (if name (geiser-syntax--if-list (caddr form))
 406                       (geiser-syntax--if-list (cadr form))))
 407              (bns (and name
 408                        (geiser-syntax--binding-form-p bfs sbfs (car names))))
 409              (rest (if (and name (not bns)) (cdddr form) (cddr form)))
 410              (use-names (and (or rest
 411                                  (< nesting 1)
 412                                  (geiser-syntax--binding-form*-p sbfs head))
 413                              (not bns))))
 414         (when name (push name locals))
 415         (when (geiser-syntax--symbol-eq head 'case-lambda)
 416           (dolist (n (and (> nesting 0) (caar (last form))))
 417             (when n (push n locals)))
 418           (setq rest (and (> nesting 0) (cdr form)))
 419           (setq use-names nil))
 420         (when (geiser-syntax--symbol-eq head 'syntax-rules)
 421           (dolist (n (and (> nesting 0) (cdaar (last form))))
 422             (when n (push n locals)))
 423           (setq rest (and (> nesting 0) (cdr form))))
 424         (when use-names
 425           (dolist (n (geiser-syntax--linearize names))
 426             (let ((xs (if (and (listp n) (listp (car n))) (car n) (list n))))
 427               (dolist (x xs) (when x (push x locals))))))
 428         (dolist (f (butlast rest))
 429           (when (and (listp f)
 430                      (geiser-syntax--symbol-eq (car f) 'define)
 431                      (cadr f))
 432             (push (cadr f) locals)))
 433         (geiser-syntax--scan-locals bfs sbfs
 434                                     (car (last (or rest names)))
 435                                     (1- nesting)
 436                                     locals)))))
 437
 438 (defun geiser-syntax--locals-around-point (bfs sbfs)
 439   (when (eq major-mode 'scheme-mode)
 440     (save-excursion
 441       (let ((sym (unless (geiser-syntax--skip-comment/string)
 442                    (thing-at-point 'symbol))))
 443         (skip-syntax-forward "->")
 444         (let ((boundary (point))
 445               (nesting (geiser-syntax--nesting-level)))
 446           (geiser-syntax--pop-to-top)
 447           (multiple-value-bind (form end)
 448               (geiser-syntax--form-after-point boundary)
 449             (delete sym
 450                     (geiser-syntax--scan-locals bfs
 451                                                 sbfs
 452                                                 form
 453                                                 (1- nesting)
 454                                                 '()))))))))
 455
 456 \f
 457 ;;; Display and fontify strings as Scheme code:
 458
 459 (defun geiser-syntax--display (a)
 460   (cond ((null a) "()")
 461         ((eq a :t) "#t")
 462         ((eq a :f) "#f")
 463         ((geiser-syntax--keywordp a) (format "#%s" a))
 464         ((symbolp a) (format "%s" a))
 465         ((equal a "...") "...")
 466         ((stringp a) (format "%S" a))
 467         ((and (listp a) (symbolp (car a))
 468               (equal (symbol-name (car a)) "quote"))
 469          (format "'%s" (geiser-syntax--display (cadr a))))
 470         ((listp a)
 471          (format "(%s)"
 472                  (geiser-syntax--mapconcat 'geiser-syntax--display a " ")))
 473         (t (format "%s" a))))
 474
 475 (defconst geiser-syntax--font-lock-buffer-name " *geiser font lock*")
 476
 477 (defun geiser-syntax--font-lock-buffer-p (&optional buffer)
 478   (equal (buffer-name buffer) geiser-syntax--font-lock-buffer-name))
 479
 480 (defun geiser-syntax--font-lock-buffer ()
 481   (or (get-buffer geiser-syntax--font-lock-buffer-name)
 482       (let ((buffer (get-buffer-create geiser-syntax--font-lock-buffer-name)))
 483         (set-buffer buffer)
 484         (let ((geiser-default-implementation
 485                (or geiser-default-implementation
 486                    (car geiser-active-implementations))))
 487           (scheme-mode))
 488         buffer)))
 489
 490 (defun geiser-syntax--fontify (&optional beg end)
 491   (let ((font-lock-verbose nil)
 492         (beg (or beg (point-min)))
 493         (end (or end (point-max))))
 494     (if (fboundp 'font-lock-flush)
 495         (font-lock-flush beg end)
 496       (with-no-warnings (font-lock-fontify-region beg end)))))
 497
 498 (defun geiser-syntax--scheme-str (str)
 499   (save-current-buffer
 500     (set-buffer (geiser-syntax--font-lock-buffer))
 501     (erase-buffer)
 502     (insert str)
 503     (geiser-syntax--fontify)
 504     (buffer-string)))
 505
 506 \f
 507 (provide 'geiser-syntax)