elisp/geiser-mode.el

   1 ;; geiser-mode.el -- minor mode for scheme buffers
   2
   3 ;; Copyright (C) 2009, 2010, 2011, 2012, 2013, 2014, 2015 Jose Antonio Ortega Ruiz
   4
   5 ;; This program is free software; you can redistribute it and/or
   6 ;; modify it under the terms of the Modified BSD License. You should
   7 ;; have received a copy of the license along with this program. If
   8 ;; not, see <http://www.xfree86.org/3.3.6/COPYRIGHT2.html#5>.
   9
  10 ;; Start date: Sun Feb 08, 2009 15:13
  11
  12 \f
  13
  14 (require 'geiser-repl)
  15 (require 'geiser-menu)
  16 (require 'geiser-doc)
  17 (require 'geiser-compile)
  18 (require 'geiser-completion)
  19 (require 'geiser-company)
  20 (require 'geiser-xref)
  21 (require 'geiser-edit)
  22 (require 'geiser-autodoc)
  23 (require 'geiser-debug)
  24 (require 'geiser-syntax)
  25 (require 'geiser-impl)
  26 (require 'geiser-eval)
  27 (require 'geiser-popup)
  28 (require 'geiser-custom)
  29 (require 'geiser-base)
  30
  31 \f
  32 ;;; Customization:
  33
  34 (defgroup geiser-mode nil
  35   "Mode enabling Geiser abilities in Scheme buffers &co.."
  36   :group 'geiser)
  37
  38 (geiser-custom--defcustom geiser-mode-auto-p t
  39   "Whether `geiser-mode' should be active by default in all scheme buffers."
  40   :group 'geiser-mode
  41   :type 'boolean)
  42
  43 (geiser-custom--defcustom geiser-mode-start-repl-p nil
  44   "Whether a REPL should be automatically started if one is not
  45 active when `geiser-mode' is activated in a buffer."
  46   :group 'geiser-mode
  47   :type 'boolean)
  48
  49 (geiser-custom--defcustom geiser-mode-autodoc-p t
  50   "Whether `geiser-autodoc-mode' gets enabled by default in Scheme buffers."
  51   :group 'geiser-mode
  52   :group 'geiser-autodoc
  53   :type 'boolean)
  54
  55 (geiser-custom--defcustom geiser-mode-company-p t
  56   "Whether to use company-mode for completion, if available."
  57   :group 'geiser-mode
  58   :type 'boolean)
  59
  60 (geiser-custom--defcustom geiser-mode-smart-tab-p nil
  61   "Whether `geiser-smart-tab-mode' gets enabled by default in Scheme buffers."
  62   :group 'geiser-mode
  63   :type 'boolean)
  64
  65
  66 \f
  67 ;;; Evaluation commands:
  68
  69 (defun geiser--go-to-repl ()
  70   (switch-to-geiser nil nil (current-buffer))
  71   (push-mark)
  72   (goto-char (point-max)))
  73
  74 (defun geiser-eval-region (start end &optional and-go raw nomsg)
  75   "Eval the current region in the Geiser REPL.
  76
  77 With prefix, goes to the REPL buffer afterwards (as
  78 `geiser-eval-region-and-go')"
  79   (interactive "rP")
  80   (save-restriction
  81     (narrow-to-region start end)
  82     (check-parens))
  83   (geiser-debug--send-region nil
  84                              start
  85                              end
  86                              (and and-go 'geiser--go-to-repl)
  87                              (not raw)
  88                              nomsg))
  89
  90 (defun geiser-eval-region-and-go (start end)
  91   "Eval the current region in the Geiser REPL and visit it afterwads."
  92   (interactive "r")
  93   (geiser-eval-region start end t))
  94
  95 (geiser-impl--define-caller geiser-eval--bounds eval-bounds ()
  96   "A pair with the bounds of a buffer to be evaluated, defaulting
  97   to (cons (point-min) . (point-max)).")
  98
  99 (defun geiser-eval-buffer (&optional and-go raw nomsg)
 100   "Eval the current buffer in the Geiser REPL.
 101
 102 With prefix, goes to the REPL buffer afterwards (as
 103 `geiser-eval-buffer-and-go')"
 104   (interactive "P")
 105   (let* ((bounds (geiser-eval--bounds geiser-impl--implementation))
 106          (from (or (car bounds) (point-min)))
 107          (to (or (cdr bounds) (point-max))))
 108     (geiser-eval-region from to and-go raw nomsg)))
 109
 110 (defun geiser-eval-buffer-and-go ()
 111   "Eval the current buffer in the Geiser REPL and visit it afterwads."
 112   (interactive)
 113   (geiser-eval-buffer t))
 114
 115 (defun geiser-eval-definition (&optional and-go)
 116   "Eval the current definition in the Geiser REPL.
 117
 118 With prefix, goes to the REPL buffer afterwards (as
 119 `geiser-eval-definition-and-go')"
 120   (interactive "P")
 121   (save-excursion
 122     (end-of-defun)
 123     (let ((end (point)))
 124       (beginning-of-defun)
 125       (geiser-eval-region (point) end and-go t))))
 126
 127 (defun geiser-eval-definition-and-go ()
 128   "Eval the current definition in the Geiser REPL and visit it afterwads."
 129   (interactive)
 130   (geiser-eval-definition t))
 131
 132 (defun geiser-eval-last-sexp (print-to-buffer-p)
 133   "Eval the previous sexp in the Geiser REPL.
 134
 135 With a prefix, print the result of the evaluation to the buffer."
 136   (interactive "P")
 137   (let* ((ret (geiser-eval-region (save-excursion (backward-sexp) (point))
 138                                   (point)
 139                                   nil
 140                                   t
 141                                   print-to-buffer-p))
 142          (str (geiser-eval--retort-result-str ret (when print-to-buffer-p ""))))
 143     (when (and print-to-buffer-p (not (string= "" str)))
 144       (push-mark)
 145       (insert str))))
 146
 147 (defun geiser-compile-definition (&optional and-go)
 148   "Compile the current definition in the Geiser REPL.
 149
 150 With prefix, goes to the REPL buffer afterwards (as
 151 `geiser-eval-definition-and-go')"
 152   (interactive "P")
 153   (save-excursion
 154     (end-of-defun)
 155     (let ((end (point)))
 156       (beginning-of-defun)
 157       (geiser-debug--send-region t
 158                                  (point)
 159                                  end
 160                                  (and and-go 'geiser--go-to-repl)
 161                                  t))))
 162
 163 (defun geiser-compile-definition-and-go ()
 164   "Compile the current definition in the Geiser REPL and visit it afterwads."
 165   (interactive)
 166   (geiser-compile-definition t))
 167
 168 (defun geiser-expand-region (start end &optional all raw)
 169   "Macro-expand the current region and display it in a buffer.
 170 With prefix, recursively macro-expand the resulting expression."
 171   (interactive "rP")
 172   (geiser-debug--expand-region start end all (not raw)))
 173
 174 (defun geiser-expand-definition (&optional all)
 175   "Macro-expand the current definition.
 176
 177 With prefix, recursively macro-expand the resulting expression."
 178   (interactive "P")
 179   (save-excursion
 180     (end-of-defun)
 181     (let ((end (point)))
 182       (beginning-of-defun)
 183       (geiser-expand-region (point) end all t))))
 184
 185 (defun geiser-expand-last-sexp (&optional all)
 186   "Macro-expand the previous sexp.
 187
 188 With prefix, recursively macro-expand the resulting expression."
 189   (interactive "P")
 190   (geiser-expand-region (save-excursion (backward-sexp) (point))
 191                         (point)
 192                         all
 193                         t))
 194
 195 (defun geiser-set-scheme ()
 196   "Associates current buffer with a given Scheme implementation."
 197   (interactive)
 198   (let ((impl (geiser-impl--read-impl)))
 199     (geiser-impl--set-buffer-implementation impl)
 200     (geiser-repl--set-up-repl impl)))
 201
 202 (defun geiser-mode-switch-to-repl (arg)
 203   "Switches to Geiser REPL.
 204
 205 With prefix, try to enter the current buffer's module."
 206   (interactive "P")
 207   (if arg
 208       (switch-to-geiser-module (geiser-eval--get-module) (current-buffer))
 209     (switch-to-geiser nil nil (current-buffer))))
 210
 211 (defun geiser-mode-switch-to-repl-and-enter ()
 212   "Switches to Geiser REPL and enters current buffer's module."
 213   (interactive)
 214   (geiser-mode-switch-to-repl t))
 215
 216 (defun geiser-restart-repl ()
 217   "Restarts the REPL associated with the current buffer."
 218   (interactive)
 219   (let ((b (current-buffer)))
 220     (geiser-mode-switch-to-repl nil)
 221     (comint-kill-subjob)
 222     (sit-for 0.1) ;; ugly hack; but i don't care enough to fix it
 223     (call-interactively 'run-geiser)
 224     (sit-for 0.2) ;; ditto
 225     (goto-char (point-max))
 226     (pop-to-buffer b)))
 227
 228 (defun geiser-squarify (n)
 229   "Toggle between () and [] for current form.
 230
 231 With numeric prefix, perform that many toggles, forward for
 232 positive values and backward for negative."
 233   (interactive "p")
 234   (let ((pared (and (boundp 'paredit-mode) paredit-mode))
 235         (fwd (> n 0))
 236         (steps (abs n)))
 237     (when (and pared (fboundp 'paredit-mode)) (paredit-mode -1))
 238     (unwind-protect
 239         (save-excursion
 240           (unless (looking-at-p "\\s(") (backward-up-list))
 241           (while (> steps 0)
 242             (let ((p (point))
 243                   (round (looking-at-p "(")))
 244               (forward-sexp)
 245               (backward-delete-char 1)
 246               (insert (if round "]" ")"))
 247               (goto-char p)
 248               (delete-char 1)
 249               (insert (if round "[" "("))
 250               (setq steps (1- steps))
 251               (backward-char)
 252               (condition-case nil
 253                   (progn (when fwd (forward-sexp 2))
 254                          (backward-sexp))
 255                 (error (setq steps 0))))))
 256       (when (and pared (fboundp 'paredit-mode)) (paredit-mode 1)))))
 257
 258 (defun geiser-insert-lambda (&optional full)
 259   "Insert λ at point.  With prefix, inserts (λ ())."
 260   (interactive "P")
 261   (if (not full)
 262       (insert (make-char 'greek-iso8859-7 107))
 263     (insert "(" (make-char 'greek-iso8859-7 107) " ())")
 264     (backward-char 2)))
 265
 266 \f
 267 ;;; Geiser mode:
 268
 269 (make-variable-buffer-local
 270  (defvar geiser-mode-string nil
 271    "Modeline indicator for geiser-mode"))
 272
 273 (defun geiser-mode--lighter ()
 274   (or geiser-mode-string
 275       (format " %s" (or (geiser-impl--impl-str) "G"))))
 276
 277 (defvar geiser-mode-map (make-sparse-keymap))
 278
 279 (define-minor-mode geiser-mode
 280   "Toggle Geiser's mode.
 281
 282 With no argument, this command toggles the mode.
 283 Non-null prefix argument turns on the mode.
 284 Null prefix argument turns off the mode.
 285
 286 When Geiser mode is enabled, a host of nice utilities for
 287 interacting with the Geiser REPL is at your disposal.
 288 \\{geiser-mode-map}"
 289   :init-value nil
 290   :lighter (:eval (geiser-mode--lighter))
 291   :group 'geiser-mode
 292   :keymap geiser-mode-map
 293   (when geiser-mode (geiser-impl--set-buffer-implementation nil t))
 294   (setq geiser-autodoc-mode-string "/A")
 295   (setq geiser-smart-tab-mode-string "/T")
 296   (geiser-company--setup (and geiser-mode geiser-mode-company-p))
 297   (geiser-completion--setup geiser-mode)
 298   (when geiser-mode-autodoc-p
 299     (geiser-autodoc-mode (if geiser-mode 1 -1)))
 300   (when geiser-mode-smart-tab-p
 301     (geiser-smart-tab-mode (if geiser-mode 1 -1)))
 302   (geiser-syntax--add-kws)
 303   (when (and geiser-mode
 304              geiser-mode-start-repl-p
 305              (not (geiser-repl--connection*)))
 306     (save-window-excursion (run-geiser geiser-impl--implementation))))
 307
 308 (defun turn-on-geiser-mode ()
 309   "Enable `geiser-mode' (in a Scheme buffer)."
 310   (interactive)
 311   (geiser-mode 1))
 312
 313 (defun turn-off-geiser-mode ()
 314   "Disable `geiser-mode' (in a Scheme buffer)."
 315   (interactive)
 316   (geiser-mode -1))
 317
 318 (defun geiser-mode--maybe-activate ()
 319   (when (and geiser-mode-auto-p (eq major-mode 'scheme-mode))
 320     (turn-on-geiser-mode)))
 321
 322 \f
 323 ;;; Keys:
 324
 325 (geiser-menu--defmenu geiserm geiser-mode-map
 326   ("Eval sexp before point" "\C-x\C-e" geiser-eval-last-sexp)
 327   ("Eval definition" "\M-\C-x" geiser-eval-definition)
 328   ("Eval definition and go" "\C-c\M-e" geiser-eval-definition-and-go)
 329   ("Eval region" "\C-c\C-r" geiser-eval-region :enable mark-active)
 330   ("Eval region and go" "\C-c\M-r" geiser-eval-region-and-go
 331    geiser-eval-region :enable mark-active)
 332   ("Eval buffer" "\C-c\C-b" geiser-eval-buffer)
 333   ("Eval buffer and go" "\C-c\M-b" geiser-eval-buffer-and-go)
 334 ;;  ("Compile definition" "\C-c\M-c" geiser-compile-definition)
 335 ;;  ("Compile definition and go" "\C-c\C-c" geiser-compile-definition-and-go)
 336   (menu "Macroexpand"
 337         ("Sexp before point" ("\C-c\C-m\C-e" "\C-c\C-me")
 338          geiser-expand-last-sexp)
 339         ("Region" ("\C-c\C-m\C-r" "\C-c\C-mr") geiser-expand-region)
 340         ("Definition" ("\C-c\C-m\C-x" "\C-c\C-mx") geiser-expand-definition))
 341   --
 342   ("Symbol documentation" ("\C-c\C-d\C-d" "\C-c\C-dd")
 343    geiser-doc-symbol-at-point :enable (geiser--symbol-at-point))
 344   ("Short symbol documentation" ("\C-c\C-d\C-s" "\C-c\C-ds")
 345    geiser-autodoc-show :enable (geiser--symbol-at-point))
 346   ("Module documentation" ("\C-c\C-d\C-m" "\C-c\C-dm") geiser-doc-module)
 347   ("Symbol manual lookup" ("\C-c\C-d\C-i" "\C-c\C-di")
 348    geiser-doc-look-up-manual :enable (geiser-doc--manual-available-p))
 349   (mode "Autodoc mode" ("\C-c\C-d\C-a" "\C-c\C-da") geiser-autodoc-mode)
 350   --
 351   ("Compile buffer" "\C-c\C-k" geiser-compile-current-buffer)
 352   ("Switch to REPL" "\C-c\C-z" geiser-mode-switch-to-repl)
 353   ("Switch to REPL and enter module" "\C-c\C-a"
 354    geiser-mode-switch-to-repl-and-enter)
 355   ("Set Scheme..." "\C-c\C-s" geiser-set-scheme)
 356   --
 357   ("Edit symbol at point" "\M-." geiser-edit-symbol-at-point
 358    :enable (geiser--symbol-at-point))
 359   ("Go to previous definition" "\M-," geiser-pop-symbol-stack)
 360   ("Complete symbol" ((kbd "M-TAB")) completion-at-point
 361    :enable (geiser--symbol-at-point))
 362   ("Complete module name" ((kbd "M-`") (kbd "C-."))
 363    geiser-completion--complete-module)
 364   ("Edit module" ("\C-c\C-e\C-m" "\C-c\C-em") geiser-edit-module)
 365   ("Add to load path..." ("\C-c\C-e\C-l" "\C-c\C-el") geiser-add-to-load-path)
 366   ("Toggle ()/[]" ("\C-c\C-e\C-[" "\C-c\C-e[") geiser-squarify)
 367   ("Insert λ" ("\C-c\\" "\C-c\C-\\") geiser-insert-lambda)
 368   --
 369   ("Callers" ((kbd "C-c <")) geiser-xref-callers
 370    :enable (and (geiser-eval--supported-p 'callers)
 371                 (geiser--symbol-at-point)))
 372   ("Callees" ((kbd "C-c >")) geiser-xref-callees
 373    :enable (and (geiser-eval--supported-p 'callees)
 374                 (geiser--symbol-at-point)))
 375   --
 376   (mode "Smart TAB mode" nil geiser-smart-tab-mode)
 377   --
 378   (custom "Customize Geiser mode" geiser-mode))
 379
 380 (define-key geiser-mode-map [menu-bar scheme] 'undefined)
 381
 382 ;; (geiser-mode--triple-chord ?x ?m 'geiser-xref-generic-methods)
 383
 384 \f
 385 ;;; Reload support:
 386
 387 (defun geiser-mode--buffers ()
 388   (let ((buffers))
 389     (dolist (buffer (buffer-list))
 390       (when (buffer-live-p buffer)
 391         (set-buffer buffer)
 392         (when geiser-mode
 393           (push (cons buffer geiser-impl--implementation) buffers))))
 394     buffers))
 395
 396 (defun geiser-mode--restore (buffers)
 397   (dolist (b buffers)
 398     (when (buffer-live-p (car b))
 399       (set-buffer (car b))
 400       (when (cdr b)
 401         (geiser-impl--set-buffer-implementation (cdr b)))
 402       (geiser-mode 1))))
 403
 404 (defun geiser-mode-unload-function ()
 405   (dolist (b (geiser-mode--buffers))
 406     (with-current-buffer (car b) (geiser-mode nil))))
 407
 408 \f
 409 (provide 'geiser-mode)