elisp/geiser-chicken.el

   1 ;; geiser-chicken.el -- chicken's implementation of the geiser protocols
   2
   3 ;; Copyright (C) 2014, 2015 Daniel Leslie
   4
   5 ;; Based on geiser-guile.el by Jose Antonio Ortego Ruize
   6
   7 ;; This program is free software; you can redistribute it and/or
   8 ;; modify it under the terms of the Modified BSD License. You should
   9 ;; have received a copy of the license along with this program. If
  10 ;; not, see <http://www.xfree86.org/3.3.6/COPYRIGHT2.html#5>.
  11
  12 ;; Start date: Sun Mar 08, 2009 23:03
  13
  14
  15 (require 'geiser-connection)
  16 (require 'geiser-syntax)
  17 (require 'geiser-custom)
  18 (require 'geiser-base)
  19 (require 'geiser-eval)
  20 (require 'geiser-edit)
  21 (require 'geiser-log)
  22 (require 'geiser)
  23
  24 (require 'compile)
  25 (require 'info-look)
  26
  27 (eval-when-compile (require 'cl))
  28
  29 (defconst geiser-chicken-builtin-keywords
  30   '("assume"
  31     "compiler-typecase"
  32     "cond-expand"
  33     "condition-case"
  34     "declare"
  35     "define-constant"
  36     "define-inline"
  37     "define-interface"
  38     "define-record"
  39     "define-specialization"
  40     "define-type"
  41     "dotimes"
  42     "ecase"
  43     "fluid-let"
  44     "foreign-lambda"
  45     "foreign-lambda*"
  46     "foreign-primitive"
  47     "foreign-safe-lambda"
  48     "foreign-safe-lambda*"
  49     "functor"
  50     "handle-exceptions"
  51     "let-location"
  52     "let-optionals"
  53     "let-optionals*"
  54     "letrec-values"
  55     "module"
  56     "regex-case"
  57     "select"
  58     "use"
  59     "with-input-from-pipe"))
  60
  61 \f
  62 ;;; Customization:
  63
  64 (defgroup geiser-chicken nil
  65   "Customization for Geiser's Chicken flavour."
  66   :group 'geiser)
  67
  68 (geiser-custom--defcustom geiser-chicken-binary
  69   (cond ((eq system-type 'windows-nt) '("csi.exe" "-:c"))
  70         ((eq system-type 'darwin) "csi")
  71         (t "csi"))
  72   "Name to use to call the Chicken executable when starting a REPL."
  73   :type '(choice string (repeat string))
  74   :group 'geiser-chicken)
  75
  76 (geiser-custom--defcustom geiser-chicken-load-path nil
  77   "A list of paths to be added to Chicken's load path when it's
  78 started."
  79   :type '(repeat file)
  80   :group 'geiser-chicken)
  81
  82 (geiser-custom--defcustom geiser-chicken-init-file "~/.chicken-geiser"
  83   "Initialization file with user code for the Chicken REPL.
  84 If all you want is to load ~/.csirc, set
  85 `geiser-chicken-load-init-file-p' instead."
  86   :type 'string
  87   :group 'geiser-chicken)
  88
  89 (geiser-custom--defcustom geiser-chicken-load-init-file-p nil
  90   "Whether to load ~/.chicken when starting Chicken.
  91 Note that, due to peculiarities in the way Chicken loads its init
  92 file, using `geiser-chicken-init-file' is not equivalent to setting
  93 this variable to t."
  94   :type 'boolean
  95   :group 'geiser-chicken)
  96
  97 (geiser-custom--defcustom geiser-chicken-extra-keywords nil
  98   "Extra keywords highlighted in Chicken scheme buffers."
  99   :type '(repeat string)
 100   :group 'geiser-chicken)
 101
 102 (geiser-custom--defcustom geiser-chicken-case-sensitive-p t
 103   "Non-nil means keyword highlighting is case-sensitive."
 104   :type 'boolean
 105   :group 'geiser-chicken)
 106
 107 (geiser-custom--defcustom geiser-chicken-match-limit 20
 108   "The limit on the number of matching symbols that Chicken will provide to Geiser."
 109   :type 'integer
 110   :group 'geiser-chicken)
 111
 112 (geiser-custom--defcustom geiser-chicken-required-modules
 113     (list "chicken-doc" "apropos" "data-structures" "extras" "ports" "posix" "srfi-1" "srfi-13" "srfi-14" "srfi-18" "srfi-69" "tcp" "utils")
 114   "Modules automatically loaded in the Chicken REPL."
 115   :type '(repeat string)
 116   :group 'geiser-chicken)
 117
 118 \f
 119 ;;; REPL support:
 120
 121 (defun geiser-chicken--binary ()
 122   (if (listp geiser-chicken-binary)
 123       (car geiser-chicken-binary)
 124     geiser-chicken-binary))
 125
 126 (defun geiser-chicken--parameters ()
 127   "Return a list with all parameters needed to start Chicken.
 128 This function uses `geiser-chicken-init-file' if it exists."
 129   (let ((init-file (and (stringp geiser-chicken-init-file)
 130                         (expand-file-name geiser-chicken-init-file)))
 131         (n-flags (and (not geiser-chicken-load-init-file-p) '("-n"))))
 132   `(,@(and (listp geiser-chicken-binary) (cdr geiser-chicken-binary))
 133     ,@n-flags "-include-path" ,(expand-file-name "chicken/" geiser-scheme-dir)
 134     ,@(apply 'append (mapcar (lambda (p) (list "-include-path" p))
 135                              geiser-chicken-load-path))
 136     ,@(and init-file (file-readable-p init-file) (list init-file))
 137     ,@(apply 'append (mapcar (lambda (m) (list "-R" m))
 138                              geiser-chicken-required-modules)))))
 139
 140 (defconst geiser-chicken--prompt-regexp "#[^;]*;[^:0-9]*:?[0-9]+> ")
 141
 142 \f
 143 ;;; Evaluation support:
 144
 145 (defun geiser-chicken--geiser-procedure (proc &rest args)
 146   (case proc
 147     ((eval compile)
 148      (let ((form (mapconcat 'identity (cdr args) " "))
 149            (module (if (car args) (concat "'" (car args)) "#f")))
 150        (format "(geiser-eval %s '%s)" module form)))
 151     ((load-file compile-file)
 152      (format "(geiser-load-file %s)" (car args)))
 153     ((no-values)
 154      "(geiser-no-values)")
 155     (t
 156      (let ((form (mapconcat 'identity args " ")))
 157        (format "(geiser-%s %s)" proc form)))))
 158
 159 (defconst geiser-chicken--module-re
 160   "( *module +\\(([^)]+)\\|[^ ]+\\)\\|( *define-library +\\(([^)]+)\\|[^ ]+\\)")
 161
 162 (defun geiser-chicken--get-module (&optional module)
 163   (cond ((null module)
 164          (save-excursion
 165            (geiser-syntax--pop-to-top)
 166            (if (or (re-search-backward geiser-chicken--module-re nil t)
 167                    (looking-at geiser-chicken--module-re)
 168                    (re-search-forward geiser-chicken--module-re nil t))
 169                (geiser-chicken--get-module (match-string-no-properties 1))
 170              :f)))
 171         ((listp module) module)
 172         ((stringp module)
 173          (condition-case nil
 174              (car (geiser-syntax--read-from-string module))
 175            (error :f)))
 176         (t :f)))
 177
 178 (defun geiser-chicken--module-cmd (module fmt &optional def)
 179   (when module
 180     (let* ((module (geiser-chicken--get-module module))
 181            (module (cond ((or (null module) (eq module :f)) def)
 182                          (t (format "%s" module)))))
 183       (and module (format fmt module)))))
 184
 185 (defun geiser-chicken--import-command (module)
 186   (geiser-chicken--module-cmd module "(use %s)"))
 187
 188 (defun geiser-chicken--enter-command (module)
 189   (geiser-chicken--module-cmd module ",m %s" module))
 190
 191 (defun geiser-chicken--exit-command () ",q")
 192
 193 (defun geiser-chicken--symbol-begin (module)
 194   (if module
 195       (max (save-excursion (beginning-of-line) (point))
 196            (save-excursion (skip-syntax-backward "^(>") (1- (point))))
 197     (save-excursion (skip-syntax-backward "^'-()>") (point))))
 198
 199 \f
 200 ;;; Error display
 201
 202 (defun geiser-chicken--display-error (module key msg)
 203   (newline)
 204   (when (stringp msg)
 205     (save-excursion (insert msg))
 206     (geiser-edit--buttonize-files))
 207   (and (not key) msg (not (zerop (length msg)))))
 208
 209 \f
 210 ;;; Trying to ascertain whether a buffer is Chicken Scheme:
 211
 212 (defconst geiser-chicken--guess-re
 213   (regexp-opt (append '("csi" "chicken") geiser-chicken-builtin-keywords)))
 214
 215 (defun geiser-chicken--guess ()
 216   (save-excursion
 217     (goto-char (point-min))
 218     (re-search-forward geiser-chicken--guess-re nil t)))
 219
 220 (defun geiser-chicken--external-help (id module)
 221   "Loads chicken doc into a buffer"
 222   (browse-url (format "http://api.call-cc.org/cdoc?q=%s&query-name=Look+up" id)))
 223
 224 \f
 225 ;;; Keywords and syntax
 226
 227 (defun geiser-chicken--keywords ()
 228   (append
 229    (geiser-syntax--simple-keywords geiser-chicken-extra-keywords)
 230    (geiser-syntax--simple-keywords geiser-chicken-builtin-keywords)))
 231
 232 (geiser-syntax--scheme-indent
 233  (assume 1)
 234  (compiler-typecase 1)
 235  (cond-expand 0)
 236  (condition-case 1)
 237  (cut 1)
 238  (cute 1)
 239  (declare 0)
 240  (dotimes 1)
 241  (ecase 1)
 242  (fluid-let 1)
 243  (foreign-lambda 2)
 244  (foreign-lambda* 2)
 245  (foreign-primitive 2)
 246  (foreign-safe-lambda 2)
 247  (foreign-safe-lambda* 2)
 248  (functor 3)
 249  (handle-exceptions 2)
 250  (import 0)
 251  (let-location 1)
 252  (let-optionals 2)
 253  (let-optionals* 2)
 254  (letrec-values 1)
 255  (module 2)
 256  (regex-case 1)
 257  (select 1)
 258  (set! 1)
 259  (use 0)
 260  (with-input-from-pipe 1)
 261  (with-output-to-pipe 1))
 262
 263 \f
 264 ;;; REPL startup
 265
 266 (defconst geiser-chicken-minimum-version "4.8.0.0")
 267
 268 (defun geiser-chicken--version (binary)
 269   (car (process-lines binary "-e" "(display (chicken-version))")))
 270
 271 (defun connect-to-chicken ()
 272   "Start a Chicken REPL connected to a remote process."
 273   (interactive)
 274   (geiser-connect 'chicken))
 275
 276 (defun geiser-chicken--compile-or-load (force-load)
 277   (let ((target
 278          (expand-file-name "chicken/geiser/emacs.so" geiser-scheme-dir))
 279         (source
 280          (expand-file-name "chicken/geiser/emacs.scm" geiser-scheme-dir))
 281         (force-load (or force-load (eq system-type 'windows-nt)))
 282         (suppression-prefix
 283          "(define geiser-stdout (current-output-port))(current-output-port (make-output-port (lambda a #f) (lambda a #f)))")
 284         (suppression-postfix
 285          "(current-output-port geiser-stdout)"))
 286     (let ((load-sequence
 287            (cond
 288             (force-load
 289              (format "(load \"%s\")\n(import geiser)\n" source))
 290             ((file-exists-p target)
 291              (format "%s(load \"%s\")(import geiser)%s\n"
 292                      suppression-prefix target suppression-postfix))
 293             (t
 294              (format "%s(use utils)(compile-file \"%s\" options: '(\"-O3\" \"-s\") output-file: \"%s\" load: #t)(import geiser)%s\n"
 295                      suppression-prefix source target suppression-postfix)))))
 296       (geiser-eval--send/wait load-sequence))))
 297
 298 (defun geiser-chicken--startup (remote)
 299   (compilation-setup t)
 300   (geiser-chicken--compile-or-load t))
 301
 302 \f
 303 ;;; Implementation definition:
 304
 305 (define-geiser-implementation chicken
 306   (unsupported-procedures '(callers callees generic-methods))
 307   (binary geiser-chicken--binary)
 308   (arglist geiser-chicken--parameters)
 309   (version-command geiser-chicken--version)
 310   (minimum-version geiser-chicken-minimum-version)
 311   (repl-startup geiser-chicken--startup)
 312   (prompt-regexp geiser-chicken--prompt-regexp)
 313   (debugger-prompt-regexp nil)
 314   (enter-debugger nil)
 315   (marshall-procedure geiser-chicken--geiser-procedure)
 316   (find-module geiser-chicken--get-module)
 317   (enter-command geiser-chicken--enter-command)
 318   (exit-command geiser-chicken--exit-command)
 319   (import-command geiser-chicken--import-command)
 320   (find-symbol-begin geiser-chicken--symbol-begin)
 321   (display-error geiser-chicken--display-error)
 322   (external-help geiser-chicken--external-help)
 323   (check-buffer geiser-chicken--guess)
 324   (keywords geiser-chicken--keywords)
 325   (case-sensitive geiser-chicken-case-sensitive-p))
 326
 327 (geiser-impl--add-to-alist 'regexp "\\.scm$" 'chicken t)
 328 (geiser-impl--add-to-alist 'regexp "\\.release-info$" 'chicken t)
 329 (geiser-impl--add-to-alist 'regexp "\\.meta$" 'chicken t)
 330 (geiser-impl--add-to-alist 'regexp "\\.setup$" 'chicken t)
 331
 332 (provide 'geiser-chicken)