CMakeLists.txt

   1 # 3.1 is OK for most parts. However:
   2 # 3.3 is needed in src/libFLAC
   3 # 3.5 is needed in src/libFLAC/ia32
   4 # 3.9 is needed in 'doc' because of doxygen_add_docs()
   5 cmake_minimum_required(VERSION 3.5)
   6
   7 if(NOT (CMAKE_BUILD_TYPE OR CMAKE_CONFIGURATION_TYPES OR DEFINED ENV{CFLAGS} OR DEFINED ENV{CXXFLAGS}))
   8     set(CMAKE_BUILD_TYPE Release CACHE STRING "Choose the type of build, options are: None Debug Release RelWithDebInfo")
   9 endif()
  10
  11 project(FLAC VERSION 1.3.3) # HOMEPAGE_URL "https://www.xiph.org/flac/")
  12
  13 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
  14
  15 option(BUILD_CXXLIBS "Build libFLAC++" ON)
  16 option(BUILD_PROGRAMS "Build and install programs" ON)
  17 option(BUILD_EXAMPLES "Build and install examples" ON)
  18 option(BUILD_DOCS "Build and install doxygen documents" ON)
  19 option(WITH_STACK_PROTECTOR "Enable GNU GCC stack smash protection" ON)
  20 option(INSTALL_MANPAGES "Install MAN pages" ON)
  21 option(INSTALL_PKGCONFIG_MODULES "Install PkgConfig modules" ON)
  22 option(INSTALL_CMAKE_CONFIG_MODULE "Install CMake package-config module" ON)
  23 option(WITH_OGG "ogg support (default: test for libogg)" ON)
  24
  25 if(WITH_OGG)
  26     find_package(Ogg REQUIRED)
  27 endif()
  28
  29 find_package(Iconv)
  30 set(HAVE_ICONV ${Iconv_FOUND})
  31
  32 if(CMAKE_C_COMPILER_ID MATCHES "GNU|Clang")
  33     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -Wstrict-prototypes -Wmissing-prototypes -Waggregate-return -Wcast-align -Wnested-externs -Wshadow -Wundef -Wmissing-declarations -Winline")
  34     set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} -O3 -funroll-loops")
  35 endif()
  36 if(CMAKE_CXX_COMPILER_ID MATCHES "GNU|Clang")
  37     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall -Wextra -Wcast-align -Wshadow -Wwrite-strings -Wctor-dtor-privacy -Wnon-virtual-dtor -Wreorder -Wsign-promo -Wundef")
  38 endif()
  39
  40 include(CMakePackageConfigHelpers)
  41 include(CPack)
  42 include(CTest)
  43 include(CheckCCompilerFlag)
  44 include(CheckCXXCompilerFlag)
  45 include(CheckSymbolExists)
  46 include(CheckFunctionExists)
  47 include(CheckIncludeFile)
  48 include(CheckCSourceCompiles)
  49 include(CheckCXXSourceCompiles)
  50 include(GNUInstallDirs)
  51 include(UseSystemExtensions)
  52 include(TestBigEndian)
  53
  54 check_include_file("byteswap.h" HAVE_BYTESWAP_H)
  55 check_include_file("inttypes.h" HAVE_INTTYPES_H)
  56 check_include_file("stdint.h" HAVE_STDINT_H)
  57 if(MSVC)
  58     check_include_file("intrin.h" FLAC__HAS_X86INTRIN)
  59 else()
  60     check_include_file("x86intrin.h" FLAC__HAS_X86INTRIN)
  61 endif()
  62
  63 check_function_exists(fseeko HAVE_FSEEKO)
  64
  65 check_c_source_compiles("int main() { return __builtin_bswap16 (0) ; }" HAVE_BSWAP16)
  66 check_c_source_compiles("int main() { return __builtin_bswap32 (0) ; }" HAVE_BSWAP32)
  67
  68 test_big_endian(CPU_IS_BIG_ENDIAN)
  69
  70 check_c_compiler_flag(-Werror HAVE_WERROR_FLAG)
  71 check_c_compiler_flag(-Wdeclaration-after-statement HAVE_DECL_AFTER_STMT_FLAG)
  72 check_c_compiler_flag(-mstackrealign HAVE_STACKREALIGN_FLAG)
  73 check_cxx_compiler_flag(-Weffc++ HAVE_WEFFCXX_FLAG)
  74
  75 if(WITH_STACK_PROTECTOR)
  76   if(NOT MSVC)
  77     check_c_compiler_flag("-fstack-protector-strong" HAVE_STACK_PROTECTOR_FLAG)
  78   endif()
  79 endif()
  80
  81 if(HAVE_WERROR_FLAG)
  82     option(ENABLE_WERROR "Enable -Werror in all Makefiles" OFF)
  83 endif()
  84
  85 add_compile_options(
  86     $<$<BOOL:${MSVC}>:/wd4267>
  87     $<$<BOOL:${MSVC}>:/wd4996>
  88     $<$<BOOL:${ENABLE_WERROR}>:-Werror>
  89     $<$<AND:$<COMPILE_LANGUAGE:CXX>,$<BOOL:${HAVE_WEFFCXX_FLAG}>>:-Weffc++>
  90     $<$<AND:$<COMPILE_LANGUAGE:C>,$<BOOL:${HAVE_DECL_AFTER_STMT_FLAG}>>:-Wdeclaration-after-statement>)
  91
  92 if(HAVE_STACK_PROTECTOR_FLAG)
  93     add_compile_options(-fstack-protector-strong)
  94 endif()
  95
  96 if(CMAKE_SYSTEM_PROCESSOR STREQUAL "i686" AND HAVE_STACKREALIGN_FLAG)
  97     add_compile_options(-mstackrealign)
  98 endif()
  99
 100 include_directories("include")
 101
 102 include_directories("${CMAKE_CURRENT_BINARY_DIR}")
 103 add_definitions(-DHAVE_CONFIG_H)
 104
 105 if(MSVC)
 106     add_definitions(
 107         -D_CRT_SECURE_NO_WARNINGS
 108         -D_USE_MATH_DEFINES)
 109 endif()
 110 if(CMAKE_BUILD_TYPE STREQUAL Debug OR CMAKE_BUILD_TYPE STREQUAL RelWithDebInfo)
 111     add_definitions(-DFLAC__OVERFLOW_DETECT)
 112 endif()
 113
 114 add_subdirectory("src")
 115 add_subdirectory("microbench")
 116 if(BUILD_DOCS)
 117     add_subdirectory("doc")
 118 endif()
 119 if(BUILD_EXAMPLES)
 120     add_subdirectory("examples")
 121 endif()
 122 if(BUILD_TESTING)
 123     add_subdirectory("test")
 124 endif()
 125
 126 configure_file(config.cmake.h.in config.h)
 127
 128 if(INSTALL_CMAKE_CONFIG_MODULE)
 129     install(
 130         EXPORT targets
 131         DESTINATION "${CMAKE_INSTALL_DATADIR}/${PROJECT_NAME}/cmake"
 132         NAMESPACE FLAC::)
 133
 134     configure_package_config_file(
 135         flac-config.cmake.in flac-config.cmake
 136         INSTALL_DESTINATION "${CMAKE_INSTALL_DATADIR}/${PROJECT_NAME}/cmake")
 137     write_basic_package_version_file(
 138         flac-config-version.cmake COMPATIBILITY AnyNewerVersion)
 139
 140     install(
 141         FILES
 142             "${CMAKE_CURRENT_BINARY_DIR}/flac-config.cmake"
 143             "${CMAKE_CURRENT_BINARY_DIR}/flac-config-version.cmake"
 144         DESTINATION "${CMAKE_INSTALL_DATADIR}/${PROJECT_NAME}/cmake")
 145 endif()
 146
 147 file(GLOB FLAC_HEADERS "include/FLAC/*.h")
 148 file(GLOB FLAC++_HEADERS "include/FLAC++/*.h")
 149 install(FILES ${FLAC_HEADERS} DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/FLAC")
 150 install(FILES ${FLAC++_HEADERS} DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/FLAC++")
 151 if(INSTALL_MANPAGES)
 152     install(FILES "man/flac.1" "man/metaflac.1" DESTINATION "${CMAKE_INSTALL_MANDIR}")
 153 endif()