lisp/progmodes/elisp-mode.el

   1 ;;; elisp-mode.el --- Emacs Lisp mode  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 1985-1986, 1999-2015 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: emacs-devel@gnu.org
   6 ;; Keywords: lisp, languages
   7 ;; Package: emacs
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; The major mode for editing Emacs Lisp code.
  27 ;; This mode is documented in the Emacs manual.
  28
  29 ;;; Code:
  30
  31 (require 'lisp-mode)
  32
  33 (define-abbrev-table 'emacs-lisp-mode-abbrev-table ()
  34   "Abbrev table for Emacs Lisp mode.
  35 It has `lisp-mode-abbrev-table' as its parent."
  36   :parents (list lisp-mode-abbrev-table))
  37
  38 (defvar emacs-lisp-mode-syntax-table
  39   (let ((table (make-syntax-table lisp--mode-syntax-table)))
  40     (modify-syntax-entry ?\[ "(]  " table)
  41     (modify-syntax-entry ?\] ")[  " table)
  42     table)
  43   "Syntax table used in `emacs-lisp-mode'.")
  44
  45 (defvar emacs-lisp-mode-map
  46   (let ((map (make-sparse-keymap "Emacs-Lisp"))
  47         (menu-map (make-sparse-keymap "Emacs-Lisp"))
  48         (lint-map (make-sparse-keymap))
  49         (prof-map (make-sparse-keymap))
  50         (tracing-map (make-sparse-keymap)))
  51     (set-keymap-parent map lisp-mode-shared-map)
  52     (define-key map "\e\t" 'completion-at-point)
  53     (define-key map "\e\C-x" 'eval-defun)
  54     (define-key map "\e\C-q" 'indent-pp-sexp)
  55     (bindings--define-key map [menu-bar emacs-lisp]
  56       (cons "Emacs-Lisp" menu-map))
  57     (bindings--define-key menu-map [eldoc]
  58       '(menu-item "Auto-Display Documentation Strings" eldoc-mode
  59                   :button (:toggle . (bound-and-true-p eldoc-mode))
  60                   :help "Display the documentation string for the item under cursor"))
  61     (bindings--define-key menu-map [checkdoc]
  62       '(menu-item "Check Documentation Strings" checkdoc
  63                   :help "Check documentation strings for style requirements"))
  64     (bindings--define-key menu-map [re-builder]
  65       '(menu-item "Construct Regexp" re-builder
  66                   :help "Construct a regexp interactively"))
  67     (bindings--define-key menu-map [tracing] (cons "Tracing" tracing-map))
  68     (bindings--define-key tracing-map [tr-a]
  69       '(menu-item "Untrace All" untrace-all
  70                   :help "Untrace all currently traced functions"))
  71     (bindings--define-key tracing-map [tr-uf]
  72       '(menu-item "Untrace Function..." untrace-function
  73                   :help "Untrace function, and possibly activate all remaining advice"))
  74     (bindings--define-key tracing-map [tr-sep] menu-bar-separator)
  75     (bindings--define-key tracing-map [tr-q]
  76       '(menu-item "Trace Function Quietly..." trace-function-background
  77                   :help "Trace the function with trace output going quietly to a buffer"))
  78     (bindings--define-key tracing-map [tr-f]
  79       '(menu-item "Trace Function..." trace-function
  80                   :help "Trace the function given as an argument"))
  81     (bindings--define-key menu-map [profiling] (cons "Profiling" prof-map))
  82     (bindings--define-key prof-map [prof-restall]
  83       '(menu-item "Remove Instrumentation for All Functions" elp-restore-all
  84                   :help "Restore the original definitions of all functions being profiled"))
  85     (bindings--define-key prof-map [prof-restfunc]
  86       '(menu-item "Remove Instrumentation for Function..." elp-restore-function
  87                   :help "Restore an instrumented function to its original definition"))
  88
  89     (bindings--define-key prof-map [sep-rem] menu-bar-separator)
  90     (bindings--define-key prof-map [prof-resall]
  91       '(menu-item "Reset Counters for All Functions" elp-reset-all
  92                   :help "Reset the profiling information for all functions being profiled"))
  93     (bindings--define-key prof-map [prof-resfunc]
  94       '(menu-item "Reset Counters for Function..." elp-reset-function
  95                   :help "Reset the profiling information for a function"))
  96     (bindings--define-key prof-map [prof-res]
  97       '(menu-item "Show Profiling Results" elp-results
  98                   :help "Display current profiling results"))
  99     (bindings--define-key prof-map [prof-pack]
 100       '(menu-item "Instrument Package..." elp-instrument-package
 101                   :help "Instrument for profiling all function that start with a prefix"))
 102     (bindings--define-key prof-map [prof-func]
 103       '(menu-item "Instrument Function..." elp-instrument-function
 104                   :help "Instrument a function for profiling"))
 105     ;; Maybe this should be in a separate submenu from the ELP stuff?
 106     (bindings--define-key prof-map [sep-natprof] menu-bar-separator)
 107     (bindings--define-key prof-map [prof-natprof-stop]
 108       '(menu-item "Stop Native Profiler" profiler-stop
 109                   :help "Stop recording profiling information"
 110                   :enable (and (featurep 'profiler)
 111                                (profiler-running-p))))
 112     (bindings--define-key prof-map [prof-natprof-report]
 113       '(menu-item "Show Profiler Report" profiler-report
 114                   :help "Show the current profiler report"
 115                   :enable (and (featurep 'profiler)
 116                                (profiler-running-p))))
 117     (bindings--define-key prof-map [prof-natprof-start]
 118       '(menu-item "Start Native Profiler..." profiler-start
 119                   :help "Start recording profiling information"))
 120
 121     (bindings--define-key menu-map [lint] (cons "Linting" lint-map))
 122     (bindings--define-key lint-map [lint-di]
 123       '(menu-item "Lint Directory..." elint-directory
 124                   :help "Lint a directory"))
 125     (bindings--define-key lint-map [lint-f]
 126       '(menu-item "Lint File..." elint-file
 127                   :help "Lint a file"))
 128     (bindings--define-key lint-map [lint-b]
 129       '(menu-item "Lint Buffer" elint-current-buffer
 130                   :help "Lint the current buffer"))
 131     (bindings--define-key lint-map [lint-d]
 132       '(menu-item "Lint Defun" elint-defun
 133                   :help "Lint the function at point"))
 134     (bindings--define-key menu-map [edebug-defun]
 135       '(menu-item "Instrument Function for Debugging" edebug-defun
 136                   :help "Evaluate the top level form point is in, stepping through with Edebug"
 137                   :keys "C-u C-M-x"))
 138     (bindings--define-key menu-map [separator-byte] menu-bar-separator)
 139     (bindings--define-key menu-map [disas]
 140       '(menu-item "Disassemble Byte Compiled Object..." disassemble
 141                   :help "Print disassembled code for OBJECT in a buffer"))
 142     (bindings--define-key menu-map [byte-recompile]
 143       '(menu-item "Byte-recompile Directory..." byte-recompile-directory
 144                   :help "Recompile every `.el' file in DIRECTORY that needs recompilation"))
 145     (bindings--define-key menu-map [emacs-byte-compile-and-load]
 146       '(menu-item "Byte-compile and Load" emacs-lisp-byte-compile-and-load
 147                   :help "Byte-compile the current file (if it has changed), then load compiled code"))
 148     (bindings--define-key menu-map [byte-compile]
 149       '(menu-item "Byte-compile This File" emacs-lisp-byte-compile
 150                   :help "Byte compile the file containing the current buffer"))
 151     (bindings--define-key menu-map [separator-eval] menu-bar-separator)
 152     (bindings--define-key menu-map [ielm]
 153       '(menu-item "Interactive Expression Evaluation" ielm
 154                   :help "Interactively evaluate Emacs Lisp expressions"))
 155     (bindings--define-key menu-map [eval-buffer]
 156       '(menu-item "Evaluate Buffer" eval-buffer
 157                   :help "Execute the current buffer as Lisp code"))
 158     (bindings--define-key menu-map [eval-region]
 159       '(menu-item "Evaluate Region" eval-region
 160                   :help "Execute the region as Lisp code"
 161                   :enable mark-active))
 162     (bindings--define-key menu-map [eval-sexp]
 163       '(menu-item "Evaluate Last S-expression" eval-last-sexp
 164                   :help "Evaluate sexp before point; print value in echo area"))
 165     (bindings--define-key menu-map [separator-format] menu-bar-separator)
 166     (bindings--define-key menu-map [comment-region]
 167       '(menu-item "Comment Out Region" comment-region
 168                   :help "Comment or uncomment each line in the region"
 169                   :enable mark-active))
 170     (bindings--define-key menu-map [indent-region]
 171       '(menu-item "Indent Region" indent-region
 172                   :help "Indent each nonblank line in the region"
 173                   :enable mark-active))
 174     (bindings--define-key menu-map [indent-line]
 175       '(menu-item "Indent Line" lisp-indent-line))
 176     map)
 177   "Keymap for Emacs Lisp mode.
 178 All commands in `lisp-mode-shared-map' are inherited by this map.")
 179
 180 (defun emacs-lisp-byte-compile ()
 181   "Byte compile the file containing the current buffer."
 182   (interactive)
 183   (if buffer-file-name
 184       (byte-compile-file buffer-file-name)
 185     (error "The buffer must be saved in a file first")))
 186
 187 (defun emacs-lisp-byte-compile-and-load ()
 188   "Byte-compile the current file (if it has changed), then load compiled code."
 189   (interactive)
 190   (or buffer-file-name
 191       (error "The buffer must be saved in a file first"))
 192   (require 'bytecomp)
 193   ;; Recompile if file or buffer has changed since last compilation.
 194   (if (and (buffer-modified-p)
 195            (y-or-n-p (format "Save buffer %s first? " (buffer-name))))
 196       (save-buffer))
 197   (byte-recompile-file buffer-file-name nil 0 t))
 198
 199 (defun emacs-lisp-macroexpand ()
 200   "Macroexpand the form after point.
 201 Comments in the form will be lost."
 202   (interactive)
 203   (let* ((start (point))
 204          (exp (read (current-buffer)))
 205          ;; Compute it before, since it may signal errors.
 206          (new (macroexpand-1 exp)))
 207     (if (equal exp new)
 208         (message "Not a macro call, nothing to expand")
 209       (delete-region start (point))
 210       (pp new (current-buffer))
 211       (if (bolp) (delete-char -1))
 212       (indent-region start (point)))))
 213
 214 (defcustom emacs-lisp-mode-hook nil
 215   "Hook run when entering Emacs Lisp mode."
 216   :options '(eldoc-mode imenu-add-menubar-index checkdoc-minor-mode)
 217   :type 'hook
 218   :group 'lisp)
 219
 220 ;;;###autoload
 221 (define-derived-mode emacs-lisp-mode prog-mode "Emacs-Lisp"
 222   "Major mode for editing Lisp code to run in Emacs.
 223 Commands:
 224 Delete converts tabs to spaces as it moves back.
 225 Blank lines separate paragraphs.  Semicolons start comments.
 226
 227 \\{emacs-lisp-mode-map}"
 228   :group 'lisp
 229   (defvar xref-find-function)
 230   (defvar xref-identifier-completion-table-function)
 231   (lisp-mode-variables nil nil 'elisp)
 232   (add-hook 'after-load-functions #'elisp--font-lock-flush-elisp-buffers)
 233   (setq-local electric-pair-text-pairs
 234               (cons '(?\` . ?\') electric-pair-text-pairs))
 235   (setq imenu-case-fold-search nil)
 236   (add-function :before-until (local 'eldoc-documentation-function)
 237                 #'elisp-eldoc-documentation-function)
 238   (setq-local xref-find-function #'elisp-xref-find)
 239   (setq-local xref-identifier-completion-table-function
 240               #'elisp--xref-identifier-completion-table)
 241   (add-hook 'completion-at-point-functions
 242             #'elisp-completion-at-point nil 'local))
 243
 244 ;; Font-locking support.
 245
 246 (defun elisp--font-lock-flush-elisp-buffers (&optional file)
 247   ;; FIXME: Aren't we only ever called from after-load-functions?
 248   ;; Don't flush during load unless called from after-load-functions.
 249   ;; In that case, FILE is non-nil.  It's somehow strange that
 250   ;; load-in-progress is t when an after-load-function is called since
 251   ;; that should run *after* the load...
 252   (when (or (not load-in-progress) file)
 253     ;; FIXME: If the loaded file did not define any macros, there shouldn't
 254     ;; be any need to font-lock-flush all the Elisp buffers.
 255     (dolist (buf (buffer-list))
 256       (with-current-buffer buf
 257         (when (derived-mode-p 'emacs-lisp-mode)
 258           ;; So as to take into account new macros that may have been defined
 259           ;; by the just-loaded file.
 260           (font-lock-flush))))))
 261
 262 ;;; Completion at point for Elisp
 263
 264 (defun elisp--local-variables-1 (vars sexp)
 265   "Return the vars locally bound around the witness, or nil if not found."
 266   (let (res)
 267     (while
 268         (unless
 269             (setq res
 270                   (pcase sexp
 271                     (`(,(or `let `let*) ,bindings)
 272                      (let ((vars vars))
 273                        (when (eq 'let* (car sexp))
 274                          (dolist (binding (cdr (reverse bindings)))
 275                            (push (or (car-safe binding) binding) vars)))
 276                        (elisp--local-variables-1
 277                         vars (car (cdr-safe (car (last bindings)))))))
 278                     (`(,(or `let `let*) ,bindings . ,body)
 279                      (let ((vars vars))
 280                        (dolist (binding bindings)
 281                          (push (or (car-safe binding) binding) vars))
 282                        (elisp--local-variables-1 vars (car (last body)))))
 283                     (`(lambda ,_args)
 284                      ;; FIXME: Look for the witness inside `args'.
 285                      (setq sexp nil))
 286                     (`(lambda ,args . ,body)
 287                      (elisp--local-variables-1
 288                       (append (remq '&optional (remq '&rest args)) vars)
 289                       (car (last body))))
 290                     (`(condition-case ,_ ,e) (elisp--local-variables-1 vars e))
 291                     (`(condition-case ,v ,_ . ,catches)
 292                      (elisp--local-variables-1
 293                       (cons v vars) (cdr (car (last catches)))))
 294                     (`(quote . ,_)
 295                      ;; FIXME: Look for the witness inside sexp.
 296                      (setq sexp nil))
 297                     ;; FIXME: Handle `cond'.
 298                     (`(,_ . ,_)
 299                      (elisp--local-variables-1 vars (car (last sexp))))
 300                     (`elisp--witness--lisp (or vars '(nil)))
 301                     (_ nil)))
 302           ;; We didn't find the witness in the last element so we try to
 303           ;; backtrack to the last-but-one.
 304           (setq sexp (ignore-errors (butlast sexp)))))
 305     res))
 306
 307 (defun elisp--local-variables ()
 308   "Return a list of locally let-bound variables at point."
 309   (save-excursion
 310     (skip-syntax-backward "w_")
 311     (let* ((ppss (syntax-ppss))
 312            (txt (buffer-substring-no-properties (or (car (nth 9 ppss)) (point))
 313                                                 (or (nth 8 ppss) (point))))
 314            (closer ()))
 315       (dolist (p (nth 9 ppss))
 316         (push (cdr (syntax-after p)) closer))
 317       (setq closer (apply #'string closer))
 318       (let* ((sexp (condition-case nil
 319                        (car (read-from-string
 320                              (concat txt "elisp--witness--lisp" closer)))
 321                      ((invalid-read-syntax end-of-file) nil)))
 322              (macroexpand-advice (lambda (expander form &rest args)
 323                                    (condition-case nil
 324                                        (apply expander form args)
 325                                      (error form))))
 326              (sexp
 327               (unwind-protect
 328                   (progn
 329                     (advice-add 'macroexpand :around macroexpand-advice)
 330                     (macroexpand-all sexp))
 331                 (advice-remove 'macroexpand macroexpand-advice)))
 332              (vars (elisp--local-variables-1 nil sexp)))
 333         (delq nil
 334               (mapcar (lambda (var)
 335                         (and (symbolp var)
 336                              (not (string-match (symbol-name var) "\\`[&_]"))
 337                              ;; Eliminate uninterned vars.
 338                              (intern-soft var)
 339                              var))
 340                       vars))))))
 341
 342 (defvar elisp--local-variables-completion-table
 343   ;; Use `defvar' rather than `defconst' since defconst would purecopy this
 344   ;; value, which would doubly fail: it would fail because purecopy can't
 345   ;; handle the recursive bytecode object, and it would fail because it would
 346   ;; move `lastpos' and `lastvars' to pure space where they'd be immutable!
 347   (let ((lastpos nil) (lastvars nil))
 348     (letrec ((hookfun (lambda ()
 349                         (setq lastpos nil)
 350                         (remove-hook 'post-command-hook hookfun))))
 351       (completion-table-dynamic
 352        (lambda (_string)
 353          (save-excursion
 354            (skip-syntax-backward "_w")
 355            (let ((newpos (cons (point) (current-buffer))))
 356              (unless (equal lastpos newpos)
 357                (add-hook 'post-command-hook hookfun)
 358                (setq lastpos newpos)
 359                (setq lastvars
 360                      (mapcar #'symbol-name (elisp--local-variables))))))
 361          lastvars)))))
 362
 363 (defun elisp--expect-function-p (pos)
 364   "Return non-nil if the symbol at point is expected to be a function."
 365   (or
 366    (and (eq (char-before pos) ?')
 367         (eq (char-before (1- pos)) ?#))
 368    (save-excursion
 369      (let ((parent (nth 1 (syntax-ppss pos))))
 370        (when parent
 371          (goto-char parent)
 372          (and
 373           (looking-at (concat "(\\(cl-\\)?"
 374                               (regexp-opt '("declare-function"
 375                                             "function" "defadvice"
 376                                             "callf" "callf2"
 377                                             "defsetf"))
 378                               "[ \t\r\n]+"))
 379           (eq (match-end 0) pos)))))))
 380
 381 (defun elisp--form-quoted-p (pos)
 382   "Return non-nil if the form at POS is not evaluated.
 383 It can be quoted, or be inside a quoted form."
 384   ;; FIXME: Do some macro expansion maybe.
 385   (save-excursion
 386     (let ((state (syntax-ppss pos)))
 387       (or (nth 8 state)   ; Code inside strings usually isn't evaluated.
 388           ;; FIXME: The 9th element is undocumented.
 389           (let ((nesting (cons (point) (reverse (nth 9 state))))
 390                 res)
 391             (while (and nesting (not res))
 392               (goto-char (pop nesting))
 393               (cond
 394                ((or (eq (char-after) ?\[)
 395                     (progn
 396                       (skip-chars-backward " ")
 397                       (memq (char-before) '(?' ?`))))
 398                 (setq res t))
 399                ((eq (char-before) ?,)
 400                 (setq nesting nil))))
 401             res)))))
 402
 403 ;; FIXME: Support for Company brings in features which straddle eldoc.
 404 ;; We should consolidate this, so that major modes can provide all that
 405 ;; data all at once:
 406 ;; - a function to extract "the reference at point" (may be more complex
 407 ;;     than a mere string, to distinguish various namespaces).
 408 ;; - a function to jump to such a reference.
 409 ;; - a function to show the signature/interface of such a reference.
 410 ;; - a function to build a help-buffer about that reference.
 411 ;; FIXME: Those functions should also be used by the normal completion code in
 412 ;; the *Completions* buffer.
 413
 414 (defun elisp--company-doc-buffer (str)
 415   (let ((symbol (intern-soft str)))
 416     ;; FIXME: we really don't want to "display-buffer and then undo it".
 417     (save-window-excursion
 418       ;; Make sure we don't display it in another frame, otherwise
 419       ;; save-window-excursion won't be able to undo it.
 420       (let ((display-buffer-overriding-action
 421              '(nil . ((inhibit-switch-frame . t)))))
 422         (ignore-errors
 423           (cond
 424            ((fboundp symbol) (describe-function symbol))
 425            ((boundp symbol) (describe-variable symbol))
 426            ((featurep symbol) (describe-package symbol))
 427            ((facep symbol) (describe-face symbol))
 428            (t (signal 'user-error nil)))
 429           (help-buffer))))))
 430
 431 (defun elisp--company-doc-string (str)
 432   (let* ((symbol (intern-soft str))
 433          (doc (if (fboundp symbol)
 434                   (documentation symbol t)
 435                 (documentation-property symbol 'variable-documentation t))))
 436     (and (stringp doc)
 437          (string-match ".*$" doc)
 438          (match-string 0 doc))))
 439
 440 (declare-function find-library-name "find-func" (library))
 441 (declare-function find-function-library "find-func" (function &optional l-o v))
 442
 443 (defun elisp--company-location (str)
 444   (let ((sym (intern-soft str)))
 445     (cond
 446      ((fboundp sym) (find-definition-noselect sym nil))
 447      ((boundp sym) (find-definition-noselect sym 'defvar))
 448      ((featurep sym)
 449       (require 'find-func)
 450       (cons (find-file-noselect (find-library-name
 451                                  (symbol-name sym)))
 452             0))
 453      ((facep sym) (find-definition-noselect sym 'defface)))))
 454
 455 (defun elisp-completion-at-point ()
 456   "Function used for `completion-at-point-functions' in `emacs-lisp-mode'."
 457   (with-syntax-table emacs-lisp-mode-syntax-table
 458     (let* ((pos (point))
 459            (beg (condition-case nil
 460                     (save-excursion
 461                       (backward-sexp 1)
 462                       (skip-syntax-forward "'")
 463                       (point))
 464                   (scan-error pos)))
 465            (end
 466             (unless (or (eq beg (point-max))
 467                         (member (char-syntax (char-after beg))
 468                                 '(?\s ?\" ?\( ?\))))
 469               (condition-case nil
 470                   (save-excursion
 471                     (goto-char beg)
 472                     (forward-sexp 1)
 473                     (skip-chars-backward "'")
 474                     (when (>= (point) pos)
 475                       (point)))
 476                 (scan-error pos))))
 477            ;; t if in function position.
 478            (funpos (eq (char-before beg) ?\())
 479            (quoted (elisp--form-quoted-p beg)))
 480       (when (and end (or (not (nth 8 (syntax-ppss)))
 481                          (eq (char-before beg) ?`)))
 482         (let ((table-etc
 483                (if (or (not funpos) quoted)
 484                    ;; FIXME: We could look at the first element of the list and
 485                    ;; use it to provide a more specific completion table in some
 486                    ;; cases.  E.g. filter out keywords that are not understood by
 487                    ;; the macro/function being called.
 488                    (cond
 489                     ((elisp--expect-function-p beg)
 490                      (list nil obarray
 491                            :predicate #'fboundp
 492                            :company-doc-buffer #'elisp--company-doc-buffer
 493                            :company-docsig #'elisp--company-doc-string
 494                            :company-location #'elisp--company-location))
 495                     (quoted
 496                      (list nil obarray
 497                            ;; Don't include all symbols (bug#16646).
 498                            :predicate (lambda (sym)
 499                                         (or (boundp sym)
 500                                             (fboundp sym)
 501                                             (featurep sym)
 502                                             (symbol-plist sym)))
 503                            :annotation-function
 504                            (lambda (str) (if (fboundp (intern-soft str)) " <f>"))
 505                            :company-doc-buffer #'elisp--company-doc-buffer
 506                            :company-docsig #'elisp--company-doc-string
 507                            :company-location #'elisp--company-location))
 508                     (t
 509                      (list nil (completion-table-merge
 510                                 elisp--local-variables-completion-table
 511                                 (apply-partially #'completion-table-with-predicate
 512                                                  obarray
 513                                                  #'boundp
 514                                                  'strict))
 515                            :company-doc-buffer #'elisp--company-doc-buffer
 516                            :company-docsig #'elisp--company-doc-string
 517                            :company-location #'elisp--company-location)))
 518                  ;; Looks like a funcall position.  Let's double check.
 519                  (save-excursion
 520                    (goto-char (1- beg))
 521                    (let ((parent
 522                           (condition-case nil
 523                               (progn (up-list -1) (forward-char 1)
 524                                      (let ((c (char-after)))
 525                                        (if (eq c ?\() ?\(
 526                                          (if (memq (char-syntax c) '(?w ?_))
 527                                              (read (current-buffer))))))
 528                             (error nil))))
 529                      (pcase parent
 530                        ;; FIXME: Rather than hardcode special cases here,
 531                        ;; we should use something like a symbol-property.
 532                        (`declare
 533                         (list t (mapcar (lambda (x) (symbol-name (car x)))
 534                                         (delete-dups
 535                                          ;; FIXME: We should include some
 536                                          ;; docstring with each entry.
 537                                          (append
 538                                           macro-declarations-alist
 539                                           defun-declarations-alist)))))
 540                        ((and (or `condition-case `condition-case-unless-debug)
 541                              (guard (save-excursion
 542                                       (ignore-errors
 543                                         (forward-sexp 2)
 544                                         (< (point) beg)))))
 545                         (list t obarray
 546                               :predicate (lambda (sym) (get sym 'error-conditions))))
 547                        ((or `let `let*
 548                             (and ?\(
 549                                  (guard (save-excursion
 550                                           (goto-char (1- beg))
 551                                           (up-list -1)
 552                                           (forward-symbol -1)
 553                                           (looking-at "\\_<let\\*?\\_>")))))
 554                         (list t obarray
 555                               :predicate #'boundp
 556                               :company-doc-buffer #'elisp--company-doc-buffer
 557                               :company-docsig #'elisp--company-doc-string
 558                               :company-location #'elisp--company-location))
 559                        (_ (list nil obarray
 560                                 :predicate #'fboundp
 561                                 :company-doc-buffer #'elisp--company-doc-buffer
 562                                 :company-docsig #'elisp--company-doc-string
 563                                 :company-location #'elisp--company-location
 564                                 ))))))))
 565           (nconc (list beg end)
 566                  (if (null (car table-etc))
 567                      (cdr table-etc)
 568                    (cons
 569                     (if (memq (char-syntax (or (char-after end) ?\s))
 570                               '(?\s ?>))
 571                         (cadr table-etc)
 572                       (apply-partially 'completion-table-with-terminator
 573                                        " " (cadr table-etc)))
 574                     (cddr table-etc)))))))))
 575
 576 (define-obsolete-function-alias
 577   'lisp-completion-at-point 'elisp-completion-at-point "25.1")
 578
 579 ;;; Xref backend
 580
 581 (declare-function xref-make-elisp-location "xref" (symbol type file))
 582 (declare-function xref-make-bogus-location "xref" (message))
 583 (declare-function xref-make "xref" (description location))
 584
 585 (defun elisp-xref-find (action id)
 586   (require 'find-func)
 587   (pcase action
 588     (`definitions
 589       (let ((sym (intern-soft id)))
 590         (when sym
 591           (elisp--xref-find-definitions sym))))
 592     (`references
 593      (elisp--xref-find-references id))
 594     (`apropos
 595      (elisp--xref-find-apropos id))))
 596
 597 (defun elisp--xref-identifier-location (type sym)
 598   (let ((file
 599          (pcase type
 600            (`defun (when (fboundp sym)
 601                      (let ((fun-lib
 602                             (find-function-library sym)))
 603                        (setq sym (car fun-lib))
 604                        (cdr fun-lib))))
 605            (`defvar (and (boundp sym)
 606                          ;; Don't show minor modes twice.
 607                          ;; TODO: If TYPE ever becomes dependent on the
 608                          ;; context, move this check outside.
 609                          (not (fboundp sym))
 610                          (or (symbol-file sym 'defvar)
 611                              (help-C-file-name sym 'var))))
 612            (`feature (and (featurep sym)
 613                           ;; Skip when a function with the same name
 614                           ;; is defined, because it's probably in the
 615                           ;; same file.
 616                           (not (fboundp sym))
 617                           (ignore-errors
 618                             (find-library-name (symbol-name sym)))))
 619            (`defface (when (facep sym)
 620                        (symbol-file sym 'defface))))))
 621     (when file
 622       (when (string-match-p "\\.elc\\'" file)
 623         (setq file (substring file 0 -1)))
 624       (xref-make-elisp-location sym type file))))
 625
 626 (defun elisp--xref-find-definitions (symbol)
 627   (save-excursion
 628     (let ((fmt "(%s %s)")
 629           lst)
 630       (put-text-property 1 3 'face 'font-lock-keyword-face fmt)
 631       (put-text-property 4 6 'face 'font-lock-function-name-face fmt)
 632       (dolist (type '(feature defface defvar defun))
 633         (let ((loc
 634                (condition-case err
 635                    (elisp--xref-identifier-location type symbol)
 636                  (error
 637                   (xref-make-bogus-location (error-message-string err))))))
 638           (when loc
 639             (push
 640              (xref-make (format fmt type symbol)
 641                         loc)
 642              lst))))
 643       lst)))
 644
 645 (defun elisp--xref-find-references (symbol)
 646   (let* ((dirs (sort
 647                 (mapcar
 648                  (lambda (dir)
 649                    (file-name-as-directory (expand-file-name dir)))
 650                  (cons package-user-dir load-path))
 651                 #'string<))
 652          (ref dirs))
 653     ;; Delete subdirectories from the list.
 654     (while (cdr ref)
 655       (if (string-prefix-p (car ref) (cadr ref))
 656           (setcdr ref (cddr ref))
 657         (setq ref (cdr ref))))
 658     (cl-mapcan
 659      (lambda (dir)
 660        (and (file-exists-p dir)
 661             (xref-collect-references symbol dir)))
 662      dirs)))
 663
 664 (defun elisp--xref-find-apropos (regexp)
 665   (apply #'nconc
 666          (let (lst)
 667            (dolist (sym (apropos-internal regexp))
 668             (push (elisp--xref-find-definitions sym) lst))
 669            (nreverse lst))))
 670
 671 (defvar elisp--xref-identifier-completion-table
 672   (apply-partially #'completion-table-with-predicate
 673                    obarray
 674                    (lambda (sym)
 675                      (or (boundp sym)
 676                          (fboundp sym)
 677                          (featurep sym)
 678                          (facep sym)))
 679                    'strict))
 680
 681 (defun elisp--xref-identifier-completion-table ()
 682   elisp--xref-identifier-completion-table)
 683
 684 ;;; Elisp Interaction mode
 685
 686 (defvar lisp-interaction-mode-map
 687   (let ((map (make-sparse-keymap))
 688         (menu-map (make-sparse-keymap "Lisp-Interaction")))
 689     (set-keymap-parent map lisp-mode-shared-map)
 690     (define-key map "\e\C-x" 'eval-defun)
 691     (define-key map "\e\C-q" 'indent-pp-sexp)
 692     (define-key map "\e\t" 'completion-at-point)
 693     (define-key map "\n" 'eval-print-last-sexp)
 694     (bindings--define-key map [menu-bar lisp-interaction]
 695       (cons "Lisp-Interaction" menu-map))
 696     (bindings--define-key menu-map [eval-defun]
 697       '(menu-item "Evaluate Defun" eval-defun
 698                   :help "Evaluate the top-level form containing point, or after point"))
 699     (bindings--define-key menu-map [eval-print-last-sexp]
 700       '(menu-item "Evaluate and Print" eval-print-last-sexp
 701                   :help "Evaluate sexp before point; print value into current buffer"))
 702     (bindings--define-key menu-map [edebug-defun-lisp-interaction]
 703       '(menu-item "Instrument Function for Debugging" edebug-defun
 704                   :help "Evaluate the top level form point is in, stepping through with Edebug"
 705                   :keys "C-u C-M-x"))
 706     (bindings--define-key menu-map [indent-pp-sexp]
 707       '(menu-item "Indent or Pretty-Print" indent-pp-sexp
 708                   :help "Indent each line of the list starting just after point, or prettyprint it"))
 709     (bindings--define-key menu-map [complete-symbol]
 710       '(menu-item "Complete Lisp Symbol" completion-at-point
 711                   :help "Perform completion on Lisp symbol preceding point"))
 712     map)
 713   "Keymap for Lisp Interaction mode.
 714 All commands in `lisp-mode-shared-map' are inherited by this map.")
 715
 716 (define-derived-mode lisp-interaction-mode emacs-lisp-mode "Lisp Interaction"
 717   "Major mode for typing and evaluating Lisp forms.
 718 Like Lisp mode except that \\[eval-print-last-sexp] evals the Lisp expression
 719 before point, and prints its value into the buffer, advancing point.
 720 Note that printing is controlled by `eval-expression-print-length'
 721 and `eval-expression-print-level'.
 722
 723 Commands:
 724 Delete converts tabs to spaces as it moves back.
 725 Paragraphs are separated only by blank lines.
 726 Semicolons start comments.
 727
 728 \\{lisp-interaction-mode-map}"
 729   :abbrev-table nil)
 730
 731 ;;; Emacs Lisp Byte-Code mode
 732
 733 (eval-and-compile
 734   (defconst emacs-list-byte-code-comment-re
 735     (concat "\\(#\\)@\\([0-9]+\\) "
 736             ;; Make sure it's a docstring and not a lazy-loaded byte-code.
 737             "\\(?:[^(]\\|([^\"]\\)")))
 738
 739 (defun elisp--byte-code-comment (end &optional _point)
 740   "Try to syntactically mark the #@NNN ....^_ docstrings in byte-code files."
 741   (let ((ppss (syntax-ppss)))
 742     (when (and (nth 4 ppss)
 743                (eq (char-after (nth 8 ppss)) ?#))
 744       (let* ((n (save-excursion
 745                   (goto-char (nth 8 ppss))
 746                   (when (looking-at emacs-list-byte-code-comment-re)
 747                     (string-to-number (match-string 2)))))
 748              ;; `maxdiff' tries to make sure the loop below terminates.
 749              (maxdiff n))
 750         (when n
 751           (let* ((bchar (match-end 2))
 752                  (b (position-bytes bchar)))
 753             (goto-char (+ b n))
 754             (while (let ((diff (- (position-bytes (point)) b n)))
 755                      (unless (zerop diff)
 756                        (when (> diff maxdiff) (setq diff maxdiff))
 757                        (forward-char (- diff))
 758                        (setq maxdiff (if (> diff 0) diff
 759                                        (max (1- maxdiff) 1)))
 760                        t))))
 761           (if (<= (point) end)
 762               (put-text-property (1- (point)) (point)
 763                                  'syntax-table
 764                                  (string-to-syntax "> b"))
 765             (goto-char end)))))))
 766
 767 (defun elisp-byte-code-syntax-propertize (start end)
 768   (elisp--byte-code-comment end (point))
 769   (funcall
 770    (syntax-propertize-rules
 771     (emacs-list-byte-code-comment-re
 772      (1 (prog1 "< b" (elisp--byte-code-comment end (point))))))
 773    start end))
 774
 775 ;;;###autoload
 776 (add-to-list 'auto-mode-alist '("\\.elc\\'" . elisp-byte-code-mode))
 777 ;;;###autoload
 778 (define-derived-mode elisp-byte-code-mode emacs-lisp-mode
 779   "Elisp-Byte-Code"
 780   "Major mode for *.elc files."
 781   ;; TODO: Add way to disassemble byte-code under point.
 782   (setq-local open-paren-in-column-0-is-defun-start nil)
 783   (setq-local syntax-propertize-function
 784               #'elisp-byte-code-syntax-propertize))
 785
 786
 787 ;;; Globally accessible functionality
 788
 789 (defun eval-print-last-sexp (&optional eval-last-sexp-arg-internal)
 790   "Evaluate sexp before point; print value into current buffer.
 791
 792 Normally, this function truncates long output according to the value
 793 of the variables `eval-expression-print-length' and
 794 `eval-expression-print-level'.  With a prefix argument of zero,
 795 however, there is no such truncation.  Such a prefix argument
 796 also causes integers to be printed in several additional formats
 797 \(octal, hexadecimal, and character).
 798
 799 If `eval-expression-debug-on-error' is non-nil, which is the default,
 800 this command arranges for all errors to enter the debugger."
 801   (interactive "P")
 802   (let ((standard-output (current-buffer)))
 803     (terpri)
 804     (eval-last-sexp (or eval-last-sexp-arg-internal t))
 805     (terpri)))
 806
 807
 808 (defun last-sexp-setup-props (beg end value alt1 alt2)
 809   "Set up text properties for the output of `elisp--eval-last-sexp'.
 810 BEG and END are the start and end of the output in current-buffer.
 811 VALUE is the Lisp value printed, ALT1 and ALT2 are strings for the
 812 alternative printed representations that can be displayed."
 813   (let ((map (make-sparse-keymap)))
 814     (define-key map "\C-m" 'elisp-last-sexp-toggle-display)
 815     (define-key map [down-mouse-2] 'mouse-set-point)
 816     (define-key map [mouse-2] 'elisp-last-sexp-toggle-display)
 817     (add-text-properties
 818      beg end
 819      `(printed-value (,value ,alt1 ,alt2)
 820                      mouse-face highlight
 821                      keymap ,map
 822                      help-echo "RET, mouse-2: toggle abbreviated display"
 823                      rear-nonsticky (mouse-face keymap help-echo
 824                                                 printed-value)))))
 825
 826
 827 (defun elisp-last-sexp-toggle-display (&optional _arg)
 828   "Toggle between abbreviated and unabbreviated printed representations."
 829   (interactive "P")
 830   (save-restriction
 831     (widen)
 832     (let ((value (get-text-property (point) 'printed-value)))
 833       (when value
 834         (let ((beg (or (previous-single-property-change (min (point-max) (1+ (point)))
 835                                                         'printed-value)
 836                        (point)))
 837               (end (or (next-single-char-property-change (point) 'printed-value) (point)))
 838               (standard-output (current-buffer))
 839               (point (point)))
 840           (delete-region beg end)
 841           (insert (nth 1 value))
 842           (or (= beg point)
 843               (setq point (1- (point))))
 844           (last-sexp-setup-props beg (point)
 845                                  (nth 0 value)
 846                                  (nth 2 value)
 847                                  (nth 1 value))
 848           (goto-char (min (point-max) point)))))))
 849
 850 (defun prin1-char (char)                ;FIXME: Move it, e.g. to simple.el.
 851   "Return a string representing CHAR as a character rather than as an integer.
 852 If CHAR is not a character, return nil."
 853   (and (integerp char)
 854        (eventp char)
 855        (let ((c (event-basic-type char))
 856              (mods (event-modifiers char))
 857              string)
 858          ;; Prevent ?A from turning into ?\S-a.
 859          (if (and (memq 'shift mods)
 860                   (zerop (logand char ?\S-\^@))
 861                   (not (let ((case-fold-search nil))
 862                          (char-equal c (upcase c)))))
 863              (setq c (upcase c) mods nil))
 864          ;; What string are we considering using?
 865          (condition-case nil
 866              (setq string
 867                    (concat
 868                     "?"
 869                     (mapconcat
 870                      (lambda (modif)
 871                        (cond ((eq modif 'super) "\\s-")
 872                              (t (string ?\\ (upcase (aref (symbol-name modif) 0)) ?-))))
 873                      mods "")
 874                     (cond
 875                      ((memq c '(?\; ?\( ?\) ?\{ ?\} ?\[ ?\] ?\" ?\' ?\\)) (string ?\\ c))
 876                      ((eq c 127) "\\C-?")
 877                      (t
 878                       (string c)))))
 879            (error nil))
 880          ;; Verify the string reads a CHAR, not to some other character.
 881          ;; If it doesn't, return nil instead.
 882          (and string
 883               (= (car (read-from-string string)) char)
 884               string))))
 885
 886 (defun elisp--preceding-sexp ()
 887   "Return sexp before the point."
 888   (let ((opoint (point))
 889         ignore-quotes
 890         expr)
 891     (save-excursion
 892       (with-syntax-table emacs-lisp-mode-syntax-table
 893         ;; If this sexp appears to be enclosed in `...'
 894         ;; then ignore the surrounding quotes.
 895         (setq ignore-quotes
 896               (or (eq (following-char) ?\')
 897                   (eq (preceding-char) ?\')))
 898         (forward-sexp -1)
 899         ;; If we were after `?\e' (or similar case),
 900         ;; use the whole thing, not just the `e'.
 901         (when (eq (preceding-char) ?\\)
 902           (forward-char -1)
 903           (when (eq (preceding-char) ??)
 904             (forward-char -1)))
 905
 906         ;; Skip over hash table read syntax.
 907         (and (> (point) (1+ (point-min)))
 908              (looking-back "#s" (- (point) 2))
 909              (forward-char -2))
 910
 911         ;; Skip over `#N='s.
 912         (when (eq (preceding-char) ?=)
 913           (let (labeled-p)
 914             (save-excursion
 915               (skip-chars-backward "0-9#=")
 916               (setq labeled-p (looking-at "\\(#[0-9]+=\\)+")))
 917             (when labeled-p
 918               (forward-sexp -1))))
 919
 920         (save-restriction
 921           (if (and ignore-quotes (eq (following-char) ?`))
 922               ;; vladimir@cs.ualberta.ca 30-Jul-1997: Skip ` in `variable' so
 923               ;; that the value is returned, not the name.
 924               (forward-char))
 925           (when (looking-at ",@?") (goto-char (match-end 0)))
 926           (narrow-to-region (point-min) opoint)
 927           (setq expr (read (current-buffer)))
 928           ;; If it's an (interactive ...) form, it's more useful to show how an
 929           ;; interactive call would use it.
 930           ;; FIXME: Is it really the right place for this?
 931           (when (eq (car-safe expr) 'interactive)
 932                (setq expr
 933                   `(call-interactively
 934                     (lambda (&rest args) ,expr args))))
 935           expr)))))
 936 (define-obsolete-function-alias 'preceding-sexp 'elisp--preceding-sexp "25.1")
 937
 938 (defun elisp--eval-last-sexp (eval-last-sexp-arg-internal)
 939   "Evaluate sexp before point; print value in the echo area.
 940 If EVAL-LAST-SEXP-ARG-INTERNAL is non-nil, print output into
 941 current buffer.  If EVAL-LAST-SEXP-ARG-INTERNAL is `0', print
 942 output with no limit on the length and level of lists, and
 943 include additional formats for integers \(octal, hexadecimal, and
 944 character)."
 945   (let ((standard-output (if eval-last-sexp-arg-internal (current-buffer) t)))
 946     ;; Setup the lexical environment if lexical-binding is enabled.
 947     (elisp--eval-last-sexp-print-value
 948      (eval (eval-sexp-add-defvars (elisp--preceding-sexp)) lexical-binding)
 949      eval-last-sexp-arg-internal)))
 950
 951
 952 (defun elisp--eval-last-sexp-print-value (value &optional eval-last-sexp-arg-internal)
 953   (let ((unabbreviated (let ((print-length nil) (print-level nil))
 954                          (prin1-to-string value)))
 955         (print-length (and (not (zerop (prefix-numeric-value
 956                                         eval-last-sexp-arg-internal)))
 957                            eval-expression-print-length))
 958         (print-level (and (not (zerop (prefix-numeric-value
 959                                        eval-last-sexp-arg-internal)))
 960                           eval-expression-print-level))
 961         (beg (point))
 962         end)
 963     (prog1
 964         (prin1 value)
 965       (let ((str (eval-expression-print-format value)))
 966         (if str (princ str)))
 967       (setq end (point))
 968       (when (and (bufferp standard-output)
 969                  (or (not (null print-length))
 970                      (not (null print-level)))
 971                  (not (string= unabbreviated
 972                                (buffer-substring-no-properties beg end))))
 973         (last-sexp-setup-props beg end value
 974                                unabbreviated
 975                                (buffer-substring-no-properties beg end))
 976         ))))
 977
 978
 979 (defvar elisp--eval-last-sexp-fake-value (make-symbol "t"))
 980
 981 (defun eval-sexp-add-defvars (exp &optional pos)
 982   "Prepend EXP with all the `defvar's that precede it in the buffer.
 983 POS specifies the starting position where EXP was found and defaults to point."
 984   (setq exp (macroexpand-all exp))      ;Eager macro-expansion.
 985   (if (not lexical-binding)
 986       exp
 987     (save-excursion
 988       (unless pos (setq pos (point)))
 989       (let ((vars ()))
 990         (goto-char (point-min))
 991         (while (re-search-forward
 992                 "(def\\(?:var\\|const\\|custom\\)[ \t\n]+\\([^; '()\n\t]+\\)"
 993                 pos t)
 994           (let ((var (intern (match-string 1))))
 995             (and (not (special-variable-p var))
 996                  (save-excursion
 997                    (zerop (car (syntax-ppss (match-beginning 0)))))
 998               (push var vars))))
 999         `(progn ,@(mapcar (lambda (v) `(defvar ,v)) vars) ,exp)))))
1000
1001 (defun eval-last-sexp (eval-last-sexp-arg-internal)
1002   "Evaluate sexp before point; print value in the echo area.
1003 Interactively, with prefix argument, print output into current buffer.
1004
1005 Normally, this function truncates long output according to the value
1006 of the variables `eval-expression-print-length' and
1007 `eval-expression-print-level'.  With a prefix argument of zero,
1008 however, there is no such truncation.  Such a prefix argument
1009 also causes integers to be printed in several additional formats
1010 \(octal, hexadecimal, and character).
1011
1012 If `eval-expression-debug-on-error' is non-nil, which is the default,
1013 this command arranges for all errors to enter the debugger."
1014   (interactive "P")
1015   (if (null eval-expression-debug-on-error)
1016       (elisp--eval-last-sexp eval-last-sexp-arg-internal)
1017     (let ((value
1018            (let ((debug-on-error elisp--eval-last-sexp-fake-value))
1019              (cons (elisp--eval-last-sexp eval-last-sexp-arg-internal)
1020                    debug-on-error))))
1021       (unless (eq (cdr value) elisp--eval-last-sexp-fake-value)
1022         (setq debug-on-error (cdr value)))
1023       (car value))))
1024
1025 (defun elisp--eval-defun-1 (form)
1026   "Treat some expressions specially.
1027 Reset the `defvar' and `defcustom' variables to the initial value.
1028 \(For `defcustom', use the :set function if there is one.)
1029 Reinitialize the face according to the `defface' specification."
1030   ;; The code in edebug-defun should be consistent with this, but not
1031   ;; the same, since this gets a macroexpanded form.
1032   (cond ((not (listp form))
1033          form)
1034         ((and (eq (car form) 'defvar)
1035               (cdr-safe (cdr-safe form))
1036               (boundp (cadr form)))
1037          ;; Force variable to be re-set.
1038          `(progn (defvar ,(nth 1 form) nil ,@(nthcdr 3 form))
1039                  (setq-default ,(nth 1 form) ,(nth 2 form))))
1040         ;; `defcustom' is now macroexpanded to
1041         ;; `custom-declare-variable' with a quoted value arg.
1042         ((and (eq (car form) 'custom-declare-variable)
1043               (default-boundp (eval (nth 1 form) lexical-binding)))
1044          ;; Force variable to be bound, using :set function if specified.
1045          (let ((setfunc (memq :set form)))
1046            (when setfunc
1047              (setq setfunc (car-safe (cdr-safe setfunc)))
1048              (or (functionp setfunc) (setq setfunc nil)))
1049            (funcall (or setfunc 'set-default)
1050                     (eval (nth 1 form) lexical-binding)
1051                     ;; The second arg is an expression that evaluates to
1052                     ;; an expression.  The second evaluation is the one
1053                     ;; normally performed not by normal execution but by
1054                     ;; custom-initialize-set (for example), which does not
1055                     ;; use lexical-binding.
1056                     (eval (eval (nth 2 form) lexical-binding))))
1057          form)
1058         ;; `defface' is macroexpanded to `custom-declare-face'.
1059         ((eq (car form) 'custom-declare-face)
1060          ;; Reset the face.
1061          (let ((face-symbol (eval (nth 1 form) lexical-binding)))
1062            (setq face-new-frame-defaults
1063                  (assq-delete-all face-symbol face-new-frame-defaults))
1064            (put face-symbol 'face-defface-spec nil)
1065            (put face-symbol 'face-override-spec nil))
1066          form)
1067         ((eq (car form) 'progn)
1068          (cons 'progn (mapcar #'elisp--eval-defun-1 (cdr form))))
1069         (t form)))
1070
1071 (defun elisp--eval-defun ()
1072   "Evaluate defun that point is in or before.
1073 The value is displayed in the echo area.
1074 If the current defun is actually a call to `defvar',
1075 then reset the variable using the initial value expression
1076 even if the variable already has some other value.
1077 \(Normally `defvar' does not change the variable's value
1078 if it already has a value.\)
1079
1080 Return the result of evaluation."
1081   ;; FIXME: the print-length/level bindings should only be applied while
1082   ;; printing, not while evaluating.
1083   (let ((debug-on-error eval-expression-debug-on-error)
1084         (print-length eval-expression-print-length)
1085         (print-level eval-expression-print-level))
1086     (save-excursion
1087       ;; Arrange for eval-region to "read" the (possibly) altered form.
1088       ;; eval-region handles recording which file defines a function or
1089       ;; variable.
1090       (let ((standard-output t)
1091             beg end form)
1092         ;; Read the form from the buffer, and record where it ends.
1093         (save-excursion
1094           (end-of-defun)
1095           (beginning-of-defun)
1096           (setq beg (point))
1097           (setq form (read (current-buffer)))
1098           (setq end (point)))
1099         ;; Alter the form if necessary.
1100         (let ((form (eval-sexp-add-defvars
1101                      (elisp--eval-defun-1 (macroexpand form)))))
1102           (eval-region beg end standard-output
1103                        (lambda (_ignore)
1104                          ;; Skipping to the end of the specified region
1105                          ;; will make eval-region return.
1106                          (goto-char end)
1107                          form))))))
1108   (let ((str (eval-expression-print-format (car values))))
1109     (if str (princ str)))
1110   ;; The result of evaluation has been put onto VALUES.  So return it.
1111   (car values))
1112
1113 (defun eval-defun (edebug-it)
1114   "Evaluate the top-level form containing point, or after point.
1115
1116 If the current defun is actually a call to `defvar' or `defcustom',
1117 evaluating it this way resets the variable using its initial value
1118 expression (using the defcustom's :set function if there is one), even
1119 if the variable already has some other value.  \(Normally `defvar' and
1120 `defcustom' do not alter the value if there already is one.)  In an
1121 analogous way, evaluating a `defface' overrides any customizations of
1122 the face, so that it becomes defined exactly as the `defface' expression
1123 says.
1124
1125 If `eval-expression-debug-on-error' is non-nil, which is the default,
1126 this command arranges for all errors to enter the debugger.
1127
1128 With a prefix argument, instrument the code for Edebug.
1129
1130 If acting on a `defun' for FUNCTION, and the function was
1131 instrumented, `Edebug: FUNCTION' is printed in the echo area.  If not
1132 instrumented, just FUNCTION is printed.
1133
1134 If not acting on a `defun', the result of evaluation is displayed in
1135 the echo area.  This display is controlled by the variables
1136 `eval-expression-print-length' and `eval-expression-print-level',
1137 which see."
1138   (interactive "P")
1139   (cond (edebug-it
1140          (require 'edebug)
1141          (eval-defun (not edebug-all-defs)))
1142         (t
1143          (if (null eval-expression-debug-on-error)
1144              (elisp--eval-defun)
1145            (let (new-value value)
1146              (let ((debug-on-error elisp--eval-last-sexp-fake-value))
1147                (setq value (elisp--eval-defun))
1148                (setq new-value debug-on-error))
1149              (unless (eq elisp--eval-last-sexp-fake-value new-value)
1150                (setq debug-on-error new-value))
1151              value)))))
1152
1153 ;;; ElDoc Support
1154
1155 (defvar elisp--eldoc-last-data (make-vector 3 nil)
1156   "Bookkeeping; elements are as follows:
1157   0 - contains the last symbol read from the buffer.
1158   1 - contains the string last displayed in the echo area for variables,
1159       or argument string for functions.
1160   2 - 'function if function args, 'variable if variable documentation.")
1161
1162 (defun elisp-eldoc-documentation-function ()
1163   "`eldoc-documentation-function' (which see) for Emacs Lisp."
1164   (let ((current-symbol (elisp--current-symbol))
1165         (current-fnsym  (elisp--fnsym-in-current-sexp)))
1166     (cond ((null current-fnsym)
1167            nil)
1168           ((eq current-symbol (car current-fnsym))
1169            (or (apply #'elisp--get-fnsym-args-string current-fnsym)
1170                (elisp--get-var-docstring current-symbol)))
1171           (t
1172            (or (elisp--get-var-docstring current-symbol)
1173                (apply #'elisp--get-fnsym-args-string current-fnsym))))))
1174
1175 (defun elisp--get-fnsym-args-string (sym &optional index)
1176   "Return a string containing the parameter list of the function SYM.
1177 If SYM is a subr and no arglist is obtainable from the docstring
1178 or elsewhere, return a 1-line docstring."
1179   (let ((argstring
1180          (cond
1181           ((not (and sym (symbolp sym) (fboundp sym))) nil)
1182           ((and (eq sym (aref elisp--eldoc-last-data 0))
1183                 (eq 'function (aref elisp--eldoc-last-data 2)))
1184            (aref elisp--eldoc-last-data 1))
1185           (t
1186            (let* ((advertised (gethash (indirect-function sym)
1187                                        advertised-signature-table t))
1188                   doc
1189                   (args
1190                    (cond
1191                     ((listp advertised) advertised)
1192                     ((setq doc (help-split-fundoc
1193                                 (condition-case nil (documentation sym t)
1194                                   (invalid-function nil))
1195                                 sym))
1196                      (car doc))
1197                     (t (help-function-arglist sym)))))
1198              ;; Stringify, and store before highlighting, downcasing, etc.
1199              ;; FIXME should truncate before storing.
1200              (elisp--last-data-store sym (elisp--function-argstring args)
1201                                     'function))))))
1202     ;; Highlight, truncate.
1203     (if argstring
1204         (elisp--highlight-function-argument sym argstring index))))
1205
1206 (defun elisp--highlight-function-argument (sym args index)
1207   "Highlight argument INDEX in ARGS list for function SYM.
1208 In the absence of INDEX, just call `elisp--docstring-format-sym-doc'."
1209   ;; FIXME: This should probably work on the list representation of `args'
1210   ;; rather than its string representation.
1211   ;; FIXME: This function is much too long, we need to split it up!
1212   (let ((start          nil)
1213         (end            0)
1214         (argument-face  'eldoc-highlight-function-argument)
1215         (args-lst (mapcar (lambda (x)
1216                             (replace-regexp-in-string
1217                              "\\`[(]\\|[)]\\'" "" x))
1218                           (split-string args))))
1219     ;; Find the current argument in the argument string.  We need to
1220     ;; handle `&rest' and informal `...' properly.
1221     ;;
1222     ;; FIXME: What to do with optional arguments, like in
1223     ;;        (defun NAME ARGLIST [DOCSTRING] BODY...) case?
1224     ;;        The problem is there is no robust way to determine if
1225     ;;        the current argument is indeed a docstring.
1226
1227     ;; When `&key' is used finding position based on `index'
1228     ;; would be wrong, so find the arg at point and determine
1229     ;; position in ARGS based on this current arg.
1230     (when (string-match "&key" args)
1231       (let* (case-fold-search
1232              key-have-value
1233              (sym-name (symbol-name sym))
1234              (cur-w (current-word))
1235              (args-lst-ak (cdr (member "&key" args-lst)))
1236              (limit (save-excursion
1237                       (when (re-search-backward sym-name nil t)
1238                         (match-end 0))))
1239              (cur-a (if (and cur-w (string-match ":\\([^ ()]*\\)" cur-w))
1240                         (substring cur-w 1)
1241                       (save-excursion
1242                         (let (split)
1243                           (when (re-search-backward ":\\([^()\n]*\\)" limit t)
1244                             (setq split (split-string (match-string 1) " " t))
1245                             (prog1 (car split)
1246                               (when (cdr split)
1247                                 (setq key-have-value t))))))))
1248              ;; If `cur-a' is not one of `args-lst-ak'
1249              ;; assume user is entering an unknown key
1250              ;; referenced in last position in signature.
1251              (other-key-arg (and (stringp cur-a)
1252                                  args-lst-ak
1253                                  (not (member (upcase cur-a) args-lst-ak))
1254                                  (upcase (car (last args-lst-ak))))))
1255         (unless (string= cur-w sym-name)
1256           ;; The last keyword have already a value
1257           ;; i.e :foo a b and cursor is at b.
1258           ;; If signature have also `&rest'
1259           ;; (assume it is after the `&key' section)
1260           ;; go to the arg after `&rest'.
1261           (if (and key-have-value
1262                    (save-excursion
1263                      (not (re-search-forward ":.*" (point-at-eol) t)))
1264                    (string-match "&rest \\([^ ()]*\\)" args))
1265               (setq index nil ; Skip next block based on positional args.
1266                     start (match-beginning 1)
1267                     end   (match-end 1))
1268             ;; If `cur-a' is nil probably cursor is on a positional arg
1269             ;; before `&key', in this case, exit this block and determine
1270             ;; position with `index'.
1271             (when (and cur-a     ; A keyword arg (dot removed) or nil.
1272                        (or (string-match
1273                             (concat "\\_<" (upcase cur-a) "\\_>") args)
1274                            (string-match
1275                             (concat "\\_<" other-key-arg "\\_>") args)))
1276               (setq index nil ; Skip next block based on positional args.
1277                     start (match-beginning 0)
1278                     end   (match-end 0)))))))
1279     ;; Handle now positional arguments.
1280     (while (and index (>= index 1))
1281       (if (string-match "[^ ()]+" args end)
1282           (progn
1283             (setq start (match-beginning 0)
1284                   end   (match-end 0))
1285             (let ((argument (match-string 0 args)))
1286               (cond ((string= argument "&rest")
1287                      ;; All the rest arguments are the same.
1288                      (setq index 1))
1289                     ((string= argument "&optional"))         ; Skip.
1290                     ((string= argument "&allow-other-keys")) ; Skip.
1291                     ;; Back to index 0 in ARG1 ARG2 ARG2 ARG3 etc...
1292                     ;; like in `setq'.
1293                     ((or (and (string-match-p "\\.\\.\\.$" argument)
1294                               (string= argument (car (last args-lst))))
1295                          (and (string-match-p "\\.\\.\\.$"
1296                                               (substring args 1 (1- (length args))))
1297                               (= (length (remove "..." args-lst)) 2)
1298                               (> index 1) (eq (logand index 1) 1)))
1299                      (setq index 0))
1300                     (t
1301                      (setq index (1- index))))))
1302         (setq end           (length args)
1303               start         (1- end)
1304               argument-face 'font-lock-warning-face
1305               index         0)))
1306     (let ((doc args))
1307       (when start
1308         (setq doc (copy-sequence args))
1309         (add-text-properties start end (list 'face argument-face) doc))
1310       (setq doc (elisp--docstring-format-sym-doc
1311                  sym doc (if (functionp sym) 'font-lock-function-name-face
1312                            'font-lock-keyword-face)))
1313       doc)))
1314
1315 ;; Return a string containing a brief (one-line) documentation string for
1316 ;; the variable.
1317 (defun elisp--get-var-docstring (sym)
1318   (cond ((not sym) nil)
1319         ((and (eq sym (aref elisp--eldoc-last-data 0))
1320               (eq 'variable (aref elisp--eldoc-last-data 2)))
1321          (aref elisp--eldoc-last-data 1))
1322         (t
1323          (let ((doc (documentation-property sym 'variable-documentation t)))
1324            (when doc
1325              (let ((doc (elisp--docstring-format-sym-doc
1326                          sym (elisp--docstring-first-line doc)
1327                          'font-lock-variable-name-face)))
1328                (elisp--last-data-store sym doc 'variable)))))))
1329
1330 (defun elisp--last-data-store (symbol doc type)
1331   (aset elisp--eldoc-last-data 0 symbol)
1332   (aset elisp--eldoc-last-data 1 doc)
1333   (aset elisp--eldoc-last-data 2 type)
1334   doc)
1335
1336 ;; Note that any leading `*' in the docstring (which indicates the variable
1337 ;; is a user option) is removed.
1338 (defun elisp--docstring-first-line (doc)
1339   (and (stringp doc)
1340        (substitute-command-keys
1341         (save-match-data
1342           ;; Don't use "^" in the regexp below since it may match
1343           ;; anywhere in the doc-string.
1344           (let ((start (if (string-match "\\`\\*" doc) (match-end 0) 0)))
1345             (cond ((string-match "\n" doc)
1346                    (substring doc start (match-beginning 0)))
1347                   ((zerop start) doc)
1348                   (t (substring doc start))))))))
1349
1350 (defvar eldoc-echo-area-use-multiline-p)
1351
1352 ;; If the entire line cannot fit in the echo area, the symbol name may be
1353 ;; truncated or eliminated entirely from the output to make room for the
1354 ;; description.
1355 (defun elisp--docstring-format-sym-doc (sym doc face)
1356   (save-match-data
1357     (let* ((name (symbol-name sym))
1358            (ea-multi eldoc-echo-area-use-multiline-p)
1359            ;; Subtract 1 from window width since emacs will not write
1360            ;; any chars to the last column, or in later versions, will
1361            ;; cause a wraparound and resize of the echo area.
1362            (ea-width (1- (window-width (minibuffer-window))))
1363            (strip (- (+ (length name) (length ": ") (length doc)) ea-width)))
1364       (cond ((or (<= strip 0)
1365                  (eq ea-multi t)
1366                  (and ea-multi (> (length doc) ea-width)))
1367              (format "%s: %s" (propertize name 'face face) doc))
1368             ((> (length doc) ea-width)
1369              (substring (format "%s" doc) 0 ea-width))
1370             ((>= strip (length name))
1371              (format "%s" doc))
1372             (t
1373              ;; Show the end of the partial symbol name, rather
1374              ;; than the beginning, since the former is more likely
1375              ;; to be unique given package namespace conventions.
1376              (setq name (substring name strip))
1377              (format "%s: %s" (propertize name 'face face) doc))))))
1378
1379 \f
1380 ;; Return a list of current function name and argument index.
1381 (defun elisp--fnsym-in-current-sexp ()
1382   (save-excursion
1383     (let ((argument-index (1- (elisp--beginning-of-sexp))))
1384       ;; If we are at the beginning of function name, this will be -1.
1385       (when (< argument-index 0)
1386         (setq argument-index 0))
1387       ;; Don't do anything if current word is inside a string.
1388       (if (= (or (char-after (1- (point))) 0) ?\")
1389           nil
1390         (list (elisp--current-symbol) argument-index)))))
1391
1392 ;; Move to the beginning of current sexp.  Return the number of nested
1393 ;; sexp the point was over or after.
1394 (defun elisp--beginning-of-sexp ()
1395   (let ((parse-sexp-ignore-comments t)
1396         (num-skipped-sexps 0))
1397     (condition-case _
1398         (progn
1399           ;; First account for the case the point is directly over a
1400           ;; beginning of a nested sexp.
1401           (condition-case _
1402               (let ((p (point)))
1403                 (forward-sexp -1)
1404                 (forward-sexp 1)
1405                 (when (< (point) p)
1406                   (setq num-skipped-sexps 1)))
1407             (error))
1408           (while
1409               (let ((p (point)))
1410                 (forward-sexp -1)
1411                 (when (< (point) p)
1412                   (setq num-skipped-sexps (1+ num-skipped-sexps))))))
1413       (error))
1414     num-skipped-sexps))
1415
1416 ;; returns nil unless current word is an interned symbol.
1417 (defun elisp--current-symbol ()
1418   (let ((c (char-after (point))))
1419     (and c
1420          (memq (char-syntax c) '(?w ?_))
1421          (intern-soft (current-word)))))
1422
1423 (defun elisp--function-argstring (arglist)
1424   "Return ARGLIST as a string enclosed by ().
1425 ARGLIST is either a string, or a list of strings or symbols."
1426   (let ((str (cond ((stringp arglist) arglist)
1427                    ((not (listp arglist)) nil)
1428                    (t (format "%S" (help-make-usage 'toto arglist))))))
1429     (if (and str (string-match "\\`([^ )]+ ?" str))
1430         (replace-match "(" t t str)
1431       str)))
1432
1433 (provide 'elisp-mode)
1434 ;;; elisp-mode.el ends here