m4/geany-docutils.m4

   1 dnl GEANY_CHECK_DOCUTILS
   2 dnl Check for the tools used to generate documentation
   3 dnl
   4 AC_DEFUN([GEANY_CHECK_DOCUTILS],
   5 [
   6         GEANY_CHECK_DOCUTILS_HTML
   7         GEANY_CHECK_DOCUTILS_PDF
   8 ])
   9 dnl
  10 dnl GEANY_CHECK_DOCUTILS_HTML
  11 dnl For HTML documentation generation
  12 dnl
  13 AC_DEFUN([GEANY_CHECK_DOCUTILS_HTML],
  14 [
  15         AC_ARG_ENABLE([html-docs],
  16                 [AS_HELP_STRING([--enable-html-docs],
  17                         [generate HTML documentation using rst2html [default=no]])],
  18                 [geany_enable_html_docs="$enableval"],
  19                 [geany_enable_html_docs="no"])
  20         AC_ARG_VAR([RST2HTML], [Path to Docutils rst2html executable])
  21         AS_IF([test "x$geany_enable_html_docs" != "xno"],
  22         [
  23 dnl TODO: try rst2html.py first
  24                 AS_IF([test -z "$RST2HTML"], [RST2HTML="rst2html"])
  25                 AC_PATH_PROG([RST2HTML], [$RST2HTML], [no])
  26                 AS_IF([test "x$RST2HTML" != "xno"],
  27                         [geany_enable_html_docs="yes"],
  28                         [test "x$geany_enable_html_docs" = "xyes"],
  29                         [AC_MSG_ERROR([Documentation enabled but rst2html not found])],
  30                         [geany_enable_html_docs="no"])
  31         ])
  32         AM_CONDITIONAL([WITH_RST2HTML], [test "x$geany_enable_html_docs" != "xno"])
  33         GEANY_STATUS_ADD([Build HTML documentation], [$geany_enable_html_docs])
  34 ])
  35 dnl
  36 dnl GEANY_CHECK_DOCUTILS_PDF
  37 dnl For PDF documentation generation
  38 dnl
  39 AC_DEFUN([GEANY_CHECK_DOCUTILS_PDF],
  40 [
  41         AC_ARG_ENABLE([pdf-docs],
  42                 [AS_HELP_STRING([--enable-pdf-docs],
  43                         [generate PDF documentation using rst2pdf [default=no]])],
  44                 [geany_enable_pdf_docs="$enableval"],
  45                 [geany_enable_pdf_docs="no"])
  46         AC_ARG_VAR([RST2PDF], [Path to Docutils rst2pdf executable])
  47         AS_IF([test "x$geany_enable_pdf_docs" != "xno"],
  48         [
  49                 AS_IF([test -z "$RST2PDF"], [RST2PDF="rst2pdf"])
  50                 AC_PATH_PROG([RST2PDF], [$RST2PDF], [no])
  51                 AS_IF([test "x$RST2PDF" != "xno"],
  52                         [geany_enable_pdf_docs="yes"],
  53                         [test "x$geany_enable_pdf_docs" = "xyes"],
  54                         [AC_MSG_ERROR([PDF documentation enabled but rst2pdf not found])],
  55                         [geany_enable_pdf_docs="no"])
  56         ])
  57         AM_CONDITIONAL([WITH_RST2PDF], [test "x$geany_enable_pdf_docs" != "xno"])
  58         GEANY_STATUS_ADD([Build PDF documentation], [$geany_enable_pdf_docs])
  59 ])