geany.nsi.in

   1 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
   2 ; geany.nsi - this file is part of Geany, a fast and lightweight IDE
   3 ;
   4 ; Copyright 2007-2012 Enrico Tröger <enrico(dot)troeger(at)uvena(dot)de>
   5 ; Copyright 2007-2012 Nick Treleaven <nick(dot)treleaven(at)btinternet(dot)com>
   6 ;
   7 ; This program is free software; you can redistribute it and/or modify
   8 ; it under the terms of the GNU General Public License as published by
   9 ; the Free Software Foundation; either version 2 of the License, or
  10 ; (at your option) any later version.
  11 ;
  12 ; This program is distributed in the hope that it will be useful,
  13 ; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ; GNU General Public License for more details.
  16 ;
  17 ; You should have received a copy of the GNU General Public License
  18 ; along with this program; if not, write to the Free Software
  19 ; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
  20 ;
  21 ;
  22 ; Installer script for Geany (Windows Installer)
  23 ; (Script originally generated by the HM NIS Edit Script Wizard)
  24 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  25
  26
  27 ; Do a Cyclic Redundancy Check to make sure the installer was not corrupted by the download
  28 CRCCheck force
  29 RequestExecutionLevel highest ; set execution level for Windows Vista
  30
  31 ;;;;;;;;;;;;;;;;;;;
  32 ; helper defines  ;
  33 ;;;;;;;;;;;;;;;;;;;
  34 !define PRODUCT_NAME "Geany"
  35 !define PRODUCT_VERSION "@VERSION@"
  36 !define PRODUCT_VERSION_ID "@VERSION@.0.0"
  37 !define PRODUCT_PUBLISHER "The Geany developer team"
  38 !define PRODUCT_WEB_SITE "http://www.geany.org/"
  39 !define PRODUCT_DIR_REGKEY "Software\Geany"
  40 !define PRODUCT_UNINST_KEY "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}"
  41 !define PRODUCT_EXE "$INSTDIR\bin\Geany.exe"
  42 !define PRODUCT_REGNAME "Geany.ProjectFile"
  43 !define PRODUCT_EXT ".geany"
  44 !define RESOURCEDIR "geany-${PRODUCT_VERSION}"
  45 !define GTK_VERSION @GTK_VERSION@
  46
  47 ;;;;;;;;;;;;;;;;;;;;;
  48 ; Version resource  ;
  49 ;;;;;;;;;;;;;;;;;;;;;
  50 VIProductVersion "${PRODUCT_VERSION_ID}"
  51 VIAddVersionKey "ProductName" "${PRODUCT_NAME}"
  52 VIAddVersionKey "FileVersion" "${PRODUCT_VERSION}"
  53 VIAddVersionKey "ProductVersion" "${PRODUCT_VERSION}"
  54 VIAddVersionKey "LegalCopyright" "Copyright 2005-2014 by the Geany developer team"
  55 VIAddVersionKey "FileDescription" "${PRODUCT_NAME} Installer"
  56
  57 BrandingText "$(^NAME) installer (NSIS 2.46)"
  58 InstallDir "$PROGRAMFILES\Geany"
  59 Name "${PRODUCT_NAME} ${PRODUCT_VERSION}"
  60 SetCompressor /SOLID lzma
  61 ShowInstDetails hide
  62 ShowUnInstDetails hide
  63 XPStyle on
  64 !ifdef INCLUDE_GTK
  65 OutFile "geany-${PRODUCT_VERSION}_setup.exe"
  66 !else
  67 OutFile "geany-${PRODUCT_VERSION}_nogtk_setup.exe"
  68 !endif
  69
  70 Var Answer
  71 Var UserName
  72 Var StartmenuFolder
  73 Var UNINSTDIR
  74
  75 ;;;;;;;;;;;;;;;;
  76 ; MUI Settings ;
  77 ;;;;;;;;;;;;;;;;
  78 !include "MUI2.nsh"
  79
  80 ;Reserve files used in .onInit, for faster start-up
  81 ReserveFile "${NSISDIR}\Plugins\System.dll"
  82 ReserveFile "${NSISDIR}\Plugins\UserInfo.dll"
  83 ReserveFile "${NSISDIR}\Plugins\InstallOptions.dll"
  84 ReserveFile "${NSISDIR}\Plugins\LangDLL.dll"
  85
  86 !define MUI_ABORTWARNING
  87 !define MUI_ICON "icons\geany.ico"
  88 !define MUI_UNICON "${NSISDIR}\Contrib\Graphics\Icons\modern-uninstall-full.ico"
  89
  90 ; Welcome page
  91 !insertmacro MUI_PAGE_WELCOME
  92 ; License page
  93 ;!define MUI_LICENSEPAGE_RADIOBUTTONS
  94 !insertmacro MUI_PAGE_LICENSE "${RESOURCEDIR}\Copying.txt"
  95 ; Components page
  96 !insertmacro MUI_PAGE_COMPONENTS
  97 ; Directory page
  98 !define MUI_PAGE_CUSTOMFUNCTION_LEAVE OnDirLeave
  99 !insertmacro MUI_PAGE_DIRECTORY
 100 ; Start menu page
 101 !define MUI_STARTMENUPAGE_DEFAULTFOLDER "Geany"
 102 !define MUI_STARTMENUPAGE_REGISTRY_ROOT HKLM
 103 !define MUI_STARTMENUPAGE_REGISTRY_KEY "${PRODUCT_UNINST_KEY}"
 104 !define MUI_STARTMENUPAGE_REGISTRY_VALUENAME "Start Menu Folder"
 105 !insertmacro MUI_PAGE_STARTMENU ${PRODUCT_NAME} "$StartmenuFolder"
 106 ; Instfiles page
 107 !insertmacro MUI_PAGE_INSTFILES
 108 ; Finish page
 109 !define MUI_FINISHPAGE_SHOWREADME "$INSTDIR\News.txt"
 110 !define MUI_FINISHPAGE_SHOWREADME_TEXT "Show Release Notes"
 111 !define MUI_FINISHPAGE_SHOWREADME_NOTCHECKED
 112 !define MUI_FINISHPAGE_RUN "$INSTDIR\bin\Geany.exe"
 113 !define MUI_FINISHPAGE_RUN_NOTCHECKED
 114 !insertmacro MUI_PAGE_FINISH
 115
 116 !insertmacro MUI_UNPAGE_INSTFILES ; Uninstaller page
 117 !insertmacro MUI_LANGUAGE "English" ; Language file
 118
 119 ;;;;;;;;;;;;;;;;;;;;;;;;;;;
 120 ; Sections and InstTypes  ;
 121 ;;;;;;;;;;;;;;;;;;;;;;;;;;;
 122 InstType "Full"
 123 InstType "Minimal"
 124
 125 Section "!Program Files" SEC01
 126         SectionIn RO 1 2
 127         SetOverwrite ifnewer
 128
 129         SetOutPath "$INSTDIR"
 130         File "${RESOURCEDIR}\*.txt"
 131
 132         SetOutPath "$INSTDIR\bin"
 133         File "${RESOURCEDIR}\bin\Geany.exe"
 134         File "${RESOURCEDIR}\bin\*Geany*.dll"
 135
 136         SetOutPath "$INSTDIR\data"
 137         File "${RESOURCEDIR}\data\GPL-2"
 138         File "${RESOURCEDIR}\data\file*"
 139         File "${RESOURCEDIR}\data\geany.glade"
 140 !if ${GTK_VERSION} >= 3
 141         File "${RESOURCEDIR}\data\geany.css"
 142 !else
 143         File "${RESOURCEDIR}\data\geany.gtkrc"
 144 !endif
 145         File "${RESOURCEDIR}\data\snippets.conf"
 146         File "${RESOURCEDIR}\data\ui_toolbar.xml"
 147
 148         SetOutPath "$INSTDIR\data\templates"
 149         File /r "${RESOURCEDIR}\data\templates\*"
 150
 151         SetOutPath "$INSTDIR\data\colorschemes"
 152         File /r "${RESOURCEDIR}\data\colorschemes\*"
 153         # Geany color schemes project, don't bail out if they are missing
 154         File /nonfatal /r "..\geany-themes\colorschemes\*.conf"
 155
 156         SetOutPath "$INSTDIR\share\icons"
 157         File /r "${RESOURCEDIR}\share\icons\*"
 158
 159         SetOutPath "$INSTDIR"
 160
 161         CreateShortCut "$INSTDIR\Geany.lnk" "$INSTDIR\bin\Geany.exe"
 162         !insertmacro MUI_STARTMENU_WRITE_BEGIN ${PRODUCT_NAME}
 163         CreateDirectory "$SMPROGRAMS\$StartmenuFolder"
 164         CreateShortCut "$SMPROGRAMS\$StartmenuFolder\Geany.lnk" "$INSTDIR\bin\Geany.exe"
 165         !insertmacro MUI_STARTMENU_WRITE_END
 166
 167         ; register the extension .geany
 168         ; write information about file type
 169         WriteRegStr SHCTX "Software\Classes\${PRODUCT_REGNAME}" "" "${PRODUCT_NAME} Project File"
 170         WriteRegStr SHCTX "Software\Classes\${PRODUCT_REGNAME}\DefaultIcon" "" "${PRODUCT_EXE},0"
 171         WriteRegStr SHCTX "Software\Classes\${PRODUCT_REGNAME}\Shell\open\command" "" '"${PRODUCT_EXE}" "%1"'
 172         ; write information about file extensions
 173         WriteRegStr SHCTX "Software\Classes\${PRODUCT_EXT}" "" "${PRODUCT_REGNAME}"
 174         ; refresh shell
 175         System::Call 'shell32.dll::SHChangeNotify(i, i, i, i) (0x08000000, 0, 0, 0)'
 176 SectionEnd
 177
 178 Section "Plugins" SEC02
 179         SectionIn 1
 180         SetOverwrite ifnewer
 181         SetOutPath "$INSTDIR\lib\geany"
 182         File "${RESOURCEDIR}\lib\geany\*.dll"
 183 SectionEnd
 184
 185 Section "Language Files" SEC03
 186         SectionIn 1
 187         SetOutPath "$INSTDIR\share\locale"
 188         File /r "${RESOURCEDIR}\share\locale\*"
 189 !ifdef INCLUDE_GTK
 190         SetOutPath "$INSTDIR\share\locale"
 191         File /r "gtk\share\locale\*"
 192 !endif
 193 SectionEnd
 194
 195 Section "Documentation" SEC04
 196         SectionIn 1
 197         SetOverwrite ifnewer
 198         SetOutPath "$INSTDIR\share\doc"
 199         File /r "${RESOURCEDIR}\share\doc\*"
 200         WriteIniStr "$INSTDIR\Documentation.url" "InternetShortcut" "URL" "$INSTDIR\share\doc\geany\html\index.html"
 201         !insertmacro MUI_STARTMENU_WRITE_BEGIN ${PRODUCT_NAME}
 202         CreateShortCut "$SMPROGRAMS\$StartmenuFolder\Documentation.lnk" "$INSTDIR\Documentation.url"
 203         !insertmacro MUI_STARTMENU_WRITE_END
 204 SectionEnd
 205
 206 Section "Autocompletion Tags" SEC05
 207         SectionIn 1
 208         SetOutPath "$INSTDIR\data"
 209         SetOverwrite ifnewer
 210         File "${RESOURCEDIR}\data\php.tags"
 211         File "${RESOURCEDIR}\data\pascal.tags"
 212         File "${RESOURCEDIR}\data\python.tags"
 213         File "${RESOURCEDIR}\data\html_entities.tags"
 214         File "${RESOURCEDIR}\data\c99.tags"
 215 SectionEnd
 216
 217 ; Include GTK runtime library but only if desired from command line
 218 !ifdef INCLUDE_GTK
 219 Section "GTK ${GTK_VERSION} Runtime Environment" SEC06
 220         SectionIn 1
 221         SetOverwrite ifnewer
 222         SetOutPath "$INSTDIR"
 223         File "gtk\ReadMe.Dependencies.Geany.txt"
 224         SetOutPath "$INSTDIR\bin"
 225         File /r "gtk\bin\*"
 226         SetOutPath "$INSTDIR\etc"
 227         File /r "gtk\etc\*"
 228         SetOutPath "$INSTDIR\lib"
 229         File /r "gtk\lib\*"
 230         SetOutPath "$INSTDIR\share\themes"
 231         File /r "gtk\share\themes\*"
 232 !if ${GTK_VERSION} >= 3
 233         SetOutPath "$INSTDIR\share\icons"
 234         File /r "gtk\share\icons\*"
 235         SetOutPath "$INSTDIR\share\glib-2.0"
 236         File /r "gtk\share\glib-2.0\*"
 237         SetOutPath "$INSTDIR\share\gtk-3.0"
 238         File /r "gtk\share\gtk-3.0\*"
 239 !endif
 240 SectionEnd
 241 !endif
 242
 243 Section "Context Menus" SEC07
 244         SectionIn 1
 245         WriteRegStr HKCR "*\shell\OpenWithGeany" "" "Open with Geany"
 246         WriteRegStr HKCR "*\shell\OpenWithGeany" "Icon" "$INSTDIR\bin\geany.exe"
 247         WriteRegStr HKCR "*\shell\OpenWithGeany\command" "" '"$INSTDIR\bin\geany.exe" "%1"'
 248 SectionEnd
 249
 250 Section "Desktop Shortcuts" SEC08
 251         SectionIn 1
 252         CreateShortCut "$DESKTOP\Geany.lnk" "$INSTDIR\bin\Geany.exe"
 253         CreateShortCut "$QUICKLAUNCH\Geany.lnk" "$INSTDIR\bin\Geany.exe"
 254 SectionEnd
 255
 256 ; Development files
 257 Section "Development files" SEC09
 258         SetOverwrite ifnewer
 259         SetOutPath "$INSTDIR\include"
 260         File /r "${RESOURCEDIR}\include\*"
 261
 262         SetOutPath "$INSTDIR\lib\pkgconfig"
 263         File "${RESOURCEDIR}\lib\pkgconfig\geany.pc"
 264 SectionEnd
 265
 266 Section -AdditionalIcons
 267         SetOutPath $INSTDIR
 268         !insertmacro MUI_STARTMENU_WRITE_BEGIN ${PRODUCT_NAME}
 269         WriteIniStr "$INSTDIR\Website.url" "InternetShortcut" "URL" "${PRODUCT_WEB_SITE}"
 270         CreateShortCut "$SMPROGRAMS\$StartmenuFolder\Website.lnk" "$INSTDIR\Website.url"
 271         CreateShortCut "$SMPROGRAMS\$StartmenuFolder\Uninstall.lnk" "$INSTDIR\uninst.exe"
 272         !insertmacro MUI_STARTMENU_WRITE_END
 273 SectionEnd
 274
 275 Section -Post
 276         WriteUninstaller "$INSTDIR\uninst.exe"
 277         WriteRegStr SHCTX "${PRODUCT_DIR_REGKEY}" Path "$INSTDIR"
 278         WriteRegStr SHCTX "${PRODUCT_UNINST_KEY}" "StartMenu" "$SMPROGRAMS\$StartmenuFolder"
 279         ${if} $Answer == "yes" ; if user is admin
 280                 WriteRegStr SHCTX "${PRODUCT_UNINST_KEY}" "DisplayName" "$(^Name)"
 281                 WriteRegStr SHCTX "${PRODUCT_UNINST_KEY}" "UninstallString" "$INSTDIR\uninst.exe"
 282                 WriteRegStr SHCTX "${PRODUCT_UNINST_KEY}" "DisplayIcon" "$INSTDIR\bin\Geany.exe"
 283                 WriteRegStr SHCTX "${PRODUCT_UNINST_KEY}" "DisplayVersion" "${PRODUCT_VERSION}"
 284                 WriteRegStr SHCTX "${PRODUCT_UNINST_KEY}" "URLInfoAbout" "${PRODUCT_WEB_SITE}"
 285                 WriteRegStr SHCTX "${PRODUCT_UNINST_KEY}" "URLUpdateInfo" "${PRODUCT_WEB_SITE}"
 286                 WriteRegStr SHCTX "${PRODUCT_UNINST_KEY}" "Publisher" "${PRODUCT_PUBLISHER}"
 287                 WriteRegDWORD SHCTX "${PRODUCT_UNINST_KEY}" "NoModify" 0x00000001
 288                 WriteRegDWORD SHCTX "${PRODUCT_UNINST_KEY}" "NoRepair" 0x00000001
 289         ${endif}
 290 SectionEnd
 291
 292 Section Uninstall
 293         Delete "$INSTDIR\Website.url"
 294         Delete "$INSTDIR\Documentation.url"
 295         Delete "$INSTDIR\uninst.exe"
 296         Delete "$INSTDIR\News.txt"
 297         Delete "$INSTDIR\ReadMe.txt"
 298         Delete "$INSTDIR\ReadMe.Dependencies.Geany.txt"
 299         Delete "$INSTDIR\Thanks.txt"
 300         Delete "$INSTDIR\ToDo.txt"
 301         Delete "$INSTDIR\Authors.txt"
 302         Delete "$INSTDIR\ChangeLog.txt"
 303         Delete "$INSTDIR\Copying.txt"
 304         Delete "$INSTDIR\Geany.lnk"
 305
 306         ; delete start menu entry
 307         ReadRegStr $0 SHCTX "${PRODUCT_UNINST_KEY}" "StartMenu"
 308         RMDir /r "$0"
 309
 310         Delete "$QUICKLAUNCH\Geany.lnk"
 311         Delete "$DESKTOP\Geany.lnk"
 312
 313         RMDir /r "$INSTDIR\bin"
 314         RMDir /r "$INSTDIR\data"
 315         RMDir /r "$INSTDIR\etc"
 316         RMDir /r "$INSTDIR\include"
 317         RMDir /r "$INSTDIR\lib"
 318         RMDir /r "$INSTDIR\share"
 319         RMDir "$INSTDIR"
 320
 321         ; remove .geany file extension
 322         ReadRegStr $R0 SHCTX "Software\Classes\${PRODUCT_EXT}" ""
 323         ${if} $R0 == "${PRODUCT_REGNAME}"
 324                 DeleteRegKey SHCTX "${PRODUCT_EXT}"
 325                 DeleteRegKey HKCR "${PRODUCT_EXT}"
 326                 DeleteRegKey SHCTX "${PRODUCT_REGNAME}"
 327                 DeleteRegKey HKCR "${PRODUCT_REGNAME}"
 328         ${endif}
 329
 330         DeleteRegKey HKCR "*\shell\OpenWithGeany"
 331
 332         DeleteRegKey SHCTX "${PRODUCT_UNINST_KEY}"
 333         DeleteRegKey HKCU "${PRODUCT_UNINST_KEY}"
 334         DeleteRegKey SHCTX "${PRODUCT_DIR_REGKEY}"
 335         DeleteRegKey HKCU "${PRODUCT_DIR_REGKEY}"
 336
 337         SetAutoClose true
 338 SectionEnd
 339
 340 ;;;;;;;;;;;;;;;;;;;;;;;;;
 341 ; Section descriptions  ;
 342 ;;;;;;;;;;;;;;;;;;;;;;;;;
 343 !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
 344 !insertmacro MUI_DESCRIPTION_TEXT ${SEC01} "Required program files. You cannot skip these files."
 345 !insertmacro MUI_DESCRIPTION_TEXT ${SEC02} "Available plugins like 'Version Diff', 'Class Builder' and 'Insert Special Characters'."
 346 !insertmacro MUI_DESCRIPTION_TEXT ${SEC03} "Various translations of Geany's interface."
 347 !insertmacro MUI_DESCRIPTION_TEXT ${SEC04} "Manual in Text and HTML format."
 348 !insertmacro MUI_DESCRIPTION_TEXT ${SEC05} "Symbol lists necessary for auto completion of symbols."
 349 !ifdef INCLUDE_GTK
 350 !insertmacro MUI_DESCRIPTION_TEXT ${SEC06} "You need these files to run Geany. If you have already installed a GTK Runtime Environment (${GTK_VERSION} or higher), you can skip it."
 351 !endif
 352 !insertmacro MUI_DESCRIPTION_TEXT ${SEC07} "Add context menu item 'Open With Geany'"
 353 !insertmacro MUI_DESCRIPTION_TEXT ${SEC08} "Create shortcuts for Geany on the desktop and in the Quicklaunch Bar"
 354 !insertmacro MUI_DESCRIPTION_TEXT ${SEC09} "You need these files only if you want to develop own plugins for Geany. If unsure, you can skip it."
 355 !insertmacro MUI_FUNCTION_DESCRIPTION_END
 356
 357 ;;;;;;;;;;;;;;;;;;;;;
 358 ; helper functions  ;
 359 ;;;;;;;;;;;;;;;;;;;;;
 360
 361 ; (from http://jabref.svn.sourceforge.net/viewvc/jabref/trunk/jabref/src/windows/nsis/setup.nsi)
 362 !macro IsUserAdmin Result UName
 363         ClearErrors
 364         UserInfo::GetName
 365         IfErrors Win9x
 366         Pop $0
 367         StrCpy ${UName} $0
 368         UserInfo::GetAccountType
 369         Pop $1
 370         ${if} $1 == "Admin"
 371                 StrCpy ${Result} "yes"
 372         ${else}
 373                 StrCpy ${Result} "no"
 374         ${endif}
 375         Goto done
 376
 377 Win9x:
 378         StrCpy ${Result} "yes"
 379 done:
 380 !macroend
 381
 382 Function .onInit
 383         StrCpy "$StartmenuFolder" "Geany"
 384
 385         ; (from http://jabref.svn.sourceforge.net/viewvc/jabref/trunk/jabref/src/windows/nsis/setup.nsi)
 386         ; If the user does *not* have administrator privileges, abort
 387         StrCpy $Answer ""
 388         StrCpy $UserName ""
 389         !insertmacro IsUserAdmin $Answer $UserName ; macro from LyXUtils.nsh
 390         ${if} $Answer == "yes"
 391                 SetShellVarContext all ; set that e.g. shortcuts will be created for all users
 392         ${else}
 393                 SetShellVarContext current
 394                 ; TODO is this really what we want? $PROGRAMFILES is not much better because
 395                 ; probably the unprivileged user can't write it anyways
 396                 StrCpy $INSTDIR "$PROFILE\$(^Name)"
 397         ${endif}
 398
 399         ; prevent running multiple instances of the installer
 400         System::Call 'kernel32::CreateMutexA(i 0, i 0, t "geany_installer") i .r1 ?e'
 401         Pop $R0
 402         StrCmp $R0 0 +3
 403         MessageBox MB_OK|MB_ICONEXCLAMATION "The installer is already running." /SD IDOK
 404         Abort
 405         ; warn about a new install over an existing installation
 406         ReadRegStr $R0 SHCTX "${PRODUCT_UNINST_KEY}" "UninstallString"
 407         StrCmp $R0 "" finish
 408
 409         MessageBox MB_YESNO|MB_ICONEXCLAMATION \
 410         "Geany has already been installed. $\nDo you want to remove the previous version before installing $(^Name) ?" \
 411                 /SD IDYES IDYES remove IDNO finish
 412
 413 remove:
 414         ; run the uninstaller
 415         ClearErrors
 416         ; we read the installation path of the old installation from the Registry
 417         ReadRegStr $UNINSTDIR SHCTX "${PRODUCT_DIR_REGKEY}" "Path"
 418         IfSilent dosilent nonsilent
 419 dosilent:
 420         ExecWait '$R0 /S _?=$UNINSTDIR' ;Do not copy the uninstaller to a temp file
 421         Goto finish
 422 nonsilent:
 423         ExecWait '$R0 _?=$UNINSTDIR' ;Do not copy the uninstaller to a temp file
 424 finish:
 425 FunctionEnd
 426
 427 Function un.onUninstSuccess
 428         HideWindow
 429         MessageBox MB_ICONINFORMATION|MB_OK "$(^Name) was successfully removed from your computer." \
 430                 /SD IDOK
 431 FunctionEnd
 432
 433 Function un.onInit
 434         ; If the user does *not* have administrator privileges, abort
 435         StrCpy $Answer ""
 436         !insertmacro IsUserAdmin $Answer $UserName
 437         ${if} $Answer == "yes"
 438                 SetShellVarContext all
 439         ${else}
 440                 ; check if the Geany has been installed with admin permisions
 441                 ReadRegStr $0 HKLM "${PRODUCT_UNINST_KEY}" "Publisher"
 442                 ${if} $0 != ""
 443                         MessageBox MB_OK|MB_ICONSTOP "You need administrator privileges to uninstall Geany!" \
 444                                 /SD IDOK
 445                         Abort
 446                 ${endif}
 447                 SetShellVarContext current
 448         ${endif}
 449
 450         MessageBox MB_ICONQUESTION|MB_YESNO|MB_DEFBUTTON2 "Are you sure you want to completely remove $(^Name) and all of its components?" \
 451                 /SD IDYES IDYES +2
 452         Abort
 453 FunctionEnd
 454
 455 Function OnDirLeave
 456         ClearErrors
 457         SetOutPath "$INSTDIR" ; what about IfError creating $INSTDIR?
 458         GetTempFileName $1 "$INSTDIR" ; creates tmp file (or fails)
 459         FileOpen $0 "$1" "w" ; error to open?
 460         FileWriteByte $0 "0"
 461         IfErrors notPossible possible
 462
 463 notPossible:
 464         RMDir "$INSTDIR" ; removes folder if empty
 465         MessageBox MB_OK "The given directory is not writeable. Please choose another one!" /SD IDOK
 466         Abort
 467 possible:
 468         FileClose $0
 469         Delete "$1"
 470 FunctionEnd