configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2012 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.1.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AC_CONFIG_AUX_DIR(build-aux)
  29 AM_INIT_AUTOMAKE
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 leimdir='${datadir}/emacs/${version}/leim'
  41 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  42 '${datadir}/emacs/site-lisp'
  43 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  44 etcdir='${datadir}/emacs/${version}/etc'
  45 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  46 docdir='${datadir}/emacs/${version}/etc'
  47 gamedir='${localstatedir}/games/emacs'
  48
  49 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  50 dnl Create a new --with option that defaults to being disabled.
  51 dnl NAME is the base name of the option.  The shell variable with_NAME
  52 dnl   will be set to either the user's value (if the option is
  53 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  54 dnl   option is not specified).  Note that the shell variable name is
  55 dnl   constructed as autoconf does, by replacing non-alphanumeric
  56 dnl   characters with "_".
  57 dnl HELP-STRING is the help text for the option.
  58 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  59   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  60     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  61 ])dnl
  62
  63 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  64 dnl Create a new --with option that defaults to being enabled.  NAME
  65 dnl   is the base name of the option.  The shell variable with_NAME
  66 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  67 dnl   'yes' (if the option is not specified).  Note that the shell
  68 dnl   variable name is constructed as autoconf does, by replacing
  69 dnl   non-alphanumeric characters with "_".
  70 dnl HELP-STRING is the help text for the option.
  71 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  72   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  73    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  74 ])dnl
  75
  76 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  77 if test "$with_pop" = yes; then
  78    AC_DEFINE(MAIL_USE_POP)
  79 fi
  80 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  81
  82 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  83 if test "$with_kerberos" != no; then
  84    AC_DEFINE(KERBEROS)
  85 fi
  86 AH_TEMPLATE(KERBEROS,
  87             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  88
  89 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  90 if test "${with_kerberos5}" != no; then
  91   if test "${with_kerberos}" = no; then
  92     with_kerberos=yes
  93     AC_DEFINE(KERBEROS)
  94   fi
  95   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  96 fi
  97
  98 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  99 dnl FIXME hesiod support may not be present, so it seems like an error
 100 dnl to define, or at least use, this unconditionally.
 101 if test "$with_hesiod" != no; then
 102   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 103 fi
 104
 105 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 106 if test "$with_mmdf" != no; then
 107    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 108 fi
 109
 110 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 111 if test "$with_mail_unlink" != no; then
 112    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 113 fi
 114
 115 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 116     [string giving default POP mail host])],
 117     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 118
 119 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 120
 121 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 122 if test "$with_sync_input" = yes; then
 123    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 124 fi
 125
 126 dnl FIXME currently it is not the last.
 127 dnl This should be the last --with option, because --with-x is
 128 dnl added later on when we find the path of X, and it's best to
 129 dnl keep them together visually.
 130 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 131  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 132 [         case "${withval}" in
 133             y | ye | yes )      val=gtk ;;
 134             n | no )            val=no  ;;
 135             l | lu | luc | luci | lucid )       val=lucid ;;
 136             a | at | ath | athe | athen | athena )      val=athena ;;
 137             m | mo | mot | moti | motif )       val=motif ;;
 138             g | gt | gtk  )     val=gtk ;;
 139             gtk3  )     val=gtk3 ;;
 140             * )
 141 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 142 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 143 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 144             ;;
 145           esac
 146           with_x_toolkit=$val
 147 ])
 148
 149 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 150 if test "$with_wide_int" = yes; then
 151   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 152 fi
 153
 154 dnl _ON results in a '--without' option in the --help output, so
 155 dnl the help text should refer to "don't compile", etc.
 156 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 157 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 158 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 159 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 160 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 161 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 162 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 163 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 164
 165 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 166 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 167 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 168
 169 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 170 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 171 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 172 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 173
 174 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 175 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 176 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 177 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 178 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 179 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 180
 181 ## For the times when you want to build Emacs but don't have
 182 ## a suitable makeinfo, and can live without the manuals.
 183 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 184 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 185
 186 ## Makefile.in needs the cache file name.
 187 AC_SUBST(cache_file)
 188
 189 ## This is an option because I do not know if all info/man support
 190 ## compressed files, nor how to test if they do so.
 191 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 192 if test $with_compress_info = yes; then
 193    GZIP_INFO=yes
 194 else
 195    GZIP_INFO=
 196 fi
 197 AC_SUBST(GZIP_INFO)
 198
 199 AC_ARG_WITH([pkg-config-prog],dnl
 200 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 201                   [path to pkg-config for finding GTK and librsvg])])
 202 if test "X${with_pkg_config_prog}" != X; then
 203    if test "${with_pkg_config_prog}" != yes; then
 204       PKG_CONFIG="${with_pkg_config_prog}"
 205    fi
 206 fi
 207
 208 CRT_DIR=
 209 AC_ARG_WITH([crt-dir],dnl
 210 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 211 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 212 CRT_DIR="${with_crt_dir}"
 213
 214 AC_ARG_WITH(gameuser,dnl
 215 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 216 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 217   && gameuser="${with_gameuser}"
 218 test "X$gameuser" = X && gameuser=games
 219
 220 AC_ARG_WITH([gnustep-conf],dnl
 221 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 222 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 223   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 224 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 225      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 226
 227 AC_ARG_ENABLE(ns-self-contained,
 228 [AS_HELP_STRING([--disable-ns-self-contained],
 229                 [disable self contained build under NeXTstep])],
 230    EN_NS_SELF_CONTAINED=$enableval,
 231    EN_NS_SELF_CONTAINED=yes)
 232
 233 AC_ARG_ENABLE(asserts,
 234 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 235       USE_XASSERTS=$enableval,
 236       USE_XASSERTS=no)
 237
 238 AC_ARG_ENABLE(locallisppath,
 239 [AS_HELP_STRING([--enable-locallisppath=PATH],
 240                 [directories Emacs should search for lisp files specific
 241                  to this site])],
 242 if test "${enableval}" = "no"; then
 243   locallisppath=
 244 elif test "${enableval}" != "yes"; then
 245   locallisppath=${enableval}
 246 fi)
 247
 248 AC_ARG_ENABLE(checking,
 249 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 250                 [enable expensive run-time checks.  With LIST,
 251                  enable only specific categories of checks.
 252                  Categories are: all,yes,no.
 253                  Flags are: stringbytes, stringoverrun, stringfreelist,
 254                  xmallocoverrun, conslist])],
 255 [ac_checking_flags="${enableval}"],[])
 256 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 257 for check in $ac_checking_flags
 258 do
 259         case $check in
 260         # these set all the flags to specific states
 261         yes)            ac_enable_checking=1 ;;
 262         no)             ac_enable_checking= ;
 263                         ac_gc_check_stringbytes= ;
 264                         ac_gc_check_string_overrun= ;
 265                         ac_gc_check_string_free_list= ;
 266                         ac_xmalloc_overrun= ;
 267                         ac_gc_check_cons_list= ;;
 268         all)            ac_enable_checking=1 ;
 269                         ac_gc_check_stringbytes=1 ;
 270                         ac_gc_check_string_overrun=1 ;
 271                         ac_gc_check_string_free_list=1 ;
 272                         ac_xmalloc_overrun=1 ;
 273                         ac_gc_check_cons_list=1 ;;
 274         # these enable particular checks
 275         stringbytes)    ac_gc_check_stringbytes=1 ;;
 276         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 277         stringfreelist) ac_gc_check_string_free_list=1 ;;
 278         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 279         conslist)       ac_gc_check_cons_list=1 ;;
 280         *)      AC_MSG_ERROR(unknown check category $check) ;;
 281         esac
 282 done
 283 IFS="$ac_save_IFS"
 284
 285 if test x$ac_enable_checking != x ; then
 286   AC_DEFINE(ENABLE_CHECKING, 1,
 287 [Enable expensive run-time checking of data types?])
 288 fi
 289 if test x$ac_gc_check_stringbytes != x ; then
 290   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 291 [Define this temporarily to hunt a bug.  If defined, the size of
 292    strings is redundantly recorded in sdata structures so that it can
 293    be compared to the sizes recorded in Lisp strings.])
 294 fi
 295 if test x$ac_gc_check_string_overrun != x ; then
 296   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 297 [Define this to check for short string overrun.])
 298 fi
 299 if test x$ac_gc_check_string_free_list != x ; then
 300   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 301 [Define this to check the string free list.])
 302 fi
 303 if test x$ac_xmalloc_overrun != x ; then
 304   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 305 [Define this to check for malloc buffer overrun.])
 306 fi
 307 if test x$ac_gc_check_cons_list != x ; then
 308   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 309 [Define this to check for errors in cons list.])
 310 fi
 311
 312 AC_ARG_ENABLE(use-lisp-union-type,
 313 [AS_HELP_STRING([--enable-use-lisp-union-type],
 314                 [use a union for the Lisp_Object data type.
 315                 This is only useful for development for catching certain types of bugs.])],
 316 if test "${enableval}" != "no"; then
 317    AC_DEFINE(USE_LISP_UNION_TYPE, 1,
 318    [Define this to use a lisp union for the Lisp_Object data type.])
 319 fi)
 320
 321
 322 AC_ARG_ENABLE(profiling,
 323 [AS_HELP_STRING([--enable-profiling],
 324                 [build emacs with profiling support.
 325                  This might not work on all platforms])],
 326 [ac_enable_profiling="${enableval}"],[])
 327 if test x$ac_enable_profiling != x ; then
 328    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 329 else
 330    PROFILING_CFLAGS=
 331 fi
 332 AC_SUBST(PROFILING_CFLAGS)
 333
 334 AC_ARG_ENABLE(autodepend,
 335 [AS_HELP_STRING([--enable-autodepend],
 336                 [automatically generate dependencies to .h-files.
 337                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 338                  found])],
 339 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 340
 341 #### Make srcdir absolute, if it isn't already.  It's important to
 342 #### avoid running the path through pwd unnecessarily, since pwd can
 343 #### give you automounter prefixes, which can go away.  We do all this
 344 #### so Emacs can find its files when run uninstalled.
 345 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 346 unset CDPATH
 347 case "${srcdir}" in
 348   /* ) ;;
 349   . )
 350     ## We may be able to use the $PWD environment variable to make this
 351     ## absolute.  But sometimes PWD is inaccurate.
 352     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 353     ## but that tested only for a well-formed and valid PWD,
 354     ## it did not object when PWD was well-formed and valid but just wrong.
 355     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 356     then
 357       srcdir="$PWD"
 358     else
 359       srcdir="`(cd ${srcdir}; pwd)`"
 360     fi
 361   ;;
 362   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 363 esac
 364
 365 #### Given the configuration name, set opsysfile to the
 366 #### name of s/*.h file we should use.
 367
 368 ### Canonicalize the configuration name.
 369
 370 AC_CANONICAL_HOST
 371 canonical=$host
 372 configuration=${host_alias-${build_alias-$host}}
 373
 374 dnl This used to use changequote, but, apart from `changequote is evil'
 375 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 376 dnl the great gob of text.  Thus it's not processed for possible expansion.
 377 dnl Just make sure the brackets remain balanced.
 378 dnl
 379 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 380 dnl indicated by comments.
 381 dnl quotation begins
 382 [
 383
 384 ### If you add support for a new configuration, add code to this
 385 ### switch statement to recognize your configuration name and select
 386 ### the appropriate operating system file.
 387
 388 ### You would hope that you could choose an s/*.h
 389 ### file based on the operating system portion.  However, it turns out
 390 ### that each s/*.h file is pretty manufacturer-specific.
 391 ### So we basically have to have a special case for each
 392 ### configuration name.
 393 ###
 394 ### As far as handling version numbers on operating systems is
 395 ### concerned, make sure things will fail in a fixable way.  If
 396 ### /etc/MACHINES doesn't say anything about version numbers, be
 397 ### prepared to handle anything reasonably.  If version numbers
 398 ### matter, be sure /etc/MACHINES says something about it.
 399
 400 opsys='' unported=no
 401 case "${canonical}" in
 402
 403   ## GNU/Linux and similar ports
 404   *-*-linux* )
 405     opsys=gnu-linux
 406   ;;
 407
 408   ## FreeBSD ports
 409   *-*-freebsd* )
 410     opsys=freebsd
 411   ;;
 412
 413   ## FreeBSD kernel + glibc based userland
 414   *-*-kfreebsd*gnu* )
 415     opsys=gnu-kfreebsd
 416   ;;
 417
 418   ## NetBSD ports
 419   *-*-netbsd* )
 420     opsys=netbsd
 421   ;;
 422
 423   ## OpenBSD ports
 424   *-*-openbsd* )
 425     opsys=openbsd
 426   ;;
 427
 428   ## Apple Darwin / Mac OS X
 429   *-apple-darwin* )
 430     case "${canonical}" in
 431       i[3456]86-* )  ;;
 432       powerpc-* )    ;;
 433       x86_64-* )     ;;
 434       * )            unported=yes ;;
 435     esac
 436     opsys=darwin
 437     ## Use fink packages if available.
 438     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 439 ##    if test -d /sw/include && test -d /sw/lib; then
 440 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 441 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 442 ##    fi
 443   ;;
 444
 445   ## HP 9000 series 700 and 800, running HP/UX
 446   hppa*-hp-hpux10.2* )
 447     opsys=hpux10-20
 448   ;;
 449   hppa*-hp-hpux1[1-9]* )
 450     opsys=hpux11
 451     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 452   ;;
 453
 454   ## IBM machines
 455   rs6000-ibm-aix4.[23]* )
 456     opsys=aix4-2
 457   ;;
 458   powerpc-ibm-aix4.[23]*  )
 459     opsys=aix4-2
 460   ;;
 461   rs6000-ibm-aix[56]* )
 462     opsys=aix4-2
 463   ;;
 464   powerpc-ibm-aix[56]*  )
 465     opsys=aix4-2
 466   ;;
 467
 468   ## Silicon Graphics machines
 469   ## Iris 4D
 470   mips-sgi-irix6.5 )
 471     opsys=irix6-5
 472     # Without defining _LANGUAGE_C, things get masked out in the headers
 473     # so that, for instance, grepping for `free' in stdlib.h fails and
 474     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 475     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 476   ;;
 477
 478   ## Suns
 479   *-sun-solaris* \
 480     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 481     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 482     case "${canonical}" in
 483       i[3456]86-*-* )   ;;
 484       amd64-*-*|x86_64-*-*) ;;
 485       sparc* )          ;;
 486       * )               unported=yes ;;
 487     esac
 488     case "${canonical}" in
 489       *-sunos5.6* | *-solaris2.6* )
 490                 opsys=sol2-6
 491                 RANLIB="ar -ts"
 492                 ;;
 493       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 494                 opsys=sol2-6
 495                 emacs_check_sunpro_c=yes
 496                 ;;
 497       *-sunos5* | *-solaris* )
 498                 opsys=sol2-10
 499                 emacs_check_sunpro_c=yes
 500                 ;;
 501     esac
 502     ## Watch out for a compiler that we know will not work.
 503     case "${canonical}" in
 504      *-solaris* | *-sunos5* )
 505                 if [ "x$CC" = x/usr/ucb/cc ]; then
 506                   ## /usr/ucb/cc doesn't work;
 507                   ## we should find some other compiler that does work.
 508                   unset CC
 509                 fi
 510                 ;;
 511       *) ;;
 512     esac
 513   ;;
 514
 515   ## Intel 386 machines where we don't care about the manufacturer.
 516   i[3456]86-*-* )
 517     case "${canonical}" in
 518       *-cygwin )                opsys=cygwin ;;
 519       *-darwin* )               opsys=darwin ;;
 520       *-sysv4.2uw* )            opsys=unixware ;;
 521       *-sysv5uw* )              opsys=unixware ;;
 522       *-sysv5OpenUNIX* )        opsys=unixware ;;
 523       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 524     esac
 525   ;;
 526
 527   * )
 528     unported=yes
 529   ;;
 530 esac
 531
 532 ### If the code above didn't choose an operating system, just choose
 533 ### an operating system based on the configuration name.  You really
 534 ### only want to use this when you have no idea what the right
 535 ### operating system is; if you know what operating systems a machine
 536 ### runs, it's cleaner to make it explicit in the case statement
 537 ### above.
 538 if test x"${opsys}" = x; then
 539   case "${canonical}" in
 540     *-gnu* )                            opsys=gnu ;;
 541     * )
 542       unported=yes
 543     ;;
 544   esac
 545 fi
 546
 547 ]
 548 dnl quotation ends
 549
 550 if test $unported = yes; then
 551   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 552 Check `etc/MACHINES' for recognized configuration names.])
 553 fi
 554
 555 opsysfile="s/${opsys}.h"
 556
 557
 558 #### Choose a compiler.
 559
 560 dnl Sets GCC=yes if using gcc.
 561 AC_PROG_CC
 562 AM_PROG_CC_C_O
 563
 564 if test x$GCC = xyes; then
 565   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 566 else
 567   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 568 fi
 569
 570 # Initialize gnulib right after choosing the compiler.
 571 gl_EARLY
 572
 573 AC_ARG_ENABLE([gcc-warnings],
 574   [AS_HELP_STRING([--enable-gcc-warnings],
 575                   [turn on lots of GCC warnings (for developers)])],
 576   [case $enableval in
 577      yes|no) ;;
 578      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 579    esac
 580    gl_gcc_warnings=$enableval],
 581   [gl_gcc_warnings=no]
 582 )
 583
 584 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 585 # ------------------------------------------------
 586 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 587 # Otherwise, run RUN-IF-NOT-FOUND.
 588 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 589   [AC_PREPROC_IFELSE(
 590     [AC_LANG_PROGRAM(
 591       [[
 592 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 593 /* ok */
 594 #else
 595 # error "your version of gcc is older than $1.$2"
 596 #endif
 597       ]]),
 598     ], [$3], [$4])
 599   ]
 600 )
 601
 602 # When compiling with GCC, prefer -isystem to -I when including system
 603 # include files, to avoid generating useless diagnostics for the files.
 604 if test "$gl_gcc_warnings" != yes; then
 605   isystem='-I'
 606 else
 607   isystem='-isystem '
 608
 609   # This, $nw, is the list of warnings we disable.
 610   nw=
 611
 612   case $with_x_toolkit in
 613     lucid | athena | motif)
 614        # Old toolkits mishandle 'const'.
 615        nw="$nw -Wwrite-strings"
 616        ;;
 617     *)
 618        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 619        ;;
 620   esac
 621   AC_SUBST([WERROR_CFLAGS])
 622
 623   nw="$nw -Waggregate-return"       # anachronistic
 624   nw="$nw -Wlong-long"              # C90 is anachronistic
 625   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 626   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 627   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 628   nw="$nw -Wcast-qual"              # Too many warnings for now
 629   nw="$nw -Wconversion"             # Too many warnings for now
 630   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 631   nw="$nw -Wsign-conversion"        # Too many warnings for now
 632   nw="$nw -Woverlength-strings"     # Not a problem these days
 633   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 634   nw="$nw -Wpadded"                 # Our structs are not padded
 635   nw="$nw -Wredundant-decls"        # We regularly (re)declare getenv etc.
 636   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 637   nw="$nw -Wformat-nonliteral"      # Emacs does this a lot
 638   nw="$nw -Wvla"                    # warnings in gettext.h
 639   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 640   nw="$nw -Wswitch-enum"            # Too many warnings for now
 641   nw="$nw -Wswitch-default"         # Too many warnings for now
 642   nw="$nw -Wfloat-equal"            # e.g., ftoastr.c
 643   nw="$nw -Winline"                 # e.g., dispnew.c's inlining of row_equal_p
 644
 645   # Emacs doesn't care about shadowing; see
 646   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 647   nw="$nw -Wshadow"
 648
 649   # The following lines should be removable at some point.
 650   nw="$nw -Wstack-protector"
 651   nw="$nw -Wstrict-overflow"
 652   nw="$nw -Wsuggest-attribute=const"
 653   nw="$nw -Wsuggest-attribute=pure"
 654
 655   gl_MANYWARN_ALL_GCC([ws])
 656   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 657   for w in $ws; do
 658     gl_WARN_ADD([$w])
 659   done
 660   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 661   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 662   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 663   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 664   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 665   gl_WARN_ADD([-Wno-format-nonliteral])
 666
 667   # In spite of excluding -Wlogical-op above, it is enabled, as of
 668   # gcc 4.5.0 20090517.
 669   gl_WARN_ADD([-Wno-logical-op])
 670
 671   gl_WARN_ADD([-fdiagnostics-show-option])
 672   gl_WARN_ADD([-funit-at-a-time])
 673
 674   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 675   AC_DEFINE([_FORTIFY_SOURCE], [2],
 676     [enable compile-time and run-time bounds-checking, and some warnings])
 677   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 678
 679   # We use a slightly smaller set of warning options for lib/.
 680   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 681   nw=
 682   nw="$nw -Wunused-macros"
 683
 684   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 685   AC_SUBST([GNULIB_WARN_CFLAGS])
 686 fi
 687
 688
 689
 690 dnl Some other nice autoconf tests.
 691 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 692 dnl AC_PROG_INSTALL
 693 dnl AC_PROG_MKDIR_P
 694 dnl if test "x$RANLIB" = x; then
 695 dnl   AC_PROG_RANLIB
 696 dnl fi
 697
 698 AC_PATH_PROG(INSTALL_INFO, install-info, :,
 699   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
 700 dnl Don't use GZIP, which is used by gzip for additional parameters.
 701 AC_PATH_PROG(GZIP_PROG, gzip)
 702 AC_PATH_PROG(PAXCTL, paxctl,,
 703   [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
 704
 705
 706 ## Need makeinfo >= 4.7 (?) to build the manuals.
 707 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 708 dnl By this stage, configure has already checked for egrep and set EGREP,
 709 dnl or exited with an error if no egrep was found.
 710 if test "$MAKEINFO" != "no" && \
 711   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'`" = x; then
 712    MAKEINFO=no
 713 fi
 714
 715 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 716 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 717 ## therefore in the category of "special tools" not normally required, which
 718 ## configure does not have to check for (eg autoconf itself).
 719 ## In a Bazaar checkout on the other hand, the manuals are not included.
 720 ## So makeinfo is a requirement to build from Bazaar, and configure
 721 ## should test for it as it does for any other build requirement.
 722 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 723 ## with pre-built manuals, from a Bazaar checkout.
 724 HAVE_MAKEINFO=yes
 725
 726 if test "$MAKEINFO" = "no"; then
 727   MAKEINFO=makeinfo
 728   if test "x${with_makeinfo}" = "xno"; then
 729     HAVE_MAKEINFO=no
 730   elif test ! -e $srcdir/info/emacs; then
 731     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
 732 source tree does not seem to have pre-built manuals in the `info' directory.
 733 Either install a suitable version of makeinfo, or re-run configure
 734 with the `--without-makeinfo' option to build without the manuals.] )
 735   fi
 736 fi
 737 AC_SUBST(HAVE_MAKEINFO)
 738
 739 dnl Just so that there is only a single place we need to edit.
 740 INFO_EXT=.info
 741 INFO_OPTS=--no-split
 742 AC_SUBST(INFO_EXT)
 743 AC_SUBST(INFO_OPTS)
 744
 745 dnl Add our options to ac_link now, after it is set up.
 746
 747 if test x$GCC = xyes; then
 748   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 749     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 750 else
 751   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 752     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 753 fi
 754
 755 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 756 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 757 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 758 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 759 dnl if not built to support GNU ld.
 760
 761 late_LDFLAGS=$LDFLAGS
 762 if test x$GCC = xyes; then
 763   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 764 else
 765   LDFLAGS="$LDFLAGS -znocombreloc"
 766 fi
 767
 768 AC_MSG_CHECKING([for -znocombreloc])
 769 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 770   [AC_MSG_RESULT(yes)],
 771   LDFLAGS=$late_LDFLAGS
 772   [AC_MSG_RESULT(no)])
 773
 774
 775 dnl The function dump-emacs will not be defined and temacs will do
 776 dnl (load "loadup") automatically unless told otherwise.
 777 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 778 case "$opsys" in
 779   your-opsys-here) CANNOT_DUMP=yes ;;
 780 esac
 781
 782 test "$CANNOT_DUMP" = "yes" && \
 783   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 784
 785 AC_SUBST(CANNOT_DUMP)
 786
 787
 788 UNEXEC_OBJ=unexelf.o
 789 case "$opsys" in
 790   # MSDOS uses unexcoff.o
 791   # MSWindows uses unexw32.o
 792   aix4-2)
 793    UNEXEC_OBJ=unexaix.o
 794    ;;
 795   cygwin)
 796    UNEXEC_OBJ=unexcw.o
 797    ;;
 798   darwin)
 799    UNEXEC_OBJ=unexmacosx.o
 800    ;;
 801   hpux10-20 | hpux11)
 802    UNEXEC_OBJ=unexhp9k800.o
 803    ;;
 804   sol2-10)
 805    # Use the Solaris dldump() function, called from unexsol.c, to dump
 806    # emacs, instead of the generic ELF dump code found in unexelf.c.
 807    # The resulting binary has a complete symbol table, and is better
 808    # for debugging and other observability tools (debuggers, pstack, etc).
 809    #
 810    # If you encounter a problem using dldump(), please consider sending
 811    # a message to the OpenSolaris tools-linking mailing list:
 812    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 813    #
 814    # It is likely that dldump() works with older Solaris too, but this has
 815    # not been tested, so for now this change is for Solaris 10 or newer.
 816    UNEXEC_OBJ=unexsol.o
 817    ;;
 818 esac
 819
 820 LD_SWITCH_SYSTEM=
 821 case "$opsys" in
 822   freebsd)
 823    ## Let `ld' find image libs and similar things in /usr/local/lib.
 824    ## The system compiler, GCC, has apparently been modified to not
 825    ## look there, contrary to what a stock GCC would do.
 826 ### It's not our place to do this.  See bug#10313#17.
 827 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
 828       :
 829    ;;
 830
 831   gnu-linux)
 832    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 833    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 834    ;;
 835
 836   netbsd)
 837 ### It's not our place to do this.  See bug#10313#17.
 838 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 839       :
 840    ;;
 841
 842   openbsd)
 843    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 844    ## otherwise Emacs dumps core on elf systems.
 845    LD_SWITCH_SYSTEM="-Z"
 846    ;;
 847 esac
 848 AC_SUBST(LD_SWITCH_SYSTEM)
 849
 850 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 851
 852 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
 853 ## which has not been defined yet.  When this was handled with cpp,
 854 ## it was expanded to null when configure sourced the s/*.h file.
 855 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 856 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 857 ## (or somesuch), but because it is supposed to go at the _front_
 858 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 859 ## Compare with the gnu-linux case below, which added to the end
 860 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 861 ## LD_SWITCH_SYSTEM_TEMACS.
 862 case "$opsys" in
 863   netbsd|openbsd)
 864    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
 865 esac
 866
 867
 868 C_SWITCH_MACHINE=
 869 case $canonical in
 870  alpha*)
 871   AC_CHECK_DECL([__ELF__])
 872   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 873     ## With ELF, make sure that all common symbols get allocated to in the
 874     ## data section.  Otherwise, the dump of temacs may miss variables in
 875     ## the shared library that have been initialized.  For example, with
 876     ## GNU libc, __malloc_initialized would normally be resolved to the
 877     ## shared library's .bss section, which is fatal.
 878     if test "x$GCC" = "xyes"; then
 879       C_SWITCH_MACHINE="-fno-common"
 880     else
 881       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 882     fi
 883   else
 884     UNEXEC_OBJ=unexalpha.o
 885   fi
 886   ;;
 887 esac
 888 AC_SUBST(C_SWITCH_MACHINE)
 889
 890 AC_SUBST(UNEXEC_OBJ)
 891
 892 C_SWITCH_SYSTEM=
 893 ## Some programs in src produce warnings saying certain subprograms
 894 ## are too complex and need a MAXMEM value greater than 2000 for
 895 ## additional optimization.  --nils@exp-math.uni-essen.de
 896 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 897   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 898 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 899 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 900 AC_SUBST(C_SWITCH_SYSTEM)
 901
 902
 903 LIBS_SYSTEM=
 904 case "$opsys" in
 905   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 906   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 907
 908   freebsd) LIBS_SYSTEM="-lutil" ;;
 909
 910   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 911
 912   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
 913
 914   ## Motif needs -lgen.
 915   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 916 esac
 917 AC_SUBST(LIBS_SYSTEM)
 918
 919
 920 ### Make sure subsequent tests use flags consistent with the build flags.
 921
 922 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 923   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 924 else
 925   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
 926 fi
 927
 928 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
 929 AC_DEFUN([AC_TYPE_SIZE_T])
 930 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
 931 AC_DEFUN([AC_TYPE_UID_T])
 932
 933
 934 LIB_MATH=-lm
 935 LIB_STANDARD=
 936 START_FILES=
 937
 938 dnl NB do not use CRT_DIR unquoted here, since it might not be set yet.
 939 case $opsys in
 940   cygwin )
 941     LIB_MATH=
 942     START_FILES='pre-crt0.o'
 943     ;;
 944   darwin )
 945     ## Adding -lm confuses the dynamic linker, so omit it.
 946     LIB_MATH=
 947     START_FILES='pre-crt0.o'
 948     ;;
 949   freebsd )
 950     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
 951     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
 952     ;;
 953   gnu-linux | gnu-kfreebsd )
 954     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
 955     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
 956     ;;
 957   hpux10-20 | hpux11 )
 958     LIB_STANDARD=-lc
 959     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
 960     ;;
 961   dnl NB this may be adjusted below.
 962   netbsd | openbsd )
 963     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
 964     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
 965     ;;
 966 esac
 967
 968 AC_SUBST(LIB_MATH)
 969 AC_SUBST(START_FILES)
 970
 971 dnl Not all platforms use crtn.o files.  Check if the current one does.
 972 crt_files=
 973
 974 for file in x $LIB_STANDARD $START_FILES; do
 975   case "$file" in
 976     *CRT_DIR*) crt_files="$crt_files `echo $file | sed -e 's|.*/||'`" ;;
 977   esac
 978 done
 979
 980 if test "x$crt_files" != x; then
 981
 982   ## If user specified a crt-dir, use that unconditionally.
 983   crt_gcc=no
 984
 985   if test "X$CRT_DIR" = "X"; then
 986
 987     CRT_DIR=/usr/lib            # default
 988
 989     case "$canonical" in
 990       x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
 991       ## On x86-64 and s390x GNU/Linux distributions, the standard library
 992       ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
 993       ## For anything else (eg /usr/lib32), it is up the user to specify
 994       ## the location (bug#5655).
 995       ## Test for crtn.o, not just the directory, because sometimes the
 996       ## directory exists but does not have the relevant files (bug#1287).
 997       ## FIXME better to test for binary compatibility somehow.
 998       test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
 999       ;;
1000
1001       powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1002     esac
1003
1004     case "$opsys" in
1005       hpux10-20) CRT_DIR=/lib ;;
1006     esac
1007
1008     test "x${GCC}" = xyes && crt_gcc=yes
1009
1010   fi                            # CRT_DIR = ""
1011
1012   crt_missing=
1013
1014   for file in $crt_files; do
1015
1016     ## If we're using gcc, try to determine it automatically by asking
1017     ## gcc.  [If this doesn't work, CRT_DIR will remain at the
1018     ## system-dependent default from above.]
1019     if test $crt_gcc = yes && test ! -e $CRT_DIR/$file; then
1020
1021        crt_file=`$CC --print-file-name=$file 2>/dev/null`
1022        case "$crt_file" in
1023          */*)
1024            CRT_DIR=`AS_DIRNAME(["$crt_file"])`
1025            ;;
1026        esac
1027     fi
1028
1029     dnl We expect all the files to be in a single directory, so after the
1030     dnl first there is no point asking gcc.
1031     crt_gcc=no
1032
1033     test -e $CRT_DIR/$file || crt_missing="$crt_missing $file"
1034   done                          # $crt_files
1035
1036   test "x$crt_missing" = x || \
1037     AC_MSG_ERROR([Required file(s) not found:$crt_missing
1038 Try using the --with-crt-dir option.])
1039
1040 fi                              # crt_files != ""
1041
1042 AC_SUBST(CRT_DIR)
1043
1044 case $opsys in
1045   netbsd | openbsd )
1046     if test -f $CRT_DIR/crti.o; then
1047
1048         test -f $CRT_DIR/crtn.o || \
1049           AC_MSG_ERROR([Required file not found: crtn.o])
1050
1051         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1052         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1053     fi
1054     ;;
1055 esac
1056
1057
1058 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1059
1060 dnl This function definition taken from Gnome 2.0
1061 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1062 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1063 dnl also defines GSTUFF_PKG_ERRORS on error
1064 AC_DEFUN([PKG_CHECK_MODULES], [
1065   succeeded=no
1066
1067   if test "$PKG_CONFIG" = "no" ; then
1068      ifelse([$4], , [AC_MSG_ERROR([
1069       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1070   else
1071      PKG_CONFIG_MIN_VERSION=0.9.0
1072      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1073         AC_MSG_CHECKING(for $2)
1074
1075         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD &&
1076            $1_CFLAGS=`$PKG_CONFIG --cflags "$2" 2>&AS_MESSAGE_LOG_FD` &&
1077            $1_LIBS=`$PKG_CONFIG --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then
1078             edit_cflags="
1079               s,///*,/,g
1080               s/^/ /
1081               s/ -I/ $isystem/g
1082               s/^ //
1083             "
1084             $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1085             $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'`
1086             AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS'])
1087             succeeded=yes
1088         else
1089             AC_MSG_RESULT(no)
1090             $1_CFLAGS=""
1091             $1_LIBS=""
1092             ## If we have a custom action on failure, don't print errors, but
1093             ## do set a variable so people can do so.
1094             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1095             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1096         fi
1097
1098         AC_SUBST($1_CFLAGS)
1099         AC_SUBST($1_LIBS)
1100      else
1101         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1102         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1103      fi
1104   fi
1105
1106   if test $succeeded = yes; then
1107      ifelse([$3], , :, [$3])
1108   else
1109      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1110   fi
1111 ])
1112
1113
1114 if test "${with_sound}" != "no"; then
1115   # Sound support for GNU/Linux and the free BSDs.
1116   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1117     have_sound_header=yes)
1118   # Emulation library used on NetBSD.
1119   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1120   AC_SUBST(LIBSOUND)
1121
1122   ALSA_REQUIRED=1.0.0
1123   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1124   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1125   if test $HAVE_ALSA = yes; then
1126     SAVE_CFLAGS="$CFLAGS"
1127     SAVE_LIBS="$LIBS"
1128     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1129     LIBS="$ALSA_LIBS $LIBS"
1130     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1131                     emacs_alsa_normal=yes,
1132                     emacs_alsa_normal=no)
1133     if test "$emacs_alsa_normal" != yes; then
1134       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1135                      [[snd_lib_error_set_handler (0);]])],
1136                      emacs_alsa_subdir=yes,
1137                      emacs_alsa_subdir=no)
1138       if test "$emacs_alsa_subdir" != yes; then
1139         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1140       fi
1141       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1142     fi
1143
1144     CFLAGS="$SAVE_CFLAGS"
1145     LIBS="$SAVE_LIBS"
1146     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1147     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1148     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1149   fi
1150
1151   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1152   dnl compiles only on the specified platforms.  For others, it
1153   dnl probably doesn't make sense to try.
1154   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1155      case "$opsys" in
1156        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1157        gnu-linux|freebsd|netbsd)
1158          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1159          ;;
1160      esac
1161   fi
1162
1163   AC_SUBST(CFLAGS_SOUND)
1164 fi
1165
1166 dnl checks for header files
1167 AC_CHECK_HEADERS_ONCE(
1168   sys/select.h sys/time.h utime.h
1169   linux/version.h sys/systeminfo.h
1170   stdio_ext.h fcntl.h coff.h pty.h
1171   sys/vlimit.h sys/resource.h
1172   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1173
1174 AC_MSG_CHECKING(if personality LINUX32 can be set)
1175 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1176                emacs_cv_personality_linux32=yes,
1177                emacs_cv_personality_linux32=no)
1178 AC_MSG_RESULT($emacs_cv_personality_linux32)
1179
1180 if test $emacs_cv_personality_linux32 = yes; then
1181   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1182             [Define to 1 if personality LINUX32 can be set.])
1183 fi
1184
1185 dnl On Solaris 8 there's a compilation warning for term.h because
1186 dnl it doesn't define `bool'.
1187 AC_CHECK_HEADERS(term.h, , , -)
1188 AC_HEADER_TIME
1189 AC_CHECK_DECLS([sys_siglist])
1190 if test $ac_cv_have_decl_sys_siglist != yes; then
1191   # For Tru64, at least:
1192   AC_CHECK_DECLS([__sys_siglist])
1193   if test $ac_cv_have_decl___sys_siglist = yes; then
1194     AC_DEFINE(sys_siglist, __sys_siglist,
1195               [Define to any substitute for sys_siglist.])
1196   fi
1197 fi
1198 AC_HEADER_SYS_WAIT
1199
1200 dnl Some systems have utime.h but don't declare the struct anyplace.
1201 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1202 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1203 #include <sys/time.h>
1204 #include <time.h>
1205 #else
1206 #ifdef HAVE_SYS_TIME_H
1207 #include <sys/time.h>
1208 #else
1209 #include <time.h>
1210 #endif
1211 #endif
1212 #ifdef HAVE_UTIME_H
1213 #include <utime.h>
1214 #endif]], [[static struct utimbuf x; x.actime = x.modtime;]])],
1215   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1216 if test $emacs_cv_struct_utimbuf = yes; then
1217   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1218 fi
1219
1220 dnl Check for speed_t typedef.
1221 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1222   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1223     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1224 if test $emacs_cv_speed_t = yes; then
1225   AC_DEFINE(HAVE_SPEED_T, 1,
1226            [Define to 1 if `speed_t' is declared by <termios.h>.])
1227 fi
1228
1229 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1230 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1231 #include <sys/time.h>
1232 #include <time.h>
1233 #else
1234 #ifdef HAVE_SYS_TIME_H
1235 #include <sys/time.h>
1236 #else
1237 #include <time.h>
1238 #endif
1239 #endif]], [[static struct timeval x; x.tv_sec = x.tv_usec;]])],
1240   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1241 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1242 if test $emacs_cv_struct_timeval = yes; then
1243   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1244 fi
1245
1246 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1247 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]],
1248 [[static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;]])],
1249   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1250 HAVE_EXCEPTION=$emacs_cv_struct_exception
1251 if test $emacs_cv_struct_exception != yes; then
1252   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1253 fi
1254
1255 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1256 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1257 #if HAVE_SYS_SOCKET_H
1258 #include <sys/socket.h>
1259 #endif])
1260 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1261 #if HAVE_SYS_SOCKET_H
1262 #include <sys/socket.h>
1263 #endif])
1264 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1265 #if HAVE_SYS_SOCKET_H
1266 #include <sys/socket.h>
1267 #endif])
1268 AC_CHECK_FUNCS(getifaddrs freeifaddrs)
1269
1270 dnl checks for structure members
1271 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1272                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1273                   struct ifreq.ifr_addr,
1274                   struct ifreq.ifr_addr.sa_len], , ,
1275                  [AC_INCLUDES_DEFAULT
1276 #if HAVE_SYS_SOCKET_H
1277 #include <sys/socket.h>
1278 #endif
1279 #if HAVE_NET_IF_H
1280 #include <net/if.h>
1281 #endif])
1282
1283 dnl Check for endianness.
1284 dnl AC_C_BIGENDIAN is done by gnulib.
1285
1286 AC_CACHE_CHECK([for  __attribute__ ((__aligned__ (expr)))],
1287   [emacs_cv_attribute_aligned],
1288   [AC_COMPILE_IFELSE(
1289      [AC_LANG_PROGRAM(
1290         [[char __attribute__ ((__aligned__ (1 << 3))) c;]],
1291         [[]])],
1292      [emacs_cv_attribute_aligned=yes],
1293      [emacs_cv_attribute_aligned=no])])
1294 if test $emacs_cv_attribute_aligned = yes; then
1295   AC_DEFINE([HAVE_ATTRIBUTE_ALIGNED], 1,
1296     [Define to 1 if GCC-style __attribute__ ((__aligned__ (expr))) works.])
1297 fi
1298
1299 dnl check for Make feature
1300 dnl AC_PROG_MAKE_SET is done by Automake.
1301
1302 DEPFLAGS=
1303 MKDEPDIR=":"
1304 deps_frag=deps.mk
1305 dnl check for GNU Make if we have GCC and autodepend is on.
1306 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1307    AC_MSG_CHECKING([whether we are using GNU Make])
1308    HAVE_GNU_MAKE=no
1309    testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1310    if test "x$testval" != x; then
1311       HAVE_GNU_MAKE=yes
1312    else
1313       ac_enable_autodepend=no
1314    fi
1315    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1316    if test $HAVE_GNU_MAKE = yes; then
1317       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1318       SAVE_CFLAGS="$CFLAGS"
1319       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1320       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1321       CFLAGS="$SAVE_CFLAGS"
1322       test -f deps.d || ac_enable_autodepend=no
1323       rm -rf deps.d
1324       AC_MSG_RESULT([$ac_enable_autodepend])
1325    fi
1326    if test $ac_enable_autodepend = yes; then
1327       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1328       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1329       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1330       deps_frag=autodeps.mk
1331    fi
1332 fi
1333 deps_frag=$srcdir/src/$deps_frag
1334 AC_SUBST(MKDEPDIR)
1335 AC_SUBST(DEPFLAGS)
1336 AC_SUBST_FILE(deps_frag)
1337
1338
1339 lisp_frag=$srcdir/src/lisp.mk
1340 AC_SUBST_FILE(lisp_frag)
1341
1342
1343 dnl checks for operating system services
1344 AC_SYS_LONG_FILE_NAMES
1345
1346 #### Choose a window system.
1347
1348 AC_PATH_X
1349 if test "$no_x" = yes; then
1350   window_system=none
1351 else
1352   window_system=x11
1353 fi
1354
1355 LD_SWITCH_X_SITE_RPATH=
1356 if test "${x_libraries}" != NONE; then
1357   if test -n "${x_libraries}"; then
1358     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1359     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1360   fi
1361   x_default_search_path=""
1362   x_search_path=${x_libraries}
1363   if test -z "${x_search_path}"; then
1364     x_search_path=/usr/lib
1365   fi
1366   for x_library in `echo ${x_search_path}: | \
1367                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1368     x_search_path="\
1369 ${x_library}/X11/%L/%T/%N%C%S:\
1370 ${x_library}/X11/%l/%T/%N%C%S:\
1371 ${x_library}/X11/%T/%N%C%S:\
1372 ${x_library}/X11/%L/%T/%N%S:\
1373 ${x_library}/X11/%l/%T/%N%S:\
1374 ${x_library}/X11/%T/%N%S"
1375     if test x"${x_default_search_path}" = x; then
1376       x_default_search_path=${x_search_path}
1377     else
1378       x_default_search_path="${x_search_path}:${x_default_search_path}"
1379     fi
1380   done
1381 fi
1382 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1383
1384 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1385   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1386 fi
1387
1388 if test x"${x_includes}" = x; then
1389   bitmapdir=/usr/include/X11/bitmaps
1390 else
1391   # accumulate include directories that have X11 bitmap subdirectories
1392   bmd_acc="dummyval"
1393   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1394     if test -d "${bmd}/X11/bitmaps"; then
1395       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1396     fi
1397     if test -d "${bmd}/bitmaps"; then
1398       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1399     fi
1400   done
1401   if test ${bmd_acc} != "dummyval"; then
1402     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1403   fi
1404 fi
1405
1406 HAVE_NS=no
1407 NS_IMPL_COCOA=no
1408 NS_IMPL_GNUSTEP=no
1409 tmp_CPPFLAGS="$CPPFLAGS"
1410 tmp_CFLAGS="$CFLAGS"
1411 CPPFLAGS="$CPPFLAGS -x objective-c"
1412 CFLAGS="$CFLAGS -x objective-c"
1413 TEMACS_LDFLAGS2="\${LDFLAGS}"
1414 GNU_OBJC_CFLAGS=
1415 if test "${with_ns}" != no; then
1416   if test "${opsys}" = darwin; then
1417      NS_IMPL_COCOA=yes
1418      ns_appdir=`pwd`/nextstep/Emacs.app
1419      ns_appbindir=${ns_appdir}/Contents/MacOS
1420      ns_appresdir=${ns_appdir}/Contents/Resources
1421      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1422   elif test -f $GNUSTEP_CONFIG_FILE; then
1423      NS_IMPL_GNUSTEP=yes
1424      ns_appdir=`pwd`/nextstep/Emacs.app
1425      ns_appbindir=${ns_appdir}
1426      ns_appresdir=${ns_appdir}/Resources
1427      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1428      dnl FIXME sourcing this several times in subshells seems inefficient.
1429      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1430      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1431      dnl I seemed to need these as well with GNUstep-startup 0.25.
1432      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1433      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1434      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1435        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1436      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1437        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1438      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1439      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1440      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1441      LIB_STANDARD=
1442      START_FILES=
1443      TEMACS_LDFLAGS2=
1444      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1445      dnl If they had chosen to either define it or not, we could have
1446      dnl just used AC_CHECK_DECL here.
1447      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1448        emacs_cv_objc_exceptions,
1449 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1450 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1451 1;
1452 #else
1453 fail;
1454 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1455      if test $emacs_cv_objc_exceptions = yes; then
1456        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1457        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1458          [Define if GNUstep uses ObjC exceptions.])
1459        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1460      fi
1461   fi
1462
1463   dnl This is only used while we test the NS headers, it gets reset below.
1464   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1465
1466   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1467                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1468   files are missing or cannot be compiled.])])
1469   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1470                                      [NSInteger i;])],
1471                     ns_have_nsinteger=yes,
1472                     ns_have_nsinteger=no)
1473   if test $ns_have_nsinteger = yes; then
1474     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1475   fi
1476 fi
1477 AC_SUBST(TEMACS_LDFLAGS2)
1478
1479 INSTALL_ARCH_INDEP_EXTRA=install-etc
1480 ns_self_contained=no
1481 ns_frag=/dev/null
1482 NS_OBJ=
1483 NS_OBJC_OBJ=
1484 if test "${HAVE_NS}" = yes; then
1485   if test "$with_toolkit_scroll_bars" = "no"; then
1486     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1487   fi
1488
1489   window_system=nextstep
1490   with_xft=no
1491   # set up packaging dirs
1492   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1493      ns_self_contained=yes
1494      prefix=${ns_appresdir}
1495      exec_prefix=${ns_appbindir}
1496      dnl This one isn't really used, only archlibdir is.
1497      libexecdir="\${ns_appbindir}/libexec"
1498      archlibdir="\${ns_appbindir}/libexec"
1499      docdir="\${ns_appresdir}/etc"
1500      etcdir="\${ns_appresdir}/etc"
1501      dnl FIXME maybe set datarootdir instead.
1502      dnl That would also get applications, icons, man.
1503      infodir="\${ns_appresdir}/info"
1504      mandir="\${ns_appresdir}/man"
1505      lispdir="\${ns_appresdir}/lisp"
1506      leimdir="\${ns_appresdir}/leim"
1507      INSTALL_ARCH_INDEP_EXTRA=
1508   fi
1509   ns_frag=$srcdir/src/ns.mk
1510   NS_OBJ="fontset.o fringe.o image.o"
1511   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1512 fi
1513 CFLAGS="$tmp_CFLAGS"
1514 CPPFLAGS="$tmp_CPPFLAGS"
1515 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1516 AC_SUBST(ns_self_contained)
1517 AC_SUBST(NS_OBJ)
1518 AC_SUBST(NS_OBJC_OBJ)
1519 AC_SUBST(LIB_STANDARD)
1520 AC_SUBST_FILE(ns_frag)
1521
1522 case "${window_system}" in
1523   x11 )
1524     HAVE_X_WINDOWS=yes
1525     HAVE_X11=yes
1526     case "${with_x_toolkit}" in
1527       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1528       motif ) USE_X_TOOLKIT=MOTIF ;;
1529       gtk ) with_gtk=yes
1530 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1531 dnl USE_X_TOOLKIT is set.
1532             USE_X_TOOLKIT=none ;;
1533       gtk3 ) with_gtk3=yes
1534              USE_X_TOOLKIT=none ;;
1535       no ) USE_X_TOOLKIT=none ;;
1536 dnl If user did not say whether to use a toolkit, make this decision later:
1537 dnl use the toolkit if we have gtk, or X11R5 or newer.
1538       * ) USE_X_TOOLKIT=maybe ;;
1539     esac
1540   ;;
1541   nextstep | none )
1542     HAVE_X_WINDOWS=no
1543     HAVE_X11=no
1544     USE_X_TOOLKIT=none
1545   ;;
1546 esac
1547
1548 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1549    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1550    if test "$HAVE_XSERVER" = true ||
1551       test -n "$DISPLAY" ||
1552       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1553         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1554 were found.  You should install the relevant development files for X
1555 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1556 sure you have development files for image handling, i.e.
1557 tiff, gif, jpeg, png and xpm.
1558 If you are sure you want Emacs compiled without X window support, pass
1559   --without-x
1560 to configure.])
1561    fi
1562 fi
1563
1564 ### If we're using X11, we should use the X menu package.
1565 HAVE_MENUS=no
1566 case ${HAVE_X11} in
1567   yes ) HAVE_MENUS=yes ;;
1568 esac
1569
1570 # Does the opsystem file prohibit the use of the GNU malloc?
1571 # Assume not, until told otherwise.
1572 GNU_MALLOC=yes
1573
1574 AC_CACHE_CHECK(
1575   [whether malloc is Doug Lea style],
1576   [emacs_cv_var_doug_lea_malloc],
1577   [AC_LINK_IFELSE(
1578      [AC_LANG_PROGRAM(
1579         [[#include <malloc.h>
1580           static void hook (void) {}]],
1581         [[malloc_set_state (malloc_get_state ());
1582           __after_morecore_hook = hook;
1583           __malloc_initialize_hook = hook;]])],
1584      [emacs_cv_var_doug_lea_malloc=yes],
1585      [emacs_cv_var_doug_lea_malloc=no])])
1586 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
1587
1588
1589 dnl See comments in aix4-2.h about maybe using system malloc there.
1590 system_malloc=no
1591 case "$opsys" in
1592   ## darwin ld insists on the use of malloc routines in the System framework.
1593   darwin|sol2-10) system_malloc=yes ;;
1594 esac
1595
1596 if test "${system_malloc}" = "yes"; then
1597   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1598   GNU_MALLOC=no
1599   GNU_MALLOC_reason="
1600     (The GNU allocators don't work with this system configuration.)"
1601   GMALLOC_OBJ=
1602   VMLIMIT_OBJ=
1603 else
1604   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1605   VMLIMIT_OBJ=vm-limit.o
1606 fi
1607 AC_SUBST(GMALLOC_OBJ)
1608 AC_SUBST(VMLIMIT_OBJ)
1609
1610 if test "$doug_lea_malloc" = "yes" ; then
1611   if test "$GNU_MALLOC" = yes ; then
1612     GNU_MALLOC_reason="
1613       (Using Doug Lea's new malloc from the GNU C Library.)"
1614   fi
1615   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1616             [Define to 1 if you are using the GNU C Library.])
1617
1618   ## Use mmap directly for allocating larger buffers.
1619   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1620   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1621   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
1622   case "$opsys" in
1623     gnu*) REL_ALLOC=no ;;
1624   esac
1625 fi
1626
1627 if test x"${REL_ALLOC}" = x; then
1628   REL_ALLOC=${GNU_MALLOC}
1629 fi
1630
1631 use_mmap_for_buffers=no
1632 case "$opsys" in
1633   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1634 esac
1635
1636 AC_FUNC_MMAP
1637 if test $use_mmap_for_buffers = yes; then
1638   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1639   REL_ALLOC=no
1640 fi
1641
1642 LIBS="$LIBS_SYSTEM $LIBS"
1643
1644 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1645 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1646 AC_CHECK_LIB(dnet, dnet_ntoa)
1647 dnl This causes -lresolv to get used in subsequent tests,
1648 dnl which causes failures on some systems such as HPUX 9.
1649 dnl AC_CHECK_LIB(resolv, gethostbyname)
1650
1651 dnl FIXME replace main with a function we actually want from this library.
1652 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1653
1654 dnl Check if pthreads is available.
1655 LIB_PTHREAD=
1656 AC_CHECK_HEADERS_ONCE(pthread.h)
1657 if test "$ac_cv_header_pthread_h"; then
1658   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
1659   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
1660   dnl testing for pthread_self if Emacs uses gmalloc.c.
1661   if test "$GMALLOC_OBJ" = gmalloc.o; then
1662     emacs_pthread_function=pthread_atfork
1663   else
1664     emacs_pthread_function=pthread_self
1665   fi
1666   AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
1667 fi
1668 if test "$HAVE_PTHREAD" = yes; then
1669   case "${canonical}" in
1670     *-hpux*) ;;
1671     *) LIB_PTHREAD="-lpthread"
1672        LIBS="$LIB_PTHREAD $LIBS" ;;
1673   esac
1674   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
1675 fi
1676 AC_SUBST([LIB_PTHREAD])
1677
1678 AC_CHECK_LIB(pthreads, cma_open)
1679
1680 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1681 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1682 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1683 ## added to LIBS in configure would never contain the pthreads part,
1684 ## but the value used in Makefiles might.  FIXME?
1685 ##
1686 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1687 ## be harmless on older versions of X where it happens to exist.
1688 test "$opsys" = "aix4-2" && \
1689   test $ac_cv_lib_pthreads_cma_open = yes && \
1690   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1691
1692 dnl Check for need for bigtoc support on IBM AIX
1693
1694 case ${host_os} in
1695 aix*)
1696   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1697     case $GCC in
1698     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1699     *) gdb_cv_bigtoc=-bbigtoc ;;
1700     esac
1701
1702     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1703     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1704   ])
1705   ;;
1706 esac
1707
1708 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1709 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1710 # REAL_CPPFLAGS later on.
1711
1712 REAL_CFLAGS="$CFLAGS"
1713 REAL_CPPFLAGS="$CPPFLAGS"
1714
1715 if test "${HAVE_X11}" = "yes"; then
1716   DEFS="$C_SWITCH_X_SITE $DEFS"
1717   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1718   LIBS="-lX11 $LIBS"
1719   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1720   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1721
1722   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1723   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
1724   # but it's more convenient here to set LD_RUN_PATH since this
1725   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
1726   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1727     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1728     export LD_RUN_PATH
1729   fi
1730
1731   if test "${opsys}" = "gnu-linux"; then
1732     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1733     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1734      [[XOpenDisplay ("foo");]])],
1735      [xgnu_linux_first_failure=no],
1736      [xgnu_linux_first_failure=yes])
1737     if test "${xgnu_linux_first_failure}" = "yes"; then
1738       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1739       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1740       OLD_CPPFLAGS="$CPPFLAGS"
1741       OLD_LIBS="$LIBS"
1742       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1743       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1744       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1745       LIBS="$LIBS -b i486-linuxaout"
1746       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1747        [[XOpenDisplay ("foo");]])],
1748        [xgnu_linux_second_failure=no],
1749        [xgnu_linux_second_failure=yes])
1750       if test "${xgnu_linux_second_failure}" = "yes"; then
1751         # If we get the same failure with -b, there is no use adding -b.
1752         # So take it out.  This plays safe.
1753         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1754         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1755         CPPFLAGS="$OLD_CPPFLAGS"
1756         LIBS="$OLD_LIBS"
1757         AC_MSG_RESULT(no)
1758       else
1759         AC_MSG_RESULT(yes)
1760       fi
1761     else
1762       AC_MSG_RESULT(no)
1763     fi
1764   fi
1765
1766   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1767   # header files included from there.
1768   AC_MSG_CHECKING(for Xkb)
1769   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1770 #include <X11/XKBlib.h>]],
1771         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1772         emacs_xkb=yes, emacs_xkb=no)
1773   AC_MSG_RESULT($emacs_xkb)
1774   if test $emacs_xkb = yes; then
1775     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1776   fi
1777
1778   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1779 XScreenNumberOfScreen)
1780 fi
1781
1782 if test "${window_system}" = "x11"; then
1783   AC_MSG_CHECKING(X11 version 6)
1784   AC_CACHE_VAL(emacs_cv_x11_version_6,
1785   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1786 [[#if XlibSpecificationRelease < 6
1787 fail;
1788 #endif
1789 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1790   if test $emacs_cv_x11_version_6 = yes; then
1791     AC_MSG_RESULT(6 or newer)
1792     AC_DEFINE(HAVE_X11R6, 1,
1793               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1794     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1795     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1796     ## XIM support.
1797     case "$opsys" in
1798       sol2-*) : ;;
1799       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1800            [Define if you have usable X11R6-style XIM support.])
1801          ;;
1802     esac
1803   else
1804     AC_MSG_RESULT(before 6)
1805   fi
1806 fi
1807
1808
1809 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1810 HAVE_RSVG=no
1811 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1812   if test "${with_rsvg}" != "no"; then
1813     RSVG_REQUIRED=2.11.0
1814     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1815
1816     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1817     AC_SUBST(RSVG_CFLAGS)
1818     AC_SUBST(RSVG_LIBS)
1819
1820     if test $HAVE_RSVG = yes; then
1821       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1822       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1823       LIBS="$RSVG_LIBS $LIBS"
1824     fi
1825   fi
1826 fi
1827
1828 HAVE_IMAGEMAGICK=no
1829 if test "${HAVE_X11}" = "yes"; then
1830   if test "${with_imagemagick}" != "no"; then
1831     ## 6.2.8 is the earliest version known to work, but earlier versions
1832     ## might work - let us know if you find one.
1833     ## 6.0.7 does not work.  See bug#7955.
1834     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1835     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1836     AC_SUBST(IMAGEMAGICK_CFLAGS)
1837     AC_SUBST(IMAGEMAGICK_LIBS)
1838
1839     if test $HAVE_IMAGEMAGICK = yes; then
1840       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1841       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1842       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1843       AC_CHECK_FUNCS(MagickExportImagePixels)
1844     fi
1845   fi
1846 fi
1847
1848
1849 HAVE_GTK=no
1850 GTK_OBJ=
1851 if test "${with_gtk3}" = "yes"; then
1852   GLIB_REQUIRED=2.28
1853   GTK_REQUIRED=3.0
1854   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1855
1856   dnl Checks for libraries.
1857   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1858   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1859      AC_MSG_ERROR($GTK_PKG_ERRORS)
1860   fi
1861   AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
1862   GTK_OBJ=emacsgtkfixed.o
1863 fi
1864
1865 if test "$pkg_check_gtk" != "yes"; then
1866   HAVE_GTK=no
1867 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1868   GLIB_REQUIRED=2.10
1869   GTK_REQUIRED=2.10
1870   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1871
1872   dnl Checks for libraries.
1873   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1874   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1875      AC_MSG_ERROR($GTK_PKG_ERRORS)
1876   fi
1877 fi
1878 fi
1879
1880 if test x"$pkg_check_gtk" = xyes; then
1881
1882   AC_SUBST(GTK_CFLAGS)
1883   AC_SUBST(GTK_LIBS)
1884   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1885   CFLAGS="$CFLAGS $GTK_CFLAGS"
1886   LIBS="$GTK_LIBS $LIBS"
1887   dnl Try to compile a simple GTK program.
1888   GTK_COMPILES=no
1889   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1890   if test "${GTK_COMPILES}" != "yes"; then
1891     if test "$USE_X_TOOLKIT" != "maybe"; then
1892       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1893     fi
1894   else
1895     HAVE_GTK=yes
1896     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1897     GTK_OBJ="gtkutil.o $GTK_OBJ"
1898     USE_X_TOOLKIT=none
1899     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1900       :
1901     else
1902       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1903        closing open displays.  This is no problem if you just use
1904        one display, but if you use more than one and close one of them
1905        Emacs may crash.]])
1906       sleep 3
1907     fi
1908   fi
1909
1910 fi
1911 AC_SUBST(GTK_OBJ)
1912
1913
1914 if test "${HAVE_GTK}" = "yes"; then
1915
1916   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1917   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1918   if test "$with_toolkit_scroll_bars" != no; then
1919     with_toolkit_scroll_bars=yes
1920   fi
1921
1922   dnl  Check if we have the old file selection dialog declared and
1923   dnl  in the link library.  In 2.x it may be in the library,
1924   dnl  but not declared if deprecated featured has been selected out.
1925   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1926   HAVE_GTK_FILE_SELECTION=no
1927   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1928                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1929 #include <gtk/gtk.h>])
1930   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1931     AC_CHECK_FUNCS(gtk_file_selection_new)
1932   fi
1933
1934
1935   dnl Check for functions introduced in 2.14 and later.
1936   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1937                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1938                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1939                  gtk_orientable_set_orientation \
1940                  gtk_window_set_has_resize_grip)
1941 fi
1942
1943 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1944 dnl other platforms.
1945 HAVE_DBUS=no
1946 DBUS_OBJ=
1947 if test "${with_dbus}" = "yes"; then
1948    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1949    if test "$HAVE_DBUS" = yes; then
1950      LIBS="$LIBS $DBUS_LIBS"
1951      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1952      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
1953      dnl dbus_validate_* have been introduced in D-Bus 1.5.12.
1954      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
1955                     dbus_validate_bus_name \
1956                     dbus_validate_path \
1957                     dbus_validate_interface \
1958                     dbus_validate_member)
1959      DBUS_OBJ=dbusbind.o
1960    fi
1961 fi
1962 AC_SUBST(DBUS_OBJ)
1963
1964 dnl GSettings has been tested under GNU/Linux only.
1965 HAVE_GSETTINGS=no
1966 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
1967    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
1968    if test "$HAVE_GSETTINGS" = "yes"; then
1969       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
1970       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
1971       SETTINGS_LIBS="$GSETTINGS_LIBS"
1972    fi
1973 fi
1974
1975 dnl GConf has been tested under GNU/Linux only.
1976 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1977 HAVE_GCONF=no
1978 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1979    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1980    if test "$HAVE_GCONF" = yes; then
1981       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1982       dnl Newer GConf doesn't link with g_objects, so this is not defined.
1983       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
1984       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
1985    fi
1986 fi
1987
1988 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
1989     SAVE_CFLAGS="$CFLAGS"
1990     SAVE_LIBS="$LIBS"
1991     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
1992     LIBS="$SETTINGS_LIBS $LIBS"
1993     AC_CHECK_FUNCS([g_type_init])
1994     CFLAGS="$SAVE_CFLAGS"
1995     LIBS="$SAVE_LIBS"
1996 fi
1997 AC_SUBST(SETTINGS_CFLAGS)
1998 AC_SUBST(SETTINGS_LIBS)
1999
2000
2001 dnl SELinux is available for GNU/Linux only.
2002 HAVE_LIBSELINUX=no
2003 LIBSELINUX_LIBS=
2004 if test "${with_selinux}" = "yes"; then
2005    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2006    if test "$HAVE_LIBSELINUX" = yes; then
2007       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2008       LIBSELINUX_LIBS=-lselinux
2009    fi
2010 fi
2011 AC_SUBST(LIBSELINUX_LIBS)
2012
2013 HAVE_GNUTLS=no
2014 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
2015 if test "${with_gnutls}" = "yes" ; then
2016   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2017   if test "${HAVE_GNUTLS}" = "yes"; then
2018     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2019   fi
2020
2021   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2022   LIBS="$LIBGNUTLS_LIBS $LIBS"
2023   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
2024
2025   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
2026     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
2027   fi
2028 fi
2029
2030 AC_SUBST(LIBGNUTLS_LIBS)
2031 AC_SUBST(LIBGNUTLS_CFLAGS)
2032
2033 dnl Do not put whitespace before the #include statements below.
2034 dnl Older compilers (eg sunos4 cc) choke on it.
2035 HAVE_XAW3D=no
2036 LUCID_LIBW=
2037 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2038   if test "$with_xaw3d" != no; then
2039     AC_MSG_CHECKING(for xaw3d)
2040     AC_CACHE_VAL(emacs_cv_xaw3d,
2041     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2042 #include <X11/Intrinsic.h>
2043 #include <X11/Xaw3d/Simple.h>]],
2044       [[]])],
2045       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2046                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2047       emacs_cv_xaw3d=no)])
2048   else
2049     emacs_cv_xaw3d=no
2050   fi
2051   if test $emacs_cv_xaw3d = yes; then
2052     AC_MSG_RESULT([yes; using Lucid toolkit])
2053     USE_X_TOOLKIT=LUCID
2054     HAVE_XAW3D=yes
2055     LUCID_LIBW=-lXaw3d
2056     AC_DEFINE(HAVE_XAW3D, 1,
2057               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2058   else
2059     AC_MSG_RESULT(no)
2060     AC_MSG_CHECKING(for libXaw)
2061     AC_CACHE_VAL(emacs_cv_xaw,
2062     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2063 #include <X11/Intrinsic.h>
2064 #include <X11/Xaw/Simple.h>]],
2065       [[]])],
2066       emacs_cv_xaw=yes,
2067       emacs_cv_xaw=no)])
2068     if test $emacs_cv_xaw = yes; then
2069       AC_MSG_RESULT([yes; using Lucid toolkit])
2070       USE_X_TOOLKIT=LUCID
2071       LUCID_LIBW=-lXaw
2072     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2073       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2074     else
2075       AC_MSG_ERROR([No X toolkit could be found.
2076 If you are sure you want Emacs compiled without an X toolkit, pass
2077   --with-x-toolkit=no
2078 to configure.  Otherwise, install the development libraries for the toolkit
2079 that you want to use (e.g. Gtk+) and re-run configure.])
2080     fi
2081   fi
2082 fi
2083
2084 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2085
2086 LIBXTR6=
2087 if test "${USE_X_TOOLKIT}" != "none"; then
2088   AC_MSG_CHECKING(X11 toolkit version)
2089   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2090   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2091 [[#if XtSpecificationRelease < 6
2092 fail;
2093 #endif
2094 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2095   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2096   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2097     AC_MSG_RESULT(6 or newer)
2098     AC_DEFINE(HAVE_X11XTR6, 1,
2099               [Define to 1 if you have the X11R6 or newer version of Xt.])
2100     LIBXTR6="-lSM -lICE"
2101     case "$opsys" in
2102       ## Use libw.a along with X11R6 Xt.
2103       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2104     esac
2105   else
2106     AC_MSG_RESULT(before 6)
2107   fi
2108
2109 dnl If using toolkit, check whether libXmu.a exists.
2110 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2111   OLDLIBS="$LIBS"
2112   if test x$HAVE_X11XTR6 = xyes; then
2113     LIBS="-lXt -lSM -lICE $LIBS"
2114   else
2115     LIBS="-lXt $LIBS"
2116   fi
2117   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2118   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2119 fi
2120 AC_SUBST(LIBXTR6)
2121
2122 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2123 dnl Why not just test for libxmu in the normal way?
2124 LIBXMU=-lXmu
2125 case $opsys in
2126   ## These systems don't supply Xmu.
2127   hpux* | aix4-2 )
2128     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2129     ;;
2130 esac
2131 AC_SUBST(LIBXMU)
2132
2133 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2134 if test "${HAVE_X11}" = "yes"; then
2135   if test "${USE_X_TOOLKIT}" != "none"; then
2136     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2137   fi
2138 fi
2139
2140 LIBXP=
2141 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2142   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2143   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2144     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2145 int x = 5;
2146 #else
2147 Motif version prior to 2.1.
2148 #endif]])],
2149     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2150   if test $emacs_cv_motif_version_2_1 = yes; then
2151     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2152   else
2153     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2154     # We put this in CFLAGS temporarily to precede other -I options
2155     # that might be in CFLAGS temporarily.
2156     # We put this in CPPFLAGS where it precedes the other -I options.
2157     OLD_CPPFLAGS=$CPPFLAGS
2158     OLD_CFLAGS=$CFLAGS
2159     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2160     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2161     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2162       [[int x = 5;]])],
2163       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2164     if test $emacs_cv_lesstif = yes; then
2165       # Make sure this -I option remains in CPPFLAGS after it is set
2166       # back to REAL_CPPFLAGS.
2167       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2168       # have those other -I options anyway.  Ultimately, having this
2169       # directory ultimately in CPPFLAGS will be enough.
2170       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2171       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2172     else
2173       CFLAGS=$OLD_CFLAGS
2174       CPPFLAGS=$OLD_CPPFLAGS
2175     fi
2176   fi
2177   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2178     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2179 fi
2180
2181 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2182 dnl using Motif or Xaw3d is available, and unless
2183 dnl --with-toolkit-scroll-bars=no was specified.
2184
2185 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2186             [Define to 1 if we should use toolkit scroll bars.])dnl
2187 USE_TOOLKIT_SCROLL_BARS=no
2188 if test "${with_toolkit_scroll_bars}" != "no"; then
2189   if test "${USE_X_TOOLKIT}" != "none"; then
2190     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2191       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2192       HAVE_XAW3D=no
2193       USE_TOOLKIT_SCROLL_BARS=yes
2194     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2195       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2196       USE_TOOLKIT_SCROLL_BARS=yes
2197     fi
2198   elif test "${HAVE_GTK}" = "yes"; then
2199     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2200     USE_TOOLKIT_SCROLL_BARS=yes
2201   elif test "${HAVE_NS}" = "yes"; then
2202     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2203     USE_TOOLKIT_SCROLL_BARS=yes
2204   fi
2205 fi
2206
2207 dnl See if XIM is available.
2208 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2209           #include <X11/Xlib.h>
2210           #include <X11/Xresource.h>]],
2211          [[XIMProc  callback;]])],
2212          [HAVE_XIM=yes
2213          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2214          HAVE_XIM=no)
2215
2216 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2217
2218 if test "${with_xim}" != "no"; then
2219   AC_DEFINE(USE_XIM, 1,
2220             [Define to 1 if we should use XIM, if it is available.])
2221 fi
2222
2223
2224 if test "${HAVE_XIM}" != "no"; then
2225   late_CFLAGS=$CFLAGS
2226   if test "$GCC" = yes; then
2227     CFLAGS="$CFLAGS --pedantic-errors"
2228   fi
2229   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2230 #include <X11/Xlib.h>
2231 #include <X11/Xresource.h>]],
2232 [[Display *display;
2233 XrmDatabase db;
2234 char *res_name;
2235 char *res_class;
2236 XIMProc  callback;
2237 XPointer *client_data;
2238 #ifndef __GNUC__
2239 /* If we're not using GCC, it's probably not XFree86, and this is
2240    probably right, but we can't use something like --pedantic-errors.  */
2241 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2242                                            char*, XIMProc, XPointer*);
2243 #endif
2244 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2245    client_data);]])],
2246     [emacs_cv_arg6_star=yes])
2247   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2248          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2249 either XPointer or XPointer*.])dnl
2250   if test "$emacs_cv_arg6_star" = yes; then
2251     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2252   else
2253     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2254   fi
2255   CFLAGS=$late_CFLAGS
2256 fi
2257
2258 ### Start of font-backend (under any platform) section.
2259 # (nothing here yet -- this is a placeholder)
2260 ### End of font-backend (under any platform) section.
2261
2262 ### Start of font-backend (under X11) section.
2263 if test "${HAVE_X11}" = "yes"; then
2264    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2265
2266    ## Use -lXft if available, unless `--with-xft=no'.
2267    HAVE_XFT=maybe
2268     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2269       with_xft="no";
2270     fi
2271     if test "x${with_xft}" != "xno"; then
2272
2273       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2274       ## Because xftfont.c uses XRenderQueryExtension, we also
2275       ## need to link to -lXrender.
2276       HAVE_XRENDER=no
2277       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2278       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2279         OLD_CPPFLAGS="$CPPFLAGS"
2280         OLD_CFLAGS="$CFLAGS"
2281         OLD_LIBS="$LIBS"
2282         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2283         CFLAGS="$CFLAGS $XFT_CFLAGS"
2284         XFT_LIBS="-lXrender $XFT_LIBS"
2285         LIBS="$XFT_LIBS $LIBS"
2286         AC_CHECK_HEADER(X11/Xft/Xft.h,
2287           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2288
2289         if test "${HAVE_XFT}" = "yes"; then
2290           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2291             AC_SUBST(XFT_LIBS)
2292           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2293         else
2294           CPPFLAGS="$OLD_CPPFLAGS"
2295           CFLAGS="$OLD_CFLAGS"
2296           LIBS="$OLD_LIBS"
2297         fi                        # "${HAVE_XFT}" = "yes"
2298       fi                          # "$HAVE_XFT" != no
2299     fi                            # "x${with_xft}" != "xno"
2300
2301     ## We used to allow building with FreeType and without Xft.
2302     ## However, the ftx font backend driver is not in good shape.
2303     if test "$HAVE_XFT" != "yes"; then
2304        dnl For the "Does Emacs use" message at the end.
2305        HAVE_XFT=no
2306        HAVE_FREETYPE=no
2307     else
2308        dnl Strict linkers fail with
2309        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2310        dnl if -lfreetype is not specified.
2311        dnl The following is needed to set FREETYPE_LIBS.
2312        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2313                          HAVE_FREETYPE=no)
2314
2315        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2316     fi
2317
2318     HAVE_LIBOTF=no
2319     if test "${HAVE_FREETYPE}" = "yes"; then
2320       AC_DEFINE(HAVE_FREETYPE, 1,
2321                 [Define to 1 if using the freetype and fontconfig libraries.])
2322       if test "${with_libotf}" != "no"; then
2323         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2324                           HAVE_LIBOTF=no)
2325         if test "$HAVE_LIBOTF" = "yes"; then
2326           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2327           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2328                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2329                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2330           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2331             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2332                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2333           fi
2334         fi
2335       fi
2336     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2337     dnl Does the new font backend require it, or can it work without it?
2338     fi
2339
2340     HAVE_M17N_FLT=no
2341     if test "${HAVE_LIBOTF}" = yes; then
2342       if test "${with_m17n_flt}" != "no"; then
2343         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2344         if test "$HAVE_M17N_FLT" = "yes"; then
2345           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2346         fi
2347       fi
2348     fi
2349 else
2350     HAVE_XFT=no
2351     HAVE_FREETYPE=no
2352     HAVE_LIBOTF=no
2353     HAVE_M17N_FLT=no
2354 fi
2355
2356 ### End of font-backend (under X11) section.
2357
2358 AC_SUBST(FREETYPE_CFLAGS)
2359 AC_SUBST(FREETYPE_LIBS)
2360 AC_SUBST(FONTCONFIG_CFLAGS)
2361 AC_SUBST(FONTCONFIG_LIBS)
2362 AC_SUBST(LIBOTF_CFLAGS)
2363 AC_SUBST(LIBOTF_LIBS)
2364 AC_SUBST(M17N_FLT_CFLAGS)
2365 AC_SUBST(M17N_FLT_LIBS)
2366
2367 ### Use -lXpm if available, unless `--with-xpm=no'.
2368 HAVE_XPM=no
2369 LIBXPM=
2370 if test "${HAVE_X11}" = "yes"; then
2371   if test "${with_xpm}" != "no"; then
2372     AC_CHECK_HEADER(X11/xpm.h,
2373       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2374     if test "${HAVE_XPM}" = "yes"; then
2375       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2376       AC_EGREP_CPP(no_return_alloc_pixels,
2377       [#include "X11/xpm.h"
2378 #ifndef XpmReturnAllocPixels
2379 no_return_alloc_pixels
2380 #endif
2381       ], HAVE_XPM=no, HAVE_XPM=yes)
2382
2383       if test "${HAVE_XPM}" = "yes"; then
2384         AC_MSG_RESULT(yes)
2385       else
2386         AC_MSG_RESULT(no)
2387       fi
2388     fi
2389   fi
2390
2391   if test "${HAVE_XPM}" = "yes"; then
2392     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2393     LIBXPM=-lXpm
2394   fi
2395 fi
2396 AC_SUBST(LIBXPM)
2397
2398 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2399 HAVE_JPEG=no
2400 LIBJPEG=
2401 if test "${HAVE_X11}" = "yes"; then
2402   if test "${with_jpeg}" != "no"; then
2403     dnl Checking for jpeglib.h can lose because of a redefinition of
2404     dnl  HAVE_STDLIB_H.
2405     AC_CHECK_HEADER(jerror.h,
2406       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2407   fi
2408
2409   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2410   if test "${HAVE_JPEG}" = "yes"; then
2411     AC_DEFINE(HAVE_JPEG)
2412     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2413         [#include <jpeglib.h>
2414          version=JPEG_LIB_VERSION
2415 ],
2416         [AC_DEFINE(HAVE_JPEG)],
2417         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2418         HAVE_JPEG=no])
2419   fi
2420   if test "${HAVE_JPEG}" = "yes"; then
2421     LIBJPEG=-ljpeg
2422   fi
2423 fi
2424 AC_SUBST(LIBJPEG)
2425
2426 ### Use -lpng if available, unless `--with-png=no'.
2427 HAVE_PNG=no
2428 LIBPNG=
2429 if test "${HAVE_X11}" = "yes"; then
2430   if test "${with_png}" != "no"; then
2431     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2432     # in /usr/include/libpng.
2433     AC_CHECK_HEADERS(png.h libpng/png.h)
2434     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2435       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2436     fi
2437   fi
2438
2439   if test "${HAVE_PNG}" = "yes"; then
2440     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2441     LIBPNG="-lpng -lz -lm"
2442   fi
2443 fi
2444 AC_SUBST(LIBPNG)
2445
2446 ### Use -ltiff if available, unless `--with-tiff=no'.
2447 HAVE_TIFF=no
2448 LIBTIFF=
2449 if test "${HAVE_X11}" = "yes"; then
2450   if test "${with_tiff}" != "no"; then
2451     AC_CHECK_HEADER(tiffio.h,
2452       [tifflibs="-lz -lm"
2453       # At least one tiff package requires the jpeg library.
2454       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2455       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2456   fi
2457
2458   if test "${HAVE_TIFF}" = "yes"; then
2459     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2460     dnl FIXME -lz -lm, as per libpng?
2461     LIBTIFF=-ltiff
2462   fi
2463 fi
2464 AC_SUBST(LIBTIFF)
2465
2466 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2467 HAVE_GIF=no
2468 LIBGIF=
2469 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2470   AC_CHECK_HEADER(gif_lib.h,
2471 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2472 # Earlier versions can crash Emacs.
2473     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2474
2475   if test "$HAVE_GIF" = yes; then
2476     LIBGIF=-lgif
2477   elif test "$HAVE_GIF" = maybe; then
2478 # If gif_lib.h but no libgif, try libungif.
2479     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2480     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2481   fi
2482
2483   if test "${HAVE_GIF}" = "yes"; then
2484     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2485   fi
2486 fi
2487 AC_SUBST(LIBGIF)
2488
2489 dnl Check for required libraries.
2490 if test "${HAVE_X11}" = "yes"; then
2491   MISSING=""
2492   WITH_NO=""
2493   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2494     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2495   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2496     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2497   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2498     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2499   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2500     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2501   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2502     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2503
2504   if test "X${MISSING}" != X; then
2505     AC_MSG_ERROR([The following required libraries were not found:
2506     $MISSING
2507 Maybe some development libraries/packages are missing?
2508 If you don't want to link with them give
2509     $WITH_NO
2510 as options to configure])
2511   fi
2512 fi
2513
2514 ### Use -lgpm if available, unless `--with-gpm=no'.
2515 HAVE_GPM=no
2516 LIBGPM=
2517 if test "${with_gpm}" != "no"; then
2518   AC_CHECK_HEADER(gpm.h,
2519     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2520
2521   if test "${HAVE_GPM}" = "yes"; then
2522     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2523     LIBGPM=-lgpm
2524   fi
2525 fi
2526 AC_SUBST(LIBGPM)
2527
2528 dnl Check for malloc/malloc.h on darwin
2529 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
2530
2531 GNUSTEP_CFLAGS=
2532 ### Use NeXTstep API to implement GUI.
2533 if test "${HAVE_NS}" = "yes"; then
2534   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2535   if test "${NS_IMPL_COCOA}" = "yes"; then
2536     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2537   fi
2538   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2539     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2540     # See also .m.o rule in Makefile.in */
2541     # FIXME: are all these flags really needed?  Document here why.  */
2542     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
2543     ## Extra CFLAGS applied to src/*.m files.
2544     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2545   fi
2546   # We also have mouse menus.
2547   HAVE_MENUS=yes
2548   OTHER_FILES=ns-app
2549 fi
2550
2551
2552 ### Use session management (-lSM -lICE) if available
2553 HAVE_X_SM=no
2554 LIBXSM=
2555 if test "${HAVE_X11}" = "yes"; then
2556   AC_CHECK_HEADER(X11/SM/SMlib.h,
2557     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2558
2559   if test "${HAVE_X_SM}" = "yes"; then
2560     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2561     LIBXSM="-lSM -lICE"
2562     case "$LIBS" in
2563       *-lSM*) ;;
2564       *)      LIBS="$LIBXSM $LIBS" ;;
2565     esac
2566   fi
2567 fi
2568 AC_SUBST(LIBXSM)
2569
2570 ### Use libxml (-lxml2) if available
2571 HAVE_LIBXML2=no
2572 if test "${with_xml2}" != "no"; then
2573   ### I'm not sure what the version number should be, so I just guessed.
2574   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2575   if test "${HAVE_LIBXML2}" = "yes"; then
2576     LIBS="$LIBXML2_LIBS $LIBS"
2577     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2578     if test "${HAVE_LIBXML2}" = "yes"; then
2579       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2580     else
2581       LIBXML2_LIBS=""
2582       LIBXML2_CFLAGS=""
2583     fi
2584   fi
2585 fi
2586 AC_SUBST(LIBXML2_LIBS)
2587 AC_SUBST(LIBXML2_CFLAGS)
2588
2589 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2590 AC_CACHE_CHECK(whether netdb declares h_errno,
2591                emacs_cv_netdb_declares_h_errno,
2592 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2593   [[return h_errno;]])],
2594   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2595 if test $emacs_cv_netdb_declares_h_errno = yes; then
2596   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2597 fi
2598
2599 # fmod, logb, and frexp are found in -lm on most systems.
2600 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2601 AC_CHECK_LIB(m, sqrt)
2602
2603 # Check for mail-locking functions in a "mail" library.  Probably this should
2604 # have the same check as for liblockfile below.
2605 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2606 if test $have_mail = yes; then
2607   LIBS_MAIL=-lmail
2608   LIBS="$LIBS_MAIL $LIBS"
2609   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2610 else
2611   LIBS_MAIL=
2612 fi
2613 dnl Debian, at least:
2614 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2615 if test $have_lockfile = yes; then
2616    LIBS_MAIL=-llockfile
2617    LIBS="$LIBS_MAIL $LIBS"
2618    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2619 else
2620 # If we have the shared liblockfile, assume we must use it for mail
2621 # locking (e.g. Debian).  If we couldn't link against liblockfile
2622 # (no liblockfile.a installed), ensure that we don't need to.
2623   dnl This works for files generally, not just executables.
2624   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2625   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2626                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2627   if test $ac_cv_prog_liblockfile = yes; then
2628     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2629 This probably means that movemail could lose mail.
2630 There may be a `development' package to install containing liblockfile.])
2631   fi
2632 fi
2633 AC_CHECK_FUNCS(touchlock)
2634 AC_CHECK_HEADERS_ONCE(maillock.h)
2635 AC_SUBST(LIBS_MAIL)
2636
2637 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2638 ## interlock access to the mail spool.  The alternative is a lock file named
2639 ## /usr/spool/mail/$USER.lock.
2640 mail_lock=no
2641 case "$opsys" in
2642   aix4-2) mail_lock="lockf" ;;
2643
2644   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2645
2646   ## On GNU/Linux systems, both methods are used by various mail programs.
2647   ## I assume most people are using newer mailers that have heard of flock.
2648   ## Change this if you need to.
2649   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2650   ## configure gets the right answers, and that means *NOT* using flock.
2651   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2652   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2653   ## Debian maintainer hasn't provided a clean fix for Emacs.
2654   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2655   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2656   ## correct logic.  -- fx
2657   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2658   ## liblockfile is a Free Software replacement for libmail, used on
2659   ## Debian systems and elsewhere. -rfr.
2660   gnu-*)
2661     mail_lock="flock"
2662     if test $have_mail = yes || test $have_lockfile = yes; then
2663       test $ac_cv_header_maillock_h = yes && mail_lock=no
2664     fi
2665     ;;
2666 esac
2667
2668 BLESSMAIL_TARGET=
2669 case "$mail_lock" in
2670   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2671
2672   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2673
2674   *) BLESSMAIL_TARGET="need-blessmail" ;;
2675 esac
2676 AC_SUBST(BLESSMAIL_TARGET)
2677
2678
2679 AC_CHECK_FUNCS(gethostname \
2680 rename closedir mkdir rmdir getrusage get_current_dir_name \
2681 random lrand48 logb frexp fmod rint cbrt setsid \
2682 strerror fpathconf select euidaccess getpagesize setlocale \
2683 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2684 __fpending strsignal setitimer \
2685 sendto recvfrom getsockname getpeername \
2686 gai_strerror mkstemp getline getdelim fsync sync \
2687 difftime posix_memalign \
2688 getpwent endpwent getgrent endgrent \
2689 cfmakeraw cfsetspeed copysign __executable_start)
2690
2691 dnl Cannot use AC_CHECK_FUNCS
2692 AC_CACHE_CHECK([for __builtin_unwind_init],
2693                emacs_cv_func___builtin_unwind_init,
2694 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2695                 emacs_cv_func___builtin_unwind_init=yes,
2696                 emacs_cv_func___builtin_unwind_init=no)])
2697 if test $emacs_cv_func___builtin_unwind_init = yes; then
2698   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2699             [Define to 1 if you have the `__builtin_unwind_init' function.])
2700 fi
2701
2702 AC_CHECK_HEADERS_ONCE(sys/un.h)
2703
2704 AC_FUNC_FSEEKO
2705
2706 AC_FUNC_GETPGRP
2707
2708 # UNIX98 PTYs.
2709 AC_CHECK_FUNCS(grantpt)
2710
2711 # PTY-related GNU extensions.
2712 AC_CHECK_FUNCS(getpt)
2713
2714 # Check this now, so that we will NOT find the above functions in ncurses.
2715 # That is because we have not set up to link ncurses in lib-src.
2716 # It's better to believe a function is not available
2717 # than to expect to find it in ncurses.
2718 # Also we need tputs and friends to be able to build at all.
2719 AC_MSG_CHECKING([for library containing tputs])
2720 # Run a test program that contains a call to tputs, a call that is
2721 # never executed.  This tests whether a pre-'main' dynamic linker
2722 # works with the library.  It's too much trouble to actually call
2723 # tputs in the test program, due to portability hassles.  When
2724 # cross-compiling, assume the test program will run if it links.
2725 AC_DEFUN([tputs_link_source], [
2726   AC_LANG_SOURCE(
2727      [[extern void tputs (const char *, int, int (*)(int));
2728        int main (int argc, char **argv)
2729        {
2730           if (argc == 10000)
2731             tputs (argv[0], 0, 0);
2732           return 0;
2733        }]])
2734 ])
2735 # Maybe curses should be tried earlier?
2736 # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
2737 for tputs_library in '' tinfo ncurses terminfo termcap curses; do
2738   OLIBS=$LIBS
2739   if test -z "$tputs_library"; then
2740     LIBS_TERMCAP=
2741     msg='none required'
2742   else
2743     LIBS_TERMCAP=-l$tputs_library
2744     msg=$LIBS_TERMCAP
2745     LIBS="$LIBS_TERMCAP $LIBS"
2746   fi
2747   AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
2748     [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
2749   LIBS=$OLIBS
2750   if test "X$msg" != Xno; then
2751     break
2752   fi
2753 done
2754 AC_MSG_RESULT([$msg])
2755 if test "X$msg" = Xno; then
2756   AC_MSG_ERROR([The required function `tputs' was not found in any library.
2757 The following libraries were tried (in order):
2758   libtinfo, libncurses, libterminfo, libtermcap, libcurses
2759 Please try installing whichever of these libraries is most appropriate
2760 for your system, together with its header files.
2761 For example, a libncurses-dev(el) or similar package.])
2762 fi
2763
2764 ## Use termcap instead of terminfo?
2765 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
2766 TERMINFO=yes
2767 ## FIXME?  In the cases below where we unconditionally set
2768 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
2769 ## if that was found above to have tputs.
2770 ## Should we use the gnu* logic everywhere?
2771 case "$opsys" in
2772   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2773   ##  The ncurses library has been moved out of the System framework in
2774   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2775   ##  option to use it.
2776   darwin) LIBS_TERMCAP="-lncurses" ;;
2777
2778   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
2779
2780   freebsd)
2781     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2782     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2783     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
2784 [[#if __FreeBSD_version < 400000
2785 fail;
2786 #endif
2787 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2788
2789     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2790
2791     if test $emacs_cv_freebsd_terminfo = yes; then
2792       LIBS_TERMCAP="-lncurses"
2793     else
2794       TERMINFO=no
2795       LIBS_TERMCAP="-ltermcap"
2796     fi
2797     ;;
2798
2799   netbsd)
2800     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
2801       TERMINFO=no
2802       LIBS_TERMCAP="-ltermcap"
2803     fi
2804     ;;
2805
2806   openbsd) LIBS_TERMCAP="-lncurses" ;;
2807
2808   ## hpux: Make sure we get select from libc rather than from libcurses
2809   ##  because libcurses on HPUX 10.10 has a broken version of select.
2810   ##  We used to use -lc -lcurses, but this may be cleaner.
2811   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
2812   # set that way, now it uses the default).  Isn't this a contradiction?
2813   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2814
2815 esac
2816
2817 TERMCAP_OBJ=tparam.o
2818 if test $TERMINFO = yes; then
2819   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2820   TERMCAP_OBJ=terminfo.o
2821 fi
2822 AC_SUBST(LIBS_TERMCAP)
2823 AC_SUBST(TERMCAP_OBJ)
2824
2825
2826 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2827 resolv=no
2828 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2829 #include <arpa/nameser.h>
2830 #include <resolv.h>]],
2831     [[return res_init();]])],
2832     have_res_init=yes, have_res_init=no)
2833 if test "$have_res_init" = no; then
2834   OLIBS="$LIBS"
2835   LIBS="$LIBS -lresolv"
2836   AC_MSG_CHECKING(for res_init with -lresolv)
2837   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2838 #include <arpa/nameser.h>
2839 #include <resolv.h>]],
2840     [[return res_init();]])],
2841     have_res_init=yes, have_res_init=no)
2842   AC_MSG_RESULT($have_res_init)
2843   if test "$have_res_init" = yes ; then
2844     resolv=yes
2845   fi
2846   LIBS="$OLIBS"
2847 fi
2848
2849 if test "$have_res_init" = yes; then
2850   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2851 fi
2852
2853 # Do we need the Hesiod library to provide the support routines?
2854 LIBHESIOD=
2855 if test "$with_hesiod" != no ; then
2856   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2857   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2858      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2859                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2860   if test "$resolv" = yes ; then
2861     RESOLVLIB=-lresolv
2862   else
2863     RESOLVLIB=
2864   fi
2865   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2866         hesiod=yes, :, $RESOLVLIB)])
2867
2868   if test x"$hesiod" = xyes; then
2869     AC_DEFINE(HAVE_LIBHESIOD, 1,
2870               [Define to 1 if you have the hesiod library (-lhesiod).])
2871     LIBHESIOD=-lhesiod
2872   fi
2873 fi
2874 AC_SUBST(LIBHESIOD)
2875
2876 # Do we need libresolv (due to res_init or Hesiod)?
2877 if test "$resolv" = yes ; then
2878   AC_DEFINE(HAVE_LIBRESOLV, 1,
2879             [Define to 1 if you have the resolv library (-lresolv).])
2880   LIBRESOLV=-lresolv
2881 else
2882   LIBRESOLV=
2883 fi
2884 AC_SUBST(LIBRESOLV)
2885
2886 # These tell us which Kerberos-related libraries to use.
2887 COM_ERRLIB=
2888 CRYPTOLIB=
2889 KRB5LIB=
2890 DESLIB=
2891 KRB4LIB=
2892
2893 if test "${with_kerberos}" != no; then
2894   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2895   if test $have_com_err = yes; then
2896     COM_ERRLIB=-lcom_err
2897     LIBS="$COM_ERRLIB $LIBS"
2898     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2899   fi
2900   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2901   if test $have_crypto = yes; then
2902     CRYPTOLIB=-lcrypto
2903     LIBS="$CRYPTOLIB $LIBS"
2904     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2905   fi
2906   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2907   if test $have_k5crypto = yes; then
2908     CRYPTOLIB=-lk5crypto
2909     LIBS="$CRYPTOLIB $LIBS"
2910     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2911   fi
2912   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2913   if test $have_krb5=yes; then
2914     KRB5LIB=-lkrb5
2915     LIBS="$KRB5LIB $LIBS"
2916     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2917   fi
2918   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2919   if test "${with_kerberos5}" = no; then
2920     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2921     if test $have_des425 = yes; then
2922       DESLIB=-ldes425
2923       LIBS="$DESLIB $LIBS"
2924       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2925     else
2926       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2927       if test $have_des = yes; then
2928         DESLIB=-ldes
2929         LIBS="$DESLIB $LIBS"
2930         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2931       fi
2932     fi
2933     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2934     if test $have_krb4 = yes; then
2935       KRB4LIB=-lkrb4
2936       LIBS="$KRB4LIB $LIBS"
2937       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2938     else
2939       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2940       if test $have_krb = yes; then
2941         KRB4LIB=-lkrb
2942         LIBS="$KRB4LIB $LIBS"
2943         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2944       fi
2945     fi
2946   fi
2947
2948   if test "${with_kerberos5}" != no; then
2949     AC_CHECK_HEADERS(krb5.h,
2950       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2951                         [#include <krb5.h>])])
2952   else
2953     AC_CHECK_HEADERS(des.h,,
2954                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2955                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2956     AC_CHECK_HEADERS(krb.h,,
2957                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2958                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2959   fi
2960   AC_CHECK_HEADERS(com_err.h)
2961 fi
2962
2963 AC_SUBST(COM_ERRLIB)
2964 AC_SUBST(CRYPTOLIB)
2965 AC_SUBST(KRB5LIB)
2966 AC_SUBST(DESLIB)
2967 AC_SUBST(KRB4LIB)
2968
2969 AC_CHECK_FUNCS_ONCE(tzset)
2970 AC_MSG_CHECKING(whether localtime caches TZ)
2971 AC_CACHE_VAL(emacs_cv_localtime_cache,
2972 [if test x$ac_cv_func_tzset = xyes; then
2973 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
2974 char TZ_GMT0[] = "TZ=GMT0";
2975 char TZ_PST8[] = "TZ=PST8";
2976 main()
2977 {
2978   time_t now = time ((time_t *) 0);
2979   int hour_GMT0, hour_unset;
2980   if (putenv (TZ_GMT0) != 0)
2981     exit (1);
2982   hour_GMT0 = localtime (&now)->tm_hour;
2983   unsetenv("TZ");
2984   hour_unset = localtime (&now)->tm_hour;
2985   if (putenv (TZ_PST8) != 0)
2986     exit (1);
2987   if (localtime (&now)->tm_hour == hour_GMT0)
2988     exit (1);
2989   unsetenv("TZ");
2990   if (localtime (&now)->tm_hour != hour_unset)
2991     exit (1);
2992   exit (0);
2993 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2994 [# If we have tzset, assume the worst when cross-compiling.
2995 emacs_cv_localtime_cache=yes])
2996 else
2997         # If we lack tzset, report that localtime does not cache TZ,
2998         # since we can't invalidate the cache if we don't have tzset.
2999         emacs_cv_localtime_cache=no
3000 fi])dnl
3001 AC_MSG_RESULT($emacs_cv_localtime_cache)
3002 if test $emacs_cv_localtime_cache = yes; then
3003   AC_DEFINE(LOCALTIME_CACHE, 1,
3004             [Define to 1 if localtime caches TZ.])
3005 fi
3006
3007 if test "x$HAVE_TIMEVAL" = xyes; then
3008   AC_CHECK_FUNCS(gettimeofday)
3009   if test $ac_cv_func_gettimeofday = yes; then
3010     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
3011                    emacs_cv_gettimeofday_two_arguments,
3012     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3013 #ifdef TIME_WITH_SYS_TIME
3014 #include <sys/time.h>
3015 #include <time.h>
3016 #else
3017 #ifdef HAVE_SYS_TIME_H
3018 #include <sys/time.h>
3019 #else
3020 #include <time.h>
3021 #endif
3022 #endif]],
3023       [[struct timeval time;
3024        gettimeofday (&time, 0);]])],
3025       emacs_cv_gettimeofday_two_arguments=yes,
3026       emacs_cv_gettimeofday_two_arguments=no)])
3027     if test $emacs_cv_gettimeofday_two_arguments = no; then
3028       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
3029                 [Define to 1 if gettimeofday accepts only one argument.])
3030     fi
3031   fi
3032 fi
3033
3034 ok_so_far=yes
3035 AC_CHECK_FUNC(socket, , ok_so_far=no)
3036 if test $ok_so_far = yes; then
3037   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3038 fi
3039 if test $ok_so_far = yes; then
3040   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3041 fi
3042 if test $ok_so_far = yes; then
3043 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3044   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3045             [Define to 1 if you have inet sockets.])
3046 fi
3047
3048 if test -f /usr/lpp/X11/bin/smt.exp; then
3049   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3050             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3051 fi
3052
3053 AC_MSG_CHECKING(whether system supports dynamic ptys)
3054 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3055   AC_MSG_RESULT(yes)
3056   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3057 else
3058   AC_MSG_RESULT(no)
3059 fi
3060
3061 AC_FUNC_FORK
3062
3063 AC_CHECK_FUNCS(snprintf)
3064
3065 dnl Adapted from Haible's version.
3066 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3067   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3068     [[char* cs = nl_langinfo(CODESET);]])],
3069     emacs_cv_langinfo_codeset=yes,
3070     emacs_cv_langinfo_codeset=no)
3071   ])
3072 if test $emacs_cv_langinfo_codeset = yes; then
3073   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3074     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3075 fi
3076
3077 AC_TYPE_MBSTATE_T
3078
3079 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3080   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3081                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3082 if test "$emacs_cv_c_restrict_arr" = yes; then
3083   AC_DEFINE(__restrict_arr, __restrict,
3084     [Define to compiler's equivalent of C99 restrict keyword in array
3085      declarations.  Define as empty for no equivalent.])
3086 fi
3087
3088 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3089 dnl how the tty code is related to POSIX and/or other versions of termios.
3090 dnl The following looks like a useful start.
3091 dnl
3092 dnl AC_SYS_POSIX_TERMIOS
3093 dnl if test $ac_cv_sys_posix_termios = yes; then
3094 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3095 dnl                                and macros for terminal control.])
3096 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3097 dnl fi
3098
3099 # Set up the CFLAGS for real compilation, so we can substitute it.
3100 CFLAGS="$REAL_CFLAGS"
3101 CPPFLAGS="$REAL_CPPFLAGS"
3102
3103 ## Hack to detect a buggy GCC version.
3104 if test "x$GCC" = xyes \
3105    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3106    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3107    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3108    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3109 fi
3110
3111 version=$PACKAGE_VERSION
3112
3113 ### Specify what sort of things we'll be editing into Makefile and config.h.
3114 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3115 AC_SUBST(version)
3116 AC_SUBST(configuration)
3117 ## Unused?
3118 AC_SUBST(canonical)
3119 AC_SUBST(srcdir)
3120 AC_SUBST(prefix)
3121 AC_SUBST(exec_prefix)
3122 AC_SUBST(bindir)
3123 AC_SUBST(datadir)
3124 AC_SUBST(sharedstatedir)
3125 AC_SUBST(libexecdir)
3126 AC_SUBST(mandir)
3127 AC_SUBST(infodir)
3128 AC_SUBST(lispdir)
3129 AC_SUBST(leimdir)
3130 AC_SUBST(locallisppath)
3131 AC_SUBST(lisppath)
3132 AC_SUBST(x_default_search_path)
3133 AC_SUBST(etcdir)
3134 AC_SUBST(archlibdir)
3135 AC_SUBST(docdir)
3136 AC_SUBST(bitmapdir)
3137 AC_SUBST(gamedir)
3138 AC_SUBST(gameuser)
3139 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3140 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3141 ## end of LIBX_BASE, but nothing ever set it.
3142 AC_SUBST(LD_SWITCH_X_SITE)
3143 AC_SUBST(C_SWITCH_X_SITE)
3144 AC_SUBST(GNUSTEP_CFLAGS)
3145 AC_SUBST(CFLAGS)
3146 ## Used in lwlib/Makefile.in.
3147 AC_SUBST(X_TOOLKIT_TYPE)
3148 S_FILE="\$(srcdir)/${opsysfile}"
3149 AC_SUBST(S_FILE)
3150 AC_SUBST(ns_appdir)
3151 AC_SUBST(ns_appbindir)
3152 AC_SUBST(ns_appresdir)
3153 AC_SUBST(ns_appsrc)
3154 AC_SUBST(GNU_OBJC_CFLAGS)
3155 AC_SUBST(OTHER_FILES)
3156
3157 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3158                    [Define to the canonical Emacs configuration name.])
3159 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3160                    [Define to the options passed to configure.])
3161 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3162                    [Define to the used os dependent file.])
3163
3164 XMENU_OBJ=
3165 XOBJ=
3166 FONT_OBJ=
3167 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3168   AC_DEFINE(HAVE_X_WINDOWS, 1,
3169             [Define to 1 if you want to use the X window system.])
3170   XMENU_OBJ=xmenu.o
3171   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3172   FONT_OBJ=xfont.o
3173   if test "$HAVE_XFT" = "yes"; then
3174     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3175   elif test "$HAVE_FREETYPE" = "yes"; then
3176     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3177   fi
3178   AC_SUBST(FONT_OBJ)
3179 fi
3180 AC_SUBST(XMENU_OBJ)
3181 AC_SUBST(XOBJ)
3182 AC_SUBST(FONT_OBJ)
3183
3184 WIDGET_OBJ=
3185 MOTIF_LIBW=
3186 if test "${USE_X_TOOLKIT}" != "none" ; then
3187   WIDGET_OBJ=widget.o
3188   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3189   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3190     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3191   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3192     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3193     MOTIF_LIBW=-lXm
3194     case "$opsys" in
3195       gnu-linux)
3196         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3197         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3198         ;;
3199
3200       unixware)
3201         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3202         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3203         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3204         ;;
3205
3206       aix4-2)
3207         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3208         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3209         ;;
3210     esac
3211     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3212   fi
3213 fi
3214 AC_SUBST(WIDGET_OBJ)
3215
3216 TOOLKIT_LIBW=
3217 case "$USE_X_TOOLKIT" in
3218   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3219   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3220   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3221 esac
3222 AC_SUBST(TOOLKIT_LIBW)
3223
3224 if test "$USE_X_TOOLKIT" = "none"; then
3225   LIBXT_OTHER="\$(LIBXSM)"
3226   OLDXMENU_TARGET="really-oldXMenu"
3227 else
3228   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3229   OLDXMENU_TARGET="really-lwlib"
3230 fi
3231 AC_SUBST(LIBXT_OTHER)
3232
3233 ## The X Menu stuff is present in the X10 distribution, but missing
3234 ## from X11.  If we have X10, just use the installed library;
3235 ## otherwise, use our own copy.
3236 if test "${HAVE_X11}" = "yes" ; then
3237   AC_DEFINE(HAVE_X11, 1,
3238             [Define to 1 if you want to use version 11 of X windows.
3239              Otherwise, Emacs expects to use version 10.])
3240
3241   if test "$USE_X_TOOLKIT" = "none"; then
3242     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
3243   else
3244     OLDXMENU="\${lwlibdir}/liblw.a"
3245   fi
3246   LIBXMENU="\$(OLDXMENU)"
3247   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3248   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3249 else
3250   ## For a syntactically valid Makefile; not actually used for anything.
3251   ## See comments in src/Makefile.in.
3252   OLDXMENU=nothing
3253   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3254   if test "${HAVE_X_WINDOWS}" = "yes"; then
3255     LIBXMENU="-lXMenu"
3256   else
3257     LIBXMENU=
3258   fi
3259   LIBX_OTHER=
3260   OLDXMENU_DEPS=
3261 fi
3262
3263 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3264   OLDXMENU_TARGET=
3265   OLDXMENU=nothing
3266   LIBXMENU=
3267   OLDXMENU_DEPS=
3268 fi
3269
3270 AC_SUBST(OLDXMENU_TARGET)
3271 AC_SUBST(OLDXMENU)
3272 AC_SUBST(LIBXMENU)
3273 AC_SUBST(LIBX_OTHER)
3274 AC_SUBST(OLDXMENU_DEPS)
3275
3276 if test "${HAVE_MENUS}" = "yes" ; then
3277   AC_DEFINE(HAVE_MENUS, 1,
3278             [Define to 1 if you have mouse menus.
3279              (This is automatic if you use X, but the option to specify it remains.)
3280              It is also defined with other window systems that support xmenu.c.])
3281 fi
3282
3283 if test "${GNU_MALLOC}" = "yes" ; then
3284   AC_DEFINE(GNU_MALLOC, 1,
3285             [Define to 1 if you want to use the GNU memory allocator.])
3286 fi
3287
3288 RALLOC_OBJ=
3289 if test "${REL_ALLOC}" = "yes" ; then
3290   AC_DEFINE(REL_ALLOC, 1,
3291             [Define REL_ALLOC if you want to use the relocating allocator for
3292              buffer space.])
3293
3294   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3295 fi
3296 AC_SUBST(RALLOC_OBJ)
3297
3298 if test "$opsys" = "cygwin"; then
3299   CYGWIN_OBJ="sheap.o"
3300   ## Cygwin differs because of its unexec().
3301   PRE_ALLOC_OBJ=
3302   POST_ALLOC_OBJ=lastfile.o
3303 else
3304   CYGWIN_OBJ=
3305   PRE_ALLOC_OBJ=lastfile.o
3306   POST_ALLOC_OBJ=
3307 fi
3308 AC_SUBST(CYGWIN_OBJ)
3309 AC_SUBST(PRE_ALLOC_OBJ)
3310 AC_SUBST(POST_ALLOC_OBJ)
3311
3312 # Configure gnulib here, now that we know LIBS.
3313 gl_ASSERT_NO_GNULIB_POSIXCHECK
3314 gl_ASSERT_NO_GNULIB_TESTS
3315 gl_INIT
3316
3317 case "$opsys" in
3318   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3319
3320   darwin)
3321    ## The -headerpad option tells ld (see man page) to leave room at the
3322    ## end of the header for adding load commands.  Needed for dumping.
3323    ## 0x690 is the total size of 30 segment load commands (at 56
3324    ## each); under Cocoa 31 commands are required.
3325    if test "$HAVE_NS" = "yes"; then
3326      libs_nsgui="-framework AppKit"
3327      headerpad_extra=6C8
3328    else
3329      libs_nsgui=
3330      headerpad_extra=690
3331    fi
3332    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3333
3334    ## This is here because src/Makefile.in did some extra fiddling around
3335    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3336    ##   #ifndef LD_SWITCH_SYSTEM
3337    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3338    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3339    ## not using gcc, darwin.
3340    ## Because this was done in src/Makefile.in, the resulting part of
3341    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3342    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3343    ## rather than LD_SWITCH_SYSTEM.
3344    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3345      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3346    ;;
3347
3348   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
3349   ## find X at run-time.
3350   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
3351   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
3352   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3353   ## had different values in configure (in ac_link) and src/Makefile.in.
3354   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3355   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
3356
3357   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3358 esac
3359
3360 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3361   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3362 fi
3363
3364 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3365
3366
3367 LD_FIRSTFLAG=
3368 ORDINARY_LINK=
3369 case "$opsys" in
3370   ## gnu: GNU needs its own crt0.
3371   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3372
3373   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3374   ## library search parth, i.e. it won't search /usr/lib for libc and
3375   ## friends.  Using -nostartfiles instead avoids this problem, and
3376   ## will also work on earlier NetBSD releases.
3377   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
3378
3379   ## powerpc*: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3380   ##   MkLinux/LinuxPPC needs this.
3381   ## s390x-* only supports opsys = gnu-linux so it can be added here.
3382   gnu-*)
3383     case "$canonical" in
3384       powerpc*|s390x-*) LD_FIRSTFLAG="-nostdlib" ;;
3385     esac
3386     ;;
3387 esac
3388
3389
3390 if test "x$ORDINARY_LINK" = "xyes"; then
3391
3392   LD_FIRSTFLAG=""
3393   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3394
3395 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
3396 ## freebsd, gnu-* not on powerpc*|s390x*.
3397 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
3398
3399   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3400   ## places that are difficult to figure out at make time.  Fortunately,
3401   ## these same versions allow you to pass arbitrary flags on to the
3402   ## linker, so there is no reason not to use it as a linker.
3403   ##
3404   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3405   ## searching for libraries in its internal directories, so we have to
3406   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3407   LD_FIRSTFLAG="-nostdlib"
3408 fi
3409
3410 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3411 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
3412
3413 AC_SUBST(LD_FIRSTFLAG)
3414
3415
3416 ## FIXME? The logic here is not precisely the same as that above.
3417 ## There is no check here for a pre-defined LD_FIRSTFLAG.
3418 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3419 LIB_GCC=
3420 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3421
3422   case "$opsys" in
3423     freebsd|netbsd|openbsd) LIB_GCC= ;;
3424
3425     gnu-*)
3426       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3427       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3428       case $host_cpu in
3429       arm*)
3430         LIB_GCC="-lgcc_s"
3431         ;;
3432       *)
3433         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3434         ## immediately undefine it again and redefine it to empty.
3435         ## Was the C_SWITCH_X_SITE part really necessary?
3436 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3437         LIB_GCC=
3438         ;;
3439       esac
3440       ;;
3441
3442     ## Ask GCC where to find libgcc.a.
3443     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3444   esac
3445 fi                              dnl if $GCC
3446 AC_SUBST(LIB_GCC)
3447
3448
3449 ## If we're using X11/GNUstep, define some consequences.
3450 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3451   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3452   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3453 fi
3454
3455
3456 AH_TOP([/* GNU Emacs site configuration template file.
3457
3458 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2012
3459   Free Software Foundation, Inc.
3460
3461 This file is part of GNU Emacs.
3462
3463 GNU Emacs is free software: you can redistribute it and/or modify
3464 it under the terms of the GNU General Public License as published by
3465 the Free Software Foundation, either version 3 of the License, or
3466 (at your option) any later version.
3467
3468 GNU Emacs is distributed in the hope that it will be useful,
3469 but WITHOUT ANY WARRANTY; without even the implied warranty of
3470 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3471 GNU General Public License for more details.
3472
3473 You should have received a copy of the GNU General Public License
3474 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3475
3476
3477 /* No code in Emacs #includes config.h twice, but some bits of code
3478    intended to work with other packages as well (like gmalloc.c)
3479    think they can include it as many times as they like.  */
3480 #ifndef EMACS_CONFIG_H
3481 #define EMACS_CONFIG_H
3482 ])dnl
3483
3484 AH_BOTTOM([
3485 /* On AIX 3 this must be included before any other include file.  */
3486 #include <alloca.h>
3487 #if ! HAVE_ALLOCA
3488 # error "alloca not available on this machine"
3489 #endif
3490
3491 /* Define AMPERSAND_FULL_NAME if you use the convention
3492    that & in the full name stands for the login id.  */
3493 /* Turned on June 1996 supposing nobody will mind it.  */
3494 #define AMPERSAND_FULL_NAME
3495
3496 /* `subprocesses' should be defined if you want to
3497    have code for asynchronous subprocesses
3498    (as used in M-x compile and M-x shell).
3499    Only MSDOS does not support this (it overrides
3500    this in its config_opsysfile below).  */
3501
3502 #define subprocesses
3503
3504 /* Include the os dependent file.  */
3505 #include config_opsysfile
3506
3507 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3508    SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.
3509   (There is probably a better place to do this, but right now the
3510    Cocoa side does this in s/darwin.h and we cannot parallel this
3511    exactly since GNUstep is multi-OS.  */
3512 #if defined HAVE_NS && defined NS_IMPL_GNUSTEP
3513 #  define SYSTEM_PURESIZE_EXTRA 30000
3514 #endif
3515
3516 #ifdef emacs /* Don't do this for lib-src.  */
3517 /* Tell regex.c to use a type compatible with Emacs.  */
3518 #define RE_TRANSLATE_TYPE Lisp_Object
3519 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3520 #ifdef make_number
3521 /* If make_number is a macro, use it.  */
3522 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3523 #else
3524 /* If make_number is a function, avoid it.  */
3525 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3526 #endif
3527 #endif
3528
3529 #include <string.h>
3530 #include <stdlib.h>
3531
3532 #if defined __GNUC__ && (__GNUC__ > 2 \
3533                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3534 #define NO_RETURN       __attribute__ ((__noreturn__))
3535 #else
3536 #define NO_RETURN       /* nothing */
3537 #endif
3538
3539 #if __GNUC__ >= 3  /* On GCC 3.0 we might get a warning.  */
3540 #define NO_INLINE __attribute__((noinline))
3541 #else
3542 #define NO_INLINE
3543 #endif
3544
3545 #if (__GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 1))
3546 #define EXTERNALLY_VISIBLE __attribute__((externally_visible))
3547 #else
3548 #define EXTERNALLY_VISIBLE
3549 #endif
3550
3551 #if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7)
3552 # define ATTRIBUTE_FORMAT(spec) __attribute__ ((__format__ spec))
3553 #else
3554 # define ATTRIBUTE_FORMAT(spec) /* empty */
3555 #endif
3556
3557 #if __GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 4)
3558 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3559    ATTRIBUTE_FORMAT ((__gnu_printf__, formatstring_parameter, first_argument))
3560 #else
3561 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3562    ATTRIBUTE_FORMAT ((__printf__, formatstring_parameter, first_argument))
3563 #endif
3564
3565 /* Some versions of GNU/Linux define noinline in their headers.  */
3566 #ifdef noinline
3567 #undef noinline
3568 #endif
3569
3570 /* These won't be used automatically yet.  We also need to know, at least,
3571    that the stack is continuous.  */
3572 #ifdef __GNUC__
3573 #  ifndef GC_SETJMP_WORKS
3574   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3575 #    define GC_SETJMP_WORKS 1
3576 #  endif
3577 #endif
3578
3579 #endif /* EMACS_CONFIG_H */
3580
3581 /*
3582 Local Variables:
3583 mode: c
3584 End:
3585 */
3586 ])dnl
3587
3588 #### Report on what we decided to do.
3589 #### Report GTK as a toolkit, even if it doesn't use Xt.
3590 #### It makes printing result more understandable as using GTK sets
3591 #### toolkit_scroll_bars to yes by default.
3592 if test "${HAVE_GTK}" = "yes"; then
3593   USE_X_TOOLKIT=GTK
3594 fi
3595
3596 echo "
3597 Configured for \`${canonical}'.
3598
3599   Where should the build process find the source code?    ${srcdir}
3600   What operating system file should Emacs use?
3601         \`${opsysfile}'
3602   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3603   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3604   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3605   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3606   What window system should Emacs use?                    ${window_system}
3607   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3608
3609 if test -n "${x_includes}"; then
3610 echo "  Where do we find X Windows header files?                ${x_includes}"
3611 else
3612 echo "  Where do we find X Windows header files?                Standard dirs"
3613 fi
3614 if test -n "${x_libraries}"; then
3615 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3616 else
3617 echo "  Where do we find X Windows libraries?                   Standard dirs"
3618 fi
3619
3620 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3621 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3622 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3623 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3624 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3625 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3626 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3627 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3628
3629 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3630 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3631 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3632 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
3633 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3634 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
3635 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
3636
3637 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3638 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3639 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3640 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3641
3642 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3643 echo
3644
3645 if test -n "${EMACSDATA}"; then
3646    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
3647 fi
3648 if test -n "${EMACSDOC}"; then
3649    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
3650 fi
3651
3652 if test $USE_XASSERTS = yes; then
3653    echo "  Compiling with asserts turned on."
3654    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3655 fi
3656
3657 echo
3658
3659 if test "$HAVE_NS" = "yes"; then
3660    echo
3661    echo "You must run \"${MAKE-make} install\" in order to test the built application.
3662 The installed application will go to nextstep/Emacs.app and can be
3663 run or moved from there."
3664    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3665       echo "The application will be fully self-contained."
3666     else
3667       echo "The lisp resources for the application will be installed under ${prefix}.
3668 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
3669 to run if these resources are not installed."
3670    fi
3671    echo
3672 fi
3673
3674 if test "${opsys}" = "cygwin"; then
3675   case `uname -r` in
3676     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
3677            echo
3678            ;;
3679   esac
3680 fi
3681
3682 # Remove any trailing slashes in these variables.
3683 [test "${prefix}" != NONE &&
3684   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3685 test "${exec_prefix}" != NONE &&
3686   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3687
3688 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
3689 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
3690 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
3691 dnl (else you get "no `Makefile.am' found for any configure output").
3692 dnl This will work, but you get a config.status that is not quite right
3693 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
3694 dnl That doesn't have any obvious consequences for Emacs, but on the whole
3695 dnl it seems better to just live with the duplication.
3696 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile"
3697
3698 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
3699        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3700        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
3701        leim/Makefile])
3702
3703 dnl test/ is not present in release tarfiles.
3704 opt_makefile=test/automated/Makefile
3705
3706 if test -f $srcdir/${opt_makefile}.in; then
3707   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3708   dnl Again, it's best not to use a variable.  Though you can add
3709   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
3710   AC_CONFIG_FILES([test/automated/Makefile])
3711 fi
3712
3713
3714 dnl admin/ may or may not be present.
3715 opt_makefile=admin/unidata/Makefile
3716
3717 if test -f $srcdir/${opt_makefile}.in; then
3718   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3719   AC_CONFIG_FILES([admin/unidata/Makefile])
3720 fi
3721
3722
3723 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
3724
3725 AC_SUBST(SUBDIR_MAKEFILES_IN)
3726
3727 dnl Make the necessary directories, if they don't exist.
3728 AC_CONFIG_COMMANDS([mkdirs], [
3729 for dir in etc lisp ; do
3730   test -d ${dir} || mkdir ${dir}
3731 done
3732 ])
3733
3734 dnl You might wonder (I did) why epaths.h is generated by running make,
3735 dnl rather than just letting configure generate it from epaths.in.
3736 dnl One reason is that the various paths are not fully expanded (see above);
3737 dnl eg gamedir=${prefix}/var/games/emacs.
3738 dnl Secondly, the GNU Coding standards require that one should be able
3739 dnl to run `make prefix=/some/where/else' and override the values set
3740 dnl by configure.  This also explains the `move-if-change' test and
3741 dnl the use of force in the `epaths-force' rule in Makefile.in.
3742 AC_CONFIG_COMMANDS([epaths], [
3743 echo creating src/epaths.h
3744 ${MAKE-make} epaths-force
3745 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS"])
3746
3747 AC_CONFIG_COMMANDS([gdbinit], [
3748 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3749   echo creating src/.gdbinit
3750   echo source $srcdir/src/.gdbinit > src/.gdbinit
3751 fi
3752 ])
3753
3754 AC_OUTPUT
3755
3756 dnl configure.in ends here