scheme/racket/geiser/user.rkt

   1 ;;; user.rkt -- global bindings visible to geiser users
   2
   3 ;; Copyright (C) 2010, 2011 Jose Antonio Ortega Ruiz
   4
   5 ;; This program is free software; you can redistribute it and/or
   6 ;; modify it under the terms of the Modified BSD License. You should
   7 ;; have received a copy of the license along with this program. If
   8 ;; not, see <http://www.xfree86.org/3.3.6/COPYRIGHT2.html#5>.
   9
  10 ;; Start date: Wed Mar 31, 2010 22:24
  11
  12 #lang racket/base
  13
  14 (provide init-geiser-repl run-geiser-server start-geiser)
  15
  16 (require (for-syntax racket/base)
  17          mzlib/thread
  18          racket/tcp
  19          geiser
  20          geiser/enter
  21          geiser/eval
  22          geiser/modules)
  23
  24 (define top-namespace (current-namespace))
  25 (define last-entered (make-parameter ""))
  26
  27 (define (do-enter mod name)
  28   (enter-module mod)
  29   (current-namespace (module->namespace mod))
  30   (last-entered name))
  31
  32 (define (enter! mod stx)
  33   (cond [(not mod)
  34          (current-namespace top-namespace)
  35          (last-entered "")]
  36         [(symbol? mod) (do-enter mod (symbol->string mod))]
  37         [(and (list? mod)
  38               (= 2 (length mod))
  39               (eq? 'file (car mod))
  40               (path-string? (cadr mod))) (do-enter mod (cadr mod))]
  41         [(path-string? mod) (do-enter `(file ,mod) mod)]
  42         [else (raise-syntax-error
  43                #f
  44                "not a valid module path, and not #f"
  45                stx
  46                mod)]))
  47
  48 (define orig-loader (current-load/use-compiled))
  49 (define geiser-loader (module-loader orig-loader))
  50
  51 (define (geiser-eval)
  52   (define geiser-main (module->namespace 'geiser))
  53   (define (eval-here form) (eval form geiser-main))
  54   (let* ([mod (read)]
  55          [lang (read)]
  56          [form (read)])
  57     (datum->syntax #f
  58                    (list 'quote
  59                          (cond [(equal? form '(unquote apply))
  60                                 (let* ([proc (eval-here (read))]
  61                                        [args (map eval-here (read))]
  62                                        [ev (lambda () (apply proc args))])
  63                                   (eval-in `(,ev) mod lang))]
  64                                [else ((geiser:eval lang) form mod)])))))
  65
  66 (define ((geiser-read prompt))
  67   (prompt)
  68   (flush-output)
  69   (let* ([in ((current-get-interaction-input-port))]
  70          [form ((current-read-interaction) (object-name in) in)])
  71     (syntax-case form ()
  72       [(uq cmd) (eq? 'unquote (syntax-e #'uq))
  73        (case (syntax-e #'cmd)
  74          [(start-geiser) (datum->syntax #f `(list 'port ,(start-geiser)))]
  75          [(enter) (enter! (read) #'cmd)]
  76          [(geiser-eval) (geiser-eval)]
  77          [(geiser-no-values) (datum->syntax #f (void))]
  78          [(add-to-load-path) (add-to-load-path (read))]
  79          [else form])]
  80       [_ form])))
  81
  82 (define geiser-prompt
  83   (lambda ()
  84     (printf "racket@~a> "
  85             (namespace->module-name (current-namespace) (last-entered)))))
  86
  87 (define (geiser-prompt-read prompt)
  88   (make-repl-reader (geiser-read prompt)))
  89
  90 (define (init-geiser-repl)
  91   (compile-enforce-module-constants #f)
  92   (current-load/use-compiled geiser-loader)
  93   (current-prompt-read (geiser-prompt-read geiser-prompt)))
  94
  95 (define (run-geiser-repl in out enforce-module-constants)
  96   (parameterize [(compile-enforce-module-constants enforce-module-constants)
  97                  (current-input-port in)
  98                  (current-output-port out)
  99                  (current-error-port out)
 100                  (current-load/use-compiled geiser-loader)
 101                  (current-prompt-read (geiser-prompt-read geiser-prompt))]
 102     (read-eval-print-loop)))
 103
 104 (define server-channel (make-channel))
 105
 106 (define (run-geiser-server port enforce-module-constants)
 107   (run-server port
 108               (lambda (in out)
 109                 (run-geiser-repl in out enforce-module-constants))
 110               #f
 111               void
 112               (lambda (p _ __)
 113                 (let ([lsner (tcp-listen p)])
 114                   (let-values ([(_ p __ ___) (tcp-addresses lsner #t)])
 115                     (channel-put server-channel p)
 116                     lsner)))))
 117
 118 (define (start-geiser (port 0) (enforce-module-constants #f))
 119   (thread (lambda () (run-geiser-server port enforce-module-constants)))
 120   (channel-get server-channel))