m4/inttypes.m4

   1 # inttypes.m4
   2 # serial 37
   3 dnl Copyright (C) 2006-2024 Free Software Foundation, Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 dnl From Derek Price, Bruno Haible.
   9 dnl Test whether <inttypes.h> is supported or must be substituted.
  10
  11 AC_DEFUN_ONCE([gl_INTTYPES_H],
  12 [
  13   AC_REQUIRE([gl_INTTYPES_INCOMPLETE])
  14   gl_INTTYPES_PRI_SCN
  15 ])
  16
  17 AC_DEFUN_ONCE([gl_INTTYPES_INCOMPLETE],
  18 [
  19   AC_REQUIRE([gl_STDINT_H])
  20   AC_CHECK_HEADERS_ONCE([inttypes.h])
  21
  22   dnl Override <inttypes.h> always, so that the portability warnings work.
  23   AC_REQUIRE([gl_INTTYPES_H_DEFAULTS])
  24   gl_CHECK_NEXT_HEADERS([inttypes.h])
  25
  26   AC_REQUIRE([gl_MULTIARCH])
  27
  28   dnl Check for declarations of anything we want to poison if the
  29   dnl corresponding gnulib module is not in use.
  30   gl_WARN_ON_USE_PREPARE([[#include <inttypes.h>
  31     ]], [imaxabs imaxdiv strtoimax strtoumax])
  32
  33   AC_REQUIRE([AC_C_RESTRICT])
  34 ])
  35
  36 # Ensure that the PRI* and SCN* macros are defined appropriately.
  37 AC_DEFUN([gl_INTTYPES_PRI_SCN],
  38 [
  39   PRIPTR_PREFIX=
  40   if $GL_GENERATE_STDINT_H; then
  41     dnl Using the gnulib <stdint.h>. It defines intptr_t to 'long' or
  42     dnl 'long long', depending on _WIN64.
  43     AC_COMPILE_IFELSE(
  44       [AC_LANG_PROGRAM([[
  45          #ifdef _WIN64
  46          LLP64
  47          #endif
  48          ]])
  49       ],
  50       [PRIPTR_PREFIX='"l"'],
  51       [PRIPTR_PREFIX='"ll"'])
  52   else
  53     dnl Using the system's <stdint.h>.
  54     for glpfx in '' l ll I64; do
  55       case $glpfx in
  56         '')  gltype1='int';;
  57         l)   gltype1='long int';;
  58         ll)  gltype1='long long int';;
  59         I64) gltype1='__int64';;
  60       esac
  61       AC_COMPILE_IFELSE(
  62         [AC_LANG_PROGRAM([[#include <stdint.h>
  63            extern intptr_t foo;
  64            extern $gltype1 foo;]])],
  65         [PRIPTR_PREFIX='"'$glpfx'"'])
  66       test -n "$PRIPTR_PREFIX" && break
  67     done
  68   fi
  69   AC_SUBST([PRIPTR_PREFIX])
  70
  71   gl_INTTYPES_CHECK_LONG_LONG_INT_CONDITION(
  72     [INT32_MAX_LT_INTMAX_MAX],
  73     [defined INT32_MAX && defined INTMAX_MAX],
  74     [INT32_MAX < INTMAX_MAX],
  75     [sizeof (int) < sizeof (long long int)])
  76   if test $APPLE_UNIVERSAL_BUILD = 0; then
  77     gl_INTTYPES_CHECK_LONG_LONG_INT_CONDITION(
  78       [INT64_MAX_EQ_LONG_MAX],
  79       [defined INT64_MAX],
  80       [INT64_MAX == LONG_MAX],
  81       [sizeof (long long int) == sizeof (long int)])
  82   else
  83     INT64_MAX_EQ_LONG_MAX=-1
  84   fi
  85   gl_INTTYPES_CHECK_LONG_LONG_INT_CONDITION(
  86     [UINT32_MAX_LT_UINTMAX_MAX],
  87     [defined UINT32_MAX && defined UINTMAX_MAX],
  88     [UINT32_MAX < UINTMAX_MAX],
  89     [sizeof (unsigned int) < sizeof (unsigned long long int)])
  90   if test $APPLE_UNIVERSAL_BUILD = 0; then
  91     gl_INTTYPES_CHECK_LONG_LONG_INT_CONDITION(
  92       [UINT64_MAX_EQ_ULONG_MAX],
  93       [defined UINT64_MAX],
  94       [UINT64_MAX == ULONG_MAX],
  95       [sizeof (unsigned long long int) == sizeof (unsigned long int)])
  96   else
  97     UINT64_MAX_EQ_ULONG_MAX=-1
  98   fi
  99 ])
 100
 101 # Define the symbol $1 to be 1 if the condition is true, 0 otherwise.
 102 # If $2 is true, the condition is $3; otherwise if long long int is supported
 103 # approximate the condition with $4; otherwise, assume the condition is false.
 104 # The condition should work on all C99 platforms; the approximations should be
 105 # good enough to work on all practical pre-C99 platforms.
 106 # $2 is evaluated by the C preprocessor, $3 and $4 as compile-time constants.
 107 AC_DEFUN([gl_INTTYPES_CHECK_LONG_LONG_INT_CONDITION],
 108 [
 109   AC_CACHE_CHECK([whether $3],
 110     [gl_cv_test_$1],
 111     [AC_COMPILE_IFELSE(
 112        [AC_LANG_PROGRAM(
 113           [[/* Work also in C++ mode.  */
 114             #define __STDC_LIMIT_MACROS 1
 115
 116             /* Work if build is not clean.  */
 117             #define _GL_JUST_INCLUDE_SYSTEM_STDINT_H
 118
 119             #include <limits.h>
 120             #if HAVE_STDINT_H
 121              #include <stdint.h>
 122             #endif
 123
 124             #if $2
 125              #define CONDITION ($3)
 126             #else
 127              #define CONDITION ($4)
 128             #endif
 129             int test[CONDITION ? 1 : -1];]])],
 130        [gl_cv_test_$1=yes],
 131        [gl_cv_test_$1=no])])
 132   if test $gl_cv_test_$1 = yes; then
 133     $1=1;
 134   else
 135     $1=0;
 136   fi
 137   AC_SUBST([$1])
 138 ])
 139
 140 # gl_INTTYPES_MODULE_INDICATOR([modulename])
 141 # sets the shell variable that indicates the presence of the given module
 142 # to a C preprocessor expression that will evaluate to 1.
 143 # This macro invocation must not occur in macros that are AC_REQUIREd.
 144 AC_DEFUN([gl_INTTYPES_MODULE_INDICATOR],
 145 [
 146   dnl Ensure to expand the default settings once only.
 147   gl_INTTYPES_H_REQUIRE_DEFAULTS
 148   gl_MODULE_INDICATOR_SET_VARIABLE([$1])
 149 ])
 150
 151 # Initializes the default values for AC_SUBSTed shell variables.
 152 # This macro must not be AC_REQUIREd.  It must only be invoked, and only
 153 # outside of macros or in macros that are not AC_REQUIREd.
 154 AC_DEFUN([gl_INTTYPES_H_REQUIRE_DEFAULTS],
 155 [
 156   m4_defun(GL_MODULE_INDICATOR_PREFIX[_INTTYPES_H_MODULE_INDICATOR_DEFAULTS], [
 157     gl_MODULE_INDICATOR_INIT_VARIABLE([GNULIB_IMAXABS])
 158     gl_MODULE_INDICATOR_INIT_VARIABLE([GNULIB_IMAXDIV])
 159     gl_MODULE_INDICATOR_INIT_VARIABLE([GNULIB_STRTOIMAX])
 160     gl_MODULE_INDICATOR_INIT_VARIABLE([GNULIB_STRTOUMAX])
 161   ])
 162   m4_require(GL_MODULE_INDICATOR_PREFIX[_INTTYPES_H_MODULE_INDICATOR_DEFAULTS])
 163   AC_REQUIRE([gl_INTTYPES_H_DEFAULTS])
 164 ])
 165
 166 AC_DEFUN([gl_INTTYPES_H_DEFAULTS],
 167 [
 168   dnl Assume proper GNU behavior unless another module says otherwise.
 169   HAVE_DECL_IMAXABS=1;   AC_SUBST([HAVE_DECL_IMAXABS])
 170   HAVE_DECL_IMAXDIV=1;   AC_SUBST([HAVE_DECL_IMAXDIV])
 171   HAVE_DECL_STRTOIMAX=1; AC_SUBST([HAVE_DECL_STRTOIMAX])
 172   HAVE_DECL_STRTOUMAX=1; AC_SUBST([HAVE_DECL_STRTOUMAX])
 173   HAVE_IMAXDIV_T=1;      AC_SUBST([HAVE_IMAXDIV_T])
 174   HAVE_IMAXABS=1;        AC_SUBST([HAVE_IMAXABS])
 175   HAVE_IMAXDIV=1;        AC_SUBST([HAVE_IMAXDIV])
 176   REPLACE_IMAXABS=0;     AC_SUBST([REPLACE_IMAXABS])
 177   REPLACE_IMAXDIV=0;     AC_SUBST([REPLACE_IMAXDIV])
 178   REPLACE_STRTOIMAX=0;   AC_SUBST([REPLACE_STRTOIMAX])
 179   REPLACE_STRTOUMAX=0;   AC_SUBST([REPLACE_STRTOUMAX])
 180   INT32_MAX_LT_INTMAX_MAX=1;  AC_SUBST([INT32_MAX_LT_INTMAX_MAX])
 181   INT64_MAX_EQ_LONG_MAX='defined _LP64';  AC_SUBST([INT64_MAX_EQ_LONG_MAX])
 182   PRIPTR_PREFIX=__PRIPTR_PREFIX;  AC_SUBST([PRIPTR_PREFIX])
 183   UINT32_MAX_LT_UINTMAX_MAX=1;  AC_SUBST([UINT32_MAX_LT_UINTMAX_MAX])
 184   UINT64_MAX_EQ_ULONG_MAX='defined _LP64';  AC_SUBST([UINT64_MAX_EQ_ULONG_MAX])
 185 ])