elisp/geiser-chicken.el

   1 ;; geiser-chicken.el -- chicken's implementation of the geiser protocols
   2
   3 ;; Copyright (C) 2014, 2015 Daniel Leslie
   4
   5 ;; Based on geiser-guile.el by Jose Antonio Ortego Ruize
   6
   7 ;; This program is free software; you can redistribute it and/or
   8 ;; modify it under the terms of the Modified BSD License. You should
   9 ;; have received a copy of the license along with this program. If
  10 ;; not, see <http://www.xfree86.org/3.3.6/COPYRIGHT2.html#5>.
  11
  12 ;; Start date: Sun Mar 08, 2009 23:03
  13
  14
  15 (require 'geiser-connection)
  16 (require 'geiser-syntax)
  17 (require 'geiser-custom)
  18 (require 'geiser-base)
  19 (require 'geiser-eval)
  20 (require 'geiser-edit)
  21 (require 'geiser-log)
  22 (require 'geiser)
  23
  24 (require 'compile)
  25 (require 'info-look)
  26
  27 (eval-when-compile (require 'cl))
  28
  29 (defconst geiser-chicken-builtin-keywords
  30   '("assume"
  31     "compiler-typecase"
  32     "cond-expand"
  33     "condition-case"
  34     "declare"
  35     "define-constant"
  36     "define-inline"
  37     "define-interface"
  38     "define-record"
  39     "define-specialization"
  40     "define-type"
  41     "dotimes"
  42     "ecase"
  43     "fluid-let"
  44     "foreign-lambda"
  45     "foreign-lambda*"
  46     "foreign-primitive"
  47     "foreign-safe-lambda"
  48     "foreign-safe-lambda*"
  49     "functor"
  50     "handle-exceptions"
  51     "let-location"
  52     "let-optionals"
  53     "let-optionals*"
  54     "letrec-values"
  55     "module"
  56     "regex-case"
  57     "select"
  58     "use"
  59     "with-input-from-pipe"))
  60
  61 \f
  62 ;;; Customization:
  63
  64 (defgroup geiser-chicken nil
  65   "Customization for Geiser's Chicken flavour."
  66   :group 'geiser)
  67
  68 (geiser-custom--defcustom geiser-chicken-prefix-delimiters
  69     '("^:" "^#")
  70     "Regex to match symbol prefix delimiters."
  71   :type '(repeat string)
  72   :group 'geiser-chicken)
  73
  74 (geiser-custom--defcustom geiser-chicken-binary
  75   (cond ((eq system-type 'windows-nt) '("csi.exe" "-:c"))
  76         ((eq system-type 'darwin) "csi")
  77         (t "csi"))
  78   "Name to use to call the Chicken executable when starting a REPL."
  79   :type '(choice string (repeat string))
  80   :group 'geiser-chicken)
  81
  82 (geiser-custom--defcustom geiser-chicken-load-path nil
  83   "A list of paths to be added to Chicken's load path when it's
  84 started."
  85   :type '(repeat file)
  86   :group 'geiser-chicken)
  87
  88 (geiser-custom--defcustom geiser-chicken-compile-geiser-p t
  89   "Non-nil means that the Geiser runtime will be compiled on load."
  90   :type 'boolean
  91   :group 'geiser-chicken)
  92
  93 (geiser-custom--defcustom geiser-chicken-init-file "~/.chicken-geiser"
  94   "Initialization file with user code for the Chicken REPL.
  95 If all you want is to load ~/.csirc, set
  96 `geiser-chicken-load-init-file-p' instead."
  97   :type 'string
  98   :group 'geiser-chicken)
  99
 100 (geiser-custom--defcustom geiser-chicken-load-init-file-p nil
 101   "Whether to load ~/.chicken when starting Chicken.
 102 Note that, due to peculiarities in the way Chicken loads its init
 103 file, using `geiser-chicken-init-file' is not equivalent to setting
 104 this variable to t."
 105   :type 'boolean
 106   :group 'geiser-chicken)
 107
 108 (geiser-custom--defcustom geiser-chicken-extra-keywords nil
 109   "Extra keywords highlighted in Chicken scheme buffers."
 110   :type '(repeat string)
 111   :group 'geiser-chicken)
 112
 113 (geiser-custom--defcustom geiser-chicken-case-sensitive-p t
 114   "Non-nil means keyword highlighting is case-sensitive."
 115   :type 'boolean
 116   :group 'geiser-chicken)
 117
 118 \f
 119 ;;; REPL support:
 120
 121 (defun geiser-chicken--binary ()
 122   (if (listp geiser-chicken-binary)
 123       (car geiser-chicken-binary)
 124     geiser-chicken-binary))
 125
 126 (defun geiser-chicken--parameters ()
 127   "Return a list with all parameters needed to start Chicken.
 128 This function uses `geiser-chicken-init-file' if it exists."
 129   (let ((init-file (and (stringp geiser-chicken-init-file)
 130                         (expand-file-name geiser-chicken-init-file)))
 131         (n-flags (and (not geiser-chicken-load-init-file-p) '("-n"))))
 132   `(,@(and (listp geiser-chicken-binary) (cdr geiser-chicken-binary))
 133     ,@n-flags "-include-path" ,(expand-file-name "chicken/" geiser-scheme-dir)
 134     ,@(apply 'append (mapcar (lambda (p) (list "-include-path" p))
 135                              geiser-chicken-load-path))
 136     ,@(and init-file (file-readable-p init-file) (list init-file)))))
 137
 138 (defconst geiser-chicken--prompt-regexp "#[^;]*;[^:0-9]*:?[0-9]+> ")
 139
 140 \f
 141 ;;; Evaluation support:
 142
 143 (defun geiser-chicken--geiser-procedure (proc &rest args)
 144   (case proc
 145     ((eval compile)
 146      (let ((form (mapconcat 'identity (cdr args) " ")))
 147        (format "(geiser-eval %s '%s)" (or (car args) "#f") form)))
 148     ((load-file compile-file)
 149      (format "(geiser-load-file %s)" (car args)))
 150     ((no-values)
 151      "(geiser-no-values)")
 152     (t
 153      (let ((form (mapconcat 'identity args " ")))
 154        (format "(geiser-%s %s)" proc form)))))
 155
 156 (defconst geiser-chicken--module-re
 157   "( *module +\\(([^)]+)\\|[^ ]+\\)\\|( *define-library +\\(([^)]+)\\|[^ ]+\\)")
 158
 159 (defun geiser-chicken--get-module (&optional module)
 160   (cond ((null module)
 161          (save-excursion
 162            (geiser-syntax--pop-to-top)
 163            (if (or (re-search-backward geiser-chicken--module-re nil t)
 164                    (looking-at geiser-chicken--module-re)
 165                    (re-search-forward geiser-chicken--module-re nil t))
 166                (geiser-chicken--get-module (match-string-no-properties 1))
 167              :f)))
 168         ((listp module) module)
 169         ((stringp module)
 170          (condition-case nil
 171              (car (geiser-syntax--read-from-string module))
 172            (error :f)))
 173         (t :f)))
 174
 175 (defun geiser-chicken--module-cmd (module fmt &optional def)
 176   (when module
 177     (let* ((module (geiser-chicken--get-module module))
 178            (module (cond ((or (null module) (eq module :f)) def)
 179                          (t (format "%s" module)))))
 180       (and module (format fmt module)))))
 181
 182 (defun geiser-chicken--import-command (module)
 183   (geiser-chicken--module-cmd module "(use %s)"))
 184
 185 (defun geiser-chicken--enter-command (module)
 186   (geiser-chicken--module-cmd module ",m %s" module))
 187
 188 (defun geiser-chicken--exit-command () ",q")
 189
 190 (defun geiser-chicken--symbol-begin (module)
 191   (let ((distance-to-beginning-of-line (- (point) (line-beginning-position))))
 192     (apply
 193      'max
 194      (append
 195       (list (save-excursion (skip-syntax-backward "^'(>" distance-to-beginning-of-line)
 196                             (point)))
 197       (mapcar
 198        (lambda (match-string)
 199          (save-excursion (skip-chars-backward match-string distance-to-beginning-of-line)
 200                          (point)))
 201        geiser-chicken-prefix-delimiters)))))
 202
 203 \f
 204 ;;; Error display
 205
 206 (defun geiser-chicken--display-error (module key msg)
 207   (newline)
 208   (when (stringp msg)
 209     (save-excursion (insert msg))
 210     (geiser-edit--buttonize-files))
 211   (and (not key) msg (not (zerop (length msg)))))
 212
 213 \f
 214 ;;; Trying to ascertain whether a buffer is Chicken Scheme:
 215
 216 (defconst geiser-chicken--guess-re
 217   (regexp-opt (append '("csi" "chicken") geiser-chicken-builtin-keywords)))
 218
 219 (defun geiser-chicken--guess ()
 220   (save-excursion
 221     (goto-char (point-min))
 222     (re-search-forward geiser-chicken--guess-re nil t)))
 223
 224 (defun geiser-chicken--external-help (id module)
 225   "Loads chicken doc into a buffer"
 226   (browse-url (format "http://api.call-cc.org/cdoc?q=%s&query-name=Look+up" id)))
 227
 228 \f
 229 ;;; Keywords and syntax
 230
 231 (defun geiser-chicken--keywords ()
 232   (append
 233    (geiser-syntax--simple-keywords geiser-chicken-extra-keywords)
 234    (geiser-syntax--simple-keywords geiser-chicken-builtin-keywords)))
 235
 236 (geiser-syntax--scheme-indent
 237  (assume 1)
 238  (compiler-typecase 1)
 239  (cond-expand 0)
 240  (condition-case 1)
 241  (cut 1)
 242  (cute 1)
 243  (declare 0)
 244  (dotimes 1)
 245  (ecase 1)
 246  (fluid-let 1)
 247  (foreign-lambda 2)
 248  (foreign-lambda* 2)
 249  (foreign-primitive 2)
 250  (foreign-safe-lambda 2)
 251  (foreign-safe-lambda* 2)
 252  (functor 3)
 253  (handle-exceptions 2)
 254  (import 0)
 255  (let-location 1)
 256  (let-optionals 2)
 257  (let-optionals* 2)
 258  (letrec-values 1)
 259  (module 2)
 260  (regex-case 1)
 261  (select 1)
 262  (set! 1)
 263  (use 0)
 264  (with-input-from-pipe 1)
 265  (with-output-to-pipe 1))
 266
 267 \f
 268 ;;; REPL startup
 269
 270 (defconst geiser-chicken-minimum-version "4.8.0.0")
 271
 272 (defun geiser-chicken--version (binary)
 273   (shell-command-to-string
 274    (format "%s -e %s" binary
 275            (shell-quote-argument "(display (chicken-version))"))))
 276
 277 (defun connect-to-chicken ()
 278   "Start a Chicken REPL connected to a remote process."
 279   (interactive)
 280   (geiser-connect 'chicken))
 281
 282 (defun geiser-chicken--compile-or-load (force-load)
 283   (let ((target
 284          (expand-file-name "chicken/geiser/emacs.so" geiser-scheme-dir))
 285         (source
 286          (expand-file-name "chicken/geiser/emacs.scm" geiser-scheme-dir))
 287         (force-load (or force-load (eq system-type 'windows-nt)))
 288         (suppression-prefix
 289          "(define geiser-stdout (current-output-port))(current-output-port (make-output-port (lambda a #f) (lambda a #f)))")
 290         (suppression-postfix
 291          "(current-output-port geiser-stdout)"))
 292     (let ((load-sequence
 293            (cond
 294             (force-load
 295              (format "(load \"%s\")\n(import geiser)\n" source))
 296             ((file-exists-p target)
 297              (format "%s(load \"%s\")(import geiser)%s\n"
 298                      suppression-prefix target suppression-postfix))
 299             (t
 300              (format "%s(use utils)(compile-file \"%s\" options: '(\"-O3\" \"-s\") output-file: \"%s\" load: #t)(import geiser)%s\n"
 301                      suppression-prefix source target suppression-postfix)))))
 302       (geiser-eval--send/wait load-sequence))))
 303
 304 (defun geiser-chicken--startup (remote)
 305   (compilation-setup t)
 306   (geiser-chicken--compile-or-load (not geiser-chicken-compile-geiser-p)))
 307
 308 \f
 309 ;;; Implementation definition:
 310
 311 (define-geiser-implementation chicken
 312   (unsupported-procedures '(callers callees generic-methods))
 313   (binary geiser-chicken--binary)
 314   (arglist geiser-chicken--parameters)
 315   (version-command geiser-chicken--version)
 316   (minimum-version geiser-chicken-minimum-version)
 317   (repl-startup geiser-chicken--startup)
 318   (prompt-regexp geiser-chicken--prompt-regexp)
 319   (debugger-prompt-regexp nil)
 320   (enter-debugger nil)
 321   (marshall-procedure geiser-chicken--geiser-procedure)
 322   (find-module geiser-chicken--get-module)
 323   (enter-command geiser-chicken--enter-command)
 324   (exit-command geiser-chicken--exit-command)
 325   (import-command geiser-chicken--import-command)
 326   (find-symbol-begin geiser-chicken--symbol-begin)
 327   (display-error geiser-chicken--display-error)
 328   (external-help geiser-chicken--external-help)
 329   (check-buffer geiser-chicken--guess)
 330   (keywords geiser-chicken--keywords)
 331   (case-sensitive geiser-chicken-case-sensitive-p))
 332
 333 (geiser-impl--add-to-alist 'regexp "\\.scm$" 'chicken t)
 334 (geiser-impl--add-to-alist 'regexp "\\.release-info$" 'chicken t)
 335 (geiser-impl--add-to-alist 'regexp "\\.meta$" 'chicken t)
 336 (geiser-impl--add-to-alist 'regexp "\\.setup$" 'chicken t)
 337
 338 (provide 'geiser-chicken)