lisp/progmodes/elisp-mode.el

   1 ;;; elisp-mode.el --- Emacs Lisp mode  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 1985-1986, 1999-2015 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: emacs-devel@gnu.org
   6 ;; Keywords: lisp, languages
   7 ;; Package: emacs
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; The major mode for editing Emacs Lisp code.
  27 ;; This mode is documented in the Emacs manual.
  28
  29 ;;; Code:
  30
  31 (require 'lisp-mode)
  32
  33 (define-abbrev-table 'emacs-lisp-mode-abbrev-table ()
  34   "Abbrev table for Emacs Lisp mode.
  35 It has `lisp-mode-abbrev-table' as its parent."
  36   :parents (list lisp-mode-abbrev-table))
  37
  38 (defvar emacs-lisp-mode-syntax-table
  39   (let ((table (make-syntax-table lisp--mode-syntax-table)))
  40     (modify-syntax-entry ?\[ "(]  " table)
  41     (modify-syntax-entry ?\] ")[  " table)
  42     table)
  43   "Syntax table used in `emacs-lisp-mode'.")
  44
  45 (defvar emacs-lisp-mode-map
  46   (let ((map (make-sparse-keymap "Emacs-Lisp"))
  47         (menu-map (make-sparse-keymap "Emacs-Lisp"))
  48         (lint-map (make-sparse-keymap))
  49         (prof-map (make-sparse-keymap))
  50         (tracing-map (make-sparse-keymap)))
  51     (set-keymap-parent map lisp-mode-shared-map)
  52     (define-key map "\e\t" 'completion-at-point)
  53     (define-key map "\e\C-x" 'eval-defun)
  54     (define-key map "\e\C-q" 'indent-pp-sexp)
  55     (bindings--define-key map [menu-bar emacs-lisp]
  56       (cons "Emacs-Lisp" menu-map))
  57     (bindings--define-key menu-map [eldoc]
  58       '(menu-item "Auto-Display Documentation Strings" eldoc-mode
  59                   :button (:toggle . (bound-and-true-p eldoc-mode))
  60                   :help "Display the documentation string for the item under cursor"))
  61     (bindings--define-key menu-map [checkdoc]
  62       '(menu-item "Check Documentation Strings" checkdoc
  63                   :help "Check documentation strings for style requirements"))
  64     (bindings--define-key menu-map [re-builder]
  65       '(menu-item "Construct Regexp" re-builder
  66                   :help "Construct a regexp interactively"))
  67     (bindings--define-key menu-map [tracing] (cons "Tracing" tracing-map))
  68     (bindings--define-key tracing-map [tr-a]
  69       '(menu-item "Untrace All" untrace-all
  70                   :help "Untrace all currently traced functions"))
  71     (bindings--define-key tracing-map [tr-uf]
  72       '(menu-item "Untrace Function..." untrace-function
  73                   :help "Untrace function, and possibly activate all remaining advice"))
  74     (bindings--define-key tracing-map [tr-sep] menu-bar-separator)
  75     (bindings--define-key tracing-map [tr-q]
  76       '(menu-item "Trace Function Quietly..." trace-function-background
  77                   :help "Trace the function with trace output going quietly to a buffer"))
  78     (bindings--define-key tracing-map [tr-f]
  79       '(menu-item "Trace Function..." trace-function
  80                   :help "Trace the function given as an argument"))
  81     (bindings--define-key menu-map [profiling] (cons "Profiling" prof-map))
  82     (bindings--define-key prof-map [prof-restall]
  83       '(menu-item "Remove Instrumentation for All Functions" elp-restore-all
  84                   :help "Restore the original definitions of all functions being profiled"))
  85     (bindings--define-key prof-map [prof-restfunc]
  86       '(menu-item "Remove Instrumentation for Function..." elp-restore-function
  87                   :help "Restore an instrumented function to its original definition"))
  88
  89     (bindings--define-key prof-map [sep-rem] menu-bar-separator)
  90     (bindings--define-key prof-map [prof-resall]
  91       '(menu-item "Reset Counters for All Functions" elp-reset-all
  92                   :help "Reset the profiling information for all functions being profiled"))
  93     (bindings--define-key prof-map [prof-resfunc]
  94       '(menu-item "Reset Counters for Function..." elp-reset-function
  95                   :help "Reset the profiling information for a function"))
  96     (bindings--define-key prof-map [prof-res]
  97       '(menu-item "Show Profiling Results" elp-results
  98                   :help "Display current profiling results"))
  99     (bindings--define-key prof-map [prof-pack]
 100       '(menu-item "Instrument Package..." elp-instrument-package
 101                   :help "Instrument for profiling all function that start with a prefix"))
 102     (bindings--define-key prof-map [prof-func]
 103       '(menu-item "Instrument Function..." elp-instrument-function
 104                   :help "Instrument a function for profiling"))
 105     ;; Maybe this should be in a separate submenu from the ELP stuff?
 106     (bindings--define-key prof-map [sep-natprof] menu-bar-separator)
 107     (bindings--define-key prof-map [prof-natprof-stop]
 108       '(menu-item "Stop Native Profiler" profiler-stop
 109                   :help "Stop recording profiling information"
 110                   :enable (and (featurep 'profiler)
 111                                (profiler-running-p))))
 112     (bindings--define-key prof-map [prof-natprof-report]
 113       '(menu-item "Show Profiler Report" profiler-report
 114                   :help "Show the current profiler report"
 115                   :enable (and (featurep 'profiler)
 116                                (profiler-running-p))))
 117     (bindings--define-key prof-map [prof-natprof-start]
 118       '(menu-item "Start Native Profiler..." profiler-start
 119                   :help "Start recording profiling information"))
 120
 121     (bindings--define-key menu-map [lint] (cons "Linting" lint-map))
 122     (bindings--define-key lint-map [lint-di]
 123       '(menu-item "Lint Directory..." elint-directory
 124                   :help "Lint a directory"))
 125     (bindings--define-key lint-map [lint-f]
 126       '(menu-item "Lint File..." elint-file
 127                   :help "Lint a file"))
 128     (bindings--define-key lint-map [lint-b]
 129       '(menu-item "Lint Buffer" elint-current-buffer
 130                   :help "Lint the current buffer"))
 131     (bindings--define-key lint-map [lint-d]
 132       '(menu-item "Lint Defun" elint-defun
 133                   :help "Lint the function at point"))
 134     (bindings--define-key menu-map [edebug-defun]
 135       '(menu-item "Instrument Function for Debugging" edebug-defun
 136                   :help "Evaluate the top level form point is in, stepping through with Edebug"
 137                   :keys "C-u C-M-x"))
 138     (bindings--define-key menu-map [separator-byte] menu-bar-separator)
 139     (bindings--define-key menu-map [disas]
 140       '(menu-item "Disassemble Byte Compiled Object..." disassemble
 141                   :help "Print disassembled code for OBJECT in a buffer"))
 142     (bindings--define-key menu-map [byte-recompile]
 143       '(menu-item "Byte-recompile Directory..." byte-recompile-directory
 144                   :help "Recompile every `.el' file in DIRECTORY that needs recompilation"))
 145     (bindings--define-key menu-map [emacs-byte-compile-and-load]
 146       '(menu-item "Byte-compile and Load" emacs-lisp-byte-compile-and-load
 147                   :help "Byte-compile the current file (if it has changed), then load compiled code"))
 148     (bindings--define-key menu-map [byte-compile]
 149       '(menu-item "Byte-compile This File" emacs-lisp-byte-compile
 150                   :help "Byte compile the file containing the current buffer"))
 151     (bindings--define-key menu-map [separator-eval] menu-bar-separator)
 152     (bindings--define-key menu-map [ielm]
 153       '(menu-item "Interactive Expression Evaluation" ielm
 154                   :help "Interactively evaluate Emacs Lisp expressions"))
 155     (bindings--define-key menu-map [eval-buffer]
 156       '(menu-item "Evaluate Buffer" eval-buffer
 157                   :help "Execute the current buffer as Lisp code"))
 158     (bindings--define-key menu-map [eval-region]
 159       '(menu-item "Evaluate Region" eval-region
 160                   :help "Execute the region as Lisp code"
 161                   :enable mark-active))
 162     (bindings--define-key menu-map [eval-sexp]
 163       '(menu-item "Evaluate Last S-expression" eval-last-sexp
 164                   :help "Evaluate sexp before point; print value in echo area"))
 165     (bindings--define-key menu-map [separator-format] menu-bar-separator)
 166     (bindings--define-key menu-map [comment-region]
 167       '(menu-item "Comment Out Region" comment-region
 168                   :help "Comment or uncomment each line in the region"
 169                   :enable mark-active))
 170     (bindings--define-key menu-map [indent-region]
 171       '(menu-item "Indent Region" indent-region
 172                   :help "Indent each nonblank line in the region"
 173                   :enable mark-active))
 174     (bindings--define-key menu-map [indent-line]
 175       '(menu-item "Indent Line" lisp-indent-line))
 176     map)
 177   "Keymap for Emacs Lisp mode.
 178 All commands in `lisp-mode-shared-map' are inherited by this map.")
 179
 180 (defun emacs-lisp-byte-compile ()
 181   "Byte compile the file containing the current buffer."
 182   (interactive)
 183   (if buffer-file-name
 184       (byte-compile-file buffer-file-name)
 185     (error "The buffer must be saved in a file first")))
 186
 187 (defun emacs-lisp-byte-compile-and-load ()
 188   "Byte-compile the current file (if it has changed), then load compiled code."
 189   (interactive)
 190   (or buffer-file-name
 191       (error "The buffer must be saved in a file first"))
 192   (require 'bytecomp)
 193   ;; Recompile if file or buffer has changed since last compilation.
 194   (if (and (buffer-modified-p)
 195            (y-or-n-p (format "Save buffer %s first? " (buffer-name))))
 196       (save-buffer))
 197   (byte-recompile-file buffer-file-name nil 0 t))
 198
 199 (defun emacs-lisp-macroexpand ()
 200   "Macroexpand the form after point.
 201 Comments in the form will be lost."
 202   (interactive)
 203   (let* ((start (point))
 204          (exp (read (current-buffer)))
 205          ;; Compute it before, since it may signal errors.
 206          (new (macroexpand-1 exp)))
 207     (if (equal exp new)
 208         (message "Not a macro call, nothing to expand")
 209       (delete-region start (point))
 210       (pp new (current-buffer))
 211       (if (bolp) (delete-char -1))
 212       (indent-region start (point)))))
 213
 214 (defcustom emacs-lisp-mode-hook nil
 215   "Hook run when entering Emacs Lisp mode."
 216   :options '(eldoc-mode imenu-add-menubar-index checkdoc-minor-mode)
 217   :type 'hook
 218   :group 'lisp)
 219
 220 ;;;###autoload
 221 (define-derived-mode emacs-lisp-mode prog-mode "Emacs-Lisp"
 222   "Major mode for editing Lisp code to run in Emacs.
 223 Commands:
 224 Delete converts tabs to spaces as it moves back.
 225 Blank lines separate paragraphs.  Semicolons start comments.
 226
 227 \\{emacs-lisp-mode-map}"
 228   :group 'lisp
 229   (defvar xref-find-function)
 230   (defvar xref-identifier-completion-table-function)
 231   (lisp-mode-variables nil nil 'elisp)
 232   (add-hook 'after-load-functions #'elisp--font-lock-flush-elisp-buffers)
 233   (setq-local electric-pair-text-pairs
 234               (cons '(?\` . ?\') electric-pair-text-pairs))
 235   (setq imenu-case-fold-search nil)
 236   (add-function :before-until (local 'eldoc-documentation-function)
 237                 #'elisp-eldoc-documentation-function)
 238   (setq-local xref-find-function #'elisp-xref-find)
 239   (setq-local xref-identifier-completion-table-function
 240               #'elisp--xref-identifier-completion-table)
 241   (add-hook 'completion-at-point-functions
 242             #'elisp-completion-at-point nil 'local))
 243
 244 ;; Font-locking support.
 245
 246 (defun elisp--font-lock-flush-elisp-buffers (&optional file)
 247   ;; FIXME: Aren't we only ever called from after-load-functions?
 248   ;; Don't flush during load unless called from after-load-functions.
 249   ;; In that case, FILE is non-nil.  It's somehow strange that
 250   ;; load-in-progress is t when an after-load-function is called since
 251   ;; that should run *after* the load...
 252   (when (or (not load-in-progress) file)
 253     ;; FIXME: If the loaded file did not define any macros, there shouldn't
 254     ;; be any need to font-lock-flush all the Elisp buffers.
 255     (dolist (buf (buffer-list))
 256       (with-current-buffer buf
 257         (when (derived-mode-p 'emacs-lisp-mode)
 258           ;; So as to take into account new macros that may have been defined
 259           ;; by the just-loaded file.
 260           (font-lock-flush))))))
 261
 262 ;;; Completion at point for Elisp
 263
 264 (defun elisp--local-variables-1 (vars sexp)
 265   "Return the vars locally bound around the witness, or nil if not found."
 266   (let (res)
 267     (while
 268         (unless
 269             (setq res
 270                   (pcase sexp
 271                     (`(,(or `let `let*) ,bindings)
 272                      (let ((vars vars))
 273                        (when (eq 'let* (car sexp))
 274                          (dolist (binding (cdr (reverse bindings)))
 275                            (push (or (car-safe binding) binding) vars)))
 276                        (elisp--local-variables-1
 277                         vars (car (cdr-safe (car (last bindings)))))))
 278                     (`(,(or `let `let*) ,bindings . ,body)
 279                      (let ((vars vars))
 280                        (dolist (binding bindings)
 281                          (push (or (car-safe binding) binding) vars))
 282                        (elisp--local-variables-1 vars (car (last body)))))
 283                     (`(lambda ,_args)
 284                      ;; FIXME: Look for the witness inside `args'.
 285                      (setq sexp nil))
 286                     (`(lambda ,args . ,body)
 287                      (elisp--local-variables-1
 288                       (append (remq '&optional (remq '&rest args)) vars)
 289                       (car (last body))))
 290                     (`(condition-case ,_ ,e) (elisp--local-variables-1 vars e))
 291                     (`(condition-case ,v ,_ . ,catches)
 292                      (elisp--local-variables-1
 293                       (cons v vars) (cdr (car (last catches)))))
 294                     (`(quote . ,_)
 295                      ;; FIXME: Look for the witness inside sexp.
 296                      (setq sexp nil))
 297                     ;; FIXME: Handle `cond'.
 298                     (`(,_ . ,_)
 299                      (elisp--local-variables-1 vars (car (last sexp))))
 300                     (`elisp--witness--lisp (or vars '(nil)))
 301                     (_ nil)))
 302           ;; We didn't find the witness in the last element so we try to
 303           ;; backtrack to the last-but-one.
 304           (setq sexp (ignore-errors (butlast sexp)))))
 305     res))
 306
 307 (defun elisp--local-variables ()
 308   "Return a list of locally let-bound variables at point."
 309   (save-excursion
 310     (skip-syntax-backward "w_")
 311     (let* ((ppss (syntax-ppss))
 312            (txt (buffer-substring-no-properties (or (car (nth 9 ppss)) (point))
 313                                                 (or (nth 8 ppss) (point))))
 314            (closer ()))
 315       (dolist (p (nth 9 ppss))
 316         (push (cdr (syntax-after p)) closer))
 317       (setq closer (apply #'string closer))
 318       (let* ((sexp (condition-case nil
 319                        (car (read-from-string
 320                              (concat txt "elisp--witness--lisp" closer)))
 321                      ((invalid-read-syntax end-of-file) nil)))
 322              (macroexpand-advice (lambda (expander form &rest args)
 323                                    (condition-case nil
 324                                        (apply expander form args)
 325                                      (error form))))
 326              (sexp
 327               (unwind-protect
 328                   (progn
 329                     (advice-add 'macroexpand :around macroexpand-advice)
 330                     (macroexpand-all sexp))
 331                 (advice-remove 'macroexpand macroexpand-advice)))
 332              (vars (elisp--local-variables-1 nil sexp)))
 333         (delq nil
 334               (mapcar (lambda (var)
 335                         (and (symbolp var)
 336                              (not (string-match (symbol-name var) "\\`[&_]"))
 337                              ;; Eliminate uninterned vars.
 338                              (intern-soft var)
 339                              var))
 340                       vars))))))
 341
 342 (defvar elisp--local-variables-completion-table
 343   ;; Use `defvar' rather than `defconst' since defconst would purecopy this
 344   ;; value, which would doubly fail: it would fail because purecopy can't
 345   ;; handle the recursive bytecode object, and it would fail because it would
 346   ;; move `lastpos' and `lastvars' to pure space where they'd be immutable!
 347   (let ((lastpos nil) (lastvars nil))
 348     (letrec ((hookfun (lambda ()
 349                         (setq lastpos nil)
 350                         (remove-hook 'post-command-hook hookfun))))
 351       (completion-table-dynamic
 352        (lambda (_string)
 353          (save-excursion
 354            (skip-syntax-backward "_w")
 355            (let ((newpos (cons (point) (current-buffer))))
 356              (unless (equal lastpos newpos)
 357                (add-hook 'post-command-hook hookfun)
 358                (setq lastpos newpos)
 359                (setq lastvars
 360                      (mapcar #'symbol-name (elisp--local-variables))))))
 361          lastvars)))))
 362
 363 (defun elisp--expect-function-p (pos)
 364   "Return non-nil if the symbol at point is expected to be a function."
 365   (or
 366    (and (eq (char-before pos) ?')
 367         (eq (char-before (1- pos)) ?#))
 368    (save-excursion
 369      (let ((parent (nth 1 (syntax-ppss pos))))
 370        (when parent
 371          (goto-char parent)
 372          (and
 373           (looking-at (concat "(\\(cl-\\)?"
 374                               (regexp-opt '("declare-function"
 375                                             "function" "defadvice"
 376                                             "callf" "callf2"
 377                                             "defsetf"))
 378                               "[ \t\r\n]+"))
 379           (eq (match-end 0) pos)))))))
 380
 381 (defun elisp--form-quoted-p (pos)
 382   "Return non-nil if the form at POS is not evaluated.
 383 It can be quoted, or be inside a quoted form."
 384   ;; FIXME: Do some macro expansion maybe.
 385   (save-excursion
 386     (let ((state (syntax-ppss pos)))
 387       (or (nth 8 state)   ; Code inside strings usually isn't evaluated.
 388           ;; FIXME: The 9th element is undocumented.
 389           (let ((nesting (cons (point) (reverse (nth 9 state))))
 390                 res)
 391             (while (and nesting (not res))
 392               (goto-char (pop nesting))
 393               (cond
 394                ((or (eq (char-after) ?\[)
 395                     (progn
 396                       (skip-chars-backward " ")
 397                       (memq (char-before) '(?' ?`))))
 398                 (setq res t))
 399                ((eq (char-before) ?,)
 400                 (setq nesting nil))))
 401             res)))))
 402
 403 ;; FIXME: Support for Company brings in features which straddle eldoc.
 404 ;; We should consolidate this, so that major modes can provide all that
 405 ;; data all at once:
 406 ;; - a function to extract "the reference at point" (may be more complex
 407 ;;     than a mere string, to distinguish various namespaces).
 408 ;; - a function to jump to such a reference.
 409 ;; - a function to show the signature/interface of such a reference.
 410 ;; - a function to build a help-buffer about that reference.
 411 ;; FIXME: Those functions should also be used by the normal completion code in
 412 ;; the *Completions* buffer.
 413
 414 (defun elisp--company-doc-buffer (str)
 415   (let ((symbol (intern-soft str)))
 416     ;; FIXME: we really don't want to "display-buffer and then undo it".
 417     (save-window-excursion
 418       ;; Make sure we don't display it in another frame, otherwise
 419       ;; save-window-excursion won't be able to undo it.
 420       (let ((display-buffer-overriding-action
 421              '(nil . ((inhibit-switch-frame . t)))))
 422         (ignore-errors
 423           (cond
 424            ((fboundp symbol) (describe-function symbol))
 425            ((boundp symbol) (describe-variable symbol))
 426            ((featurep symbol) (describe-package symbol))
 427            ((facep symbol) (describe-face symbol))
 428            (t (signal 'user-error nil)))
 429           (help-buffer))))))
 430
 431 (defun elisp--company-doc-string (str)
 432   (let* ((symbol (intern-soft str))
 433          (doc (if (fboundp symbol)
 434                   (documentation symbol t)
 435                 (documentation-property symbol 'variable-documentation t))))
 436     (and (stringp doc)
 437          (string-match ".*$" doc)
 438          (match-string 0 doc))))
 439
 440 (declare-function find-library-name "find-func" (library))
 441 (declare-function find-function-library "find-func" (function &optional l-o v))
 442
 443 (defun elisp--company-location (str)
 444   (let ((sym (intern-soft str)))
 445     (cond
 446      ((fboundp sym) (find-definition-noselect sym nil))
 447      ((boundp sym) (find-definition-noselect sym 'defvar))
 448      ((featurep sym)
 449       (require 'find-func)
 450       (cons (find-file-noselect (find-library-name
 451                                  (symbol-name sym)))
 452             0))
 453      ((facep sym) (find-definition-noselect sym 'defface)))))
 454
 455 (defun elisp-completion-at-point ()
 456   "Function used for `completion-at-point-functions' in `emacs-lisp-mode'."
 457   (with-syntax-table emacs-lisp-mode-syntax-table
 458     (let* ((pos (point))
 459            (beg (condition-case nil
 460                     (save-excursion
 461                       (backward-sexp 1)
 462                       (skip-syntax-forward "'")
 463                       (point))
 464                   (scan-error pos)))
 465            (end
 466             (unless (or (eq beg (point-max))
 467                         (member (char-syntax (char-after beg))
 468                                 '(?\s ?\" ?\( ?\))))
 469               (condition-case nil
 470                   (save-excursion
 471                     (goto-char beg)
 472                     (forward-sexp 1)
 473                     (skip-chars-backward "'")
 474                     (when (>= (point) pos)
 475                       (point)))
 476                 (scan-error pos))))
 477            ;; t if in function position.
 478            (funpos (eq (char-before beg) ?\())
 479            (quoted (elisp--form-quoted-p beg)))
 480       (when (and end (or (not (nth 8 (syntax-ppss)))
 481                          (eq (char-before beg) ?`)))
 482         (let ((table-etc
 483                (if (or (not funpos) quoted)
 484                    ;; FIXME: We could look at the first element of the list and
 485                    ;; use it to provide a more specific completion table in some
 486                    ;; cases.  E.g. filter out keywords that are not understood by
 487                    ;; the macro/function being called.
 488                    (cond
 489                     ((elisp--expect-function-p beg)
 490                      (list nil obarray
 491                            :predicate #'fboundp
 492                            :company-doc-buffer #'elisp--company-doc-buffer
 493                            :company-docsig #'elisp--company-doc-string
 494                            :company-location #'elisp--company-location))
 495                     (quoted
 496                      (list nil obarray
 497                            ;; Don't include all symbols (bug#16646).
 498                            :predicate (lambda (sym)
 499                                         (or (boundp sym)
 500                                             (fboundp sym)
 501                                             (featurep sym)
 502                                             (symbol-plist sym)))
 503                            :annotation-function
 504                            (lambda (str) (if (fboundp (intern-soft str)) " <f>"))
 505                            :company-doc-buffer #'elisp--company-doc-buffer
 506                            :company-docsig #'elisp--company-doc-string
 507                            :company-location #'elisp--company-location))
 508                     (t
 509                      (list nil (completion-table-merge
 510                                 elisp--local-variables-completion-table
 511                                 (apply-partially #'completion-table-with-predicate
 512                                                  obarray
 513                                                  #'boundp
 514                                                  'strict))
 515                            :company-doc-buffer #'elisp--company-doc-buffer
 516                            :company-docsig #'elisp--company-doc-string
 517                            :company-location #'elisp--company-location)))
 518                  ;; Looks like a funcall position.  Let's double check.
 519                  (save-excursion
 520                    (goto-char (1- beg))
 521                    (let ((parent
 522                           (condition-case nil
 523                               (progn (up-list -1) (forward-char 1)
 524                                      (let ((c (char-after)))
 525                                        (if (eq c ?\() ?\(
 526                                          (if (memq (char-syntax c) '(?w ?_))
 527                                              (read (current-buffer))))))
 528                             (error nil))))
 529                      (pcase parent
 530                        ;; FIXME: Rather than hardcode special cases here,
 531                        ;; we should use something like a symbol-property.
 532                        (`declare
 533                         (list t (mapcar (lambda (x) (symbol-name (car x)))
 534                                         (delete-dups
 535                                          ;; FIXME: We should include some
 536                                          ;; docstring with each entry.
 537                                          (append
 538                                           macro-declarations-alist
 539                                           defun-declarations-alist)))))
 540                        ((and (or `condition-case `condition-case-unless-debug)
 541                              (guard (save-excursion
 542                                       (ignore-errors
 543                                         (forward-sexp 2)
 544                                         (< (point) beg)))))
 545                         (list t obarray
 546                               :predicate (lambda (sym) (get sym 'error-conditions))))
 547                        ((or `let `let*
 548                             (and ?\(
 549                                  (guard (save-excursion
 550                                           (goto-char (1- beg))
 551                                           (up-list -1)
 552                                           (forward-symbol -1)
 553                                           (looking-at "\\_<let\\*?\\_>")))))
 554                         (list t obarray
 555                               :predicate #'boundp
 556                               :company-doc-buffer #'elisp--company-doc-buffer
 557                               :company-docsig #'elisp--company-doc-string
 558                               :company-location #'elisp--company-location))
 559                        (_ (list nil obarray
 560                                 :predicate #'fboundp
 561                                 :company-doc-buffer #'elisp--company-doc-buffer
 562                                 :company-docsig #'elisp--company-doc-string
 563                                 :company-location #'elisp--company-location
 564                                 ))))))))
 565           (nconc (list beg end)
 566                  (if (null (car table-etc))
 567                      (cdr table-etc)
 568                    (cons
 569                     (if (memq (char-syntax (or (char-after end) ?\s))
 570                               '(?\s ?>))
 571                         (cadr table-etc)
 572                       (apply-partially 'completion-table-with-terminator
 573                                        " " (cadr table-etc)))
 574                     (cddr table-etc)))))))))
 575
 576 (define-obsolete-function-alias
 577   'lisp-completion-at-point 'elisp-completion-at-point "25.1")
 578
 579 ;;; Xref backend
 580
 581 (declare-function xref-make-elisp-location "xref" (symbol type file))
 582 (declare-function xref-make-bogus-location "xref" (message))
 583 (declare-function xref-make "xref" (description location))
 584
 585 (defun elisp-xref-find (action id)
 586   (require 'find-func)
 587   (pcase action
 588     (`definitions
 589       (let ((sym (intern-soft id)))
 590         (when sym
 591           (elisp--xref-find-definitions sym))))
 592     (`references
 593      (elisp--xref-find-references id))
 594     (`apropos
 595      (elisp--xref-find-apropos id))))
 596
 597 (defun elisp--xref-identifier-location (type sym)
 598   (let ((file
 599          (pcase type
 600            (`defun (when (fboundp sym)
 601                      (let ((fun-lib
 602                             (find-function-library sym)))
 603                        (setq sym (car fun-lib))
 604                        (cdr fun-lib))))
 605            (`defvar (and (boundp sym)
 606                          ;; Don't show minor modes twice.
 607                          ;; TODO: If TYPE ever becomes dependent on the
 608                          ;; context, move this check outside.
 609                          (not (fboundp sym))
 610                          (or (symbol-file sym 'defvar)
 611                              (help-C-file-name sym 'var))))
 612            (`feature (and (featurep sym)
 613                           ;; Skip when a function with the same name
 614                           ;; is defined, because it's probably in the
 615                           ;; same file.
 616                           (not (fboundp sym))
 617                           (ignore-errors
 618                             (find-library-name (symbol-name sym)))))
 619            (`defface (when (facep sym)
 620                        (symbol-file sym 'defface))))))
 621     (when file
 622       (when (string-match-p "\\.elc\\'" file)
 623         (setq file (substring file 0 -1)))
 624       (xref-make-elisp-location sym type file))))
 625
 626 (defun elisp--xref-find-definitions (symbol)
 627   (save-excursion
 628     (let (lst)
 629       (dolist (type '(feature defface defvar defun))
 630         (let ((loc
 631                (condition-case err
 632                    (elisp--xref-identifier-location type symbol)
 633                  (error
 634                   (xref-make-bogus-location (error-message-string err))))))
 635           (when loc
 636             (push
 637              (xref-make (format "(%s %s)" type symbol)
 638                         loc)
 639              lst))))
 640       lst)))
 641
 642 (defun elisp--xref-find-references (symbol)
 643   (let* ((dirs (sort
 644                 (mapcar
 645                  (lambda (dir)
 646                    (file-name-as-directory (expand-file-name dir)))
 647                  (cons package-user-dir load-path))
 648                 #'string<))
 649          (ref dirs))
 650     ;; Delete subdirectories from the list.
 651     (while (cdr ref)
 652       (if (string-prefix-p (car ref) (cadr ref))
 653           (setcdr ref (cddr ref))
 654         (setq ref (cdr ref))))
 655     (cl-mapcan
 656      (lambda (dir)
 657        (and (file-exists-p dir)
 658             (xref-collect-references symbol dir)))
 659      dirs)))
 660
 661 (defun elisp--xref-find-apropos (regexp)
 662   (apply #'nconc
 663          (let (lst)
 664            (dolist (sym (apropos-internal regexp))
 665             (push (elisp--xref-find-definitions sym) lst))
 666            (nreverse lst))))
 667
 668 (defvar elisp--xref-identifier-completion-table
 669   (apply-partially #'completion-table-with-predicate
 670                    obarray
 671                    (lambda (sym)
 672                      (or (boundp sym)
 673                          (fboundp sym)
 674                          (featurep sym)
 675                          (facep sym)))
 676                    'strict))
 677
 678 (defun elisp--xref-identifier-completion-table ()
 679   elisp--xref-identifier-completion-table)
 680
 681 ;;; Elisp Interaction mode
 682
 683 (defvar lisp-interaction-mode-map
 684   (let ((map (make-sparse-keymap))
 685         (menu-map (make-sparse-keymap "Lisp-Interaction")))
 686     (set-keymap-parent map lisp-mode-shared-map)
 687     (define-key map "\e\C-x" 'eval-defun)
 688     (define-key map "\e\C-q" 'indent-pp-sexp)
 689     (define-key map "\e\t" 'completion-at-point)
 690     (define-key map "\n" 'eval-print-last-sexp)
 691     (bindings--define-key map [menu-bar lisp-interaction]
 692       (cons "Lisp-Interaction" menu-map))
 693     (bindings--define-key menu-map [eval-defun]
 694       '(menu-item "Evaluate Defun" eval-defun
 695                   :help "Evaluate the top-level form containing point, or after point"))
 696     (bindings--define-key menu-map [eval-print-last-sexp]
 697       '(menu-item "Evaluate and Print" eval-print-last-sexp
 698                   :help "Evaluate sexp before point; print value into current buffer"))
 699     (bindings--define-key menu-map [edebug-defun-lisp-interaction]
 700       '(menu-item "Instrument Function for Debugging" edebug-defun
 701                   :help "Evaluate the top level form point is in, stepping through with Edebug"
 702                   :keys "C-u C-M-x"))
 703     (bindings--define-key menu-map [indent-pp-sexp]
 704       '(menu-item "Indent or Pretty-Print" indent-pp-sexp
 705                   :help "Indent each line of the list starting just after point, or prettyprint it"))
 706     (bindings--define-key menu-map [complete-symbol]
 707       '(menu-item "Complete Lisp Symbol" completion-at-point
 708                   :help "Perform completion on Lisp symbol preceding point"))
 709     map)
 710   "Keymap for Lisp Interaction mode.
 711 All commands in `lisp-mode-shared-map' are inherited by this map.")
 712
 713 (define-derived-mode lisp-interaction-mode emacs-lisp-mode "Lisp Interaction"
 714   "Major mode for typing and evaluating Lisp forms.
 715 Like Lisp mode except that \\[eval-print-last-sexp] evals the Lisp expression
 716 before point, and prints its value into the buffer, advancing point.
 717 Note that printing is controlled by `eval-expression-print-length'
 718 and `eval-expression-print-level'.
 719
 720 Commands:
 721 Delete converts tabs to spaces as it moves back.
 722 Paragraphs are separated only by blank lines.
 723 Semicolons start comments.
 724
 725 \\{lisp-interaction-mode-map}"
 726   :abbrev-table nil)
 727
 728 ;;; Emacs Lisp Byte-Code mode
 729
 730 (eval-and-compile
 731   (defconst emacs-list-byte-code-comment-re
 732     (concat "\\(#\\)@\\([0-9]+\\) "
 733             ;; Make sure it's a docstring and not a lazy-loaded byte-code.
 734             "\\(?:[^(]\\|([^\"]\\)")))
 735
 736 (defun elisp--byte-code-comment (end &optional _point)
 737   "Try to syntactically mark the #@NNN ....^_ docstrings in byte-code files."
 738   (let ((ppss (syntax-ppss)))
 739     (when (and (nth 4 ppss)
 740                (eq (char-after (nth 8 ppss)) ?#))
 741       (let* ((n (save-excursion
 742                   (goto-char (nth 8 ppss))
 743                   (when (looking-at emacs-list-byte-code-comment-re)
 744                     (string-to-number (match-string 2)))))
 745              ;; `maxdiff' tries to make sure the loop below terminates.
 746              (maxdiff n))
 747         (when n
 748           (let* ((bchar (match-end 2))
 749                  (b (position-bytes bchar)))
 750             (goto-char (+ b n))
 751             (while (let ((diff (- (position-bytes (point)) b n)))
 752                      (unless (zerop diff)
 753                        (when (> diff maxdiff) (setq diff maxdiff))
 754                        (forward-char (- diff))
 755                        (setq maxdiff (if (> diff 0) diff
 756                                        (max (1- maxdiff) 1)))
 757                        t))))
 758           (if (<= (point) end)
 759               (put-text-property (1- (point)) (point)
 760                                  'syntax-table
 761                                  (string-to-syntax "> b"))
 762             (goto-char end)))))))
 763
 764 (defun elisp-byte-code-syntax-propertize (start end)
 765   (elisp--byte-code-comment end (point))
 766   (funcall
 767    (syntax-propertize-rules
 768     (emacs-list-byte-code-comment-re
 769      (1 (prog1 "< b" (elisp--byte-code-comment end (point))))))
 770    start end))
 771
 772 ;;;###autoload
 773 (add-to-list 'auto-mode-alist '("\\.elc\\'" . elisp-byte-code-mode))
 774 ;;;###autoload
 775 (define-derived-mode elisp-byte-code-mode emacs-lisp-mode
 776   "Elisp-Byte-Code"
 777   "Major mode for *.elc files."
 778   ;; TODO: Add way to disassemble byte-code under point.
 779   (setq-local open-paren-in-column-0-is-defun-start nil)
 780   (setq-local syntax-propertize-function
 781               #'elisp-byte-code-syntax-propertize))
 782
 783
 784 ;;; Globally accessible functionality
 785
 786 (defun eval-print-last-sexp (&optional eval-last-sexp-arg-internal)
 787   "Evaluate sexp before point; print value into current buffer.
 788
 789 Normally, this function truncates long output according to the value
 790 of the variables `eval-expression-print-length' and
 791 `eval-expression-print-level'.  With a prefix argument of zero,
 792 however, there is no such truncation.  Such a prefix argument
 793 also causes integers to be printed in several additional formats
 794 \(octal, hexadecimal, and character).
 795
 796 If `eval-expression-debug-on-error' is non-nil, which is the default,
 797 this command arranges for all errors to enter the debugger."
 798   (interactive "P")
 799   (let ((standard-output (current-buffer)))
 800     (terpri)
 801     (eval-last-sexp (or eval-last-sexp-arg-internal t))
 802     (terpri)))
 803
 804
 805 (defun last-sexp-setup-props (beg end value alt1 alt2)
 806   "Set up text properties for the output of `elisp--eval-last-sexp'.
 807 BEG and END are the start and end of the output in current-buffer.
 808 VALUE is the Lisp value printed, ALT1 and ALT2 are strings for the
 809 alternative printed representations that can be displayed."
 810   (let ((map (make-sparse-keymap)))
 811     (define-key map "\C-m" 'elisp-last-sexp-toggle-display)
 812     (define-key map [down-mouse-2] 'mouse-set-point)
 813     (define-key map [mouse-2] 'elisp-last-sexp-toggle-display)
 814     (add-text-properties
 815      beg end
 816      `(printed-value (,value ,alt1 ,alt2)
 817                      mouse-face highlight
 818                      keymap ,map
 819                      help-echo "RET, mouse-2: toggle abbreviated display"
 820                      rear-nonsticky (mouse-face keymap help-echo
 821                                                 printed-value)))))
 822
 823
 824 (defun elisp-last-sexp-toggle-display (&optional _arg)
 825   "Toggle between abbreviated and unabbreviated printed representations."
 826   (interactive "P")
 827   (save-restriction
 828     (widen)
 829     (let ((value (get-text-property (point) 'printed-value)))
 830       (when value
 831         (let ((beg (or (previous-single-property-change (min (point-max) (1+ (point)))
 832                                                         'printed-value)
 833                        (point)))
 834               (end (or (next-single-char-property-change (point) 'printed-value) (point)))
 835               (standard-output (current-buffer))
 836               (point (point)))
 837           (delete-region beg end)
 838           (insert (nth 1 value))
 839           (or (= beg point)
 840               (setq point (1- (point))))
 841           (last-sexp-setup-props beg (point)
 842                                  (nth 0 value)
 843                                  (nth 2 value)
 844                                  (nth 1 value))
 845           (goto-char (min (point-max) point)))))))
 846
 847 (defun prin1-char (char)                ;FIXME: Move it, e.g. to simple.el.
 848   "Return a string representing CHAR as a character rather than as an integer.
 849 If CHAR is not a character, return nil."
 850   (and (integerp char)
 851        (eventp char)
 852        (let ((c (event-basic-type char))
 853              (mods (event-modifiers char))
 854              string)
 855          ;; Prevent ?A from turning into ?\S-a.
 856          (if (and (memq 'shift mods)
 857                   (zerop (logand char ?\S-\^@))
 858                   (not (let ((case-fold-search nil))
 859                          (char-equal c (upcase c)))))
 860              (setq c (upcase c) mods nil))
 861          ;; What string are we considering using?
 862          (condition-case nil
 863              (setq string
 864                    (concat
 865                     "?"
 866                     (mapconcat
 867                      (lambda (modif)
 868                        (cond ((eq modif 'super) "\\s-")
 869                              (t (string ?\\ (upcase (aref (symbol-name modif) 0)) ?-))))
 870                      mods "")
 871                     (cond
 872                      ((memq c '(?\; ?\( ?\) ?\{ ?\} ?\[ ?\] ?\" ?\' ?\\)) (string ?\\ c))
 873                      ((eq c 127) "\\C-?")
 874                      (t
 875                       (string c)))))
 876            (error nil))
 877          ;; Verify the string reads a CHAR, not to some other character.
 878          ;; If it doesn't, return nil instead.
 879          (and string
 880               (= (car (read-from-string string)) char)
 881               string))))
 882
 883 (defun elisp--preceding-sexp ()
 884   "Return sexp before the point."
 885   (let ((opoint (point))
 886         ignore-quotes
 887         expr)
 888     (save-excursion
 889       (with-syntax-table emacs-lisp-mode-syntax-table
 890         ;; If this sexp appears to be enclosed in `...'
 891         ;; then ignore the surrounding quotes.
 892         (setq ignore-quotes
 893               (or (eq (following-char) ?\')
 894                   (eq (preceding-char) ?\')))
 895         (forward-sexp -1)
 896         ;; If we were after `?\e' (or similar case),
 897         ;; use the whole thing, not just the `e'.
 898         (when (eq (preceding-char) ?\\)
 899           (forward-char -1)
 900           (when (eq (preceding-char) ??)
 901             (forward-char -1)))
 902
 903         ;; Skip over hash table read syntax.
 904         (and (> (point) (1+ (point-min)))
 905              (looking-back "#s" (- (point) 2))
 906              (forward-char -2))
 907
 908         ;; Skip over `#N='s.
 909         (when (eq (preceding-char) ?=)
 910           (let (labeled-p)
 911             (save-excursion
 912               (skip-chars-backward "0-9#=")
 913               (setq labeled-p (looking-at "\\(#[0-9]+=\\)+")))
 914             (when labeled-p
 915               (forward-sexp -1))))
 916
 917         (save-restriction
 918           (if (and ignore-quotes (eq (following-char) ?`))
 919               ;; vladimir@cs.ualberta.ca 30-Jul-1997: Skip ` in `variable' so
 920               ;; that the value is returned, not the name.
 921               (forward-char))
 922           (when (looking-at ",@?") (goto-char (match-end 0)))
 923           (narrow-to-region (point-min) opoint)
 924           (setq expr (read (current-buffer)))
 925           ;; If it's an (interactive ...) form, it's more useful to show how an
 926           ;; interactive call would use it.
 927           ;; FIXME: Is it really the right place for this?
 928           (when (eq (car-safe expr) 'interactive)
 929                (setq expr
 930                   `(call-interactively
 931                     (lambda (&rest args) ,expr args))))
 932           expr)))))
 933 (define-obsolete-function-alias 'preceding-sexp 'elisp--preceding-sexp "25.1")
 934
 935 (defun elisp--eval-last-sexp (eval-last-sexp-arg-internal)
 936   "Evaluate sexp before point; print value in the echo area.
 937 If EVAL-LAST-SEXP-ARG-INTERNAL is non-nil, print output into
 938 current buffer.  If EVAL-LAST-SEXP-ARG-INTERNAL is `0', print
 939 output with no limit on the length and level of lists, and
 940 include additional formats for integers \(octal, hexadecimal, and
 941 character)."
 942   (let ((standard-output (if eval-last-sexp-arg-internal (current-buffer) t)))
 943     ;; Setup the lexical environment if lexical-binding is enabled.
 944     (elisp--eval-last-sexp-print-value
 945      (eval (eval-sexp-add-defvars (elisp--preceding-sexp)) lexical-binding)
 946      eval-last-sexp-arg-internal)))
 947
 948
 949 (defun elisp--eval-last-sexp-print-value (value &optional eval-last-sexp-arg-internal)
 950   (let ((unabbreviated (let ((print-length nil) (print-level nil))
 951                          (prin1-to-string value)))
 952         (print-length (and (not (zerop (prefix-numeric-value
 953                                         eval-last-sexp-arg-internal)))
 954                            eval-expression-print-length))
 955         (print-level (and (not (zerop (prefix-numeric-value
 956                                        eval-last-sexp-arg-internal)))
 957                           eval-expression-print-level))
 958         (beg (point))
 959         end)
 960     (prog1
 961         (prin1 value)
 962       (let ((str (eval-expression-print-format value)))
 963         (if str (princ str)))
 964       (setq end (point))
 965       (when (and (bufferp standard-output)
 966                  (or (not (null print-length))
 967                      (not (null print-level)))
 968                  (not (string= unabbreviated
 969                                (buffer-substring-no-properties beg end))))
 970         (last-sexp-setup-props beg end value
 971                                unabbreviated
 972                                (buffer-substring-no-properties beg end))
 973         ))))
 974
 975
 976 (defvar elisp--eval-last-sexp-fake-value (make-symbol "t"))
 977
 978 (defun eval-sexp-add-defvars (exp &optional pos)
 979   "Prepend EXP with all the `defvar's that precede it in the buffer.
 980 POS specifies the starting position where EXP was found and defaults to point."
 981   (setq exp (macroexpand-all exp))      ;Eager macro-expansion.
 982   (if (not lexical-binding)
 983       exp
 984     (save-excursion
 985       (unless pos (setq pos (point)))
 986       (let ((vars ()))
 987         (goto-char (point-min))
 988         (while (re-search-forward
 989                 "(def\\(?:var\\|const\\|custom\\)[ \t\n]+\\([^; '()\n\t]+\\)"
 990                 pos t)
 991           (let ((var (intern (match-string 1))))
 992             (and (not (special-variable-p var))
 993                  (save-excursion
 994                    (zerop (car (syntax-ppss (match-beginning 0)))))
 995               (push var vars))))
 996         `(progn ,@(mapcar (lambda (v) `(defvar ,v)) vars) ,exp)))))
 997
 998 (defun eval-last-sexp (eval-last-sexp-arg-internal)
 999   "Evaluate sexp before point; print value in the echo area.
1000 Interactively, with prefix argument, print output into current buffer.
1001
1002 Normally, this function truncates long output according to the value
1003 of the variables `eval-expression-print-length' and
1004 `eval-expression-print-level'.  With a prefix argument of zero,
1005 however, there is no such truncation.  Such a prefix argument
1006 also causes integers to be printed in several additional formats
1007 \(octal, hexadecimal, and character).
1008
1009 If `eval-expression-debug-on-error' is non-nil, which is the default,
1010 this command arranges for all errors to enter the debugger."
1011   (interactive "P")
1012   (if (null eval-expression-debug-on-error)
1013       (elisp--eval-last-sexp eval-last-sexp-arg-internal)
1014     (let ((value
1015            (let ((debug-on-error elisp--eval-last-sexp-fake-value))
1016              (cons (elisp--eval-last-sexp eval-last-sexp-arg-internal)
1017                    debug-on-error))))
1018       (unless (eq (cdr value) elisp--eval-last-sexp-fake-value)
1019         (setq debug-on-error (cdr value)))
1020       (car value))))
1021
1022 (defun elisp--eval-defun-1 (form)
1023   "Treat some expressions specially.
1024 Reset the `defvar' and `defcustom' variables to the initial value.
1025 \(For `defcustom', use the :set function if there is one.)
1026 Reinitialize the face according to the `defface' specification."
1027   ;; The code in edebug-defun should be consistent with this, but not
1028   ;; the same, since this gets a macroexpanded form.
1029   (cond ((not (listp form))
1030          form)
1031         ((and (eq (car form) 'defvar)
1032               (cdr-safe (cdr-safe form))
1033               (boundp (cadr form)))
1034          ;; Force variable to be re-set.
1035          `(progn (defvar ,(nth 1 form) nil ,@(nthcdr 3 form))
1036                  (setq-default ,(nth 1 form) ,(nth 2 form))))
1037         ;; `defcustom' is now macroexpanded to
1038         ;; `custom-declare-variable' with a quoted value arg.
1039         ((and (eq (car form) 'custom-declare-variable)
1040               (default-boundp (eval (nth 1 form) lexical-binding)))
1041          ;; Force variable to be bound, using :set function if specified.
1042          (let ((setfunc (memq :set form)))
1043            (when setfunc
1044              (setq setfunc (car-safe (cdr-safe setfunc)))
1045              (or (functionp setfunc) (setq setfunc nil)))
1046            (funcall (or setfunc 'set-default)
1047                     (eval (nth 1 form) lexical-binding)
1048                     ;; The second arg is an expression that evaluates to
1049                     ;; an expression.  The second evaluation is the one
1050                     ;; normally performed not by normal execution but by
1051                     ;; custom-initialize-set (for example), which does not
1052                     ;; use lexical-binding.
1053                     (eval (eval (nth 2 form) lexical-binding))))
1054          form)
1055         ;; `defface' is macroexpanded to `custom-declare-face'.
1056         ((eq (car form) 'custom-declare-face)
1057          ;; Reset the face.
1058          (let ((face-symbol (eval (nth 1 form) lexical-binding)))
1059            (setq face-new-frame-defaults
1060                  (assq-delete-all face-symbol face-new-frame-defaults))
1061            (put face-symbol 'face-defface-spec nil)
1062            (put face-symbol 'face-override-spec nil))
1063          form)
1064         ((eq (car form) 'progn)
1065          (cons 'progn (mapcar #'elisp--eval-defun-1 (cdr form))))
1066         (t form)))
1067
1068 (defun elisp--eval-defun ()
1069   "Evaluate defun that point is in or before.
1070 The value is displayed in the echo area.
1071 If the current defun is actually a call to `defvar',
1072 then reset the variable using the initial value expression
1073 even if the variable already has some other value.
1074 \(Normally `defvar' does not change the variable's value
1075 if it already has a value.\)
1076
1077 Return the result of evaluation."
1078   ;; FIXME: the print-length/level bindings should only be applied while
1079   ;; printing, not while evaluating.
1080   (let ((debug-on-error eval-expression-debug-on-error)
1081         (print-length eval-expression-print-length)
1082         (print-level eval-expression-print-level))
1083     (save-excursion
1084       ;; Arrange for eval-region to "read" the (possibly) altered form.
1085       ;; eval-region handles recording which file defines a function or
1086       ;; variable.
1087       (let ((standard-output t)
1088             beg end form)
1089         ;; Read the form from the buffer, and record where it ends.
1090         (save-excursion
1091           (end-of-defun)
1092           (beginning-of-defun)
1093           (setq beg (point))
1094           (setq form (read (current-buffer)))
1095           (setq end (point)))
1096         ;; Alter the form if necessary.
1097         (let ((form (eval-sexp-add-defvars
1098                      (elisp--eval-defun-1 (macroexpand form)))))
1099           (eval-region beg end standard-output
1100                        (lambda (_ignore)
1101                          ;; Skipping to the end of the specified region
1102                          ;; will make eval-region return.
1103                          (goto-char end)
1104                          form))))))
1105   (let ((str (eval-expression-print-format (car values))))
1106     (if str (princ str)))
1107   ;; The result of evaluation has been put onto VALUES.  So return it.
1108   (car values))
1109
1110 (defun eval-defun (edebug-it)
1111   "Evaluate the top-level form containing point, or after point.
1112
1113 If the current defun is actually a call to `defvar' or `defcustom',
1114 evaluating it this way resets the variable using its initial value
1115 expression (using the defcustom's :set function if there is one), even
1116 if the variable already has some other value.  \(Normally `defvar' and
1117 `defcustom' do not alter the value if there already is one.)  In an
1118 analogous way, evaluating a `defface' overrides any customizations of
1119 the face, so that it becomes defined exactly as the `defface' expression
1120 says.
1121
1122 If `eval-expression-debug-on-error' is non-nil, which is the default,
1123 this command arranges for all errors to enter the debugger.
1124
1125 With a prefix argument, instrument the code for Edebug.
1126
1127 If acting on a `defun' for FUNCTION, and the function was
1128 instrumented, `Edebug: FUNCTION' is printed in the echo area.  If not
1129 instrumented, just FUNCTION is printed.
1130
1131 If not acting on a `defun', the result of evaluation is displayed in
1132 the echo area.  This display is controlled by the variables
1133 `eval-expression-print-length' and `eval-expression-print-level',
1134 which see."
1135   (interactive "P")
1136   (cond (edebug-it
1137          (require 'edebug)
1138          (eval-defun (not edebug-all-defs)))
1139         (t
1140          (if (null eval-expression-debug-on-error)
1141              (elisp--eval-defun)
1142            (let (new-value value)
1143              (let ((debug-on-error elisp--eval-last-sexp-fake-value))
1144                (setq value (elisp--eval-defun))
1145                (setq new-value debug-on-error))
1146              (unless (eq elisp--eval-last-sexp-fake-value new-value)
1147                (setq debug-on-error new-value))
1148              value)))))
1149
1150 ;;; ElDoc Support
1151
1152 (defvar elisp--eldoc-last-data (make-vector 3 nil)
1153   "Bookkeeping; elements are as follows:
1154   0 - contains the last symbol read from the buffer.
1155   1 - contains the string last displayed in the echo area for variables,
1156       or argument string for functions.
1157   2 - 'function if function args, 'variable if variable documentation.")
1158
1159 (defun elisp-eldoc-documentation-function ()
1160   "`eldoc-documentation-function' (which see) for Emacs Lisp."
1161   (let ((current-symbol (elisp--current-symbol))
1162         (current-fnsym  (elisp--fnsym-in-current-sexp)))
1163     (cond ((null current-fnsym)
1164            nil)
1165           ((eq current-symbol (car current-fnsym))
1166            (or (apply #'elisp--get-fnsym-args-string current-fnsym)
1167                (elisp--get-var-docstring current-symbol)))
1168           (t
1169            (or (elisp--get-var-docstring current-symbol)
1170                (apply #'elisp--get-fnsym-args-string current-fnsym))))))
1171
1172 (defun elisp--get-fnsym-args-string (sym &optional index)
1173   "Return a string containing the parameter list of the function SYM.
1174 If SYM is a subr and no arglist is obtainable from the docstring
1175 or elsewhere, return a 1-line docstring."
1176   (let ((argstring
1177          (cond
1178           ((not (and sym (symbolp sym) (fboundp sym))) nil)
1179           ((and (eq sym (aref elisp--eldoc-last-data 0))
1180                 (eq 'function (aref elisp--eldoc-last-data 2)))
1181            (aref elisp--eldoc-last-data 1))
1182           (t
1183            (let* ((advertised (gethash (indirect-function sym)
1184                                        advertised-signature-table t))
1185                   doc
1186                   (args
1187                    (cond
1188                     ((listp advertised) advertised)
1189                     ((setq doc (help-split-fundoc
1190                                 (condition-case nil (documentation sym t)
1191                                   (invalid-function nil))
1192                                 sym))
1193                      (car doc))
1194                     (t (help-function-arglist sym)))))
1195              ;; Stringify, and store before highlighting, downcasing, etc.
1196              ;; FIXME should truncate before storing.
1197              (elisp--last-data-store sym (elisp--function-argstring args)
1198                                     'function))))))
1199     ;; Highlight, truncate.
1200     (if argstring
1201         (elisp--highlight-function-argument sym argstring index))))
1202
1203 (defun elisp--highlight-function-argument (sym args index)
1204   "Highlight argument INDEX in ARGS list for function SYM.
1205 In the absence of INDEX, just call `elisp--docstring-format-sym-doc'."
1206   ;; FIXME: This should probably work on the list representation of `args'
1207   ;; rather than its string representation.
1208   ;; FIXME: This function is much too long, we need to split it up!
1209   (let ((start          nil)
1210         (end            0)
1211         (argument-face  'eldoc-highlight-function-argument)
1212         (args-lst (mapcar (lambda (x)
1213                             (replace-regexp-in-string
1214                              "\\`[(]\\|[)]\\'" "" x))
1215                           (split-string args))))
1216     ;; Find the current argument in the argument string.  We need to
1217     ;; handle `&rest' and informal `...' properly.
1218     ;;
1219     ;; FIXME: What to do with optional arguments, like in
1220     ;;        (defun NAME ARGLIST [DOCSTRING] BODY...) case?
1221     ;;        The problem is there is no robust way to determine if
1222     ;;        the current argument is indeed a docstring.
1223
1224     ;; When `&key' is used finding position based on `index'
1225     ;; would be wrong, so find the arg at point and determine
1226     ;; position in ARGS based on this current arg.
1227     (when (string-match "&key" args)
1228       (let* (case-fold-search
1229              key-have-value
1230              (sym-name (symbol-name sym))
1231              (cur-w (current-word))
1232              (args-lst-ak (cdr (member "&key" args-lst)))
1233              (limit (save-excursion
1234                       (when (re-search-backward sym-name nil t)
1235                         (match-end 0))))
1236              (cur-a (if (and cur-w (string-match ":\\([^ ()]*\\)" cur-w))
1237                         (substring cur-w 1)
1238                       (save-excursion
1239                         (let (split)
1240                           (when (re-search-backward ":\\([^()\n]*\\)" limit t)
1241                             (setq split (split-string (match-string 1) " " t))
1242                             (prog1 (car split)
1243                               (when (cdr split)
1244                                 (setq key-have-value t))))))))
1245              ;; If `cur-a' is not one of `args-lst-ak'
1246              ;; assume user is entering an unknown key
1247              ;; referenced in last position in signature.
1248              (other-key-arg (and (stringp cur-a)
1249                                  args-lst-ak
1250                                  (not (member (upcase cur-a) args-lst-ak))
1251                                  (upcase (car (last args-lst-ak))))))
1252         (unless (string= cur-w sym-name)
1253           ;; The last keyword have already a value
1254           ;; i.e :foo a b and cursor is at b.
1255           ;; If signature have also `&rest'
1256           ;; (assume it is after the `&key' section)
1257           ;; go to the arg after `&rest'.
1258           (if (and key-have-value
1259                    (save-excursion
1260                      (not (re-search-forward ":.*" (point-at-eol) t)))
1261                    (string-match "&rest \\([^ ()]*\\)" args))
1262               (setq index nil ; Skip next block based on positional args.
1263                     start (match-beginning 1)
1264                     end   (match-end 1))
1265             ;; If `cur-a' is nil probably cursor is on a positional arg
1266             ;; before `&key', in this case, exit this block and determine
1267             ;; position with `index'.
1268             (when (and cur-a     ; A keyword arg (dot removed) or nil.
1269                        (or (string-match
1270                             (concat "\\_<" (upcase cur-a) "\\_>") args)
1271                            (string-match
1272                             (concat "\\_<" other-key-arg "\\_>") args)))
1273               (setq index nil ; Skip next block based on positional args.
1274                     start (match-beginning 0)
1275                     end   (match-end 0)))))))
1276     ;; Handle now positional arguments.
1277     (while (and index (>= index 1))
1278       (if (string-match "[^ ()]+" args end)
1279           (progn
1280             (setq start (match-beginning 0)
1281                   end   (match-end 0))
1282             (let ((argument (match-string 0 args)))
1283               (cond ((string= argument "&rest")
1284                      ;; All the rest arguments are the same.
1285                      (setq index 1))
1286                     ((string= argument "&optional"))         ; Skip.
1287                     ((string= argument "&allow-other-keys")) ; Skip.
1288                     ;; Back to index 0 in ARG1 ARG2 ARG2 ARG3 etc...
1289                     ;; like in `setq'.
1290                     ((or (and (string-match-p "\\.\\.\\.$" argument)
1291                               (string= argument (car (last args-lst))))
1292                          (and (string-match-p "\\.\\.\\.$"
1293                                               (substring args 1 (1- (length args))))
1294                               (= (length (remove "..." args-lst)) 2)
1295                               (> index 1) (eq (logand index 1) 1)))
1296                      (setq index 0))
1297                     (t
1298                      (setq index (1- index))))))
1299         (setq end           (length args)
1300               start         (1- end)
1301               argument-face 'font-lock-warning-face
1302               index         0)))
1303     (let ((doc args))
1304       (when start
1305         (setq doc (copy-sequence args))
1306         (add-text-properties start end (list 'face argument-face) doc))
1307       (setq doc (elisp--docstring-format-sym-doc
1308                  sym doc (if (functionp sym) 'font-lock-function-name-face
1309                            'font-lock-keyword-face)))
1310       doc)))
1311
1312 ;; Return a string containing a brief (one-line) documentation string for
1313 ;; the variable.
1314 (defun elisp--get-var-docstring (sym)
1315   (cond ((not sym) nil)
1316         ((and (eq sym (aref elisp--eldoc-last-data 0))
1317               (eq 'variable (aref elisp--eldoc-last-data 2)))
1318          (aref elisp--eldoc-last-data 1))
1319         (t
1320          (let ((doc (documentation-property sym 'variable-documentation t)))
1321            (when doc
1322              (let ((doc (elisp--docstring-format-sym-doc
1323                          sym (elisp--docstring-first-line doc)
1324                          'font-lock-variable-name-face)))
1325                (elisp--last-data-store sym doc 'variable)))))))
1326
1327 (defun elisp--last-data-store (symbol doc type)
1328   (aset elisp--eldoc-last-data 0 symbol)
1329   (aset elisp--eldoc-last-data 1 doc)
1330   (aset elisp--eldoc-last-data 2 type)
1331   doc)
1332
1333 ;; Note that any leading `*' in the docstring (which indicates the variable
1334 ;; is a user option) is removed.
1335 (defun elisp--docstring-first-line (doc)
1336   (and (stringp doc)
1337        (substitute-command-keys
1338         (save-match-data
1339           ;; Don't use "^" in the regexp below since it may match
1340           ;; anywhere in the doc-string.
1341           (let ((start (if (string-match "\\`\\*" doc) (match-end 0) 0)))
1342             (cond ((string-match "\n" doc)
1343                    (substring doc start (match-beginning 0)))
1344                   ((zerop start) doc)
1345                   (t (substring doc start))))))))
1346
1347 (defvar eldoc-echo-area-use-multiline-p)
1348
1349 ;; If the entire line cannot fit in the echo area, the symbol name may be
1350 ;; truncated or eliminated entirely from the output to make room for the
1351 ;; description.
1352 (defun elisp--docstring-format-sym-doc (sym doc face)
1353   (save-match-data
1354     (let* ((name (symbol-name sym))
1355            (ea-multi eldoc-echo-area-use-multiline-p)
1356            ;; Subtract 1 from window width since emacs will not write
1357            ;; any chars to the last column, or in later versions, will
1358            ;; cause a wraparound and resize of the echo area.
1359            (ea-width (1- (window-width (minibuffer-window))))
1360            (strip (- (+ (length name) (length ": ") (length doc)) ea-width)))
1361       (cond ((or (<= strip 0)
1362                  (eq ea-multi t)
1363                  (and ea-multi (> (length doc) ea-width)))
1364              (format "%s: %s" (propertize name 'face face) doc))
1365             ((> (length doc) ea-width)
1366              (substring (format "%s" doc) 0 ea-width))
1367             ((>= strip (length name))
1368              (format "%s" doc))
1369             (t
1370              ;; Show the end of the partial symbol name, rather
1371              ;; than the beginning, since the former is more likely
1372              ;; to be unique given package namespace conventions.
1373              (setq name (substring name strip))
1374              (format "%s: %s" (propertize name 'face face) doc))))))
1375
1376 \f
1377 ;; Return a list of current function name and argument index.
1378 (defun elisp--fnsym-in-current-sexp ()
1379   (save-excursion
1380     (let ((argument-index (1- (elisp--beginning-of-sexp))))
1381       ;; If we are at the beginning of function name, this will be -1.
1382       (when (< argument-index 0)
1383         (setq argument-index 0))
1384       ;; Don't do anything if current word is inside a string.
1385       (if (= (or (char-after (1- (point))) 0) ?\")
1386           nil
1387         (list (elisp--current-symbol) argument-index)))))
1388
1389 ;; Move to the beginning of current sexp.  Return the number of nested
1390 ;; sexp the point was over or after.
1391 (defun elisp--beginning-of-sexp ()
1392   (let ((parse-sexp-ignore-comments t)
1393         (num-skipped-sexps 0))
1394     (condition-case _
1395         (progn
1396           ;; First account for the case the point is directly over a
1397           ;; beginning of a nested sexp.
1398           (condition-case _
1399               (let ((p (point)))
1400                 (forward-sexp -1)
1401                 (forward-sexp 1)
1402                 (when (< (point) p)
1403                   (setq num-skipped-sexps 1)))
1404             (error))
1405           (while
1406               (let ((p (point)))
1407                 (forward-sexp -1)
1408                 (when (< (point) p)
1409                   (setq num-skipped-sexps (1+ num-skipped-sexps))))))
1410       (error))
1411     num-skipped-sexps))
1412
1413 ;; returns nil unless current word is an interned symbol.
1414 (defun elisp--current-symbol ()
1415   (let ((c (char-after (point))))
1416     (and c
1417          (memq (char-syntax c) '(?w ?_))
1418          (intern-soft (current-word)))))
1419
1420 (defun elisp--function-argstring (arglist)
1421   "Return ARGLIST as a string enclosed by ().
1422 ARGLIST is either a string, or a list of strings or symbols."
1423   (let ((str (cond ((stringp arglist) arglist)
1424                    ((not (listp arglist)) nil)
1425                    (t (format "%S" (help-make-usage 'toto arglist))))))
1426     (if (and str (string-match "\\`([^ )]+ ?" str))
1427         (replace-match "(" t t str)
1428       str)))
1429
1430 (provide 'elisp-mode)
1431 ;;; elisp-mode.el ends here