elisp/geiser-mode.el

   1 ;; geiser-mode.el -- minor mode for scheme buffers
   2
   3 ;; Copyright (C) 2009, 2010, 2011, 2012, 2013 Jose Antonio Ortega Ruiz
   4
   5 ;; This program is free software; you can redistribute it and/or
   6 ;; modify it under the terms of the Modified BSD License. You should
   7 ;; have received a copy of the license along with this program. If
   8 ;; not, see <http://www.xfree86.org/3.3.6/COPYRIGHT2.html#5>.
   9
  10 ;; Start date: Sun Feb 08, 2009 15:13
  11
  12 \f
  13
  14 (require 'geiser-repl)
  15 (require 'geiser-menu)
  16 (require 'geiser-doc)
  17 (require 'geiser-compile)
  18 (require 'geiser-completion)
  19 (require 'geiser-company)
  20 (require 'geiser-xref)
  21 (require 'geiser-edit)
  22 (require 'geiser-autodoc)
  23 (require 'geiser-debug)
  24 (require 'geiser-syntax)
  25 (require 'geiser-impl)
  26 (require 'geiser-eval)
  27 (require 'geiser-popup)
  28 (require 'geiser-custom)
  29 (require 'geiser-base)
  30
  31 \f
  32 ;;; Customization:
  33
  34 (defgroup geiser-mode nil
  35   "Mode enabling Geiser abilities in Scheme buffers &co.."
  36   :group 'geiser)
  37
  38 (geiser-custom--defcustom geiser-mode-auto-p t
  39   "Whether `geiser-mode' should be active by default in all
  40 scheme buffers."
  41   :group 'geiser-mode
  42   :type 'boolean)
  43
  44 (geiser-custom--defcustom geiser-mode-start-repl-p nil
  45   "Whether a REPL should be automatically started if one is not
  46 active when `geiser-mode' is activated in a buffer."
  47   :group 'geiser-mode
  48   :type 'boolean)
  49
  50 (geiser-custom--defcustom geiser-mode-autodoc-p t
  51   "Whether `geiser-autodoc-mode' gets enabled by default in Scheme buffers."
  52   :group 'geiser-mode
  53   :group 'geiser-autodoc
  54   :type 'boolean)
  55
  56 (geiser-custom--defcustom geiser-mode-company-p t
  57   "Whether to use company-mode for completion, if available."
  58   :group 'geiser-mode
  59   :type 'boolean)
  60
  61 (geiser-custom--defcustom geiser-mode-smart-tab-p nil
  62   "Whether `geiser-smart-tab-mode' gets enabled by default in Scheme buffers."
  63   :group 'geiser-mode
  64   :type 'boolean)
  65
  66
  67 \f
  68 ;;; Evaluation commands:
  69
  70 (defun geiser--go-to-repl ()
  71   (switch-to-geiser nil nil (current-buffer))
  72   (push-mark)
  73   (goto-char (point-max)))
  74
  75 (defun geiser-eval-region (start end &optional and-go raw)
  76   "Eval the current region in the Geiser REPL.
  77 With prefix, goes to the REPL buffer afterwards (as
  78 `geiser-eval-region-and-go')"
  79   (interactive "rP")
  80   (save-restriction
  81     (narrow-to-region start end)
  82     (check-parens))
  83   (geiser-debug--send-region nil
  84                              start
  85                              end
  86                              (and and-go 'geiser--go-to-repl)
  87                              (not raw)))
  88
  89 (defun geiser-eval-region-and-go (start end)
  90   "Eval the current region in the Geiser REPL and visit it afterwads."
  91   (interactive "r")
  92   (geiser-eval-region start end t))
  93
  94 (defun geiser-eval-definition (&optional and-go)
  95   "Eval the current definition in the Geiser REPL.
  96 With prefix, goes to the REPL buffer afterwards (as
  97 `geiser-eval-definition-and-go')"
  98   (interactive "P")
  99   (save-excursion
 100     (end-of-defun)
 101     (let ((end (point)))
 102       (beginning-of-defun)
 103       (geiser-eval-region (point) end and-go t))))
 104
 105 (defun geiser-eval-definition-and-go ()
 106   "Eval the current definition in the Geiser REPL and visit it afterwads."
 107   (interactive)
 108   (geiser-eval-definition t))
 109
 110 (defun geiser-eval-last-sexp ()
 111   "Eval the previous sexp in the Geiser REPL."
 112   (interactive)
 113   (geiser-eval-region (save-excursion (backward-sexp) (point))
 114                       (point)
 115                       nil
 116                       t))
 117
 118 (defun geiser-compile-definition (&optional and-go)
 119   "Compile the current definition in the Geiser REPL.
 120 With prefix, goes to the REPL buffer afterwards (as
 121 `geiser-eval-definition-and-go')"
 122   (interactive "P")
 123   (save-excursion
 124     (end-of-defun)
 125     (let ((end (point)))
 126       (beginning-of-defun)
 127       (geiser-debug--send-region t
 128                                  (point)
 129                                  end
 130                                  (and and-go 'geiser--go-to-repl)
 131                                  t))))
 132
 133 (defun geiser-compile-definition-and-go ()
 134   "Compile the current definition in the Geiser REPL and visit it afterwads."
 135   (interactive)
 136   (geiser-compile-definition t))
 137
 138 (defun geiser-expand-region (start end &optional all raw)
 139   "Macro-expand the current region and display it in a buffer.
 140 With prefix, recursively macro-expand the resulting expression."
 141   (interactive "rP")
 142   (geiser-debug--expand-region start end all (not raw)))
 143
 144 (defun geiser-expand-definition (&optional all)
 145   "Macro-expand the current definition.
 146 With prefix, recursively macro-expand the resulting expression."
 147   (interactive "P")
 148   (save-excursion
 149     (end-of-defun)
 150     (let ((end (point)))
 151       (beginning-of-defun)
 152       (geiser-expand-region (point) end all t))))
 153
 154 (defun geiser-expand-last-sexp (&optional all)
 155   "Macro-expand the previous sexp.
 156 With prefix, recursively macro-expand the resulting expression."
 157   (interactive "P")
 158   (geiser-expand-region (save-excursion (backward-sexp) (point))
 159                         (point)
 160                         all
 161                         t))
 162
 163 (defun geiser-set-scheme ()
 164   "Associates current buffer with a given Scheme implementation."
 165   (interactive)
 166   (let ((impl (geiser-impl--read-impl)))
 167     (geiser-impl--set-buffer-implementation impl)
 168     (geiser-repl--set-up-repl impl)))
 169
 170 (defun geiser-mode-switch-to-repl (arg)
 171   "Switches to Geiser REPL.
 172 With prefix, try to enter the current buffer's module."
 173   (interactive "P")
 174   (if arg
 175       (switch-to-geiser-module (geiser-eval--get-module) (current-buffer))
 176     (switch-to-geiser nil nil (current-buffer))))
 177
 178 (defun geiser-mode-switch-to-repl-and-enter ()
 179   "Switches to Geiser REPL and enters current buffer's module."
 180   (interactive)
 181   (geiser-mode-switch-to-repl t))
 182
 183 (defun geiser-restart-repl ()
 184   "Restarts the REPL associated with the current buffer."
 185   (interactive)
 186   (let ((b (current-buffer)))
 187     (geiser-mode-switch-to-repl nil)
 188     (comint-kill-subjob)
 189     (sit-for 0.1) ;; ugly hack; but i don't care enough to fix it
 190     (call-interactively 'run-geiser)
 191     (sit-for 0.2) ;; ditto
 192     (goto-char (point-max))
 193     (pop-to-buffer b)))
 194
 195 (defun geiser-squarify (n)
 196   "Toggle between () and [] for current form.
 197 With numeric prefix, perform that many toggles, forward for
 198 positive values and backward for negative."
 199   (interactive "p")
 200   (let ((pared (and (boundp 'paredit-mode) paredit-mode))
 201         (fwd (> n 0))
 202         (steps (abs n)))
 203     (when (and pared (fboundp 'paredit-mode)) (paredit-mode -1))
 204     (unwind-protect
 205         (save-excursion
 206           (unless (looking-at-p "\\s(") (backward-up-list))
 207           (while (> steps 0)
 208             (let ((p (point))
 209                   (round (looking-at-p "(")))
 210               (forward-sexp)
 211               (backward-delete-char 1)
 212               (insert (if round "]" ")"))
 213               (goto-char p)
 214               (delete-char 1)
 215               (insert (if round "[" "("))
 216               (setq steps (1- steps))
 217               (backward-char)
 218               (condition-case nil
 219                   (progn (when fwd (forward-sexp 2))
 220                          (backward-sexp))
 221                 (error (setq steps 0))))))
 222       (when (and pared (fboundp 'paredit-mode)) (paredit-mode 1)))))
 223
 224 (defun geiser-insert-lambda (&optional full)
 225   "Insert λ at point.  With prefix, inserts (λ ())."
 226   (interactive "P")
 227   (if (not full)
 228       (insert (make-char 'greek-iso8859-7 107))
 229     (insert "(" (make-char 'greek-iso8859-7 107) " ())")
 230     (backward-char 2)))
 231
 232 \f
 233 ;;; Geiser mode:
 234
 235 (make-variable-buffer-local
 236  (defvar geiser-mode-string nil
 237    "Modeline indicator for geiser-mode"))
 238
 239 (defun geiser-mode--lighter ()
 240   (or geiser-mode-string
 241       (format " %s" (or (geiser-impl--impl-str) "G"))))
 242
 243 (defvar geiser-mode-map (make-sparse-keymap))
 244
 245 (define-minor-mode geiser-mode
 246   "Toggle Geiser's mode.
 247 With no argument, this command toggles the mode.
 248 Non-null prefix argument turns on the mode.
 249 Null prefix argument turns off the mode.
 250
 251 When Geiser mode is enabled, a host of nice utilities for
 252 interacting with the Geiser REPL is at your disposal.
 253 \\{geiser-mode-map}"
 254   :init-value nil
 255   :lighter (:eval (geiser-mode--lighter))
 256   :group 'geiser-mode
 257   :keymap geiser-mode-map
 258   (when geiser-mode (geiser-impl--set-buffer-implementation nil t))
 259   (setq geiser-autodoc-mode-string "/A")
 260   (setq geiser-smart-tab-mode-string "/T")
 261   (geiser-company--setup (and geiser-mode geiser-mode-company-p))
 262   (geiser-completion--setup geiser-mode)
 263   (when geiser-mode-autodoc-p
 264     (geiser-autodoc-mode (if geiser-mode 1 -1)))
 265   (when geiser-mode-smart-tab-p
 266     (geiser-smart-tab-mode (if geiser-mode 1 -1)))
 267   (geiser-syntax--add-kws)
 268   (when (and geiser-mode
 269              geiser-mode-start-repl-p
 270              (not (geiser-repl--connection*)))
 271     (save-window-excursion (run-geiser geiser-impl--implementation))))
 272
 273 (defun turn-on-geiser-mode ()
 274   "Enable `geiser-mode' (in a Scheme buffer)."
 275   (interactive)
 276   (geiser-mode 1))
 277
 278 (defun turn-off-geiser-mode ()
 279   "Disable `geiser-mode' (in a Scheme buffer)."
 280   (interactive)
 281   (geiser-mode -1))
 282
 283 (defun geiser-mode--maybe-activate ()
 284   (when geiser-mode-auto-p (turn-on-geiser-mode)))
 285
 286 \f
 287 ;;; Keys:
 288
 289 (geiser-menu--defmenu geiserm geiser-mode-map
 290   ("Eval sexp before point" "\C-x\C-e" geiser-eval-last-sexp)
 291   ("Eval definition" "\M-\C-x" geiser-eval-definition)
 292   ("Eval definition and go" "\C-c\M-e" geiser-eval-definition-and-go)
 293   ("Eval region" "\C-c\C-r" geiser-eval-region :enable mark-active)
 294   ("Eval region and go" "\C-c\M-r" geiser-eval-region-and-go
 295    geiser-eval-region :enable mark-active)
 296 ;;  ("Compile definition" "\C-c\M-c" geiser-compile-definition)
 297 ;;  ("Compile definition and go" "\C-c\C-c" geiser-compile-definition-and-go)
 298   (menu "Macroexpand"
 299         ("Sexp before point" ("\C-c\C-m\C-e" "\C-c\C-me")
 300          geiser-expand-last-sexp)
 301         ("Region" ("\C-c\C-m\C-r" "\C-c\C-mr") geiser-expand-region)
 302         ("Definition" ("\C-c\C-m\C-x" "\C-c\C-mx") geiser-expand-definition))
 303   --
 304   ("Symbol documentation" ("\C-c\C-d\C-d" "\C-c\C-dd")
 305    geiser-doc-symbol-at-point :enable (geiser--symbol-at-point))
 306   ("Short symbol documentation" ("\C-c\C-d\C-s" "\C-c\C-ds")
 307    geiser-autodoc-show :enable (geiser--symbol-at-point))
 308   ("Module documentation" ("\C-c\C-d\C-m" "\C-c\C-dm") geiser-doc-module)
 309   ("Symbol manual lookup" ("\C-c\C-d\C-i" "\C-c\C-di")
 310    geiser-doc-look-up-manual :enable (geiser-doc--manual-available-p))
 311   (mode "Autodoc mode" ("\C-c\C-d\C-a" "\C-c\C-da") geiser-autodoc-mode)
 312   --
 313   ("Compile buffer" "\C-c\C-k" geiser-compile-current-buffer)
 314   ("Switch to REPL" "\C-c\C-z" geiser-mode-switch-to-repl)
 315   ("Switch to REPL and enter module" "\C-c\C-a"
 316    geiser-mode-switch-to-repl-and-enter)
 317   ("Set Scheme..." "\C-c\C-s" geiser-set-scheme)
 318   --
 319   ("Edit symbol at point" "\M-." geiser-edit-symbol-at-point
 320    :enable (geiser--symbol-at-point))
 321   ("Go to previous definition" "\M-," geiser-pop-symbol-stack)
 322   ("Complete symbol" ((kbd "M-TAB")) completion-at-point
 323    :enable (geiser--symbol-at-point))
 324   ("Complete module name" ((kbd "M-`") (kbd "C-."))
 325    geiser-completion--complete-module)
 326   ("Edit module" ("\C-c\C-e\C-m" "\C-c\C-em") geiser-edit-module)
 327   ("Add to load path..." ("\C-c\C-e\C-l" "\C-c\C-el") geiser-add-to-load-path)
 328   ("Toggle ()/[]" ("\C-c\C-e\C-[" "\C-c\C-e[") geiser-squarify)
 329   ("Insert λ" ("\C-c\\" "\C-c\C-\\") geiser-insert-lambda)
 330   --
 331   ("Callers" ((kbd "C-c <")) geiser-xref-callers
 332    :enable (and (geiser-eval--supported-p 'callers)
 333                 (geiser--symbol-at-point)))
 334   ("Callees" ((kbd "C-c >")) geiser-xref-callees
 335    :enable (and (geiser-eval--supported-p 'callees)
 336                 (geiser--symbol-at-point)))
 337   --
 338   (mode "Smart TAB mode" nil geiser-smart-tab-mode)
 339   --
 340   (custom "Customize Geiser mode" geiser-mode))
 341
 342 (define-key geiser-mode-map [menu-bar scheme] 'undefined)
 343
 344 ;; (geiser-mode--triple-chord ?x ?m 'geiser-xref-generic-methods)
 345
 346 \f
 347 ;;; Reload support:
 348
 349 (defun geiser-mode--buffers ()
 350   (let ((buffers))
 351     (dolist (buffer (buffer-list))
 352       (when (buffer-live-p buffer)
 353         (set-buffer buffer)
 354         (when geiser-mode
 355           (push (cons buffer geiser-impl--implementation) buffers))))
 356     buffers))
 357
 358 (defun geiser-mode--restore (buffers)
 359   (dolist (b buffers)
 360     (when (buffer-live-p (car b))
 361       (set-buffer (car b))
 362       (when (cdr b)
 363         (geiser-impl--set-buffer-implementation (cdr b)))
 364       (geiser-mode 1))))
 365
 366 (defun geiser-mode-unload-function ()
 367   (dolist (b (geiser-mode--buffers))
 368     (with-current-buffer (car b) (geiser-mode nil))))
 369
 370 \f
 371 (provide 'geiser-mode)