elisp/geiser-company.el

   1 ;; geiser-company.el -- integration with company-mode
   2
   3 ;; Copyright (C) 2009, 2010 Jose Antonio Ortega Ruiz
   4
   5 ;; This program is free software; you can redistribute it and/or
   6 ;; modify it under the terms of the Modified BSD License. You should
   7 ;; have received a copy of the license along with this program. If
   8 ;; not, see <http://www.xfree86.org/3.3.6/COPYRIGHT2.html#5>.
   9
  10 ;; Start date: Mon Aug 24, 2009 12:44
  11
  12 \f
  13
  14 (require 'geiser-autodoc)
  15 (require 'geiser-completion)
  16 (require 'geiser-edit)
  17 (require 'geiser-base)
  18
  19 \f
  20 ;;; Helpers:
  21
  22 (make-variable-buffer-local
  23  (defvar geiser-company--enabled-flag nil))
  24
  25 (make-variable-buffer-local
  26  (defvar geiser-company--autodoc-flag nil))
  27
  28 (defsubst geiser-company--candidates (prefix module)
  29   (geiser-completion--complete prefix module))
  30
  31 (defsubst geiser-company--doc (id module)
  32   (ignore-errors
  33     (if module
  34         (format "%s [module]" id)
  35       (or (geiser-autodoc--autodoc (list (list (intern id) 0)) t)
  36           (format "%s [local id]" id)))))
  37
  38 (defsubst geiser-company--doc-buffer (id module)
  39   nil)
  40
  41 (defun geiser-company--location (id module)
  42   (ignore-errors
  43     (let ((id (intern id)))
  44       (save-excursion
  45         (if module
  46             (geiser-edit-module id 'noselect)
  47           (geiser-edit-symbol id 'noselect))))))
  48
  49 (defun geiser-company--prefix-at-point (module)
  50   (when geiser-company--enabled-flag
  51     (cond ((nth 8 (syntax-ppss)) 'stop)
  52           ((looking-at-p "\\_>") (geiser-completion--prefix module))
  53           (module 'stop)
  54           (t nil))))
  55
  56 \f
  57 ;;; Activation
  58
  59 (defun geiser-company--setup (enable)
  60   (setq geiser-company--enabled-flag enable)
  61   (when (fboundp 'geiser-company--setup-company)
  62     (geiser-company--setup-company enable)))
  63
  64 (defun geiser-company--inhibit-autodoc (ignored)
  65   (when (setq geiser-company--autodoc-flag geiser-autodoc-mode)
  66     (geiser-autodoc-mode -1)))
  67
  68 (defun geiser-company--restore-autodoc (&optional ignored)
  69   (when geiser-company--autodoc-flag
  70     (geiser-autodoc-mode 1)))
  71
  72 \f
  73 ;;; Backends:
  74 (defmacro geiser-company--make-backend (name mod)
  75   `(defun ,name (command &optional arg &rest ignored)
  76      "A `company-mode' completion back-end for `geiser-mode'."
  77      (interactive (list 'interactive))
  78      (case command
  79        ('interactive (company-begin-backend ',name))
  80        ('prefix (geiser-company--prefix-at-point ,mod))
  81        ('candidates (geiser-company--candidates arg ,mod))
  82        ('meta (geiser-company--doc arg ,mod))
  83        ('doc-buffer (geiser-company--doc-buffer arg ,mod))
  84        ('location (geiser-company--location arg ,mod))
  85        ('sorted t))))
  86
  87 (defvar geiser-company--backend '(company-geiser-ids company-geiser-modules))
  88
  89 (eval-after-load "company"
  90   '(progn
  91      (defun geiser-company--setup-company (enable)
  92        (set (make-local-variable 'company-default-lighter) "/C")
  93        (set (make-local-variable 'company-echo-delay) 0.01)
  94        (company-mode nil)
  95        (when enable (company-mode enable)))
  96      (geiser-company--make-backend company-geiser-ids nil)
  97      (geiser-company--make-backend company-geiser-modules t)
  98      (add-to-list 'company-backends geiser-company--backend)
  99      (add-hook 'company-completion-finished-hook
 100                'geiser-company--restore-autodoc)
 101      (add-hook 'company-completion-cancelled-hook
 102                'geiser-company--restore-autodoc)
 103      (add-hook 'company-completion-started-hook
 104                'geiser-company--inhibit-autodoc)))
 105
 106 \f
 107 ;;; Reload support:
 108
 109 (defun geiser-company-unload-function ()
 110   (when (boundp 'company-backends)
 111     (setq company-backends (remove geiser-company--backend company-backends))))
 112
 113 \f
 114 (provide 'geiser-company)
 115 ;;; geiser-company.el ends here