m4/errno_h.m4

   1 # errno_h.m4
   2 # serial 14
   3 dnl Copyright (C) 2004, 2006, 2008-2024 Free Software Foundation, Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 AC_PREREQ([2.61])
   9
  10 AC_DEFUN_ONCE([gl_HEADER_ERRNO_H],
  11 [
  12   AC_REQUIRE([AC_PROG_CC])
  13   AC_CACHE_CHECK([for complete errno.h], [gl_cv_header_errno_h_complete], [
  14     AC_EGREP_CPP([booboo],[
  15 #include <errno.h>
  16 #if !defined ETXTBSY
  17 booboo
  18 #endif
  19 #if !defined ENOMSG
  20 booboo
  21 #endif
  22 #if !defined EIDRM
  23 booboo
  24 #endif
  25 #if !defined ENOLINK
  26 booboo
  27 #endif
  28 #if !defined EPROTO
  29 booboo
  30 #endif
  31 #if !defined EMULTIHOP
  32 booboo
  33 #endif
  34 #if !defined EBADMSG
  35 booboo
  36 #endif
  37 #if !defined EOVERFLOW
  38 booboo
  39 #endif
  40 #if !defined ENOTSUP
  41 booboo
  42 #endif
  43 #if !defined ENETRESET
  44 booboo
  45 #endif
  46 #if !defined ECONNABORTED
  47 booboo
  48 #endif
  49 #if !defined ESTALE
  50 booboo
  51 #endif
  52 #if !defined EDQUOT
  53 booboo
  54 #endif
  55 #if !defined ECANCELED
  56 booboo
  57 #endif
  58 #if !defined EOWNERDEAD
  59 booboo
  60 #endif
  61 #if !defined ENOTRECOVERABLE
  62 booboo
  63 #endif
  64 #if !defined EILSEQ
  65 booboo
  66 #endif
  67       ],
  68       [gl_cv_header_errno_h_complete=no],
  69       [gl_cv_header_errno_h_complete=yes])
  70   ])
  71   if test $gl_cv_header_errno_h_complete = yes; then
  72     GL_GENERATE_ERRNO_H=false
  73   else
  74     gl_NEXT_HEADERS([errno.h])
  75     GL_GENERATE_ERRNO_H=true
  76   fi
  77   gl_REPLACE_ERRNO_VALUE([EMULTIHOP])
  78   gl_REPLACE_ERRNO_VALUE([ENOLINK])
  79   gl_REPLACE_ERRNO_VALUE([EOVERFLOW])
  80 ])
  81
  82 # Assuming $1 = EOVERFLOW.
  83 # The EOVERFLOW errno value ought to be defined in <errno.h>, according to
  84 # POSIX.  But some systems (like OpenBSD 4.0 or AIX 3) don't define it, and
  85 # some systems (like OSF/1) define it when _XOPEN_SOURCE_EXTENDED is defined.
  86 # Check for the value of EOVERFLOW.
  87 # Set the variables EOVERFLOW_HIDDEN and EOVERFLOW_VALUE.
  88 AC_DEFUN([gl_REPLACE_ERRNO_VALUE],
  89 [
  90   if $GL_GENERATE_ERRNO_H; then
  91     AC_CACHE_CHECK([for ]$1[ value], [gl_cv_header_errno_h_]$1, [
  92       AC_EGREP_CPP([yes],[
  93 #include <errno.h>
  94 #ifdef ]$1[
  95 yes
  96 #endif
  97       ],
  98       [gl_cv_header_errno_h_]$1[=yes],
  99       [gl_cv_header_errno_h_]$1[=no])
 100       if test $gl_cv_header_errno_h_]$1[ = no; then
 101         AC_EGREP_CPP([yes],[
 102 #define _XOPEN_SOURCE_EXTENDED 1
 103 #include <errno.h>
 104 #ifdef ]$1[
 105 yes
 106 #endif
 107           ], [gl_cv_header_errno_h_]$1[=hidden])
 108         if test $gl_cv_header_errno_h_]$1[ = hidden; then
 109           dnl The macro exists but is hidden.
 110           dnl Define it to the same value.
 111           AC_COMPUTE_INT([gl_cv_header_errno_h_]$1, $1, [
 112 #define _XOPEN_SOURCE_EXTENDED 1
 113 #include <errno.h>
 114 /* The following two lines are a workaround against an autoconf-2.52 bug.  */
 115 #include <stdio.h>
 116 #include <stdlib.h>
 117 ])
 118         fi
 119       fi
 120     ])
 121     case $gl_cv_header_errno_h_]$1[ in
 122       yes | no)
 123         ]$1[_HIDDEN=0; ]$1[_VALUE=
 124         ;;
 125       *)
 126         ]$1[_HIDDEN=1; ]$1[_VALUE="$gl_cv_header_errno_h_]$1["
 127         ;;
 128     esac
 129     AC_SUBST($1[_HIDDEN])
 130     AC_SUBST($1[_VALUE])
 131   fi
 132 ])