lisp/hi-lock.el

   1 ;;; hi-lock.el --- minor mode for interactive automatic highlighting
   2
   3 ;; Copyright (C) 2000-2012 Free Software Foundation, Inc.
   4
   5 ;; Author: David M. Koppelman <koppel@ece.lsu.edu>
   6 ;; Keywords: faces, minor-mode, matching, display
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24 ;;
  25 ;;  With the hi-lock commands text matching interactively entered
  26 ;;  regexp's can be highlighted.  For example, `M-x highlight-regexp
  27 ;;  RET clearly RET RET' will highlight all occurrences of `clearly'
  28 ;;  using a yellow background face.  New occurrences of `clearly' will
  29 ;;  be highlighted as they are typed.  `M-x unhighlight-regexp RET'
  30 ;;  will remove the highlighting.  Any existing face can be used for
  31 ;;  highlighting and a set of appropriate faces is provided.  The
  32 ;;  regexps can be written into the current buffer in a form that will
  33 ;;  be recognized the next time the corresponding file is read (when
  34 ;;  file patterns is turned on).
  35 ;;
  36 ;;  Applications:
  37 ;;
  38 ;;    In program source code highlight a variable to quickly see all
  39 ;;    places it is modified or referenced:
  40 ;;    M-x highlight-regexp ground_contact_switches_closed RET RET
  41 ;;
  42 ;;    In a shell or other buffer that is showing lots of program
  43 ;;    output, highlight the parts of the output you're interested in:
  44 ;;    M-x highlight-regexp Total execution time [0-9]+ RET hi-blue-b RET
  45 ;;
  46 ;;    In buffers displaying tables, highlight the lines you're interested in:
  47 ;;    M-x highlight-lines-matching-regexp January 2000 RET hi-black-b RET
  48 ;;
  49 ;;    When writing text, highlight personal cliches.  This can be
  50 ;;    amusing.
  51 ;;    M-x highlight-phrase as can be seen RET RET
  52 ;;
  53 ;;  Setup:
  54 ;;
  55 ;;    Put the following code in your .emacs file.  This turns on
  56 ;;    hi-lock mode and adds a "Regexp Highlighting" entry
  57 ;;    to the edit menu.
  58 ;;
  59 ;;    (global-hi-lock-mode 1)
  60 ;;
  61 ;;    To enable the use of patterns found in files (presumably placed
  62 ;;    there by hi-lock) include the following in your .emacs file:
  63 ;;
  64 ;;    (setq hi-lock-file-patterns-policy 'ask)
  65 ;;
  66 ;;    If you get tired of being asked each time a file is loaded replace
  67 ;;    `ask' with a function that returns t if patterns should be read.
  68 ;;
  69 ;;    You might also want to bind the hi-lock commands to more
  70 ;;    finger-friendly sequences:
  71
  72 ;;    (define-key hi-lock-map "\C-z\C-h" 'highlight-lines-matching-regexp)
  73 ;;    (define-key hi-lock-map "\C-zi" 'hi-lock-find-patterns)
  74 ;;    (define-key hi-lock-map "\C-zh" 'highlight-regexp)
  75 ;;    (define-key hi-lock-map "\C-zp" 'highlight-phrase)
  76 ;;    (define-key hi-lock-map "\C-zr" 'unhighlight-regexp)
  77 ;;    (define-key hi-lock-map "\C-zb" 'hi-lock-write-interactive-patterns))
  78
  79 ;;    See the documentation for hi-lock-mode `C-h f hi-lock-mode' for
  80 ;;    additional instructions.
  81
  82 ;; Sample file patterns:
  83
  84 ; Hi-lock: (("^;;; .*" (0 (quote hi-black-hb) t)))
  85 ; Hi-lock: ( ("make-variable-buffer-\\(local\\)" (0 font-lock-keyword-face)(1 'italic append)))))
  86 ; Hi-lock: end
  87
  88 ;;; Code:
  89
  90 (require 'font-lock)
  91
  92 (defgroup hi-lock nil
  93   "Interactively add and remove font-lock patterns for highlighting text."
  94   :link '(custom-manual "(emacs)Highlight Interactively")
  95   :group 'font-lock)
  96
  97 (defcustom hi-lock-file-patterns-range 10000
  98   "Limit of search in a buffer for hi-lock patterns.
  99 When a file is visited and hi-lock mode is on, patterns starting
 100 up to this limit are added to font-lock's patterns.  See documentation
 101 of functions `hi-lock-mode' and `hi-lock-find-patterns'."
 102   :type 'integer
 103   :group 'hi-lock)
 104
 105 (defcustom hi-lock-highlight-range 200000
 106   "Size of area highlighted by hi-lock when font-lock not active.
 107 Font-lock is not active in buffers that do their own highlighting,
 108 such as the buffer created by `list-colors-display'.  In those buffers
 109 hi-lock patterns will only be applied over a range of
 110 `hi-lock-highlight-range' characters.  If font-lock is active then
 111 highlighting will be applied throughout the buffer."
 112   :type 'integer
 113   :group 'hi-lock)
 114
 115 (defcustom hi-lock-exclude-modes
 116   '(rmail-mode mime/viewer-mode gnus-article-mode)
 117   "List of major modes in which hi-lock will not run.
 118 For security reasons since font lock patterns can specify function
 119 calls."
 120   :type '(repeat symbol)
 121   :group 'hi-lock)
 122
 123 (defcustom hi-lock-file-patterns-policy 'ask
 124   "Specify when hi-lock should use patterns found in file.
 125 If `ask', prompt when patterns found in buffer; if bound to a function,
 126 use patterns when function returns t (function is called with patterns
 127 as first argument); if nil or `never' or anything else, don't use file
 128 patterns."
 129   :type '(choice (const :tag "Do not use file patterns" never)
 130                  (const :tag "Ask about file patterns" ask)
 131                  (function :tag "Function to check file patterns"))
 132   :group 'hi-lock
 133   :version "22.1")
 134
 135 ;; It can have a function value.
 136 (put 'hi-lock-file-patterns-policy 'risky-local-variable t)
 137
 138 (defgroup hi-lock-faces nil
 139   "Faces for hi-lock."
 140   :group 'hi-lock
 141   :group 'faces)
 142
 143 (defface hi-yellow
 144   '((((min-colors 88) (background dark))
 145      (:background "yellow1" :foreground "black"))
 146     (((background dark)) (:background "yellow" :foreground "black"))
 147     (((min-colors 88)) (:background "yellow1"))
 148     (t (:background "yellow")))
 149   "Default face for hi-lock mode."
 150   :group 'hi-lock-faces)
 151
 152 (defface hi-pink
 153   '((((background dark)) (:background "pink" :foreground "black"))
 154     (t (:background "pink")))
 155   "Face for hi-lock mode."
 156   :group 'hi-lock-faces)
 157
 158 (defface hi-green
 159   '((((min-colors 88) (background dark))
 160      (:background "green1" :foreground "black"))
 161     (((background dark)) (:background "green" :foreground "black"))
 162     (((min-colors 88)) (:background "green1"))
 163     (t (:background "green")))
 164   "Face for hi-lock mode."
 165   :group 'hi-lock-faces)
 166
 167 (defface hi-blue
 168   '((((background dark)) (:background "light blue" :foreground "black"))
 169     (t (:background "light blue")))
 170   "Face for hi-lock mode."
 171   :group 'hi-lock-faces)
 172
 173 (defface hi-black-b
 174   '((t (:weight bold)))
 175   "Face for hi-lock mode."
 176   :group 'hi-lock-faces)
 177
 178 (defface hi-blue-b
 179   '((((min-colors 88)) (:weight bold :foreground "blue1"))
 180     (t (:weight bold :foreground "blue")))
 181   "Face for hi-lock mode."
 182   :group 'hi-lock-faces)
 183
 184 (defface hi-green-b
 185   '((((min-colors 88)) (:weight bold :foreground "green1"))
 186     (t (:weight bold :foreground "green")))
 187   "Face for hi-lock mode."
 188   :group 'hi-lock-faces)
 189
 190 (defface hi-red-b
 191   '((((min-colors 88)) (:weight bold :foreground "red1"))
 192     (t (:weight bold :foreground "red")))
 193   "Face for hi-lock mode."
 194   :group 'hi-lock-faces)
 195
 196 (defface hi-black-hb
 197   '((t (:weight bold :height 1.67 :inherit variable-pitch)))
 198   "Face for hi-lock mode."
 199   :group 'hi-lock-faces)
 200
 201 (defvar hi-lock-file-patterns nil
 202   "Patterns found in file for hi-lock.  Should not be changed.")
 203
 204 (defvar hi-lock-interactive-patterns nil
 205   "Patterns provided to hi-lock by user.  Should not be changed.")
 206
 207 (define-obsolete-variable-alias 'hi-lock-face-history
 208                                 'hi-lock-face-defaults "23.1")
 209 (defvar hi-lock-face-defaults
 210   '("hi-yellow" "hi-pink" "hi-green" "hi-blue" "hi-black-b"
 211     "hi-blue-b" "hi-red-b" "hi-green-b" "hi-black-hb")
 212   "Default faces for hi-lock interactive functions.")
 213
 214 ;;(dolist (f hi-lock-face-defaults)
 215 ;;  (unless (facep f) (error "%s not a face" f)))
 216
 217 (define-obsolete-variable-alias 'hi-lock-regexp-history
 218                                 'regexp-history
 219                                 "23.1")
 220
 221 (defvar hi-lock-file-patterns-prefix "Hi-lock"
 222   "Search target for finding hi-lock patterns at top of file.")
 223
 224 (defvar hi-lock-archaic-interface-message-used nil
 225   "True if user alerted that `global-hi-lock-mode' is now the global switch.
 226 Earlier versions of hi-lock used `hi-lock-mode' as the global switch;
 227 the message is issued if it appears that `hi-lock-mode' is used assuming
 228 that older functionality.  This variable avoids multiple reminders.")
 229
 230 (defvar hi-lock-archaic-interface-deduce nil
 231   "If non-nil, sometimes assume that `hi-lock-mode' means `global-hi-lock-mode'.
 232 Assumption is made if `hi-lock-mode' used in the *scratch* buffer while
 233 a library is being loaded.")
 234
 235 (make-variable-buffer-local 'hi-lock-interactive-patterns)
 236 (put 'hi-lock-interactive-patterns 'permanent-local t)
 237 (make-variable-buffer-local 'hi-lock-file-patterns)
 238 (put 'hi-lock-file-patterns 'permanent-local t)
 239
 240 (defvar hi-lock-menu
 241   (let ((map (make-sparse-keymap "Hi Lock")))
 242     (define-key-after map [highlight-regexp]
 243       '(menu-item "Highlight Regexp..." highlight-regexp
 244         :help "Highlight text matching PATTERN (a regexp)."))
 245
 246     (define-key-after map [highlight-phrase]
 247       '(menu-item "Highlight Phrase..." highlight-phrase
 248         :help "Highlight text matching PATTERN (a regexp processed to match phrases)."))
 249
 250     (define-key-after map [highlight-lines-matching-regexp]
 251       '(menu-item "Highlight Lines..." highlight-lines-matching-regexp
 252         :help "Highlight lines containing match of PATTERN (a regexp)."))
 253
 254     (define-key-after map [unhighlight-regexp]
 255       '(menu-item "Remove Highlighting..." unhighlight-regexp
 256         :help "Remove previously entered highlighting pattern."
 257         :enable hi-lock-interactive-patterns))
 258
 259     (define-key-after map [hi-lock-write-interactive-patterns]
 260       '(menu-item "Patterns to Buffer" hi-lock-write-interactive-patterns
 261         :help "Insert interactively added REGEXPs into buffer at point."
 262         :enable hi-lock-interactive-patterns))
 263
 264     (define-key-after map [hi-lock-find-patterns]
 265       '(menu-item "Patterns from Buffer" hi-lock-find-patterns
 266         :help "Use patterns (if any) near top of buffer."))
 267     map)
 268   "Menu for hi-lock mode.")
 269
 270 (defvar hi-lock-map
 271   (let ((map (make-sparse-keymap "Hi Lock")))
 272     (define-key map "\C-xwi" 'hi-lock-find-patterns)
 273     (define-key map "\C-xwl" 'highlight-lines-matching-regexp)
 274     (define-key map "\C-xwp" 'highlight-phrase)
 275     (define-key map "\C-xwh" 'highlight-regexp)
 276     (define-key map "\C-xwr" 'unhighlight-regexp)
 277     (define-key map "\C-xwb" 'hi-lock-write-interactive-patterns)
 278     map)
 279   "Key map for hi-lock.")
 280
 281 ;; Visible Functions
 282
 283 ;;;###autoload
 284 (define-minor-mode hi-lock-mode
 285   "Toggle selective highlighting of patterns (Hi Lock mode).
 286 With a prefix argument ARG, enable Hi Lock mode if ARG is
 287 positive, and disable it otherwise.  If called from Lisp, enable
 288 the mode if ARG is omitted or nil.
 289
 290 Issuing one the highlighting commands listed below will
 291 automatically enable Hi Lock mode.  To enable Hi Lock mode in all
 292 buffers, use `global-hi-lock-mode' or add (global-hi-lock-mode 1)
 293 to your init file.  When Hi Lock mode is enabled, a \"Regexp
 294 Highlighting\" submenu is added to the \"Edit\" menu.  The
 295 commands in the submenu, which can be called interactively, are:
 296
 297 \\[highlight-regexp] REGEXP FACE
 298   Highlight matches of pattern REGEXP in current buffer with FACE.
 299
 300 \\[highlight-phrase] PHRASE FACE
 301   Highlight matches of phrase PHRASE in current buffer with FACE.
 302   (PHRASE can be any REGEXP, but spaces will be replaced by matches
 303   to whitespace and initial lower-case letters will become case insensitive.)
 304
 305 \\[highlight-lines-matching-regexp] REGEXP FACE
 306   Highlight lines containing matches of REGEXP in current buffer with FACE.
 307
 308 \\[unhighlight-regexp] REGEXP
 309   Remove highlighting on matches of REGEXP in current buffer.
 310
 311 \\[hi-lock-write-interactive-patterns]
 312   Write active REGEXPs into buffer as comments (if possible).  They may
 313   be read the next time file is loaded or when the \\[hi-lock-find-patterns] command
 314   is issued.  The inserted regexps are in the form of font lock keywords.
 315   (See `font-lock-keywords'.)  They may be edited and re-loaded with \\[hi-lock-find-patterns],
 316   any valid `font-lock-keywords' form is acceptable.  When a file is
 317   loaded the patterns are read if `hi-lock-file-patterns-policy' is
 318   'ask and the user responds y to the prompt, or if
 319   `hi-lock-file-patterns-policy' is bound to a function and that
 320   function returns t.
 321
 322 \\[hi-lock-find-patterns]
 323   Re-read patterns stored in buffer (in the format produced by \\[hi-lock-write-interactive-patterns]).
 324
 325 When hi-lock is started and if the mode is not excluded or patterns
 326 rejected, the beginning of the buffer is searched for lines of the
 327 form:
 328   Hi-lock: FOO
 329 where FOO is a list of patterns.  These are added to the font lock
 330 keywords already present.  The patterns must start before position
 331 \(number of characters into buffer) `hi-lock-file-patterns-range'.
 332 Patterns will be read until
 333  Hi-lock: end
 334 is found.  A mode is excluded if it's in the list `hi-lock-exclude-modes'."
 335   :group 'hi-lock
 336   :lighter (:eval (if (or hi-lock-interactive-patterns
 337                           hi-lock-file-patterns)
 338                       " Hi" ""))
 339   :global nil
 340   :keymap hi-lock-map
 341   (when (and (equal (buffer-name) "*scratch*")
 342              load-in-progress
 343              (not (called-interactively-p 'interactive))
 344              (not hi-lock-archaic-interface-message-used))
 345     (setq hi-lock-archaic-interface-message-used t)
 346     (if hi-lock-archaic-interface-deduce
 347         (global-hi-lock-mode hi-lock-mode)
 348       (warn
 349        "Possible archaic use of (hi-lock-mode).
 350 Use (global-hi-lock-mode 1) in .emacs to enable hi-lock for all buffers,
 351 use (hi-lock-mode 1) for individual buffers.  For compatibility with Emacs
 352 versions before 22 use the following in your .emacs file:
 353
 354         (if (functionp 'global-hi-lock-mode)
 355             (global-hi-lock-mode 1)
 356           (hi-lock-mode 1))
 357 ")))
 358   (if hi-lock-mode
 359       ;; Turned on.
 360       (progn
 361         (unless font-lock-mode (font-lock-mode 1))
 362         (define-key-after menu-bar-edit-menu [hi-lock]
 363           (cons "Regexp Highlighting" hi-lock-menu))
 364         (hi-lock-find-patterns)
 365         (add-hook 'font-lock-mode-hook 'hi-lock-font-lock-hook nil t))
 366     ;; Turned off.
 367     (when (or hi-lock-interactive-patterns
 368               hi-lock-file-patterns)
 369       (when hi-lock-interactive-patterns
 370         (font-lock-remove-keywords nil hi-lock-interactive-patterns)
 371         (setq hi-lock-interactive-patterns nil))
 372       (when hi-lock-file-patterns
 373         (font-lock-remove-keywords nil hi-lock-file-patterns)
 374         (setq hi-lock-file-patterns nil))
 375       (remove-overlays nil nil 'hi-lock-overlay t)
 376       (when font-lock-fontified (font-lock-fontify-buffer)))
 377     (define-key-after menu-bar-edit-menu [hi-lock] nil)
 378     (remove-hook 'font-lock-mode-hook 'hi-lock-font-lock-hook t)))
 379
 380 ;;;###autoload
 381 (define-globalized-minor-mode global-hi-lock-mode
 382   hi-lock-mode turn-on-hi-lock-if-enabled
 383   :group 'hi-lock)
 384
 385 (defun turn-on-hi-lock-if-enabled ()
 386   (setq hi-lock-archaic-interface-message-used t)
 387   (unless (memq major-mode hi-lock-exclude-modes)
 388     (hi-lock-mode 1)))
 389
 390 ;;;###autoload
 391 (defalias 'highlight-lines-matching-regexp 'hi-lock-line-face-buffer)
 392 ;;;###autoload
 393 (defun hi-lock-line-face-buffer (regexp &optional face)
 394   "Set face of all lines containing a match of REGEXP to FACE.
 395
 396 Interactively, prompt for REGEXP then FACE.  Buffer-local history
 397 list maintained for regexps, global history maintained for faces.
 398 \\<minibuffer-local-map>Use \\[previous-history-element] to retrieve previous history items,
 399 and \\[next-history-element] to retrieve default values.
 400 \(See info node `Minibuffer History'.)"
 401   (interactive
 402    (list
 403     (hi-lock-regexp-okay
 404      (read-regexp "Regexp to highlight line" (car regexp-history)))
 405     (hi-lock-read-face-name)))
 406   (or (facep face) (setq face 'hi-yellow))
 407   (unless hi-lock-mode (hi-lock-mode 1))
 408   (hi-lock-set-pattern
 409    ;; The \\(?:...\\) grouping construct ensures that a leading ^, +, * or ?
 410    ;; or a trailing $ in REGEXP will be interpreted correctly.
 411    (concat "^.*\\(?:" regexp "\\).*$") face))
 412
 413
 414 ;;;###autoload
 415 (defalias 'highlight-regexp 'hi-lock-face-buffer)
 416 ;;;###autoload
 417 (defun hi-lock-face-buffer (regexp &optional face)
 418   "Set face of each match of REGEXP to FACE.
 419
 420 Interactively, prompt for REGEXP then FACE.  Buffer-local history
 421 list maintained for regexps, global history maintained for faces.
 422 \\<minibuffer-local-map>Use \\[previous-history-element] to retrieve previous history items,
 423 and \\[next-history-element] to retrieve default values.
 424 \(See info node `Minibuffer History'.)"
 425   (interactive
 426    (list
 427     (hi-lock-regexp-okay
 428      (read-regexp "Regexp to highlight" (car regexp-history)))
 429     (hi-lock-read-face-name)))
 430   (or (facep face) (setq face 'hi-yellow))
 431   (unless hi-lock-mode (hi-lock-mode 1))
 432   (hi-lock-set-pattern regexp face))
 433
 434 ;;;###autoload
 435 (defalias 'highlight-phrase 'hi-lock-face-phrase-buffer)
 436 ;;;###autoload
 437 (defun hi-lock-face-phrase-buffer (regexp &optional face)
 438   "Set face of each match of phrase REGEXP to FACE.
 439
 440 Whitespace in REGEXP converted to arbitrary whitespace and initial
 441 lower-case letters made case insensitive."
 442   (interactive
 443    (list
 444     (hi-lock-regexp-okay
 445      (hi-lock-process-phrase
 446       (read-regexp "Phrase to highlight" (car regexp-history))))
 447     (hi-lock-read-face-name)))
 448   (or (facep face) (setq face 'hi-yellow))
 449   (unless hi-lock-mode (hi-lock-mode 1))
 450   (hi-lock-set-pattern regexp face))
 451
 452 (declare-function x-popup-menu "menu.c" (position menu))
 453
 454 ;;;###autoload
 455 (defalias 'unhighlight-regexp 'hi-lock-unface-buffer)
 456 ;;;###autoload
 457 (defun hi-lock-unface-buffer (regexp)
 458   "Remove highlighting of each match to REGEXP set by hi-lock.
 459
 460 Interactively, prompt for REGEXP.  Buffer-local history of inserted
 461 regexp's maintained.  Will accept only regexps inserted by hi-lock
 462 interactive functions.  \(See `hi-lock-interactive-patterns'.\)
 463 \\<minibuffer-local-must-match-map>Use \\[minibuffer-complete] to complete a partially typed regexp.
 464 \(See info node `Minibuffer History'.\)"
 465   (interactive
 466    (if (and (display-popup-menus-p)
 467             (listp last-nonmenu-event)
 468             use-dialog-box)
 469        (catch 'snafu
 470          (or
 471           (x-popup-menu
 472            t
 473            (cons
 474             `keymap
 475             (cons "Select Pattern to Unhighlight"
 476                   (mapcar (lambda (pattern)
 477                             (list (car pattern)
 478                                   (format
 479                                    "%s (%s)" (car pattern)
 480                                    (symbol-name
 481                                     (car
 482                                      (cdr (car (cdr (car (cdr pattern))))))))
 483                                   (cons nil nil)
 484                                   (car pattern)))
 485                           hi-lock-interactive-patterns))))
 486           ;; If the user clicks outside the menu, meaning that they
 487           ;; change their mind, x-popup-menu returns nil, and
 488           ;; interactive signals a wrong number of arguments error.
 489           ;; To prevent that, we return an empty string, which will
 490           ;; effectively disable the rest of the function.
 491           (throw 'snafu '(""))))
 492      (let ((history-list (mapcar (lambda (p) (car p))
 493                                  hi-lock-interactive-patterns)))
 494        (unless hi-lock-interactive-patterns
 495          (error "No highlighting to remove"))
 496        (list
 497         (completing-read "Regexp to unhighlight: "
 498                          hi-lock-interactive-patterns nil t
 499                          (car (car hi-lock-interactive-patterns))
 500                          (cons 'history-list 1))))))
 501   (let ((keyword (assoc regexp hi-lock-interactive-patterns)))
 502     (when keyword
 503       (font-lock-remove-keywords nil (list keyword))
 504       (setq hi-lock-interactive-patterns
 505             (delq keyword hi-lock-interactive-patterns))
 506       (remove-overlays
 507        nil nil 'hi-lock-overlay-regexp (hi-lock-string-serialize regexp))
 508       (when font-lock-fontified (font-lock-fontify-buffer)))))
 509
 510 ;;;###autoload
 511 (defun hi-lock-write-interactive-patterns ()
 512   "Write interactively added patterns, if any, into buffer at point.
 513
 514 Interactively added patterns are those normally specified using
 515 `highlight-regexp' and `highlight-lines-matching-regexp'; they can
 516 be found in variable `hi-lock-interactive-patterns'."
 517   (interactive)
 518   (if (null hi-lock-interactive-patterns)
 519       (error "There are no interactive patterns"))
 520   (let ((beg (point)))
 521     (mapc
 522      (lambda (pattern)
 523        (insert (format "%s: (%s)\n"
 524                        hi-lock-file-patterns-prefix
 525                        (prin1-to-string pattern))))
 526      hi-lock-interactive-patterns)
 527     (comment-region beg (point)))
 528   (when (> (point) hi-lock-file-patterns-range)
 529     (warn "Inserted keywords not close enough to top of file")))
 530
 531 ;; Implementation Functions
 532
 533 (defun hi-lock-process-phrase (phrase)
 534   "Convert regexp PHRASE to a regexp that matches phrases.
 535
 536 Blanks in PHRASE replaced by regexp that matches arbitrary whitespace
 537 and initial lower-case letters made case insensitive."
 538   (let ((mod-phrase nil))
 539     (setq mod-phrase
 540           (replace-regexp-in-string
 541            "\\<[a-z]" (lambda (m) (format "[%s%s]" (upcase m) m)) phrase))
 542     (setq mod-phrase
 543           (replace-regexp-in-string
 544            "\\s-+" "[ \t\n]+" mod-phrase nil t))))
 545
 546 (defun hi-lock-regexp-okay (regexp)
 547   "Return REGEXP if it appears suitable for a font-lock pattern.
 548
 549 Otherwise signal an error.  A pattern that matches the null string is
 550 not suitable."
 551   (if (string-match regexp "")
 552       (error "Regexp cannot match an empty string")
 553     regexp))
 554
 555 (defun hi-lock-read-face-name ()
 556   "Read face name from minibuffer with completion and history."
 557   (intern (completing-read
 558            "Highlight using face: "
 559            obarray 'facep t
 560            (cons (car hi-lock-face-defaults)
 561                  (let ((prefix
 562                         (try-completion
 563                          (substring (car hi-lock-face-defaults) 0 1)
 564                          hi-lock-face-defaults)))
 565                    (if (and (stringp prefix)
 566                             (not (equal prefix (car hi-lock-face-defaults))))
 567                        (length prefix) 0)))
 568            'face-name-history
 569            (cdr hi-lock-face-defaults))))
 570
 571 (defun hi-lock-set-pattern (regexp face)
 572   "Highlight REGEXP with face FACE."
 573   (let ((pattern (list regexp (list 0 (list 'quote face) t))))
 574     (unless (member pattern hi-lock-interactive-patterns)
 575       (push pattern hi-lock-interactive-patterns)
 576       (if font-lock-fontified
 577           (progn
 578             (font-lock-add-keywords nil (list pattern) t)
 579             (font-lock-fontify-buffer))
 580         (let* ((serial (hi-lock-string-serialize regexp))
 581                (range-min (- (point) (/ hi-lock-highlight-range 2)))
 582                (range-max (+ (point) (/ hi-lock-highlight-range 2)))
 583                (search-start
 584                 (max (point-min)
 585                      (- range-min (max 0 (- range-max (point-max))))))
 586                (search-end
 587                 (min (point-max)
 588                      (+ range-max (max 0 (- (point-min) range-min))))))
 589           (save-excursion
 590             (goto-char search-start)
 591             (while (re-search-forward regexp search-end t)
 592               (let ((overlay (make-overlay (match-beginning 0) (match-end 0))))
 593                 (overlay-put overlay 'hi-lock-overlay t)
 594                 (overlay-put overlay 'hi-lock-overlay-regexp serial)
 595                 (overlay-put overlay 'face face))
 596               (goto-char (match-end 0)))))))))
 597
 598 (defun hi-lock-set-file-patterns (patterns)
 599   "Replace file patterns list with PATTERNS and refontify."
 600   (when (or hi-lock-file-patterns patterns)
 601     (font-lock-remove-keywords nil hi-lock-file-patterns)
 602     (setq hi-lock-file-patterns patterns)
 603     (font-lock-add-keywords nil hi-lock-file-patterns t)
 604     (font-lock-fontify-buffer)))
 605
 606 (defun hi-lock-find-patterns ()
 607   "Find patterns in current buffer for hi-lock."
 608   (interactive)
 609   (unless (memq major-mode hi-lock-exclude-modes)
 610     (let ((all-patterns nil)
 611           (target-regexp (concat "\\<" hi-lock-file-patterns-prefix ":")))
 612       (save-excursion
 613         (save-restriction
 614           (widen)
 615           (goto-char (point-min))
 616           (re-search-forward target-regexp
 617                              (+ (point) hi-lock-file-patterns-range) t)
 618           (beginning-of-line)
 619           (while (and (re-search-forward target-regexp (+ (point) 100) t)
 620                       (not (looking-at "\\s-*end")))
 621             (condition-case nil
 622                 (setq all-patterns (append (read (current-buffer)) all-patterns))
 623               (error (message "Invalid pattern list expression at %d"
 624                               (line-number-at-pos)))))))
 625       (when (and all-patterns
 626                  hi-lock-mode
 627                  (cond
 628                   ((eq this-command 'hi-lock-find-patterns) t)
 629                   ((functionp hi-lock-file-patterns-policy)
 630                    (funcall hi-lock-file-patterns-policy all-patterns))
 631                   ((eq hi-lock-file-patterns-policy 'ask)
 632                    (y-or-n-p "Add patterns from this buffer to hi-lock? "))
 633                   (t nil)))
 634         (hi-lock-set-file-patterns all-patterns)
 635         (if (called-interactively-p 'interactive)
 636             (message "Hi-lock added %d patterns." (length all-patterns)))))))
 637
 638 (defun hi-lock-font-lock-hook ()
 639   "Add hi-lock patterns to font-lock's."
 640   (when font-lock-fontified
 641     (font-lock-add-keywords nil hi-lock-file-patterns t)
 642     (font-lock-add-keywords nil hi-lock-interactive-patterns t)))
 643
 644 (defvar hi-lock-string-serialize-hash
 645   (make-hash-table :test 'equal)
 646   "Hash table used to assign unique numbers to strings.")
 647
 648 (defvar hi-lock-string-serialize-serial 1
 649   "Number assigned to last new string in call to `hi-lock-string-serialize'.
 650 A string is considered new if it had not previously been used in a call to
 651 `hi-lock-string-serialize'.")
 652
 653 (defun hi-lock-string-serialize (string)
 654   "Return unique serial number for STRING."
 655   (interactive)
 656   (let ((val (gethash string hi-lock-string-serialize-hash)))
 657     (if val val
 658       (puthash string
 659                (setq hi-lock-string-serialize-serial
 660                      (1+ hi-lock-string-serialize-serial))
 661                hi-lock-string-serialize-hash)
 662       hi-lock-string-serialize-serial)))
 663
 664 (defun hi-lock-unload-function ()
 665   "Unload the Hi-Lock library."
 666   (global-hi-lock-mode -1)
 667   ;; continue standard unloading
 668   nil)
 669
 670 (provide 'hi-lock)
 671
 672 ;;; hi-lock.el ends here