m4/multiarch.m4

   1 # multiarch.m4
   2 # serial 9
   3 dnl Copyright (C) 2008-2024 Free Software Foundation, Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 # Determine whether the compiler is or may be producing universal binaries.
   9 #
  10 # On Mac OS X 10.5 and later systems, the user can create libraries and
  11 # executables that work on multiple system types--known as "fat" or
  12 # "universal" binaries--by specifying multiple '-arch' options to the
  13 # compiler but only a single '-arch' option to the preprocessor.  Like
  14 # this:
  15 #
  16 #     ./configure CC="gcc -arch i386 -arch x86_64 -arch ppc -arch ppc64" \
  17 #                 CXX="g++ -arch i386 -arch x86_64 -arch ppc -arch ppc64" \
  18 #                 CPP="gcc -E" CXXCPP="g++ -E"
  19 #
  20 # Detect this situation and set APPLE_UNIVERSAL_BUILD accordingly.
  21
  22 AC_DEFUN_ONCE([gl_MULTIARCH],
  23 [
  24   dnl Code similar to autoconf-2.63 AC_C_BIGENDIAN.
  25   AC_CACHE_CHECK([whether the compiler produces multi-arch binaries],
  26     [gl_cv_c_multiarch],
  27     [gl_cv_c_multiarch=no
  28      AC_COMPILE_IFELSE(
  29        [AC_LANG_SOURCE(
  30          [[#ifndef __APPLE_CC__
  31             not a universal capable compiler
  32            #endif
  33            typedef int dummy;
  34          ]])],
  35        [
  36         dnl Check for potential -arch flags.  It is not universal unless
  37         dnl there are at least two -arch flags with different values.
  38         arch=
  39         prev=
  40         for word in ${CC} ${CFLAGS} ${CPPFLAGS} ${LDFLAGS}; do
  41           if test -n "$prev"; then
  42             case $word in
  43               i?86 | x86_64 | ppc | ppc64 | arm | arm64)
  44                 if test -z "$arch" || test "$arch" = "$word"; then
  45                   arch="$word"
  46                 else
  47                   gl_cv_c_multiarch=yes
  48                 fi
  49                 ;;
  50             esac
  51             prev=
  52           else
  53             if test "x$word" = "x-arch"; then
  54               prev=arch
  55             fi
  56           fi
  57         done
  58        ])
  59     ])
  60   if test $gl_cv_c_multiarch = yes; then
  61     APPLE_UNIVERSAL_BUILD=1
  62   else
  63     APPLE_UNIVERSAL_BUILD=0
  64   fi
  65   AC_SUBST([APPLE_UNIVERSAL_BUILD])
  66 ])