configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([pcb], [4.0.0])
   4 AC_CONFIG_SRCDIR([src/draw.c])
   5 AC_PREREQ([2.69])
   6 AM_INIT_AUTOMAKE([1.9])
   7 AC_GNU_SOURCE
   8 AC_CONFIG_HEADERS([config.h])
   9
  10 ##########################################################################
  11 #
  12 # Try to figure out if we are building from git sources.
  13 # If we are then unless building of the documentation has
  14 # been disabled then just require the user have all the right
  15 # tools.  Users building from a tarball won't need latex, makeinfo,
  16 # etc. but if you're already downloading development sources, then
  17 # it is not unreasonable to require development tools.  What motivated
  18 # this is that using maintainer mode proved to cause regular confusion.
  19
  20 pcb_sources="tarball"
  21 AC_MSG_CHECKING([if you are building from a git checkout])
  22 pcb_git_version=no
  23 if test -f $srcdir/.gitignore ; then
  24         pcb_git_version=yes
  25         AC_MSG_RESULT([yes])
  26         pcb_sources="GIT"
  27 else
  28         AC_MSG_RESULT([no])
  29 fi
  30 AM_CONDITIONAL(GIT_VERSION, test x$pcb_git_version = xyes)
  31
  32 AC_MSG_CHECKING([if you are building from a anoncvs checkout])
  33 pcb_cvs_version=no
  34 if test -f $srcdir/CVS/Root ; then
  35         pcb_cvs_version=yes
  36         AC_MSG_RESULT([yes])
  37         pcb_sources="CVS"
  38 else
  39         AC_MSG_RESULT([no])
  40 fi
  41 AM_CONDITIONAL(CVS_VERSION, test x$pcb_cvs_version = xyes)
  42 AM_CONDITIONAL(GIT_OR_CVS_VERSION, test x$pcb_git_version = xyes -o x$pcb_cvs_version = xyes)
  43
  44
  45 ##########################################################################
  46 #
  47 # See if we are supposed to build the docs
  48 #
  49
  50 docs_yesno=yes
  51 AC_MSG_CHECKING([if the documentation should be built])
  52 AC_ARG_ENABLE([doc],
  53 [  --enable-doc            Build and install the documentation [[default=yes]]],
  54 [
  55 if test "X$enable_doc" = "Xno" ; then
  56         DOC=""
  57         AC_MSG_RESULT([no])
  58         docs_yesno=no
  59 else
  60         DOC=doc
  61         AC_MSG_RESULT([yes])
  62         docs_yesno=yes
  63 fi
  64 ],
  65 [
  66 DOC=doc
  67 AC_MSG_RESULT([yes])
  68 docs_yesno=yes
  69 ])
  70 AC_SUBST(DOC)
  71
  72
  73 dnl determine host type
  74 AC_CANONICAL_HOST
  75 AC_MSG_CHECKING(for windows)
  76 PCB_PATH_DELIMETER=":"
  77 PCB_DIR_SEPARATOR_S="/"
  78 PCB_DIR_SEPARATOR_C='/'
  79 case $host in
  80         *-*-mingw* )
  81                 WIN32=yes
  82                 CFLAGS="$CFLAGS ${MINGW_CFLAGS:--mms-bitfields -mwindows}"
  83                 CPPFLAGS="$CPPFLAGS ${MINGW_CPPFLAGS}"
  84                 ;;
  85
  86         * )
  87                 WIN32=no
  88                 ;;
  89 esac
  90
  91 AC_MSG_RESULT($WIN32)
  92 AC_SUBST(WIN32)
  93 AM_CONDITIONAL(WIN32, test x$WIN32 = xyes)
  94 if test "x$WIN32" = "xyes" ; then
  95         PCB_PATH_DELIMETER=";"
  96         PCB_DIR_SEPARATOR_S="\\\\"
  97         PCB_DIR_SEPARATOR_C='\\'
  98 fi
  99
 100 AC_DEFINE_UNQUOTED(PCB_DIR_SEPARATOR_C,'$PCB_DIR_SEPARATOR_C',[Directory separator char])
 101 AC_DEFINE_UNQUOTED(PCB_DIR_SEPARATOR_S,"$PCB_DIR_SEPARATOR_S",[Directory separator string])
 102 AC_DEFINE_UNQUOTED(PCB_PATH_DELIMETER,"$PCB_PATH_DELIMETER",[Search path separator string])
 103
 104
 105 dnl Checks for programs.
 106 AC_PROG_CC
 107 AC_PROG_CXX
 108
 109 if test "x$WIN32" = "xyes" ; then
 110         AC_CHECK_TOOL(WINDRES, windres, [no])
 111         if test "$WINDRES" = "no" ; then
 112                 AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 113         fi
 114 fi
 115
 116 # i18n
 117 GETTEXT_PACKAGE=$PACKAGE
 118 AH_TEMPLATE([GETTEXT_PACKAGE], [Name of this program's gettext domain])
 119 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE], ["$GETTEXT_PACKAGE"])
 120 AC_SUBST(GETTEXT_PACKAGE)
 121
 122 AM_GNU_GETTEXT_VERSION([0.19.3])
 123 AM_GNU_GETTEXT
 124 IT_PROG_INTLTOOL([0.35.0])
 125
 126 AC_C_INLINE
 127 AC_PROG_CC_STDC
 128 AC_PROG_CC_C99
 129 AM_PROG_CC_C_O
 130 AC_PROG_CPP
 131
 132 AC_MSG_CHECKING([that C compiler supports C99])
 133 if test "X$ac_cv_prog_cc_c99" = "Xno"; then
 134   AC_MSG_RESULT([no])
 135   AC_MSG_ERROR([A C99-compliant compiler is requred])
 136 else
 137   AC_MSG_RESULT([yes])
 138 fi
 139
 140 AC_PROG_AWK
 141 AC_PROG_MKDIR_P
 142
 143 AM_PROG_LEX
 144 AC_PATH_PROG(LEX_PATH, $LEX, [notfound])
 145 if test "$LEX_PATH" = "notfound" ; then
 146         AC_MSG_ERROR([Couldn't find a usable lex program.
 147 Please install flex which is available from
 148 ftp://ftp.gnu.org/pub/non-gnu/flex/
 149 ])
 150 fi
 151
 152
 153 AC_PROG_YACC
 154 AC_PATH_PROG(YACC_PATH, $YACC, [notfound])
 155 if test "$YACC_PATH" = "notfound" ; then
 156         AC_MSG_ERROR([Couldn't find a usable yacc program.
 157 Please install bison which is available from
 158 ftp://ftp.gnu.org/pub/gnu/bison/
 159 ])
 160 fi
 161
 162 AC_PROG_INSTALL
 163 AC_PROG_RANLIB
 164
 165 #
 166 # Used for building the icons
 167 #
 168 AC_PATH_PROG(XPMTOPPM, xpmtoppm, notfound)
 169 AC_PATH_PROG(PPMTOWINICON, ppmtowinicon, notfound)
 170 AC_PATH_PROG(CONVERT, convert, notfound)
 171
 172 ##########################################################################
 173 #
 174 #
 175 if test "X$docs_yesno" = "Xyes" -a "X$pcb_git_version" = "Xyes" ; then
 176    AC_PATH_PROG(MKINFO, makeinfo, no)
 177    if test "X$MKINFO" != "Xno"; then
 178       AC_MSG_CHECKING([for GNU makeinfo version >= 4.6])
 179       v=`$MKINFO --version | grep "GNU texinfo"`
 180       if test $? -ne 0; then
 181          AC_MSG_RESULT([non-GNU])
 182          MKINFO="no"
 183       fi
 184    fi
 185    if test "X$MKINFO" != "Xno"; then
 186       vmajor=`echo "$v" | sed 's/.* \([[0-9]]*\)\.\([[0-9]]*\)$/\1/'`
 187       vminor=`echo "$v" | sed 's/.* \([[0-9]]*\)\.\([[0-9]]*\)$/\2/'`
 188       AC_MSG_RESULT([$vmajor.$vminor])
 189       if test "$vmajor" -lt 4 \
 190               || (test "$vmajor" -eq 4 && test "$vminor" -lt 6); then
 191          MKINFO=no
 192       fi
 193    fi
 194    if test "X$MKINFO" = "Xno"; then
 195       AC_MSG_ERROR([You have requested a build
 196 of the documentation.  For this to work, you must have version 4.6 or newer of
 197 the GNU texinfo package.  You seem to have
 198
 199 $v
 200
 201 Please update to a newer version of texinfo or disable building of
 202 the documentation with --disable-doc
 203 ])
 204    fi
 205
 206    AC_PATH_PROG(TEXI2DVI, texi2dvi, no)
 207    if test "X$TEXI2DVI" = "Xno"; then
 208       AC_MSG_ERROR([You have requested a build
 209 of the documentation.  For this to work, you must have the texi2dvi program
 210 installed.  Alternatively, you can disable building the documentation with
 211 --disable-doc.])
 212    fi
 213
 214
 215         AC_PATH_PROG(PERL, perl, notfound)
 216         if test "X$PERL" = "Xnotfound"; then
 217                         AC_MSG_ERROR([You have requested a build
 218 of the documentation.  For this to work, you must have perl installed.
 219 Alternatively, you can disable building the documentation with
 220 --disable-doc.
 221 ])
 222         fi
 223
 224
 225    AC_PATH_PROG([KPSEWHICH], [kpsewhich], [no])
 226    if test "X$KPSEWHICH" = "Xno"; then
 227       AC_MSG_ERROR([You have requested a build
 228 of the documentation.  For this to work, you must have a functional install of
 229 TeX and LaTeX.  kpsewhich is part of TeX.
 230 Alternatively, you can disable building the documentation with
 231 --disable-doc.])
 232    fi
 233
 234    AC_MSG_CHECKING([If your TeX installation contains epsf.tex])
 235    f=`$KPSEWHICH epsf.tex`
 236    if test $? -eq 0 ; then
 237         AC_MSG_RESULT([yes ($f)])
 238    else
 239         AC_MSG_RESULT([no])
 240         AC_MSG_ERROR([You have requested a build
 241 of the documentation.  For this to work, you must have a functional install of
 242 TeX and LaTeX that includes epsf.tex.  On some linux distributions this is
 243 part of the texlive-generic-recommended package.
 244 Alternatively, you can disable building the documentation with
 245 --disable-doc.])
 246    fi
 247
 248 fi
 249
 250 ##########################################################################
 251 #
 252 #
 253
 254 # FIXME:  for now, only try to add -rdynamic if we're using gcc.  We really
 255 # need to figure out what the correct test is here.  In the mean time, this
 256 # should let things build with SunPRO again.
 257 if test "x$GCC" = "xyes"; then
 258 AC_MSG_CHECKING([If the compiler accepts -rdynamic])
 259 old_LDFLAGS="$LDFLAGS"
 260 LDFLAGS="$LDFLAGS -rdynamic"
 261 AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 262         [AC_MSG_RESULT([yes])],
 263         [LDFLAGS="$old_LDFLAGS"
 264         AC_MSG_RESULT([no])
 265         ])
 266 fi
 267
 268 # ------------- HID config -------------------
 269
 270 hid_guis=""
 271 hid_printers=""
 272 hid_exporters=""
 273 hid_always=""
 274
 275 for hid in `cd $srcdir/src/hid; echo *`; do
 276     F=$srcdir/src/hid/$hid/hid.conf
 277     if test -f $F
 278     then
 279     echo checking $F
 280         . $F
 281         case $type in
 282           gui ) hid_guis="$hid_guis $hid" ;;
 283           printer ) hid_printers="$hid_printers $hid" ;;
 284           export ) hid_exporters="$hid_exporters $hid" ;;
 285           always ) hid_always="$hid_always $hid" ;;
 286         esac
 287     fi
 288 done
 289
 290 AC_MSG_CHECKING([for which gui to use])
 291 AC_ARG_WITH([gui],
 292 [  --with-gui=            Specify the GUI to use: batch gtk lesstif [[default=gtk]]],
 293 [],
 294 [with_gui=gtk]
 295 )
 296 AC_MSG_RESULT([$with_gui])
 297 case " $hid_guis no none " in
 298      *\ $with_gui\ * ) HIDLIST="$with_gui" ;;
 299      * ) AC_MSG_ERROR([$with_gui is not a valid gui]) ;;
 300 esac
 301
 302 if test x"$with_gui" = x"none" -o x"$with_gui" = x"no"
 303 then
 304     HIDLIST=
 305 fi
 306
 307 AC_MSG_CHECKING([whether to enable toporouter])
 308 AC_ARG_ENABLE([toporouter],
 309  [AS_HELP_STRING([--enable-toporouter], [build toporouter [default=yes]]) ]
 310 )
 311 AS_CASE(["x$enable_toporouter"],[xyes | xno],,
 312  [enable_toporouter=yes
 313  ]
 314 )
 315 AC_MSG_RESULT([$enable_toporouter])
 316 AM_CONDITIONAL([WITH_TOPOROUTER], test $enable_toporouter != no)
 317
 318 AC_MSG_CHECKING([whether to enable toporouter output])
 319 AC_ARG_ENABLE([toporouter-output],
 320  [AS_HELP_STRING([--enable-toporouter-output], [enable toporouter graphical output [default=no]]) ]
 321 )
 322 AS_CASE(["z$enable_toporouter_output"],[zyes | zno],,
 323  [enable_toporouter_output=no]
 324 )
 325 AC_MSG_RESULT([$enable_toporouter_output])
 326 AS_CASE([$enable_toporouter_output],[yes],
 327  [
 328   topo_output_enabled=1
 329  ],
 330  [
 331   topo_output_enabled=0
 332  ]
 333 )
 334 AC_DEFINE_UNQUOTED([TOPO_OUTPUT_ENABLED], [$topo_output_enabled],
 335  [Define to 1 to enable toporouter graphical output]
 336 )
 337
 338 PKG_PROG_PKG_CONFIG()
 339
 340 if test "x$enable_toporouter_output" = "xyes"; then
 341    PKG_CHECK_MODULES(CAIRO, cairo,,
 342                      [AC_MSG_ERROR([Cannot find cairo, needed by the toporouter
 343 Please review the following errors:
 344 $CAIRO_PKG_ERRORS])]
 345    )
 346 fi
 347
 348 AC_MSG_CHECKING([for whether to use DBUS])
 349 AC_ARG_ENABLE([dbus],
 350 [  --enable-dbus           Enable DBUS IPC],
 351 [],[
 352         case " $with_gui " in
 353                 *\ gtk\ *)     enable_dbus=yes ;;
 354                 *\ lesstif\ *) enable_dbus=yes ;;
 355                 * )            enable_dbus=no ;;
 356         esac
 357 ])
 358
 359 AC_MSG_RESULT([$enable_dbus])
 360 AM_CONDITIONAL(WITH_DBUS, test x$enable_dbus = xyes)
 361
 362 if test "x$enable_dbus" = "xyes"; then
 363         case " $with_gui " in
 364                 *\ gtk\ *) ;;
 365                 *\ lesstif\ *) ;;
 366                 * ) AC_MSG_ERROR([DBUS enabled but only works with a mainloop capable GUI HID.
 367 Either do not use --enable-dbus or enable the gtk or lesstif GUI HID.])
 368         esac
 369
 370         PKG_CHECK_MODULES(DBUS, dbus-1 >= 0.61,
 371                 [saved_LIBS="$LIBS"
 372                  LIBS="$LIBS $DBUS_LIBS"
 373                  AC_CHECK_FUNCS(dbus_watch_get_unix_fd)
 374                  LIBS="$saved_LIBS" ],
 375                 [AC_MSG_ERROR([Cannot find dbus-1 >= 0.61, install it and rerun ./configure
 376 Please review the following errors:
 377 $DBUS_PKG_ERRORS])]
 378         )
 379         DBUS_VERSION=`$PKG_CONFIG dbus-1 --modversion`
 380
 381         AC_DEFINE([HAVE_DBUS], 1,
 382                 [Define to 1 if DBUS IPC is to be compiled in])
 383
 384 fi
 385
 386
 387 AC_MSG_CHECKING([for whether to use GL drawing])
 388 AC_ARG_ENABLE([gl],
 389 [  --enable-gl           Enable GL drawing (with GTK HID)],
 390 [],[
 391         case " $with_gui " in
 392                 *\ gtk\ *) enable_gl=yes;;
 393                 * ) enable_gl=no;;
 394         esac
 395 ])
 396 AC_MSG_RESULT([$enable_gl])
 397 AM_CONDITIONAL(USE_GL, test x$enable_gl = xyes)
 398
 399 if test "x$enable_gl" = "xyes"; then
 400         case " $with_gui " in
 401                 *\ gtk\ *) ;;
 402                 * ) AC_MSG_ERROR([GL drawing enabled but only works with the GTK HID.
 403 Either do not use --enable-gl or enable the gtk HID.])
 404         ;;
 405         esac
 406
 407         AX_CHECK_GL
 408         AS_IF([test X$no_gl = Xyes],
 409               [AC_MSG_FAILURE([OpenGL is required.])])
 410
 411         AX_CHECK_GLU
 412         AS_IF([test X$no_glu = Xyes],
 413               [AC_MSG_FAILURE([The OpenGL GLU library is required.])])
 414
 415         AC_DEFINE([ENABLE_GL], 1,
 416                 [Define to 1 if GL support is to be compiled in])
 417 fi
 418
 419 AC_MSG_CHECKING([for which printer to use])
 420 AC_ARG_WITH([printer],
 421 [  --with-printer=        Specify the printer: lpr [[default=lpr]]],
 422 [],[with_printer=lpr])
 423 AC_MSG_RESULT([$with_printer])
 424 case " $hid_printers " in
 425      *\ $with_printer\ * )
 426          HIDLIST="$HIDLIST $with_printer"
 427          ;;
 428      * ) AC_MSG_ERROR([$with_printer is not a valid printer]) ;;
 429 esac
 430
 431 AC_MSG_CHECKING([for which exporters to use])
 432 AC_ARG_WITH([exporters],
 433 [  --with-exporters=       Enable export devices: bom gerber gcode nelma png ps ipcd356 [[default=bom gerber gcode nelma png ps ipcd356]]],
 434 [],[with_exporters=$hid_exporters])
 435 AC_MSG_RESULT([$with_exporters])
 436 for e in `echo $with_exporters | sed 's/,/ /g'`; do
 437     case " $hid_exporters " in
 438       *\ $e\ * )
 439          HIDLIST="$HIDLIST $e"
 440          ;;
 441       * ) AC_MSG_ERROR([$e is not a valid exporter]) ;;
 442     esac
 443 done
 444
 445 if test "X$enable_jpeg" = "Xno" -a "X$enable_gif" = "Xno" -a "X$enable_png" = "Xno" ; then
 446         case " ${HIDLIST} " in
 447                 *\ png\ *)
 448                         AC_MSG_ERROR([you have requested the png HID but turned off all output
 449 formats!  If you do not want gif/jpeg/png output, use --with-exporters to list
 450 which exporters you want and do not list png there.])
 451                         ;;
 452
 453                 *)
 454                         ;;
 455         esac
 456 fi
 457
 458 for hid in $HIDLIST; do
 459     F=$srcdir/src/hid/$hid/hid.conf
 460     if test -f $F ; then
 461         echo checking $hid dependencies
 462         deps=
 463         . $F
 464         for dep in $deps; do
 465             if test "X`echo $HIDLIST | grep $dep`" = "X"; then
 466                 AC_MSG_ERROR([you have requested the $hid HID but not the $dep HID, which it depends on])
 467             fi
 468         done
 469    fi
 470 done
 471
 472 for e in $HIDLIST; do
 473     HIDLIBS="$HIDLIBS lib$e.a"
 474 done
 475
 476 AC_SUBST(HIDLIST)
 477 AC_SUBST(HIDLIBS)
 478
 479 # ------------- end HID config -------------------
 480
 481 ######################################################################
 482 #
 483 # desktop integration
 484 #
 485
 486 AC_PATH_PROG(SETENV, env, [])
 487 AC_PATH_PROG(GTK_UPDATE_ICON_CACHE_BIN, gtk-update-icon-path, [true])
 488
 489 # Change default location for XDG files (MIME and Icons)
 490 AC_ARG_WITH(xdgdatadir, [  --with-xdgdatadir=path  Change where the theme icons
 491 and mime registrations are installed [[DATADIR]]], [opt_xdgdatadir=$withval])
 492
 493 # Change default location for KDE data files (KDE MIME registrations)
 494 AC_ARG_WITH(kdedatadir, [  --with-kdedatadir=path  Change where the KDE mime reg
 495 istrations are installed [[DATADIR]]], [opt_kdedatadir=$withval])
 496
 497 if test x$opt_xdgdatadir = x; then
 498         # path was not specified with --with-xdgdatadir
 499         XDGDATADIR='${datadir}'
 500 else
 501         # path WAS specified with --with-xdgdatadir
 502         XDGDATADIR="$opt_xdgdatadir"
 503 fi
 504 AC_SUBST(XDGDATADIR)
 505
 506 if test x$opt_kdedatadir = x; then
 507         # path was not specified with --with-kdedatadir
 508         KDEDATADIR='${datadir}'
 509 else
 510         # path WAS specified with --with-kdedatadir
 511         KDEDATADIR="$opt_kdedatadir"
 512 fi
 513 AC_SUBST(KDEDATADIR)
 514
 515 AC_ARG_ENABLE(update-desktop-database,
 516         AC_HELP_STRING([--disable-update-desktop-database],
 517         [do not update desktop database after installation]),,
 518         enable_update_desktop_database=yes)
 519
 520 AM_CONDITIONAL(ENABLE_UPDATE_DESKTOP_DATABASE, test x$enable_update_desktop_database = xyes)
 521
 522 if test x$enable_update_desktop_database = xyes ; then
 523         AC_PATH_PROG(UPDATE_DESKTOP_DATABASE, [update-desktop-database], no)
 524         if test $UPDATE_DESKTOP_DATABASE = no; then
 525         AC_MSG_ERROR([Cannot find update-desktop-database, make sure it is installed and in your PATH, or configure with --disable-update-desktop-database])
 526         fi
 527 fi
 528
 529 AC_ARG_ENABLE(update-mime-database,
 530         AC_HELP_STRING([--disable-update-mime-database],
 531         [do not update mime database after installation]),,
 532         enable_update_mime_database=yes)
 533
 534 AM_CONDITIONAL(ENABLE_UPDATE_MIME_DATABASE, test x$enable_update_mime_database = xyes)
 535
 536 if test x$enable_update_mime_database = xyes ; then
 537         AC_PATH_PROG(UPDATE_MIME_DATABASE, [update-mime-database], no)
 538         if test $UPDATE_MIME_DATABASE = no; then
 539         AC_MSG_ERROR([Cannot find update-mime-database, make sure it is installed and in your PATH, or configure with --disable-update-mime-database])
 540         fi
 541 fi
 542
 543 #
 544 ######################################################################
 545
 546 AC_PATH_PROGS(M4, gm4 m4, [none])
 547 if test "X$M4" = "Xnone" ; then
 548         AC_MSG_ERROR([Did not find a m4 executible.  You need to make sure
 549         that m4 is installed on your system and that m4 is in your path])
 550 fi
 551 AC_MSG_CHECKING([if $M4 has the division involving negative numbers bug])
 552 pcb_m4_r=`echo "eval(-2/2)" | $M4`
 553 if test "$pcb_m4_r" != "-1" ; then
 554         AC_MSG_RESULT([yes])
 555         AC_MSG_ERROR([It appears that $M4 has a bug involving division
 556 with negative numbers.  In particular it just returned the result that
 557 -2/2 = $pcb_m4_r instead of -1.  This is a known bug in GNU m4-1.4.9.  Please
 558 install a non-broken m4.])
 559 else
 560         AC_MSG_RESULT([no])
 561 fi
 562
 563
 564 AC_PATH_PROGS(WISH, wish wish85 wish8.5 wish83 wish8.3 wish80 wish8.0 cygwish83 cygwish80,[none])
 565 if test "X$WISH" = "Xnone" ; then
 566         AC_MSG_ERROR([Did not find the wish executible.  You need to make sure
 567         that tcl is installed on your system and that wish is in your path])
 568 fi
 569
 570 AC_DEFINE_UNQUOTED(M4,$M4,[m4 executible])
 571 GNUM4=$M4
 572 AC_SUBST(GNUM4)
 573 AC_DEFINE_UNQUOTED(GNUM4,"$M4",[m4 program used by pcb])
 574
 575 AC_PATH_PROG(PDFLATEX, pdflatex, notfound)
 576 AM_CONDITIONAL(MISSING_PDFLATEX, test x$PDFLATEX = xnotfound)
 577
 578 AC_PATH_PROG(TEXI2DVI, texi2dvi, notfound)
 579 AM_CONDITIONAL(MISSING_TEXI2DVI, test x$TEXI2DVI = xnotfound)
 580
 581 AC_PATH_PROG(PS2PDF, ps2pdf, notfound)
 582 AM_CONDITIONAL(MISSING_PS2PDF, test x$PS2PDF = xnotfound)
 583
 584 # used to build some of the getting started guide
 585 AC_PATH_PROG(GSCHEM, gschem, notfound)
 586 AM_CONDITIONAL(MISSING_GSCHEM, test x$GSCHEM = xnotfound)
 587
 588 if test "X$docs_yesno" = "Xyes" -a "X$pcb_git_version" = "Xyes" ; then
 589         if test "$PDFLATEX" = "notfound" -o "$TEXI2DVI" = "notfound" -o "$PS2PDF" = "notfound" ; then
 590                 AC_MSG_ERROR([It appears that you are building from a source tree obtained
 591 via git but you do not have the required tools installed to build the documentation.  Here
 592 is a list of tools and the detected values:
 593 PDFLATEX:  $PDFLATEX
 594 TEXI2DVI:  $TEXI2DVI
 595 PS2PDF:    $PS2PDF
 596 GSCHEM:    $GSCHEM
 597
 598 Either make sure these tools are installed or disable building and installing the documentation
 599 by using the --disable-doc configure option.
 600 ])
 601         fi
 602 fi
 603
 604 ############################################################################
 605 #
 606 # These checks are for tools used by the testsuite.  It will not be fatal
 607 # if these are missing because this is primarily for developer use.  It is
 608 # possible that we might add some --enable flag in the future that forces
 609 # full tools for development work.
 610
 611 # Check for ImageMagick tools used by the testsuite
 612 AC_PATH_PROG(IM_ANIMATE, animate, notfound)
 613 AC_PATH_PROG(IM_COMPARE, compare, notfound)
 614 AC_PATH_PROG(IM_COMPOSITE, composite, notfound)
 615 AC_PATH_PROG(IM_CONVERT, convert, notfound)
 616 AC_PATH_PROG(IM_DISPLAY, display, notfound)
 617 AC_PATH_PROG(IM_MONTAGE, montage, notfound)
 618 missing_magick=""
 619 test "${IM_ANIMATE}" != "notfound" || missing_magick="${missing_magick} animate"
 620 test "${IM_COMPARE}" != "notfound" || missing_magick="${missing_magick} compare"
 621 test "${IM_COMPOSITE}" != "notfound" || missing_magick="${missing_magick} composite"
 622 test "${IM_CONVERT}" != "notfound" || missing_magick="${missing_magick} convert"
 623 test "${IM_DISPLAY}" != "notfound" || missing_magick="${missing_magick} display"
 624 test "${IM_MONTAGE}" != "notfound" || missing_magick="${missing_magick} montage"
 625
 626 AC_MSG_CHECKING([if all ImageMagick tools needed for the testsuite were found])
 627 if test "X${missing_magick}" != "X" ; then
 628     AC_MSG_RESULT([no.  The testsuite will be disabled because the following
 629 tools from the ImageMagick suite were not found:
 630 ${missing_magick}
 631 No loss in pcb functionality should be experienced, you just will not
 632 be able to run the full regression testsuite.
 633 ])
 634     have_magick=no
 635 else
 636     AC_MSG_RESULT([yes])
 637     have_magick=yes
 638 fi
 639
 640 have_test_tools=yes
 641
 642 test $have_magick = yes || have_test_tools=no
 643
 644 # the RS274-X export HID is partially checked by looking at the result with
 645 # gerbv
 646 AC_PATH_PROG(GERBV, gerbv, notfound)
 647 test $GERBV != notfound || have_test_tools=no
 648
 649
 650 AM_CONDITIONAL(HAVE_TEST_TOOLS, test x$have_test_tools = xyes)
 651 AC_MSG_CHECKING([if all the required testsuite tools were found])
 652 if test x$have_test_tools = xyes ; then
 653         AC_MSG_RESULT([yes])
 654 else
 655         AC_MSG_RESULT([no -- the testsuite will be disabled])
 656 fi
 657
 658
 659 #
 660 ############################################################################
 661
 662
 663 dnl Checks for libraries.
 664 AC_CHECK_LIB(m, sqrt)
 665 AC_CHECK_LIB(dl, dlopen)
 666 AC_CHECK_LIB(xnet, gethostbyname)
 667 AC_CHECK_LIB(fl, yywrap)
 668
 669 dnl Checks for functions
 670 AC_CHECK_FUNCS(getline)
 671 AC_CHECK_FUNCS(strcasestr)
 672 AC_CHECK_FUNCS(strerror)
 673 AC_CHECK_FUNCS(regcomp re_comp)
 674 AC_CHECK_FUNCS(logf expf rint)
 675 AC_CHECK_FUNCS(vsnprintf)
 676 AC_CHECK_FUNCS(getpwuid getcwd)
 677 AC_CHECK_FUNCS(rand random)
 678 AC_CHECK_FUNCS(stat)
 679
 680 AC_CHECK_FUNCS(mkdtemp)
 681
 682 # normally used for all file i/o
 683 AC_CHECK_FUNCS(popen)
 684
 685 # for lrealpath.c
 686 AC_CHECK_FUNCS(realpath canonicalize_file_name)
 687 libiberty_NEED_DECLARATION(canonicalize_file_name)
 688
 689 # for pcb_spawnvp in action.c on Windows
 690 AC_CHECK_FUNCS(_spawnvp)
 691
 692 AC_HEADER_STDC
 693 AC_CHECK_HEADERS(limits.h locale.h string.h sys/types.h regex.h pwd.h)
 694 AC_CHECK_HEADERS(sys/socket.h netinet/in.h netdb.h sys/param.h sys/times.h sys/wait.h)
 695 AC_CHECK_HEADERS(dlfcn.h)
 696
 697 if test "x${WIN32}" = "xyes" ; then
 698         AC_CHECK_HEADERS(windows.h)
 699 fi
 700 # Search for glib
 701 PKG_CHECK_MODULES(GLIB, glib-2.0, ,
 702                 [AC_MSG_RESULT([Note: cannot find glib-2.0.
 703 You may want to review the following errors:
 704 $GLIB_PKG_ERRORS])]
 705 )
 706
 707 need_gdlib=no
 708 with_gif=no
 709 with_png=no
 710 with_jpeg=no
 711
 712 for e in $HIDLIST; do
 713     case $e in
 714       lesstif )
 715         AC_PATH_XTRA
 716         save_CPPFLAGS="$CPPFLAGS"
 717         CPPFLAGS="$X_CFLAGS"
 718         AC_CHECK_LIB(X11, XOpenDisplay, , , $X_LIBS)
 719         AC_CHECK_LIB(ICE, main, , , $X_LIBS)
 720         AC_CHECK_LIB(SM, main, , , $X_LIBS)
 721         AC_CHECK_LIB(Xext, main, , , $X_LIBS)
 722         AC_CHECK_LIB(Xt, XtOpenDisplay, , , $X_LIBS)
 723         AC_CHECK_LIB(Xmu, main, , , $X_LIBS)
 724         AC_CHECK_LIB(Xpm, main, , , $X_LIBS)
 725         AC_CHECK_LIB(Xm, XmCreateMainWindow, , , $X_LIBS)
 726         CPPFLAGS="$save_CPPFLAGS"
 727         case $ac_cv_lib_Xm_XmCreateMainWindow in
 728           no )
 729             AC_MSG_ERROR([You don't seem to have the Lesstif development environment installed.])
 730             ;;
 731           * ) ;;
 732         esac
 733         AC_CHECK_HEADERS(Xm/Xm.h)
 734         case $ac_cv_header_Xm_Xm_h in
 735           no )
 736             AC_MSG_ERROR([You don't seem to have the Lesstif development environment installed.])
 737             ;;
 738           * ) ;;
 739         esac
 740         ;;
 741
 742       gtk )
 743         # Check for pkg-config
 744         AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 745         if test "$PKG_CONFIG" = "no"; then
 746                 AC_MSG_ERROR([Cannot find pkg-config, make sure it is installed and in your PATH])
 747         fi
 748
 749         PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.18.0, ,
 750                 [AC_MSG_ERROR([Cannot find gtk+ >= 2.18.0, install it and rerun ./configure
 751 Please review the following errors:
 752 $GTK_PKG_ERRORS])]
 753         )
 754         GTK_VERSION=`$PKG_CONFIG gtk+-2.0 --modversion`
 755         GLIB_VERSION=`$PKG_CONFIG glib-2.0 --modversion`
 756
 757         if test "x$enable_gl" = "xyes"; then
 758                 # Check for GtkGLExt
 759                 PKG_CHECK_MODULES(GTKGLEXT, gtkglext-1.0 >= 1.0.0, , [AC_MSG_ERROR([
 760 *** Required version of gtkglext is not installed - please install first ***
 761 Please review the following errors:
 762 $GTKGLEXT_PKG_ERRORS])]
 763                 )
 764         GTKGLEXT_VER=`$PKG_CONFIG gtkglext-1.0 --modversion`
 765         fi
 766
 767         ;;
 768
 769       png)
 770         need_gdlib=yes
 771         AC_MSG_CHECKING([if GIF output from the png HID is desired])
 772         AC_ARG_ENABLE([gif],
 773                 [  --disable-gif           Disable support for gif output when the png HID is used [[default=include gif support]]],
 774                 [
 775                 if test "X$enable_gif" != "Xno" ; then
 776                         AC_MSG_RESULT([yes])
 777                         with_gif=yes
 778                 else
 779                         AC_MSG_RESULT([no])
 780                 fi
 781                 ],
 782                 [
 783                 AC_MSG_RESULT([yes])
 784                 with_gif=yes
 785                 ])
 786
 787         AC_MSG_CHECKING([if JPEG output from the png HID is desired])
 788         AC_ARG_ENABLE([jpeg],
 789                 [  --disable-jpeg          Disable support for JPEG output when the png HID is used [[default=include JPEG support]]],
 790                 [
 791                 if test "X$enable_jpeg" != "Xno" ; then
 792                         AC_MSG_RESULT([yes])
 793                         with_jpeg=yes
 794                 else
 795                         AC_MSG_RESULT([no])
 796                 fi
 797                 ],
 798                 [
 799                 AC_MSG_RESULT([yes])
 800                 with_jpeg=yes
 801                 ])
 802
 803         AC_MSG_CHECKING([if PNG output from the png HID is desired])
 804         AC_ARG_ENABLE([png],
 805                 [  --disable-png           Disable support for PNG output when the png HID is used [[default=include PNG support]]],
 806                 [
 807                 if test "X$enable_png" != "Xno" ; then
 808                         AC_MSG_RESULT([yes])
 809                         with_png=yes
 810                 else
 811                         AC_MSG_RESULT([no])
 812                 fi
 813                 ],
 814                 [
 815                 AC_MSG_RESULT([yes])
 816                 with_png=yes
 817                 ])
 818         ;;
 819
 820       gcode|nelma)
 821         need_gdlib=yes
 822         with_png=yes
 823         ;;
 824
 825     esac
 826 done
 827
 828 if test "$need_gdlib" = "yes"; then
 829         # Search for glib
 830         PKG_CHECK_MODULES(GDLIB, gdlib, ,
 831                 [AC_MSG_ERROR([Note: cannot find gdlib.
 832 This is required for gcode, nelma, png HIDs
 833 You may want to review the following errors:
 834 $GDLIB_PKG_ERRORS])]
 835 )
 836         save_LIBS="$LIBS"
 837         LIBS="$LIBS $GDLIB_LIBS"
 838
 839         if test "X$with_gif" = "Xyes" ; then
 840                 AC_CHECK_FUNCS(gdImageGif)
 841                 if test "$ac_cv_func_gdImageGif" != "yes"; then
 842                         AC_MSG_ERROR([Your gd installation does not appear to include gif support.
 843 You may need to update your installation of gd or disable
 844 gif export with --disable-gif])
 845                 fi
 846         fi
 847
 848         if test "X$with_jpeg" = "Xyes" ; then
 849                 AC_CHECK_FUNCS(gdImageJpeg)
 850                 if test "$ac_cv_func_gdImageJpeg" != "yes"; then
 851                         AC_MSG_ERROR([Your gd installation does not appear to include JPEG support.
 852 You may need to update your installation of gd or disable
 853 JPEG export with --disable-jpeg])
 854                 fi
 855         fi
 856
 857         if test "X$with_png" = "Xyes" ; then
 858                 AC_CHECK_FUNCS(gdImagePng)
 859                 if test "$ac_cv_func_gdImagePng" != "yes"; then
 860                         AC_MSG_ERROR([Your gd installation does not appear to include PNG support.
 861 You may need to update your installation of gd or disable
 862 PNG export with --disable-png])
 863                 fi
 864         fi
 865         LIBS="$save_LIBS"
 866 fi
 867
 868 AM_CONDITIONAL(PNG, test x$with_png = xyes)
 869 AM_CONDITIONAL(GIF, test x$with_gif = xyes)
 870
 871 # ------------- check if png previews should be built for pcblib-newlib
 872 AC_MSG_CHECKING([if the m4lib to newlib export should create png previews])
 873 AC_ARG_ENABLE(
 874         [m4lib-png],
 875         [  --enable-m4lib-png      Enable creating png previews for the m4 library],
 876         [],[enable_m4lib_png=no])
 877 AC_MSG_RESULT([$enable_m4lib_png])
 878 AM_CONDITIONAL(PNG_PREVIEW, test x$enable_m4lib_png = xyes)
 879
 880
 881 # Run away.... more ugly stuff here.  By default we don't actually build
 882 # pcblib-newlib from pcblib unless we are building from cvs or git sources.
 883 # The reason is it takes a while and requires the png HID.  The problem is,
 884 # what if someone wants to use --enable-m4lib-png but the tarball was built
 885 # without the previews.  Or, what if someone does not want the PNG previews
 886 # but the person building the tarball included them.  Ugh!  So what the following
 887 # code attempts to do is detect that mismatch situation.  Note that we only
 888 # want to kick this code in when *not* building from git or cvs sources.
 889 build_pcblib_newlib=no
 890 if test "$pcb_sources" = "tarball" ; then
 891         AC_MSG_CHECKING([If pcblib-newlib was built with png previews])
 892         stamp=$srcdir/lib/pcblib-newlib.stamp
 893         if test ! -f ${stamp} ; then
 894                 AC_MSG_RESULT([unknown, missing ${stamp}])
 895                 build_pcblib_newlib=yes
 896         else
 897                 if test "`cat ${stamp}`" = "png-preview=yes" ; then
 898                         AC_MSG_RESULT([yes])
 899                         # lib exists and built with preview.
 900                         # if we don't want the preview, than rebuild
 901                         if test x$enable_m4lib_png != xyes ; then
 902                                 build_pcblib_newlib=yes
 903                         fi
 904                 else
 905                         AC_MSG_RESULT([no])
 906                         # lib exists and built without preview.
 907                         # if we want the preview, than rebuild
 908                         if test x$enable_m4lib_png = xyes ; then
 909                                 build_pcblib_newlib=yes
 910                         fi
 911                 fi
 912         fi
 913 else
 914         build_pcblib_newlib=yes
 915 fi
 916 AC_MSG_CHECKING([If pcblib-newlib needs to be rebuilt])
 917 AC_MSG_RESULT([$build_pcblib_newlib])
 918 AM_CONDITIONAL(BUILD_PCBLIB_NEWLIB, test x$build_pcblib_newlib = xyes)
 919
 920 if test "X$cross_compiling" = "Xyes" ; then
 921         # we are cross compiling so we will need a build host binary for pcb
 922         AC_PATH_PROG(PCB, [pcb], [notfound])
 923 else
 924         PCB="\${top_builddir}/src/pcb"
 925 fi
 926 AC_SUBST(PCB)
 927
 928 # now make see how essential it was that we have a pcb executable for the build
 929 # host
 930 if test "X$pcb_git_version" = "Xyes" ; then
 931         if test "X$docs_yesno" = "Xyes" -o "X$enable_m4lib_png" = "Xyes" ; then
 932                 if test "$PCB" = "notfound" ; then
 933                         AC_MSG_ERROR([You have selected a build with m4lib png
 934 previews enabled and/or with building the documentation enabled but you also
 935 appear to be cross-compiling.  For this to work, you must have a pcb installed that
 936 can run on this machine (the build machine) because it is needed for generating
 937 library footprint png previews as well as some of the figures in the documentation.
 938 If you wish to skip building the documentation and the footprint previews then add
 939 --disable-doc --disable-m4lib-png
 940 This will allow your cross build to work.])
 941                 fi
 942         fi
 943 fi
 944
 945 # ------------- Xrender -------------------
 946 have_xrender=no
 947 AC_CHECK_LIB(Xrender,XRenderQueryExtension,have_xrender=yes,have_xrender=no,$X_LIBS)
 948
 949 AC_ARG_ENABLE([xrender],
 950 [  --disable-xrender       Compile and link with Xrender [default=yes]])
 951 case "$have_xrender:$enable_xrender" in
 952    no:* ) ;;
 953    *:no ) ;;
 954    * )
 955      X_LIBS="-lXrender $X_LIBS"
 956      AC_DEFINE([HAVE_XRENDER], 1,
 957                 [Define to 1 if Xrender is available])
 958      ;;
 959 esac
 960
 961 # ------------- Xinerama -------------------
 962 have_xinerama=no
 963 AC_CHECK_LIB(Xinerama,XineramaQueryExtension,have_xinerama=yes,have_xinerama=no,$X_LIBS)
 964
 965 AC_ARG_ENABLE([xinerama],
 966 [  --disable-xinerama       Compile and link with Xinerama [default=yes]])
 967 case "$have_xinerama:$enable_xinerama" in
 968    no:* ) ;;
 969    *:no ) ;;
 970    * )
 971      X_LIBS="-lXinerama $X_LIBS"
 972      AC_DEFINE([HAVE_XINERAMA], 1,
 973                 [Define to 1 if Xinerama is available])
 974      ;;
 975 esac
 976
 977 # ------------- dmalloc -------------------
 978 dnl dmalloc checks
 979 with_dmalloc=no
 980 AC_MSG_CHECKING([if dmalloc debugging should be enabled])
 981 AC_ARG_ENABLE([dmalloc],
 982 [  --enable-dmalloc        Compile and link with dmalloc for malloc debugging [default=no]],
 983 [
 984 if test "X$enable_dmalloc" != "Xno" ; then
 985         AC_MSG_RESULT([yes])
 986         AC_CHECK_HEADER(dmalloc.h,,
 987                 AC_MSG_ERROR([You have requested dmalloc debugging but dmalloc.h could not be found]))
 988         AC_CHECK_LIB(dmalloc,main,,
 989                 AC_MSG_ERROR([You have requested dmalloc debugging but -ldmalloc could not be found]))
 990         DMALLOC_LIBS="-ldmalloc"
 991         with_dmalloc=yes
 992 else
 993         AC_MSG_RESULT([no])
 994         DMALLOC_LIBS=""
 995 fi
 996 ],
 997 [
 998         AC_MSG_RESULT([no])
 999         DMALLOC_LIBS=""
1000 ])
1001
1002 # ------------- ElectricFence -------------------
1003 dnl ElectricFence checks
1004 with_efence=no
1005 AC_MSG_CHECKING([if ElectricFence debugging should be enabled])
1006 AC_ARG_ENABLE([efence],
1007 [  --enable-efence         Link with ElectricFence for malloc debugging [default=no]],
1008 [
1009 if test "X$enable_efence" != "Xno" ; then
1010         AC_MSG_RESULT([yes])
1011         AC_CHECK_LIB(efence,main,,
1012                 AC_MSG_ERROR([You have requested ElectricFence debugging but -lefence could not be found]))
1013         with_efence=yes
1014 else
1015         AC_MSG_RESULT([no])
1016 fi
1017 ],
1018 [
1019 AC_MSG_RESULT([no])
1020 ])
1021
1022 # ------------- Enable Debug code -------------------
1023 AC_MSG_CHECKING([for whether to enable debugging code])
1024 AC_ARG_ENABLE([debug],
1025 [  --enable-debug          Enable debugging code],
1026 [],[enable_debug=no])
1027
1028 AC_MSG_RESULT([$enable_debug])
1029 AM_CONDITIONAL(DEBUG_BUILD, test x$enable_debug = xyes)
1030
1031 # ------------- mkdir required for win32 compatibility ------------
1032 # WIN32 mkdir takes only one argument, POSIX takes two.
1033 # #include "misc.h" where mkdir is required.
1034 m4_include([m4/m4_ax_func_mkdir.m4])
1035 AX_FUNC_MKDIR
1036
1037 # ------------- Type used for "Coord" type -------------------
1038
1039 AC_CHECK_HEADERS(stdint.h)
1040 AC_ARG_ENABLE([coord64],
1041 [  --enable-coord64        Force 64-bit coordinate types],
1042 [],[enable_coord64=no])
1043 AC_ARG_ENABLE([coord32],
1044 [  --enable-coord32        Force 32-bit coordinate types],
1045 [],[enable_coord32=no])
1046
1047 COORDTYPE="long"
1048
1049 echo "$enable_coord32:$enable_coord64:$ac_cv_header_stdint_h"
1050 case "$enable_coord32:$enable_coord64:$ac_cv_header_stdint_h" in
1051   yes:no:yes )
1052     COORD_TYPE="int32_t"
1053     COORD_MAX="INT32_MAX"
1054     ;;
1055   no:yes:yes )
1056     COORD_TYPE="int64_t"
1057     COORD_MAX="INT64_MAX"
1058     ;;
1059   yes:no:no  )
1060     COORD_TYPE="int"
1061     COORD_MAX="INT_MAX"
1062     ;;
1063   no:yes:no  )
1064     COORD_TYPE="long long"
1065     COORD_MAX="LLONG_MAX"
1066     ;;
1067   yes:yes:*  )
1068     AC_MSG_ERROR("*** cannot require both 32 and 64 bit coordinates")
1069     ;;
1070   *:*:*    )
1071     COORD_TYPE="long"
1072     COORD_MAX="LONG_MAX"
1073     ;;
1074 esac
1075 AC_DEFINE_UNQUOTED([COORD_TYPE],[$COORD_TYPE],
1076   [C type for Coordinates])
1077 AC_DEFINE_UNQUOTED([COORD_MAX],[$COORD_MAX],
1078   [Maximum value of coordinate type])
1079
1080 # ------------- Complete set of CPPFLAGS and LIBS -------------------
1081
1082 CPPFLAGS="$CPPFLAGS $X_CFLAGS $DBUS_CFLAGS $GDLIB_CFLAGS $GLIB_CFLAGS $GTK_CFLAGS $GD_CFLAGS $CAIRO_CFLAGS $GTKGLEXT_CFLAGS $GLU_CFLAGS $GL_CFLAGS"
1083 LIBS="$LIBS $XM_LIBS $DBUS_LIBS $X_LIBS $GDLIB_LIBS $GLIB_LIBS $GTK_LIBS $DMALLOC_LIBS $GD_LIBS $INTLLIBS $CAIRO_LIBS $GTKGLEXT_LIBS $GLU_LIBS $GL_LIBS"
1084
1085
1086 # if we have gcc then add -Wall
1087 if test "x$GCC" = "xyes"; then
1088         # see about adding some extra checks if the compiler takes them
1089         for flag in -Wall ; do
1090                 case " ${CFLAGS} " in
1091                         *\ ${flag}\ *)
1092                                 # flag is already present
1093                                 ;;
1094                         *)
1095                                 AC_MSG_CHECKING([if the compiler accepts ${flag}])
1096                                 ac_save_CFLAGS="$CFLAGS"
1097                                 CFLAGS="$CFLAGS ${flag}"
1098                                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM()],
1099                                         [AC_MSG_RESULT([yes])],
1100                                         [AC_MSG_RESULT([no])
1101                                          CFLAGS="$ac_save_CFLAGS"
1102                                         ]
1103                                 )
1104                                 ;;
1105                 esac
1106         done
1107 fi
1108
1109 CXXFLAGS="$CFLAGS"
1110
1111 # Now add C-specific flags
1112 if test "x$GCC" = "xyes"; then
1113         # see about adding some extra checks if the compiler takes them
1114         for flag in -Wdeclaration-after-statement ; do
1115                 case " ${CFLAGS} " in
1116                         *\ ${flag}\ *)
1117                                 # flag is already present
1118                                 ;;
1119                         *)
1120                                 AC_MSG_CHECKING([if the compiler accepts ${flag}])
1121                                 ac_save_CFLAGS="$CFLAGS"
1122                                 CFLAGS="$CFLAGS ${flag}"
1123                                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM()],
1124                                         [AC_MSG_RESULT([yes])],
1125                                         [AC_MSG_RESULT([no])
1126                                          CFLAGS="$ac_save_CFLAGS"
1127                                         ]
1128                                 )
1129                                 ;;
1130                 esac
1131         done
1132 fi
1133
1134 # See if we are building gcc with C++.
1135 AC_ARG_ENABLE(build-with-cxx,
1136 [  --enable-build-with-cxx build with C++ compiler instead of C compiler],
1137 ENABLE_BUILD_WITH_CXX=$enableval,
1138 ENABLE_BUILD_WITH_CXX=no)
1139
1140 case "$ENABLE_BUILD_WITH_CXX" in
1141   yes)
1142     CC_OR_CXX="$CXX"
1143     ;;
1144   no)
1145     CC_OR_CXX="$CC"
1146     ;;
1147 esac
1148 AC_SUBST(CC_OR_CXX)
1149
1150 # font filename
1151 FONTFILENAME=${FONTFILENAME:-"default_font"}
1152 AC_SUBST(FONTFILENAME)
1153 AC_DEFINE_UNQUOTED(FONTFILENAME,"$FONTFILENAME",[File for default font])
1154
1155 # standard autoconf variables
1156 CPPFLAGS="$CPPFLAGS -DPREFIXDIR=\\\"\${prefix}\\\""
1157 CPPFLAGS="$CPPFLAGS -DBINDIR=\\\"\${bindir}\\\""
1158 CPPFLAGS="$CPPFLAGS -DHOST=\\\"\${host}\\\""
1159
1160 # directory for old-style library and for fonts
1161 PCBLIBDIR=${datadir}/pcb
1162 AC_SUBST(PCBLIBDIR)
1163 #AC_DEFINE_UNQUOTED(PCBLIBDIR,"$PCBLIBDIR",[Library directory])
1164 CPPFLAGS="$CPPFLAGS -DPCBLIBDIR=\\\"$PCBLIBDIR\\\""
1165
1166 # name for old-style library
1167 LIBRARYFILENAME=pcblib
1168 AC_SUBST(LIBRARYFILENAME)
1169 AC_DEFINE_UNQUOTED(LIBRARYFILENAME,"$LIBRARYFILENAME",[library file name])
1170
1171
1172 # directory for new library
1173 PCBTREEDIR=${datadir}/pcb/newlib
1174 PCBTREEPATH=${PCBTREEDIR}:${PCBLIBDIR}/pcblib-newlib
1175 PCBTREEDIR=${PCBTREEDIR:-"$PCBTREEDIR"}
1176 AC_SUBST(PCBTREEDIR)
1177 AC_SUBST(PCBTREEPATH)
1178 #AC_DEFINE_UNQUOTED(PCBTREEDIR,"$PCBLIB",[top directory for new style pcb library])
1179 CPPFLAGS="$CPPFLAGS -DPCBTREEDIR=\\\"$PCBTREEDIR\\\""
1180 CPPFLAGS="$CPPFLAGS -DPCBTREEPATH=\\\"$PCBTREEPATH\\\""
1181
1182 # Figure out relative paths
1183 AC_MSG_CHECKING([for the bindir to pcblibdir relative path])
1184 adl_COMPUTE_RELATIVE_PATHS([bindir:PCBLIBDIR:bindir_to_pcblibdir])
1185 adl_NORMALIZE_PATH([bindir_to_pcblibdir], [$PCB_DIR_SEPARATOR_S])
1186 AC_MSG_RESULT([$bindir_to_pcblibdir])
1187 AC_DEFINE_UNQUOTED(BINDIR_TO_PCBLIBDIR, "$bindir_to_pcblibdir", [Relative path from bindir to pcblibdir])
1188
1189 AC_MSG_CHECKING([for the bindir to pcbtreedir relative path])
1190 adl_COMPUTE_RELATIVE_PATHS([bindir:PCBTREEDIR:bindir_to_pcbtreedir])
1191 adl_NORMALIZE_PATH([bindir_to_pcbtreedir], [$PCB_DIR_SEPARATOR_S])
1192 AC_MSG_RESULT([$bindir_to_pcbtreedir])
1193 AC_DEFINE_UNQUOTED(BINDIR_TO_PCBTREEDIR, "$bindir_to_pcbtreedir", [Relative path from bindir to pcbtreedir])
1194
1195
1196 AC_MSG_CHECKING([for the bindir to exec_prefix relative path])
1197 adl_COMPUTE_RELATIVE_PATHS([bindir:exec_prefix:bindir_to_execprefix])
1198 adl_NORMALIZE_PATH([bindir_to_execprefix], [$PCB_DIR_SEPARATOR_S])
1199 AC_MSG_RESULT([$bindir_to_execprefix])
1200 AC_DEFINE_UNQUOTED(BINDIR_TO_EXECPREFIX, "$bindir_to_execprefix", [Relative path from bindir to exec_prefix])
1201
1202
1203 BTNMOD=${BTNMOD:-"Mod1"}
1204 AC_SUBST(BTNMOD)
1205
1206 TOPDIRS=
1207 for dir in src lib newlib doc example tools tutorial README_FILES
1208 do
1209    test -d $dir/. && TOPDIRS="$TOPDIRS $dir"
1210 done
1211 AC_SUBST(TOPDIRS)
1212
1213 AC_CONFIG_FILES(Makefile data/Makefile intl/Makefile po/Makefile.in)
1214
1215 if test -d $srcdir/README_FILES; then
1216    AC_CONFIG_FILES(README_FILES/Makefile)
1217 fi
1218 if test -d $srcdir/doc; then
1219    AC_CONFIG_FILES(doc/Makefile)
1220 fi
1221 if test -d $srcdir/doc/gs; then
1222    AC_CONFIG_FILES(doc/gs/Makefile)
1223    AC_CONFIG_FILES(doc/gs/gafrc)
1224    AC_CONFIG_FILES(doc/gs/gschemrc)
1225 fi
1226 if test -d $srcdir/example; then
1227    AC_CONFIG_FILES(example/Makefile)
1228    AC_CONFIG_FILES(example/libraries/Makefile)
1229 fi
1230 if test -d $srcdir/lib; then
1231    AC_CONFIG_FILES(lib/CreateLibraryContents.sh)
1232    AC_CONFIG_FILES(lib/CreateLibrary.sh)
1233    AC_CONFIG_FILES(lib/ListLibraryContents.sh)
1234    AC_CONFIG_FILES(lib/Makefile)
1235    AC_CONFIG_FILES(lib/QueryLibrary.sh)
1236    AC_CONFIG_FILES(lib/qfp-ui)
1237 fi
1238 if test -d $srcdir/newlib; then
1239    AC_CONFIG_FILES(newlib/2_pin_thru-hole_packages/Makefile)
1240    AC_CONFIG_FILES(newlib/Makefile)
1241    AC_CONFIG_FILES(newlib/connectors/Makefile)
1242    AC_CONFIG_FILES(newlib/crystal/Makefile)
1243    AC_CONFIG_FILES(newlib/electro-optics/Makefile)
1244    AC_CONFIG_FILES(newlib/headers/Makefile)
1245    AC_CONFIG_FILES(newlib/keystone/Makefile)
1246    AC_CONFIG_FILES(newlib/msp430/Makefile)
1247    AC_CONFIG_FILES(newlib/not_vetted_ingo/Makefile)
1248    AC_CONFIG_FILES(newlib/sockets/Makefile)
1249    AC_CONFIG_FILES(newlib/tests/Makefile)
1250 fi
1251 AC_CONFIG_FILES(src/Makefile)
1252 AC_CONFIG_FILES(src/icons/Makefile)
1253 if test -d $srcdir/tools; then
1254    AC_CONFIG_FILES(tools/Makefile)
1255 fi
1256 if test -d $srcdir/tutorial; then
1257    AC_CONFIG_FILES(tutorial/Makefile)
1258 fi
1259
1260 dnl testsuite
1261 AC_CONFIG_FILES(tests/Makefile)
1262
1263 dnl GTS 0.7.6 - http://gts.sourceforge.net/
1264 AC_CONFIG_FILES(gts/Makefile)
1265
1266 dnl win32 build scripts
1267 AC_CONFIG_FILES(w32/Makefile)
1268
1269 dnl for building under cygwin
1270 AC_CONFIG_FILES(win32/Makefile)
1271
1272 AC_OUTPUT
1273
1274 with_gui=`echo $with_gui`
1275 with_printer=`echo $with_printer`
1276 with_exporters=`echo $with_exporters | sed 's/,/ /g'`
1277
1278 expandedXDGDATADIR=`eval "echo $XDGDATADIR"`
1279 expandedKDEDATADIR=`eval "echo $KDEDATADIR"`
1280
1281 AC_MSG_RESULT([
1282 ** Configuration summary for $PACKAGE $VERSION:
1283
1284    Cross Compiling:          $cross_compiling
1285    CC:                       $CC
1286    CXX:                      $CXX
1287    CPPFLAGS:                 $CPPFLAGS
1288    CFLAGS:                   $CFLAGS
1289    CXXFLAGS:                 $CXXFLAGS
1290    LIBS:                     $LIBS
1291    PCB:                      $PCB
1292
1293    GUI:                      $with_gui
1294    Printer:                  $with_printer
1295    Exporters:                $with_exporters
1296    Coordinate type:          $COORD_TYPE
1297    Source tree distribution: $pcb_sources
1298    Build documentation:      $docs_yesno
1299    Build toporouter:         $enable_toporouter
1300    Enable toporouter output: $enable_toporouter_output
1301    xdg data directory:       $expandedXDGDATADIR
1302    KDE data directory:       $expandedKDEDATADIR
1303    dmalloc debugging:        $with_dmalloc
1304    ElectricFence debugging:  $with_efence
1305    Regression tests enabled: $have_test_tools
1306 ])