configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.53)
   3 AC_REVISION(0.2.3)
   4 AC_INIT(themes/default/README)
   5 AM_INIT_AUTOMAKE(fvwm-themes, 0.7.1)
   6
   7 REQUIRED_FVWM_VERSION=2.5.8
   8 AC_SUBST(REQUIRED_FVWM_VERSION)dnl
   9 REQUIRED_PERL_VERSION=5.004
  10 AC_SUBST(REQUIRED_PERL_VERSION)dnl
  11
  12 mg_ARG_WITH(fvwm-bindir,
  13         [  --with-fvwm-bindir=DIR    specify fvwm bin directory, if not in PATH],
  14         FVWM_BINDIR, ""
  15 )
  16
  17 mg_ARG_WITH(ft-datadir,
  18         [  --with-ft-datadir=DIR     specify data dir, if different from fvwm],
  19         FT_DATADIR, ""
  20 )
  21
  22 AC_ARG_ENABLE(gnome-icons,
  23         [  --enable-gnome-icons      convert gnome icons to xpm icons ],
  24         GNOME_ICONS=yes, GNOME_ICONS=no
  25 )
  26 AC_SUBST(GNOME_ICONS)dnl
  27
  28 AC_ARG_ENABLE(kde2-icons,
  29         [  --enable-kde2-icons       convert kde2 icons to xpm icons ],
  30         KDE2_ICONS=yes, KDE2_ICONS=no
  31 )
  32 AC_SUBST(KDE2_ICONS)dnl
  33
  34 AC_ARG_ENABLE(build-menus,
  35         [  --disable-build-menus     disable the rebuilding of the user menus ],
  36         [ if test "$enableval" = yes; then
  37                 BUILD_MENUS=yes
  38         else
  39                 BUILD_MENUS=no
  40         fi ],
  41         [ BUILD_MENUS=yes ]
  42 )
  43 AC_SUBST(BUILD_MENUS)
  44
  45 # disabled menu system stuff even if present in the machine
  46 AC_ARG_ENABLE(menu-system,
  47         [  --disable-menu-system     disable (Debian) menu system support ],
  48         [ if test "$enableval" = yes; then
  49                 MENU_SYSTEM=yes
  50         else
  51                 MENU_SYSTEM=no
  52         fi ],
  53         [ MENU_SYSTEM=yes ]
  54 )
  55
  56 # do not run update-menu at install even if menu-system is enabled
  57 AC_ARG_ENABLE(run-updatemenu,
  58         [  --disable-run-updatemenu  do not run (Debian) update-menu during installation even if detected ],
  59         [ if test "$enableval" = yes; then
  60                 RUN_UPDATEMENU=yes
  61         else
  62                 RUN_UPDATEMENU=no
  63         fi ],
  64         [ RUN_UPDATEMENU=yes ]
  65 )
  66
  67 dnl 'unset' is not portable, but setting to null is not enough to avoid using
  68 dnl the cached value!  For ancient shells "rm config.cache" is a solution.
  69 UNSET=true
  70 if unset UNSET 2>/dev/null; then UNSET=unset; fi
  71
  72 AC_PROG_INSTALL
  73 dnl Reports are that INSTALL is set incorrectly on Solaris.
  74 if test "`echo $INSTALL | cut -c1-2`" = ".."; then
  75         AC_MSG_ERROR([
  76         It seems that ./configure can't automatically set INSTALL.
  77         Please set this environment var yourself and rerun ./configure.
  78         For example: env INSTALL='/usr/ucb/install -c' ./configure])
  79 fi
  80
  81 AC_PATH_PROG(PERL, perl)
  82 if test -z "$PERL"; then
  83         AC_MSG_WARN(Perl is not found; you will have fatal problems using this package!)
  84         PERL=/usr/bin/perl
  85 fi
  86 AC_SUBST(PERL)dnl
  87
  88 AC_PATH_PROG(AWK, gawk)
  89 if test -z "$AWK"; then
  90         AC_PATH_PROG(AWK, nawk)
  91 fi
  92 if test -z "$AWK"; then
  93         AC_PATH_PROG(AWK, mawk)
  94 fi
  95 if test -z "$AWK"; then
  96         AWK=awk
  97 fi
  98 AC_SUBST(AWK)dnl
  99
 100 AC_PATH_PROG(TAR, gtar)
 101 if test -z "$TAR"; then
 102         AC_PATH_PROG(TAR, gnutar)
 103 fi
 104 if test -z "$TAR"; then
 105         TAR=tar
 106 fi
 107 AC_SUBST(TAR)dnl
 108
 109 AC_PATH_PROG(MKFIFO, mkfifo)
 110 if test -z "$MKFIFO"; then
 111         AC_MSG_WARN([
 112         mkfifo is not found; you will have some problems with GUI!])
 113 fi
 114
 115 # we check for FvwmM4 below
 116 AC_PATH_PROG(M4, m4)
 117 if test -z "$M4"; then
 118         AC_MSG_WARN([
 119         m4 is not found; you will have a few problems using this package!])
 120 fi
 121
 122 # Solaris is not shipped with xmessage...
 123 AC_PATH_PROG(XMESSAGE, xmessage)
 124 if test -z "$XMESSAGE"; then
 125         additional_msg=""
 126         if test "`uname`" = "SunOS"; then additional_msg="
 127         You may find the binary at http://sunfreeware.com/ ."
 128         fi
 129         AC_MSG_WARN([
 130         xmessage is not found; you will have some problems; please install it.$additional_msg])
 131 fi
 132
 133 # debian menu system
 134 AC_PATH_PROG(UPDATE_MENU, update-menus)
 135 if test -z "$UPDATE_MENU"; then
 136         MENU_SYSTEM=no
 137 fi
 138 if test "$MENU_SYSTEM" = yes; then
 139         MENU_SYSTEM_PREFIX='${ROOT_PREFIX}'"/etc/menu-methods"
 140         MENU_SYSTEM_BINSCRIPTS='fvwm_themes'
 141         MENU_SYSTEM_CONFIGDATA='fvwm_themes.h fvwm_themes_data.h'
 142         AC_SUBST(MENU_SYSTEM_PREFIX)
 143         AC_SUBST(MENU_SYSTEM_BINSCRIPTS)
 144         AC_SUBST(MENU_SYSTEM_CONFIGDATA)
 145 else
 146         RUN_UPDATEMENU=no
 147         UPDATE_MENU=false
 148 fi
 149 AC_SUBST(RUN_UPDATEMENU)
 150 AC_SUBST(UPDATE_MENU)
 151
 152 # fvwm-themes-images needs to know where the rgb.txt file is
 153 AC_PATH_XTRA
 154 if test -z "$X_LIBS"; then
 155         if test -f /usr/share/X11/rgb.txt; then
 156                 X_LIBS=-L/usr/share
 157         else
 158                 AC_MSG_WARN([
 159         Xlib is not found; fvwm-themes-images will not fully work!])
 160         fi
 161 fi
 162
 163 # FIXME: a better way to find GNOME_IMAGES_DIR?
 164 # I've no gnome-config on my machine.
 165 AC_PATH_PROG(GNOME_SESSION, gnome-session)
 166 if test -z "$GNOME_SESSION"; then
 167         GNOME_SESSION=/usr/bin/gnome-session
 168 fi
 169 GNOME_IMAGES_DIR=`echo $GNOME_SESSION | sed -e "s,/[[^/]]*/gnome-session$,,"`/share/pixmaps
 170 AC_SUBST(GNOME_IMAGES_DIR)dnl
 171
 172 $UNSET ac_cv_path_FVWM_CONFIG
 173 AC_PATH_PROG(FVWM_CONFIG, fvwm-config --version, , [$FVWM_BINDIR:${PATH}])
 174 if test -z "$FVWM_CONFIG"; then
 175         AC_MSG_ERROR([
 176         fvwm-config is not found; try --with-fvwm-bindir
 177         You need at least fvwm-$REQUIRED_FVWM_VERSION])
 178 fi
 179 AC_SUBST(FVWM_CONFIG)dnl
 180
 181 FVWM_BINDIR=`$FVWM_CONFIG --bindir`
 182 AC_SUBST(FVWM_BINDIR)dnl
 183 FVWM_DEFAULT_USERDIR=`$FVWM_CONFIG --default-userdir`
 184 AC_SUBST(FVWM_DEFAULT_USERDIR)dnl
 185 FVWM_DEFAULT_IMAGEPATH=`$FVWM_CONFIG --default-imagepath`
 186 AC_SUBST(FVWM_DEFAULT_IMAGEPATH)dnl
 187 FVWM_MODULEDIR=`$FVWM_CONFIG --fvwm-moduledir`
 188
 189 $UNSET ac_cv_path_FVWM_M4
 190 AC_PATH_PROG(FVWM_M4, FvwmM4, ,"$FVWM_MODULEDIR")
 191 if test -z "$FVWM_M4"; then
 192         AC_MSG_WARN([
 193         FvwmM4 is not found; you will have a few problems using this package!])
 194 fi
 195
 196 FVWM_VERSION=`$FVWM_CONFIG --version`
 197 if test "x$FVWM_VERSION" = "x"; then FVWM_VERSION=unknown; fi
 198 AC_SUBST(FVWM_VERSION)dnl
 199
 200 # Hopefully this "sort" is portable (after many tries using awk and expr)
 201 if (echo $REQUIRED_FVWM_VERSION; echo $FVWM_VERSION) \
 202 | sed 's/\./ /g' | uniq | sort -n -k 1 -k 2 -k 3 -c 2>/dev/null; then
 203         :
 204         # fvwm version is ok
 205 else
 206         AC_MSG_ERROR([
 207         You have fvwm-$FVWM_VERSION, which is not up to date
 208         You need at least fvwm-$REQUIRED_FVWM_VERSION])
 209 fi
 210
 211 ROOT_PREFIX=""
 212 AC_SUBST(ROOT_PREFIX)dnl
 213
 214 if echo "${prefix}NONE" | awk '/^NONE/ { exit 1 }'; then
 215         mg_DEFAULT_DIR_ARG(bindir,     '${prefix}/bin')
 216         mg_DEFAULT_DIR_ARG(mandir,     '${prefix}/man')
 217         mg_DEFAULT_DIR_ARG(datadir,    '${prefix}/share')
 218         mg_DEFAULT_DIR_ARG(FT_DATADIR, '${datadir}/fvwm')
 219 else
 220         mg_DEFAULT_DIR_ARG(bindir,     '${ROOT_PREFIX}'"`$FVWM_CONFIG --bindir`")
 221         mg_DEFAULT_DIR_ARG(mandir,     '${ROOT_PREFIX}'"`$FVWM_CONFIG --mandir`")
 222         mg_DEFAULT_DIR_ARG(datadir,    '${ROOT_PREFIX}'"`$FVWM_CONFIG --datadir`")
 223         mg_DEFAULT_DIR_ARG(FT_DATADIR, '${ROOT_PREFIX}'"`$FVWM_CONFIG --fvwm-datadir`")
 224 fi
 225
 226 #FT_FVWMSCRIPT_DIR='${FT_DATADIR}/scripts'
 227 #FT_FVWMFORM_DIR='${FT_DATADIR}/forms'
 228 FT_FVWMSCRIPT_DIR='${FT_DATADIR}'
 229 FT_FVWMFORM_DIR='${FT_DATADIR}'
 230 FT_LOCALE_DIR='${FT_DATADIR}/locale'
 231
 232 AC_SUBST(FT_DATADIR)dnl
 233 AC_SUBST(FT_FVWMSCRIPT_DIR)dnl
 234 AC_SUBST(FT_FVWMFORM_DIR)dnl
 235 AC_SUBST(FT_LOCALE_DIR)dnl
 236
 237 # migo: to match the one in FVWM...
 238 FT_VERSION_INFO="fvwm-themes $VERSION built on `date +'%b %d %Y at %T'`"
 239 AC_SUBST(FT_VERSION_INFO)dnl
 240 FT_BUILD_ID=`date '+build %d-%b-%Y %T'`
 241 AC_SUBST(FT_BUILD_ID)dnl
 242
 243 SETTINGS_FILE='${FT_DATADIR}/themes/default/settings.cfg'
 244 AC_SUBST(SETTINGS_FILE)dnl
 245
 246 # 3 lists: all themes, base and extra
 247 ALL_THEMES=`ls -d ./themes/* | grep -v /CVS | grep -v /Makefile | cut -d/ -f3`
 248 ALL_THEMES=`echo $ALL_THEMES`
 249 BASE_THEMES="afterstep cde default luthien migo multichoice olicha redmond98 redmondxp"
 250 mg_LIST_MINUS(ALL_THEMES, BASE_THEMES, EXTRA_THEMES)
 251 AC_SUBST(ALL_THEMES)AC_SUBST(BASE_THEMES)AC_SUBST(EXTRA_THEMES)dnl
 252
 253 AC_OUTPUT(
 254         Makefile
 255         bin/Makefile
 256         doc/Makefile
 257         forms/Makefile
 258         scripts/Makefile
 259         locale/Makefile
 260         locale/en/Makefile
 261         locale/fr/Makefile
 262         locale/ru/Makefile
 263         locale/ja/Makefile
 264         locale/de/Makefile
 265         locale/pl/Makefile
 266         bin/fvwm-themes-config
 267         bin/fvwm-themes-start
 268         bin/fvwm-themes-xrdb
 269         bin/fvwm-themes-menuapp
 270         bin/fvwm-themes-com
 271         bin/fvwm-themes-script
 272         bin/fvwm-themes-images
 273         bin/fvwm-themes-root
 274         debian/Makefile
 275         debian/full-control
 276         debian/extra-control
 277         debian/base-control
 278         doc/fvwm-themes.lsm
 279         rpm/fvwm-themes.spec
 280         rpm/fvwm-themes-base.spec
 281         rpm/fvwm-themes-extra.spec
 282         rpm/fvwm-themes-themes.spec
 283         rpm/Makefile
 284         menu-system/Makefile
 285 )
 286
 287 if test -n "$DEBUG"; then
 288         echo '--------------------------------- ( Debug ) ---------------------------------'
 289         echo "[prefix:            ${prefix}]"
 290         echo "[bindir:            ${bindir}]"
 291         echo "[mandir:            ${mandir}]"
 292         echo "[datadir:           ${datadir}]"
 293         echo "[ft-datadir:        ${FT_DATADIR}]"
 294         echo "[ft-fvwmscript-dir: ${FT_FVWMSCRIPT_DIR}]"
 295         echo "[ft-fvwmform-dir:   ${FT_FVWMFORM_DIR}]"
 296         echo "[menu-system:       ${MENU_SYSTEM},${MENU_SYSTEM_PREFIX},${UPDATE_MENU}]"
 297         echo "[gnome-icons:       ${GNOME_ICONS}]"
 298         echo "[gnome-session:     ${GNOME_SESSION}]"
 299         echo "[gnome-images-dir:  ${GNOME_IMAGES_DIR}]"
 300         echo "[kde2-icons:        ${KDE2_ICONS}]"
 301         echo "[settings-file:     ${SETTINGS_FILE}]"
 302         echo "[x-libs:            ${X_LIBS}]"
 303         echo "[x-extra-libs:      ${X_EXTRA_LIBS}]"
 304         echo '-----------------------------------------------------------------------------'
 305         echo "  All   themes: [${ALL_THEMES}]"
 306         echo "  Base  themes: [${BASE_THEMES}]"
 307         echo "  Extra themes: [${EXTRA_THEMES}]"
 308         echo '============================================================================='
 309 fi
 310
 311 echo "
 312 -----------------------------------------------------------------------------
 313 FVWM Themes Version:    $VERSION
 314 FVWM Version:           $FVWM_VERSION
 315 =============================================================================
 316
 317 Run 'make; su; make install' to install $PACKAGE.
 318 "