m4/geany-docutils.m4

   1 dnl GEANY_CHECK_DOCUTILS
   2 dnl Check for the tools used to generate documentation
   3 dnl
   4 AC_DEFUN([GEANY_CHECK_DOCUTILS],
   5 [
   6         GEANY_CHECK_DOCUTILS_HTML
   7         GEANY_CHECK_DOCUTILS_PDF
   8 ])
   9 dnl
  10 dnl GEANY_CHECK_DOCUTILS_HTML
  11 dnl For HTML documentation generation
  12 dnl
  13 AC_DEFUN([GEANY_CHECK_DOCUTILS_HTML],
  14 [
  15         AC_REQUIRE([GEANY_CHECK_REVISION])
  16
  17         dnl we require rst2html by default unless we don't build from Git
  18         dnl and already have the HTML manual built in-tree
  19         html_docs_default=yes
  20         AS_IF([test "$REVISION" = "-1" && test -f "$srcdir/doc/geany.html"],
  21                 [html_docs_default=auto])
  22
  23         AC_ARG_ENABLE([html-docs],
  24                 [AS_HELP_STRING([--enable-html-docs],
  25                         [generate HTML documentation using rst2html [default=auto]])],
  26                 [geany_enable_html_docs="$enableval"],
  27                 [geany_enable_html_docs="$html_docs_default"])
  28         AC_ARG_VAR([RST2HTML], [Path to Docutils rst2html executable])
  29         AS_IF([test "x$geany_enable_html_docs" != "xno"],
  30         [
  31 dnl TODO: try rst2html.py first
  32                 AS_IF([test -z "$RST2HTML"], [RST2HTML="rst2html"])
  33                 AC_PATH_PROG([RST2HTML], [$RST2HTML], [no])
  34                 AS_IF([test "x$RST2HTML" != "xno"],
  35                         [geany_enable_html_docs="yes"],
  36                         [test "x$geany_enable_html_docs" = "xyes"],
  37                         [AC_MSG_ERROR([Documentation enabled but rst2html not found.
  38 You can explicitly disable building of the HTML manual with --disable-html-docs,
  39 but you then may not have a local copy of the HTML manual.])],
  40                         [geany_enable_html_docs="no"])
  41         ])
  42         AM_CONDITIONAL([WITH_RST2HTML], [test "x$geany_enable_html_docs" != "xno"])
  43         GEANY_STATUS_ADD([Build HTML documentation], [$geany_enable_html_docs])
  44 ])
  45 dnl
  46 dnl GEANY_CHECK_DOCUTILS_PDF
  47 dnl For PDF documentation generation
  48 dnl
  49 AC_DEFUN([GEANY_CHECK_DOCUTILS_PDF],
  50 [
  51         AC_ARG_ENABLE([pdf-docs],
  52                 [AS_HELP_STRING([--enable-pdf-docs],
  53                         [generate PDF documentation using rst2pdf [default=auto]])],
  54                 [geany_enable_pdf_docs="$enableval"],
  55                 [geany_enable_pdf_docs="auto"])
  56         AC_ARG_VAR([RST2PDF], [Path to Docutils rst2pdf executable])
  57         AS_IF([test "x$geany_enable_pdf_docs" != "xno"],
  58         [
  59                 AS_IF([test -z "$RST2PDF"], [RST2PDF="rst2pdf"])
  60                 AC_PATH_PROG([RST2PDF], [$RST2PDF], [no])
  61                 AS_IF([test "x$RST2PDF" != "xno"],
  62                         [geany_enable_pdf_docs="yes"],
  63                         [test "x$geany_enable_pdf_docs" = "xyes"],
  64                         [AC_MSG_ERROR([PDF documentation enabled but rst2pdf not found])],
  65                         [geany_enable_pdf_docs="no"])
  66         ])
  67         AM_CONDITIONAL([WITH_RST2PDF], [test "x$geany_enable_pdf_docs" != "xno"])
  68         GEANY_STATUS_ADD([Build PDF documentation], [$geany_enable_pdf_docs])
  69 ])