lisp/vc-hg.el

   1 ;;; vc-hg.el --- VC backend for the mercurial version control system
   2
   3 ;; Copyright (C) 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   4
   5 ;; Author: Ivan Kanis
   6 ;; Keywords: tools
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This is a mercurial version control backend
  26
  27 ;;; Thanks:
  28
  29 ;;; Bugs:
  30
  31 ;;; Installation:
  32
  33 ;;; Todo:
  34
  35 ;; 1) Implement the rest of the vc interface. See the comment at the
  36 ;; beginning of vc.el. The current status is:
  37
  38 ;; FUNCTION NAME                               STATUS
  39 ;; BACKEND PROPERTIES
  40 ;; * revision-granularity                      OK
  41 ;; STATE-QUERYING FUNCTIONS
  42 ;; * registered (file)                         OK
  43 ;; * state (file)                              OK
  44 ;; - state-heuristic (file)                    NOT NEEDED
  45 ;; - dir-status (dir update-function)          OK
  46 ;; - dir-status-files (dir files ds uf)        OK
  47 ;; - dir-extra-headers (dir)                   OK
  48 ;; - dir-printer (fileinfo)                    OK
  49 ;; * working-revision (file)                   OK
  50 ;; - latest-on-branch-p (file)                 ??
  51 ;; * checkout-model (files)                    OK
  52 ;; - workfile-unchanged-p (file)               OK
  53 ;; - mode-line-string (file)                   NOT NEEDED
  54 ;; STATE-CHANGING FUNCTIONS
  55 ;; * register (files &optional rev comment)    OK
  56 ;; * create-repo ()                            OK
  57 ;; - init-revision ()                          NOT NEEDED
  58 ;; - responsible-p (file)                      OK
  59 ;; - could-register (file)                     OK
  60 ;; - receive-file (file rev)                   ?? PROBABLY NOT NEEDED
  61 ;; - unregister (file)                         COMMENTED OUT, MAY BE INCORRECT
  62 ;; * checkin (files rev comment)               OK
  63 ;; * find-revision (file rev buffer)           OK
  64 ;; * checkout (file &optional editable rev)    OK
  65 ;; * revert (file &optional contents-done)     OK
  66 ;; - rollback (files)                          ?? PROBABLY NOT NEEDED
  67 ;; - merge (file rev1 rev2)                    NEEDED
  68 ;; - merge-news (file)                         NEEDED
  69 ;; - steal-lock (file &optional revision)      NOT NEEDED
  70 ;; HISTORY FUNCTIONS
  71 ;; * print-log (files buffer &optional shortlog start-revision limit) OK
  72 ;; - log-view-mode ()                          OK
  73 ;; - show-log-entry (revision)                 NOT NEEDED, DEFAULT IS GOOD
  74 ;; - comment-history (file)                    NOT NEEDED
  75 ;; - update-changelog (files)                  NOT NEEDED
  76 ;; * diff (files &optional rev1 rev2 buffer)   OK
  77 ;; - revision-completion-table (files)         OK?
  78 ;; - annotate-command (file buf &optional rev) OK
  79 ;; - annotate-time ()                          OK
  80 ;; - annotate-current-time ()                  NOT NEEDED
  81 ;; - annotate-extract-revision-at-line ()      OK
  82 ;; TAG SYSTEM
  83 ;; - create-tag (dir name branchp)             NEEDED
  84 ;; - retrieve-tag (dir name update)            NEEDED
  85 ;; MISCELLANEOUS
  86 ;; - make-version-backups-p (file)             ??
  87 ;; - repository-hostname (dirname)             ??
  88 ;; - previous-revision (file rev)              OK
  89 ;; - next-revision (file rev)                  OK
  90 ;; - check-headers ()                          ??
  91 ;; - clear-headers ()                          ??
  92 ;; - delete-file (file)                        TEST IT
  93 ;; - rename-file (old new)                     OK
  94 ;; - find-file-hook ()                         PROBABLY NOT NEEDED
  95
  96 ;; 2) Implement Stefan Monnier's advice:
  97 ;; vc-hg-registered and vc-hg-state
  98 ;; Both of those functions should be super extra careful to fail gracefully in
  99 ;; unexpected circumstances. The reason this is important is that any error
 100 ;; there will prevent the user from even looking at the file :-(
 101 ;; Ideally, just like in vc-arch and vc-cvs, checking that the file is under
 102 ;; mercurial's control and extracting the current revision should be done
 103 ;; without even using `hg' (this way even if you don't have `hg' installed,
 104 ;; Emacs is able to tell you this file is under mercurial's control).
 105
 106 ;;; History:
 107 ;;
 108
 109 ;;; Code:
 110
 111 (eval-when-compile
 112   (require 'cl)
 113   (require 'vc)
 114   (require 'vc-dir))
 115
 116 ;;; Customization options
 117
 118 (defcustom vc-hg-global-switches nil
 119   "Global switches to pass to any Hg command."
 120   :type '(choice (const :tag "None" nil)
 121          (string :tag "Argument String")
 122          (repeat :tag "Argument List" :value ("") string))
 123   :version "22.2"
 124   :group 'vc)
 125
 126 (defcustom vc-hg-diff-switches t ; Hg doesn't support common args like -u
 127   "String or list of strings specifying switches for Hg diff under VC.
 128 If nil, use the value of `vc-diff-switches'.  If t, use no switches."
 129   :type '(choice (const :tag "Unspecified" nil)
 130                  (const :tag "None" t)
 131                  (string :tag "Argument String")
 132                  (repeat :tag "Argument List" :value ("") string))
 133   :version "23.1"
 134   :group 'vc)
 135
 136 \f
 137 ;;; Properties of the backend
 138
 139 (defun vc-hg-revision-granularity () 'repository)
 140 (defun vc-hg-checkout-model (files) 'implicit)
 141
 142 ;;; State querying functions
 143
 144 ;;;###autoload (defun vc-hg-registered (file)
 145 ;;;###autoload   "Return non-nil if FILE is registered with hg."
 146 ;;;###autoload   (if (vc-find-root file ".hg")       ; short cut
 147 ;;;###autoload       (progn
 148 ;;;###autoload         (load "vc-hg")
 149 ;;;###autoload         (vc-hg-registered file))))
 150
 151 ;; Modeled after the similar function in vc-bzr.el
 152 (defun vc-hg-registered (file)
 153   "Return non-nil if FILE is registered with hg."
 154   (when (vc-hg-root file)           ; short cut
 155     (let ((state (vc-hg-state file)))  ; expensive
 156       (and state (not (memq state '(ignored unregistered)))))))
 157
 158 (defun vc-hg-state (file)
 159   "Hg-specific version of `vc-state'."
 160   (let*
 161       ((status nil)
 162        (default-directory (file-name-directory file))
 163        (out
 164         (with-output-to-string
 165           (with-current-buffer
 166               standard-output
 167             (setq status
 168                   (condition-case nil
 169                       ;; Ignore all errors.
 170                       (let ((process-environment
 171                              ;; Avoid localization of messages so we can parse the output.
 172                              (append (list "TERM=dumb" "LANGUAGE=C" "HGRC=") process-environment)))
 173
 174                       (process-file
 175                        "hg" nil t nil
 176                        "status" "-A" (file-relative-name file)))
 177                     ;; Some problem happened.  E.g. We can't find an `hg'
 178                     ;; executable.
 179                     (error nil)))))))
 180     (when (eq 0 status)
 181         (when (null (string-match ".*: No such file or directory$" out))
 182           (let ((state (aref out 0)))
 183             (cond
 184              ((eq state ?=) 'up-to-date)
 185              ((eq state ?A) 'added)
 186              ((eq state ?M) 'edited)
 187              ((eq state ?I) 'ignored)
 188              ((eq state ?R) 'removed)
 189              ((eq state ?!) 'missing)
 190              ((eq state ??) 'unregistered)
 191              ((eq state ?C) 'up-to-date) ;; Older mercurials use this
 192              (t 'up-to-date)))))))
 193
 194 (defun vc-hg-working-revision (file)
 195   "Hg-specific version of `vc-working-revision'."
 196   (let*
 197       ((status nil)
 198        (default-directory (file-name-directory file))
 199        (out
 200         (with-output-to-string
 201           (with-current-buffer
 202               standard-output
 203             (setq status
 204                   (condition-case nil
 205                       (let ((process-environment
 206                              ;; Avoid localization of messages so we can parse the output.
 207                              (append (list "TERM=dumb" "LANGUAGE=C" "HGRC=")
 208                                      process-environment)))
 209                         ;; Ignore all errors.
 210                         (process-file
 211                          "hg" nil t nil
 212                          "parent" "--template" "{rev}" (file-relative-name file)))
 213                     ;; Some problem happened.  E.g. We can't find an `hg'
 214                     ;; executable.
 215                     (error nil)))))))
 216     (when (eq 0 status) out)))
 217
 218 ;;; History functions
 219
 220 (defcustom vc-hg-log-switches nil
 221   "String or list of strings specifying switches for hg log under VC."
 222   :type '(choice (const :tag "None" nil)
 223                  (string :tag "Argument String")
 224                  (repeat :tag "Argument List" :value ("") string))
 225   :group 'vc-hg)
 226
 227 (defun vc-hg-print-log (files buffer &optional shortlog start-revision limit)
 228   "Get change log associated with FILES."
 229   ;; `vc-do-command' creates the buffer, but we need it before running
 230   ;; the command.
 231   (vc-setup-buffer buffer)
 232   ;; If the buffer exists from a previous invocation it might be
 233   ;; read-only.
 234   (let ((inhibit-read-only t))
 235     (with-current-buffer
 236         buffer
 237       (apply 'vc-hg-command buffer 0 files "log"
 238              (append
 239               (when start-revision (list (format "-r%s:" start-revision)))
 240               (when limit (list "-l" (format "%s" limit)))
 241               (when shortlog '("--style" "compact"))
 242               vc-hg-log-switches)))))
 243
 244 (defvar log-view-message-re)
 245 (defvar log-view-file-re)
 246 (defvar log-view-font-lock-keywords)
 247 (defvar log-view-per-file-logs)
 248 (defvar vc-short-log)
 249
 250 (define-derived-mode vc-hg-log-view-mode log-view-mode "Hg-Log-View"
 251   (require 'add-log) ;; we need the add-log faces
 252   (set (make-local-variable 'log-view-file-re) "\\`a\\`")
 253   (set (make-local-variable 'log-view-per-file-logs) nil)
 254   (set (make-local-variable 'log-view-message-re)
 255        (if vc-short-log
 256            "^\\([0-9]+\\)\\(?:\\[.*\\]\\)? +\\([0-9a-z]\\{12\\}\\) +\\(\\(?:[0-9]+\\)-\\(?:[0-9]+\\)-\\(?:[0-9]+\\) \\(?:[0-9]+\\):\\(?:[0-9]+\\) \\(?:[-+0-9]+\\)\\) +\\(.*\\)$"
 257          "^changeset:[ \t]*\\([0-9]+\\):\\(.+\\)"))
 258   (set (make-local-variable 'log-view-font-lock-keywords)
 259        (if vc-short-log
 260            (append `((,log-view-message-re
 261                       (1 'log-view-message-face)
 262                       (2 'log-view-message-face)
 263                       (3 'change-log-date)
 264                       (4 'change-log-name))))
 265        (append
 266         log-view-font-lock-keywords
 267         '(
 268           ;; Handle the case:
 269           ;; user: FirstName LastName <foo@bar>
 270           ("^user:[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 271            (1 'change-log-name)
 272            (2 'change-log-email))
 273           ;; Handle the cases:
 274           ;; user: foo@bar
 275           ;; and
 276           ;; user: foo
 277           ("^user:[ \t]+\\([A-Za-z0-9_.+-]+\\(?:@[A-Za-z0-9_.-]+\\)?\\)"
 278            (1 'change-log-email))
 279           ("^date: \\(.+\\)" (1 'change-log-date))
 280             ("^summary:[ \t]+\\(.+\\)" (1 'log-view-message)))))))
 281
 282 (declare-function log-edit-mode "log-edit" ())
 283 (defvar log-edit-extra-flags)
 284 (defvar log-edit-before-checkin-process)
 285
 286 (define-derived-mode vc-hg-log-edit-mode log-edit-mode "Hg-log-edit"
 287   "Mode for editing Hg commit logs.
 288 If a line like:
 289 Author: NAME
 290 is present in the log, it is removed, and
 291 --author NAME
 292 is passed to the hg commit command."
 293   (set (make-local-variable 'log-edit-extra-flags) nil)
 294   (set (make-local-variable 'log-edit-before-checkin-process)
 295        '(("^Author:[ \t]+\\(.*\\)[ \t]*$" . (list "--user" (match-string 1))))))
 296
 297 (defun vc-hg-diff (files &optional oldvers newvers buffer)
 298   "Get a difference report using hg between two revisions of FILES."
 299   (let* ((firstfile (car files))
 300          (working (and firstfile (vc-working-revision firstfile))))
 301     (when (and (equal oldvers working) (not newvers))
 302       (setq oldvers nil))
 303     (when (and (not oldvers) newvers)
 304       (setq oldvers working))
 305     (apply #'vc-hg-command (or buffer "*vc-diff*") nil files "diff"
 306            (append
 307             (vc-switches 'hg 'diff)
 308             (when oldvers
 309               (if newvers
 310                   (list "-r" oldvers "-r" newvers)
 311                 (list "-r" oldvers)))))))
 312
 313 (defun vc-hg-revision-table (files)
 314   (let ((default-directory (file-name-directory (car files))))
 315     (with-temp-buffer
 316       (vc-hg-command t nil files "log" "--template" "{rev} ")
 317       (split-string
 318        (buffer-substring-no-properties (point-min) (point-max))))))
 319
 320 ;; Modeled after the similar function in vc-cvs.el
 321 (defun vc-hg-revision-completion-table (files)
 322   (lexical-let ((files files)
 323                 table)
 324     (setq table (lazy-completion-table
 325                  table (lambda () (vc-hg-revision-table files))))
 326     table))
 327
 328 (defun vc-hg-annotate-command (file buffer &optional revision)
 329   "Execute \"hg annotate\" on FILE, inserting the contents in BUFFER.
 330 Optional arg REVISION is a revision to annotate from."
 331   (vc-hg-command buffer 0 file "annotate" "-d" "-n" "--follow"
 332                  (when revision (concat "-r" revision))))
 333
 334 (declare-function vc-annotate-convert-time "vc-annotate" (time))
 335
 336 ;; The format for one line output by "hg annotate -d -n" looks like this:
 337 ;;215 Wed Jun 20 21:22:58 2007 -0700: CONTENTS
 338 ;; i.e: VERSION_NUMBER DATE: CONTENTS
 339 ;; If the user has set the "--follow" option, the output looks like:
 340 ;;215 Wed Jun 20 21:22:58 2007 -0700 foo.c: CONTENTS
 341 ;; i.e. VERSION_NUMBER DATE FILENAME: CONTENTS
 342 (defconst vc-hg-annotate-re
 343   "^[ \t]*\\([0-9]+\\) \\(.\\{30\\}\\)\\(?:\\(: \\)\\|\\(?: +\\(.+\\): \\)\\)")
 344
 345 (defun vc-hg-annotate-time ()
 346   (when (looking-at vc-hg-annotate-re)
 347     (goto-char (match-end 0))
 348     (vc-annotate-convert-time
 349      (date-to-time (match-string-no-properties 2)))))
 350
 351 (defun vc-hg-annotate-extract-revision-at-line ()
 352   (save-excursion
 353     (beginning-of-line)
 354     (when (looking-at vc-hg-annotate-re)
 355       (if (match-beginning 3)
 356           (match-string-no-properties 1)
 357         (cons (match-string-no-properties 1)
 358               (expand-file-name (match-string-no-properties 4)))))))
 359
 360 (defun vc-hg-previous-revision (file rev)
 361   (let ((newrev (1- (string-to-number rev))))
 362     (when (>= newrev 0)
 363       (number-to-string newrev))))
 364
 365 (defun vc-hg-next-revision (file rev)
 366   (let ((newrev (1+ (string-to-number rev)))
 367         (tip-revision
 368          (with-temp-buffer
 369            (vc-hg-command t 0 nil "tip")
 370            (goto-char (point-min))
 371            (re-search-forward "^changeset:[ \t]*\\([0-9]+\\):")
 372            (string-to-number (match-string-no-properties 1)))))
 373     ;; We don't want to exceed the maximum possible revision number, ie
 374     ;; the tip revision.
 375     (when (<= newrev tip-revision)
 376       (number-to-string newrev))))
 377
 378 ;; Modeled after the similar function in vc-bzr.el
 379 (defun vc-hg-delete-file (file)
 380   "Delete FILE and delete it in the hg repository."
 381   (condition-case ()
 382       (delete-file file)
 383     (file-error nil))
 384   (vc-hg-command nil 0 file "remove" "--after" "--force"))
 385
 386 ;; Modeled after the similar function in vc-bzr.el
 387 (defun vc-hg-rename-file (old new)
 388   "Rename file from OLD to NEW using `hg mv'."
 389   (vc-hg-command nil 0 new "mv" old))
 390
 391 (defun vc-hg-register (files &optional rev comment)
 392   "Register FILES under hg.
 393 REV is ignored.
 394 COMMENT is ignored."
 395   (vc-hg-command nil 0 files "add"))
 396
 397 (defun vc-hg-create-repo ()
 398   "Create a new Mercurial repository."
 399   (vc-hg-command nil 0 nil "init"))
 400
 401 (defalias 'vc-hg-responsible-p 'vc-hg-root)
 402
 403 ;; Modeled after the similar function in vc-bzr.el
 404 (defun vc-hg-could-register (file)
 405   "Return non-nil if FILE could be registered under hg."
 406   (and (vc-hg-responsible-p file)      ; shortcut
 407        (condition-case ()
 408            (with-temp-buffer
 409              (vc-hg-command t nil file "add" "--dry-run"))
 410              ;; The command succeeds with no output if file is
 411              ;; registered.
 412          (error))))
 413
 414 ;; FIXME: This would remove the file. Is that correct?
 415 ;; (defun vc-hg-unregister (file)
 416 ;;   "Unregister FILE from hg."
 417 ;;   (vc-hg-command nil nil file "remove"))
 418
 419 (defun vc-hg-checkin (files rev comment &optional extra-args)
 420   "Hg-specific version of `vc-backend-checkin'.
 421 REV is ignored."
 422   (apply 'vc-hg-command nil 0 files  (append (list "commit" "-m" comment) extra-args)))
 423
 424 (defun vc-hg-find-revision (file rev buffer)
 425   (let ((coding-system-for-read 'binary)
 426         (coding-system-for-write 'binary))
 427     (if rev
 428         (vc-hg-command buffer 0 file "cat" "-r" rev)
 429       (vc-hg-command buffer 0 file "cat"))))
 430
 431 ;; Modeled after the similar function in vc-bzr.el
 432 (defun vc-hg-checkout (file &optional editable rev)
 433   "Retrieve a revision of FILE.
 434 EDITABLE is ignored.
 435 REV is the revision to check out into WORKFILE."
 436   (let ((coding-system-for-read 'binary)
 437         (coding-system-for-write 'binary))
 438   (with-current-buffer (or (get-file-buffer file) (current-buffer))
 439     (if rev
 440         (vc-hg-command t 0 file "cat" "-r" rev)
 441       (vc-hg-command t 0 file "cat")))))
 442
 443 ;; Modeled after the similar function in vc-bzr.el
 444 (defun vc-hg-workfile-unchanged-p (file)
 445   (eq 'up-to-date (vc-hg-state file)))
 446
 447 ;; Modeled after the similar function in vc-bzr.el
 448 (defun vc-hg-revert (file &optional contents-done)
 449   (unless contents-done
 450     (with-temp-buffer (vc-hg-command t 0 file "revert"))))
 451
 452 ;;; Hg specific functionality.
 453
 454 (defvar vc-hg-extra-menu-map
 455   (let ((map (make-sparse-keymap)))
 456     (define-key map [incoming] '(menu-item "Show incoming" vc-hg-incoming))
 457     (define-key map [outgoing] '(menu-item "Show outgoing" vc-hg-outgoing))
 458     map))
 459
 460 (defun vc-hg-extra-menu () vc-hg-extra-menu-map)
 461
 462 (defun vc-hg-extra-status-menu () vc-hg-extra-menu-map)
 463
 464 (defvar log-view-vc-backend)
 465
 466 (define-derived-mode vc-hg-outgoing-mode vc-hg-log-view-mode "Hg-Outgoing"
 467   "Mode for browsing Hg outgoing changes."
 468   (set (make-local-variable 'log-view-vc-backend) 'Hg))
 469
 470 (define-derived-mode vc-hg-incoming-mode vc-hg-log-view-mode "Hg-Incoming"
 471   "Mode for browsing Hg incoming changes."
 472   (set (make-local-variable 'log-view-vc-backend) 'Hg))
 473
 474 (defstruct (vc-hg-extra-fileinfo
 475             (:copier nil)
 476             (:constructor vc-hg-create-extra-fileinfo (rename-state extra-name))
 477             (:conc-name vc-hg-extra-fileinfo->))
 478   rename-state        ;; rename or copy state
 479   extra-name)         ;; original name for copies and rename targets, new name for
 480
 481 (declare-function vc-default-dir-printer "vc-dir" (backend fileentry))
 482
 483 (defun vc-hg-dir-printer (info)
 484   "Pretty-printer for the vc-dir-fileinfo structure."
 485   (let ((extra (vc-dir-fileinfo->extra info)))
 486     (vc-default-dir-printer 'Hg info)
 487     (when extra
 488       (insert (propertize
 489                (format "   (%s %s)"
 490                        (case (vc-hg-extra-fileinfo->rename-state extra)
 491                          ('copied "copied from")
 492                          ('renamed-from "renamed from")
 493                          ('renamed-to "renamed to"))
 494                        (vc-hg-extra-fileinfo->extra-name extra))
 495                'face 'font-lock-comment-face)))))
 496
 497 (defun vc-hg-after-dir-status (update-function)
 498   (let ((status-char nil)
 499         (file nil)
 500         (translation '((?= . up-to-date)
 501                        (?C . up-to-date)
 502                        (?A . added)
 503                        (?R . removed)
 504                        (?M . edited)
 505                        (?I . ignored)
 506                        (?! . missing)
 507                        (?  . copy-rename-line)
 508                        (?? . unregistered)))
 509         (translated nil)
 510         (result nil)
 511         (last-added nil)
 512         (last-line-copy nil))
 513       (goto-char (point-min))
 514       (while (not (eobp))
 515         (setq translated (cdr (assoc (char-after) translation)))
 516         (setq file
 517               (buffer-substring-no-properties (+ (point) 2)
 518                                               (line-end-position)))
 519         (cond ((not translated)
 520                (setq last-line-copy nil))
 521               ((eq translated 'up-to-date)
 522                (setq last-line-copy nil))
 523               ((eq translated 'copy-rename-line)
 524                ;; For copied files the output looks like this:
 525                ;; A COPIED_FILE_NAME
 526                ;;   ORIGINAL_FILE_NAME
 527                (setf (nth 2 last-added)
 528                      (vc-hg-create-extra-fileinfo 'copied file))
 529                (setq last-line-copy t))
 530               ((and last-line-copy (eq translated 'removed))
 531                ;; For renamed files the output looks like this:
 532                ;; A NEW_FILE_NAME
 533                ;;   ORIGINAL_FILE_NAME
 534                ;; R ORIGINAL_FILE_NAME
 535                ;; We need to adjust the previous entry to not think it is a copy.
 536                (setf (vc-hg-extra-fileinfo->rename-state (nth 2 last-added))
 537                      'renamed-from)
 538                (push (list file translated
 539                            (vc-hg-create-extra-fileinfo
 540                             'renamed-to (nth 0 last-added))) result)
 541                (setq last-line-copy nil))
 542               (t
 543                (setq last-added (list file translated nil))
 544                (push last-added result)
 545                (setq last-line-copy nil)))
 546         (forward-line))
 547       (funcall update-function result)))
 548
 549 (defun vc-hg-dir-status (dir update-function)
 550   (vc-hg-command (current-buffer) 'async dir "status" "-C")
 551   (vc-exec-after
 552    `(vc-hg-after-dir-status (quote ,update-function))))
 553
 554 (defun vc-hg-dir-status-files (dir files default-state update-function)
 555   (apply 'vc-hg-command (current-buffer) 'async dir "status" "-C" files)
 556   (vc-exec-after
 557    `(vc-hg-after-dir-status (quote ,update-function))))
 558
 559 (defun vc-hg-dir-extra-header (name &rest commands)
 560   (concat (propertize name 'face 'font-lock-type-face)
 561           (propertize
 562            (with-temp-buffer
 563              (apply 'vc-hg-command (current-buffer) 0 nil commands)
 564              (buffer-substring-no-properties (point-min) (1- (point-max))))
 565            'face 'font-lock-variable-name-face)))
 566
 567 (defun vc-hg-dir-extra-headers (dir)
 568   "Generate extra status headers for a Mercurial tree."
 569   (let ((default-directory dir))
 570     (concat
 571      (vc-hg-dir-extra-header "Root       : " "root") "\n"
 572      (vc-hg-dir-extra-header "Branch     : " "id" "-b") "\n"
 573      (vc-hg-dir-extra-header "Tags       : " "id" "-t") ; "\n"
 574      ;; these change after each commit
 575      ;; (vc-hg-dir-extra-header "Local num  : " "id" "-n") "\n"
 576      ;; (vc-hg-dir-extra-header "Global id  : " "id" "-i")
 577      )))
 578
 579 ;; FIXME: this adds another top level menu, instead figure out how to
 580 ;; replace the Log-View menu.
 581 (easy-menu-define log-view-mode-menu vc-hg-outgoing-mode-map
 582   "Hg-outgoing Display Menu"
 583   `("Hg-outgoing"
 584     ["Push selected"  vc-hg-push]))
 585
 586 (easy-menu-define log-view-mode-menu vc-hg-incoming-mode-map
 587   "Hg-incoming Display Menu"
 588   `("Hg-incoming"
 589     ["Pull selected"  vc-hg-pull]))
 590
 591 (defun vc-hg-outgoing ()
 592   (interactive)
 593   (let ((bname "*Hg outgoing*")
 594         (vc-short-log nil))
 595     (vc-hg-command bname 1 nil "outgoing" "-n")
 596     (pop-to-buffer bname)
 597     (vc-hg-outgoing-mode)))
 598
 599 (defun vc-hg-incoming ()
 600   (interactive)
 601   (let ((bname "*Hg incoming*")
 602         (vc-short-log nil))
 603     (vc-hg-command bname 0 nil "incoming" "-n")
 604     (pop-to-buffer bname)
 605     (vc-hg-incoming-mode)))
 606
 607 (declare-function log-view-get-marked "log-view" ())
 608
 609 ;; XXX maybe also add key bindings for these functions.
 610 (defun vc-hg-push ()
 611   (interactive)
 612   (let ((marked-list (log-view-get-marked)))
 613     (if marked-list
 614         (vc-hg-command
 615          nil 0 nil
 616          (cons "push"
 617                (apply 'nconc
 618                       (mapcar (lambda (arg) (list "-r" arg)) marked-list))))
 619          (error "No log entries selected for push"))))
 620
 621 (defun vc-hg-pull ()
 622   (interactive)
 623   (let ((marked-list (log-view-get-marked)))
 624     (if marked-list
 625         (vc-hg-command
 626          nil 0 nil
 627          (cons "pull"
 628                (apply 'nconc
 629                       (mapcar (lambda (arg) (list "-r" arg)) marked-list))))
 630       (error "No log entries selected for pull"))))
 631
 632 ;;; Internal functions
 633
 634 (defun vc-hg-command (buffer okstatus file-or-list &rest flags)
 635   "A wrapper around `vc-do-command' for use in vc-hg.el.
 636 The difference to vc-do-command is that this function always invokes `hg',
 637 and that it passes `vc-hg-global-switches' to it before FLAGS."
 638   (apply 'vc-do-command (or buffer "*vc*") okstatus "hg" file-or-list
 639          (if (stringp vc-hg-global-switches)
 640              (cons vc-hg-global-switches flags)
 641            (append vc-hg-global-switches
 642                    flags))))
 643
 644 (defun vc-hg-root (file)
 645   (vc-find-root file ".hg"))
 646
 647 (provide 'vc-hg)
 648
 649 ;; arch-tag: bd094dc5-715a-434f-a331-37b9fb7cd954
 650 ;;; vc-hg.el ends here