elisp/geiser-syntax.el

   1 ;;; geiser-syntax.el -- utilities for parsing scheme syntax
   2
   3 ;; Copyright (C) 2009, 2010 Jose Antonio Ortega Ruiz
   4
   5 ;; This program is free software; you can redistribute it and/or
   6 ;; modify it under the terms of the Modified BSD License. You should
   7 ;; have received a copy of the license along with this program. If
   8 ;; not, see <http://www.xfree86.org/3.3.6/COPYRIGHT2.html#5>.
   9
  10 ;; Start date: Sun Feb 08, 2009 15:03
  11
  12 \f
  13
  14 (require 'geiser-impl)
  15 (require 'geiser-popup)
  16 (require 'geiser-base)
  17
  18 (require 'scheme)
  19
  20 (eval-when-compile (require 'cl))
  21
  22 \f
  23 ;;; Indentation:
  24
  25 (defmacro geiser-syntax--scheme-indent (&rest pairs)
  26   `(progn ,@(mapcar (lambda (p)
  27                       `(put ',(car p) 'scheme-indent-function ',(cadr p)))
  28                     pairs)))
  29
  30 (geiser-syntax--scheme-indent
  31  (begin0 1)
  32  (c-declare 0)
  33  (c-lambda 2)
  34  (case-lambda 0)
  35  (case-lambda: 0)
  36  (catch defun)
  37  (class defun)
  38  (class* defun)
  39  (compound-unit/sig 0)
  40  (define: defun)
  41  (dynamic-wind 0)
  42  (for/fold 2)
  43  (instantiate 2)
  44  (interface 1)
  45  (lambda: 1)
  46  (lambda/kw 1)
  47  (let*-values 1)
  48  (let*-values: 1)
  49  (let+ 1)
  50  (let: 1)
  51  (letrec: 1)
  52  (letrec* 1)
  53  (letrec-values 1)
  54  (letrec-values: 1)
  55  (let-values 1)
  56  (let-values: 1)
  57  (let/cc: 1)
  58  (let/ec 1)
  59  (match defun)
  60  (mixin 2)
  61  (module defun)
  62  (opt-lambda 1)
  63  (parameterize 1)
  64  (parameterize-break 1)
  65  (parameterize* 1)
  66  (pmatch defun)
  67  (quasisyntax/loc 1)
  68  (receive 2)
  69  (send* 1)
  70  (sigaction 1)
  71  (syntax-case 2)
  72  (syntax/loc 1)
  73  (type-case defun)
  74  (unit defun)
  75  (unit/sig 2)
  76  (unless 1)
  77  (when 1)
  78  (while 1)
  79  (with-fluid* 1)
  80  (with-fluids 1)
  81  (with-fluids* 1)
  82  (with-handlers 1)
  83  (with-handlers: 1)
  84  (with-method 1)
  85  (with-syntax 1))
  86
  87 \f
  88 ;;; Extra syntax keywords
  89 (defconst geiser-syntax--keywords
  90   '(("\\[\\(else\\)\\>" . 1)
  91     ("(\\(parameterize\\)\\>" . 1)))
  92
  93 (font-lock-add-keywords 'scheme-mode geiser-syntax--keywords)
  94
  95 (geiser-impl--define-caller geiser-syntax--impl-kws keywords ()
  96   "A variable (or thunk returning a value) giving additional,
  97 implementation-specific entries for font-lock-keywords.")
  98
  99 (defun geiser-syntax--add-kws ()
 100   (let ((kw (geiser-syntax--impl-kws geiser-impl--implementation)))
 101     (when kw (font-lock-add-keywords nil kw))))
 102
 103 \f
 104 ;;; A simple scheme reader
 105
 106 (defvar geiser-syntax--read/buffer-limit nil)
 107
 108 (defsubst geiser-syntax--read/eos ()
 109   (or (eobp)
 110       (and geiser-syntax--read/buffer-limit
 111            (<= geiser-syntax--read/buffer-limit (point)))))
 112
 113 (defsubst geiser-syntax--read/next-char ()
 114   (unless (geiser-syntax--read/eos)
 115     (forward-char)
 116     (char-after)))
 117
 118 (defsubst geiser-syntax--read/token (token)
 119   (geiser-syntax--read/next-char)
 120   (if (listp token) token (list token)))
 121
 122 (defsubst geiser-syntax--read/elisp ()
 123   (ignore-errors (read (current-buffer))))
 124
 125 (defun geiser-syntax--read/matching (open close)
 126   (let ((count 1)
 127         (p (1+ (point))))
 128     (while (and (> count 0)
 129                 (geiser-syntax--read/next-char))
 130       (cond ((looking-at-p open) (setq count (1+ count)))
 131             ((looking-at-p close) (setq count (1- count)))))
 132     (buffer-substring-no-properties p (point))))
 133
 134 (defsubst geiser-syntax--read/unprintable ()
 135   (geiser-syntax--read/token
 136    (cons 'unprintable (geiser-syntax--read/matching "<" ">"))))
 137
 138 (defun geiser-syntax--read/skip-comment ()
 139   (while (and (geiser-syntax--read/next-char)
 140               (nth 8 (syntax-ppss))))
 141   (geiser-syntax--read/next-token))
 142
 143 (defun geiser-syntax--read/next-token ()
 144   (skip-syntax-forward "->")
 145   (if (geiser-syntax--read/eos) '(eob)
 146     (case (char-after)
 147       (?\; (geiser-syntax--read/skip-comment))
 148       ((?\( ?\[) (geiser-syntax--read/token 'lparen))
 149       ((?\) ?\]) (geiser-syntax--read/token 'rparen))
 150       (?. (if (memq (car (syntax-after (1+ (point)))) '(0 11 12))
 151               (geiser-syntax--read/token 'dot)
 152             (cons 'atom (geiser-syntax--read/elisp))))
 153       (?\# (case (geiser-syntax--read/next-char)
 154              ('nil '(eob))
 155              (?| (geiser-syntax--read/skip-comment))
 156              (?: (if (geiser-syntax--read/next-char)
 157                      (cons 'kwd (geiser-syntax--read/elisp))
 158                    '(eob)))
 159              (?\\ (cons 'char (geiser-syntax--read/elisp)))
 160              (?\( (geiser-syntax--read/token 'vectorb))
 161              (?\< (geiser-syntax--read/unprintable))
 162              ((?' ?` ?,) (geiser-syntax--read/next-token))
 163              (t (let ((tok (geiser-syntax--read/elisp)))
 164                   (if tok (cons 'atom (intern (format "#%s" tok)))
 165                     (geiser-syntax--read/next-token))))))
 166       (?\' (geiser-syntax--read/token '(quote . quote)))
 167       (?\` (geiser-syntax--read/token
 168             `(backquote . ,backquote-backquote-symbol)))
 169       (?, (if (eq (geiser-syntax--read/next-char) ?@)
 170               (geiser-syntax--read/token
 171                `(splice . ,backquote-splice-symbol))
 172             `(unquote . ,backquote-unquote-symbol)))
 173       (?\" (cons 'string (geiser-syntax--read/elisp)))
 174       (t (cons 'atom (geiser-syntax--read/elisp))))))
 175
 176 (defsubst geiser-syntax--read/match (&rest tks)
 177   (let ((token (geiser-syntax--read/next-token)))
 178     (if (memq (car token) tks) token
 179       (error "Unexpected token: %s" token))))
 180
 181 (defsubst geiser-syntax--read/skip-until (&rest tks)
 182   (let (token)
 183     (while (and (not (memq (car token) tks))
 184                 (not (eq (car token) 'eob)))
 185       (setq token (geiser-syntax--read/next-token)))
 186     token))
 187
 188 (defsubst geiser-syntax--read/try (&rest tks)
 189   (let ((p (point))
 190         (tk (ignore-errors (apply 'geiser-syntax--read/match tks))))
 191     (unless tk (goto-char p))
 192     tk))
 193
 194 (defun geiser-syntax--read/list ()
 195   (cond ((geiser-syntax--read/try 'dot)
 196          (let ((tail (geiser-syntax--read)))
 197            (geiser-syntax--read/skip-until 'eob 'rparen)
 198            tail))
 199         ((geiser-syntax--read/try 'rparen 'eob) nil)
 200         (t (cons (geiser-syntax--read)
 201                  (geiser-syntax--read/list)))))
 202
 203 (defun geiser-syntax--read ()
 204   (let ((token (geiser-syntax--read/next-token))
 205         (max-lisp-eval-depth (max max-lisp-eval-depth 3000)))
 206     (case (car token)
 207       (eob nil)
 208       (lparen (geiser-syntax--read/list))
 209       (vectorb (apply 'vector (geiser-syntax--read/list)))
 210       ((quote backquote unquote splice) (list (cdr token)
 211                                               (geiser-syntax--read)))
 212       (kwd (intern (format ":%s" (cdr token))))
 213       (unprintable (format "#<%s>" (cdr token)))
 214       ((char string atom) (cdr token))
 215       (t (error "Reading scheme syntax: unexpected token: %s" token)))))
 216
 217 (defun geiser-syntax--read-from-string (string &optional start end)
 218   (when (stringp string)
 219     (let* ((start (or start 0))
 220            (end (or end (length string)))
 221            (max-lisp-eval-depth (max max-lisp-eval-depth (- end start))))
 222       (with-temp-buffer
 223         (save-excursion (insert string))
 224         (cons (ignore-errors (geiser-syntax--read)) (point))))))
 225
 226 (defsubst geiser-syntax--form-after-point (&optional boundary)
 227   (let ((geiser-syntax--read/buffer-limit (and (numberp boundary) boundary)))
 228     (save-excursion (values (geiser-syntax--read) (point)))))
 229
 230 \f
 231 ;;; Code parsing:
 232
 233 (defsubst geiser-syntax--symbol-at-point ()
 234   (and (not (nth 8 (syntax-ppss)))
 235        (let ((s (symbol-at-point)))
 236          (and (not (eq s '.)) s))))
 237
 238 (defsubst geiser-syntax--skip-comment/string ()
 239   (let ((pos (nth 8 (syntax-ppss))))
 240     (goto-char (or pos (point)))
 241     pos))
 242
 243 (defsubst geiser-syntax--nesting-level ()
 244   (or (nth 0 (syntax-ppss)) 0))
 245
 246 (defsubst geiser-syntax--pair-length (p)
 247   (if (cdr (last p)) (1+ (safe-length p)) (length p)))
 248
 249 (defun geiser-syntax--shallow-form (boundary)
 250   (when (looking-at-p "\\s(")
 251     (save-excursion
 252       (forward-char)
 253       (let ((elems))
 254         (ignore-errors
 255           (while (< (point) boundary)
 256             (skip-syntax-forward "-<>")
 257             (when (<= (point) boundary)
 258               (forward-sexp)
 259               (let ((s (symbol-at-point)))
 260                 (when (not (eq s '.)) (push (symbol-at-point) elems))))))
 261         (nreverse elems)))))
 262
 263 (defun geiser-syntax--scan-sexps (&optional begin)
 264   (let* ((fst (geiser-syntax--symbol-at-point))
 265          (smth (or fst (not (looking-at-p "[\s \s)\s>\s<\n]"))))
 266          (path (and fst `((,fst 0)))))
 267     (save-excursion
 268       (while (not (zerop (geiser-syntax--nesting-level)))
 269         (let ((boundary (point)))
 270           (geiser-syntax--skip-comment/string)
 271           (backward-up-list)
 272           (let ((form (geiser-syntax--shallow-form boundary)))
 273             (when (and (listp form) (car form) (symbolp (car form)))
 274               (let* ((len (geiser-syntax--pair-length form))
 275                      (pos (if smth (1- len) (progn (setq smth t) len)))
 276                      (prev (and (> pos 1) (nth (1- pos) form)))
 277                      (prev (and (keywordp prev) (list prev))))
 278                 (push `(,(car form) ,pos ,@prev) path)))))))
 279     (nreverse path)))
 280
 281 (defsubst geiser-syntax--binding-form-p (bfs sbfs f)
 282   (or (memq f '(define define* define-syntax define-syntax-rule
 283                 lambda let let* letrec parameterize))
 284       (memq f bfs)
 285       (memq f sbfs)))
 286
 287 (defsubst geiser-syntax--binding-form*-p (sbfs f)
 288   (or (eq 'let* f) (memq f sbfs)))
 289
 290 (defsubst geiser-syntax--if-symbol (x) (and (symbolp x) x))
 291 (defsubst geiser-syntax--if-list (x) (and (listp x) x))
 292 (defsubst geiser-syntax--normalize (vars)
 293   (mapcar (lambda (i) (if (listp i) (car i) i)) vars))
 294
 295 (defun geiser-syntax--linearize (form)
 296   (cond ((not (listp form)) (list form))
 297         ((null form) nil)
 298         (t (cons (car form) (geiser-syntax--linearize (cdr form))))))
 299
 300 (defun geiser-syntax--scan-locals (bfs sbfs form partial locals)
 301   (if (or (null form) (not (listp form)))
 302       (geiser-syntax--normalize locals)
 303     (if (not (geiser-syntax--binding-form-p bfs sbfs (car form)))
 304         (geiser-syntax--scan-locals bfs sbfs
 305                                     (car (last form)) partial locals)
 306       (let* ((head (car form))
 307              (name (geiser-syntax--if-symbol (cadr form)))
 308              (names (if name (geiser-syntax--if-list (caddr form))
 309                       (geiser-syntax--if-list (cadr form))))
 310              (rest (if name (cdddr form) (cddr form)))
 311              (use-names (or rest
 312                             (not partial)
 313                             (geiser-syntax--binding-form*-p sbfs
 314                                                             head))))
 315         (when name (push name locals))
 316         (when use-names
 317           (dolist (n (geiser-syntax--linearize names))
 318             (push n locals)))
 319         (dolist (f (butlast rest))
 320           (when (and (listp f) (eq (car f) 'define))
 321             (push (cadr f) locals)))
 322         (geiser-syntax--scan-locals bfs sbfs
 323                                     (car (last (or rest names)))
 324                                     partial
 325                                     locals)))))
 326
 327 (defun geiser-syntax--locals-around-point (bfs sbfs)
 328   (when (eq major-mode 'scheme-mode)
 329     (save-excursion
 330       (let* ((sym (unless (geiser-syntax--skip-comment/string)
 331                     (symbol-at-point)))
 332              (boundary (point)))
 333         (while (not (zerop (geiser-syntax--nesting-level)))
 334           (backward-up-list))
 335         (multiple-value-bind (form end)
 336             (geiser-syntax--form-after-point boundary)
 337           (delq sym
 338                 (geiser-syntax--scan-locals bfs sbfs form
 339                                             (> end boundary) '())))))))
 340
 341 \f
 342 ;;; Fontify strings as Scheme code:
 343
 344 (defun geiser-syntax--font-lock-buffer ()
 345   (let ((name " *geiser font lock*"))
 346     (or (get-buffer name)
 347         (let ((buffer (get-buffer-create name)))
 348           (set-buffer buffer)
 349           (let ((geiser-default-implementation
 350                  (or geiser-default-implementation
 351                      (car geiser-active-implementations))))
 352             (scheme-mode))
 353           buffer))))
 354
 355 (defun geiser-syntax--scheme-str (str)
 356   (save-current-buffer
 357     (set-buffer (geiser-syntax--font-lock-buffer))
 358     (erase-buffer)
 359     (insert str)
 360     (let ((font-lock-verbose nil)) (font-lock-fontify-buffer))
 361     (buffer-string)))
 362
 363 \f
 364 (provide 'geiser-syntax)
 365 ;;; geiser-syntax.el ends here