configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ([2.60])
   4 AC_INIT([Geany], [1.31],
   5                 [https://github.com/geany/geany/issues])
   6 AC_CONFIG_SRCDIR([src/geany.h])
   7 AC_CONFIG_AUX_DIR([build-aux])
   8 AC_CONFIG_MACRO_DIR([m4])
   9 AM_INIT_AUTOMAKE([1.11 -Wall parallel-tests subdir-objects])
  10 AC_CONFIG_HEADERS([config.h])
  11
  12 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  13
  14 GEANY_PREFIX
  15 GEANY_DOCDIR
  16
  17 GEANY_STATUS_ADD([Install Geany in], [${prefix}])
  18 if test -n "${build}" -a -n "${target}"; then
  19         GEANY_STATUS_ADD([Building Geany on], [${build}])
  20         GEANY_STATUS_ADD([Building Geany for], [${target}])
  21 fi
  22
  23 # why do we use this?
  24 AC_USE_SYSTEM_EXTENSIONS
  25
  26 m4_ifdef([AM_PROG_AR],[AM_PROG_AR])
  27 LT_INIT([disable-static])
  28 AC_PROG_CC
  29 AC_PROG_CC_C99
  30 AM_PROG_CC_C_O
  31
  32 AC_PROG_CXX
  33 GEANY_PROG_CXX
  34
  35 AC_PROG_INSTALL
  36 AC_PROG_LN_S
  37
  38 # autoscan start
  39
  40 # Checks for header files.
  41 AC_CHECK_HEADERS([fcntl.h fnmatch.h glob.h stdlib.h sys/time.h])
  42
  43 # Checks for typedefs, structures, and compiler characteristics.
  44 AC_TYPE_OFF_T
  45 AC_TYPE_SIZE_T
  46 AC_STRUCT_TM
  47
  48 # Checks for library functions.
  49 AC_CHECK_FUNCS([ftruncate fgetpos fnmatch mkstemp strerror strstr])
  50
  51 # autoscan end
  52
  53
  54 # check for VCS revision
  55 GEANY_CHECK_REVISION([dnl force debug mode for a VCS working copy
  56                                           CFLAGS="-g -DGEANY_DEBUG $CFLAGS"])
  57
  58
  59 AC_ARG_ENABLE([gtk3],
  60                 [AS_HELP_STRING([--enable-gtk3],
  61                                                 [compile with GTK3 support (experimental) [default=no]])],
  62                 [enable_gtk3=$enableval],
  63                 [enable_gtk3=no])
  64
  65 AS_IF([test "x$enable_gtk3" = xyes],
  66           [gtk_package=gtk+-3.0
  67            gtk_min_version=3.0],
  68           [gtk_package=gtk+-2.0
  69            gtk_min_version=2.24])
  70 AM_CONDITIONAL([GTK3], [test "x$gtk_package" = "xgtk+-3.0"])
  71
  72 # GTK/GLib/GIO checks
  73 gtk_modules="$gtk_package >= $gtk_min_version glib-2.0 >= 2.32"
  74 gtk_modules_private="gio-2.0 >= 2.32 gmodule-no-export-2.0"
  75 PKG_CHECK_MODULES([GTK], [$gtk_modules $gtk_modules_private])
  76 AC_SUBST([DEPENDENCIES], [$gtk_modules])
  77 AS_VAR_APPEND([GTK_CFLAGS], [" -DGLIB_VERSION_MIN_REQUIRED=GLIB_VERSION_2_32"])
  78 dnl Disable all GTK deprecations on 3.x so long as we want to keep 2.x support and only require 3.0.
  79 dnl No need on 2.x as we target the latest version.
  80 AM_COND_IF([GTK3], [AS_VAR_APPEND([GTK_CFLAGS], [" -DGDK_DISABLE_DEPRECATION_WARNINGS"])])
  81 AC_SUBST([GTK_CFLAGS])
  82 AC_SUBST([GTK_LIBS])
  83 GTK_VERSION=`$PKG_CONFIG --modversion $gtk_package`
  84 AC_SUBST([GTK_VERSION])
  85 GEANY_STATUS_ADD([Using GTK version], [${GTK_VERSION}])
  86 # GTHREAD checks
  87 gthread_modules="gthread-2.0"
  88 PKG_CHECK_MODULES([GTHREAD], [$gthread_modules])
  89 AC_SUBST([GTHREAD_CFLAGS])
  90 AC_SUBST([GTHREAD_LIBS])
  91
  92 # --disable-deprecated switch for GTK purification
  93 AC_ARG_ENABLE([deprecated],
  94                 [AS_HELP_STRING([--disable-deprecated], [Disable deprecated GTK functions.])],
  95                 [GTK_CFLAGS="$GTK_CFLAGS -DG_DISABLE_DEPRECATED -DGTK_DISABLE_DEPRECATED"],
  96                 [])
  97
  98
  99 # Check for binary relocation support
 100 GEANY_CHECK_BINRELOC
 101 # CTags source compatibility (we actually use GRegex instead of POSIX regcomp)
 102 AC_DEFINE([HAVE_REGCOMP], [1], [Should always be 1, required for CTags.])
 103 # Plugins support
 104 GEANY_CHECK_PLUGINS
 105 # check for mingw specific settings
 106 GEANY_CHECK_MINGW
 107
 108 GEANY_CHECK_SOCKET
 109 GEANY_CHECK_VTE
 110 GEANY_CHECK_MAC_INTEGRATION
 111 GEANY_CHECK_THE_FORCE dnl hehe
 112
 113 # i18n
 114 GEANY_I18N
 115
 116 # double eval since datarootdir is usually defined as ${prefix}/share
 117 AM_COND_IF([MINGW],
 118   [pkgdatadir='${prefix}/data'],
 119   [pkgdatadir='${datarootdir}/geany'])
 120 AC_SUBST([GEANY_DATA_DIR], [$(eval echo $(eval echo $pkgdatadir))])
 121 AC_SUBST([pkgdatadir])
 122
 123 # Documentation tools
 124 GEANY_CHECK_DOCUTILS
 125 GEANY_CHECK_DOXYGEN
 126 GEANY_CHECK_GTKDOC_HEADER
 127
 128 # libgeany
 129 GEANY_LIB_INIT
 130
 131 # Output
 132 AC_CONFIG_FILES([
 133                 Makefile
 134                 icons/Makefile
 135                 icons/16x16/Makefile
 136                 icons/24x24/Makefile
 137                 icons/32x32/Makefile
 138                 icons/48x48/Makefile
 139                 icons/scalable/Makefile
 140                 icons/tango/Makefile
 141                 icons/tango/16x16/Makefile
 142                 icons/tango/24x24/Makefile
 143                 icons/tango/32x32/Makefile
 144                 icons/tango/48x48/Makefile
 145                 icons/tango/scalable/Makefile
 146                 ctags/Makefile
 147                 scintilla/Makefile
 148                 scintilla/include/Makefile
 149                 src/Makefile
 150                 src/tagmanager/Makefile
 151                 plugins/Makefile
 152                 po/Makefile.in
 153                 data/Makefile
 154                 doc/Makefile
 155                 doc/geany.1
 156                 geany.spec
 157                 geany.pc
 158                 geany.nsi
 159                 doc/Doxyfile
 160                 tests/Makefile
 161                 tests/ctags/Makefile
 162 ])
 163 AC_OUTPUT
 164
 165 # Summary
 166 GEANY_STATUS_OUTPUT
 167 echo ""
 168 echo "Configuration is done OK."
 169 echo ""