lisp/mwheel.el

   1 ;;; mwheel.el --- Wheel mouse support
   2
   3 ;; Copyright (C) 1998, 2000-2018 Free Software Foundation, Inc.
   4 ;; Maintainer: William M. Perry <wmperry@gnu.org>
   5 ;; Keywords: mouse
   6 ;; Package: emacs
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This code will enable the use of the infamous 'wheel' on the new
  26 ;; crop of mice.  Under XFree86 and the XSuSE X Servers, the wheel
  27 ;; events are sent as button4/button5 events.
  28
  29 ;; I for one would prefer some way of converting the button4/button5
  30 ;; events into different event types, like 'mwheel-up' or
  31 ;; 'mwheel-down', but I cannot find a way to do this very easily (or
  32 ;; portably), so for now I just live with it.
  33
  34 ;; To enable this code, simply put this at the top of your .emacs
  35 ;; file:
  36 ;;
  37 ;; (mouse-wheel-mode 1)
  38
  39 ;;; Code:
  40
  41 (require 'custom)
  42 (require 'timer)
  43
  44 (defvar mouse-wheel-mode)
  45
  46 ;; Setter function for mouse-button user-options.  Switch Mouse Wheel
  47 ;; mode off and on again so that the old button is unbound and
  48 ;; new button is bound to mwheel-scroll.
  49
  50 (defun mouse-wheel-change-button (var button)
  51   (set-default var button)
  52   ;; Sync the bindings.
  53   (when (bound-and-true-p mouse-wheel-mode) (mouse-wheel-mode 1)))
  54
  55 (defvar mouse-wheel-down-button 4)
  56 (make-obsolete-variable 'mouse-wheel-down-button
  57                         'mouse-wheel-down-event
  58                         "22.1")
  59 (defcustom mouse-wheel-down-event
  60   (if (or (featurep 'w32-win) (featurep 'ns-win))
  61       'wheel-up
  62     (intern (format "mouse-%s" mouse-wheel-down-button)))
  63   "Event used for scrolling down."
  64   :group 'mouse
  65   :type 'symbol
  66   :set 'mouse-wheel-change-button)
  67
  68 (defvar mouse-wheel-up-button 5)
  69 (make-obsolete-variable 'mouse-wheel-up-button
  70                         'mouse-wheel-up-event
  71                         "22.1")
  72 (defcustom mouse-wheel-up-event
  73   (if (or (featurep 'w32-win) (featurep 'ns-win))
  74       'wheel-down
  75     (intern (format "mouse-%s" mouse-wheel-up-button)))
  76   "Event used for scrolling up."
  77   :group 'mouse
  78   :type 'symbol
  79   :set 'mouse-wheel-change-button)
  80
  81 (defvar mouse-wheel-click-button 2)
  82 (make-obsolete-variable 'mouse-wheel-click-button
  83                         'mouse-wheel-click-event
  84                         "22.1")
  85 (defcustom mouse-wheel-click-event
  86   (intern (format "mouse-%s" mouse-wheel-click-button))
  87   "Event that should be temporarily inhibited after mouse scrolling.
  88 The mouse wheel is typically on the mouse-2 button, so it may easily
  89 happen that text is accidentally yanked into the buffer when
  90 scrolling with the mouse wheel.  To prevent that, this variable can be
  91 set to the event sent when clicking on the mouse wheel button."
  92   :group 'mouse
  93   :type 'symbol
  94   :set 'mouse-wheel-change-button)
  95
  96 (defcustom mouse-wheel-inhibit-click-time 0.35
  97   "Time in seconds to inhibit clicking on mouse wheel button after scroll."
  98   :group 'mouse
  99   :type 'number)
 100
 101 (defcustom mouse-wheel-scroll-amount '(5 ((shift) . 1) ((control) . nil))
 102   "Amount to scroll windows by when spinning the mouse wheel.
 103 This is an alist mapping the modifier key to the amount to scroll when
 104 the wheel is moved with the modifier key depressed.
 105 Elements of the list have the form (MODIFIERS . AMOUNT) or just AMOUNT if
 106 MODIFIERS is nil.
 107
 108 AMOUNT should be the number of lines to scroll, or nil for near full
 109 screen.  It can also be a floating point number, specifying the fraction of
 110 a full screen to scroll.  A near full screen is `next-screen-context-lines'
 111 less than a full screen."
 112   :group 'mouse
 113   :type '(cons
 114           (choice :tag "Normal"
 115                   (const :tag "Full screen" :value nil)
 116                   (integer :tag "Specific # of lines")
 117                   (float :tag "Fraction of window")
 118                   (cons
 119                    (repeat (choice :tag "modifier"
 120                                    (const alt) (const control) (const hyper)
 121                                    (const meta) (const shift) (const super)))
 122                    (choice :tag "scroll amount"
 123                            (const :tag "Full screen" :value nil)
 124                            (integer :tag "Specific # of lines")
 125                            (float :tag "Fraction of window"))))
 126           (repeat
 127            (cons
 128             (repeat (choice :tag "modifier"
 129                             (const alt) (const control) (const hyper)
 130                             (const meta) (const shift) (const super)))
 131             (choice :tag "scroll amount"
 132                     (const :tag "Full screen" :value nil)
 133                     (integer :tag "Specific # of lines")
 134                     (float :tag "Fraction of window")))))
 135   :set 'mouse-wheel-change-button)
 136
 137 (defcustom mouse-wheel-progressive-speed t
 138   "If non-nil, the faster the user moves the wheel, the faster the scrolling.
 139 Note that this has no effect when `mouse-wheel-scroll-amount' specifies
 140 a \"near full screen\" scroll or when the mouse wheel sends key instead
 141 of button events."
 142   :group 'mouse
 143   :type 'boolean)
 144
 145 (defcustom mouse-wheel-follow-mouse t
 146   "Whether the mouse wheel should scroll the window that the mouse is over.
 147 This can be slightly disconcerting, but some people prefer it."
 148   :group 'mouse
 149   :type 'boolean)
 150
 151 ;;; For tilt-scroll
 152 ;;;
 153 (defcustom mouse-wheel-tilt-scroll nil
 154   "Enable scroll using tilting mouse wheel."
 155   :group 'mouse
 156   :type 'boolean
 157   :version "26.1")
 158
 159 (defcustom mouse-wheel-flip-direction nil
 160   "Swap direction of 'wheel-right and 'wheel-left."
 161   :group 'mouse
 162   :type 'boolean
 163   :version "26.1")
 164
 165 (eval-and-compile
 166   (if (fboundp 'event-button)
 167       (fset 'mwheel-event-button 'event-button)
 168     (defun mwheel-event-button (event)
 169       (let ((x (event-basic-type event)))
 170         ;; Map mouse-wheel events to appropriate buttons
 171         (if (eq 'mouse-wheel x)
 172             (let ((amount (car (cdr (cdr (cdr event))))))
 173               (if (< amount 0)
 174                   mouse-wheel-up-event
 175                 mouse-wheel-down-event))
 176           x))))
 177
 178   (if (fboundp 'event-window)
 179       (fset 'mwheel-event-window 'event-window)
 180     (defun mwheel-event-window (event)
 181       (posn-window (event-start event)))))
 182
 183 (defvar mwheel-inhibit-click-event-timer nil
 184   "Timer running while mouse wheel click event is inhibited.")
 185
 186 (defun mwheel-inhibit-click-timeout ()
 187   "Handler for `mwheel-inhibit-click-event-timer'."
 188   (setq mwheel-inhibit-click-event-timer nil)
 189   (remove-hook 'pre-command-hook 'mwheel-filter-click-events))
 190
 191 (defun mwheel-filter-click-events ()
 192   "Discard `mouse-wheel-click-event' while scrolling the mouse."
 193   (if (eq (event-basic-type last-input-event) mouse-wheel-click-event)
 194       (setq this-command 'ignore)))
 195
 196 (defvar mwheel-scroll-up-function 'scroll-up
 197   "Function that does the job of scrolling upward.")
 198
 199 (defvar mwheel-scroll-down-function 'scroll-down
 200   "Function that does the job of scrolling downward.")
 201
 202 (defvar mwheel-scroll-left-function 'scroll-left
 203   "Function that does the job of scrolling left.")
 204
 205 (defvar mwheel-scroll-right-function 'scroll-right
 206   "Function that does the job of scrolling right.")
 207
 208 (defvar mouse-wheel-left-event
 209   (if (or (featurep 'w32-win) (featurep 'ns-win))
 210       'wheel-left
 211     (intern "mouse-6"))
 212   "Event used for scrolling left.")
 213
 214 (defvar mouse-wheel-right-event
 215   (if (or (featurep 'w32-win) (featurep 'ns-win))
 216       'wheel-right
 217     (intern "mouse-7"))
 218   "Event used for scrolling right.")
 219
 220 (defun mwheel-scroll (event)
 221   "Scroll up or down according to the EVENT.
 222 This should be bound only to mouse buttons 4, 5, 6, and 7 on
 223 non-Windows systems."
 224   (interactive (list last-input-event))
 225   (let* ((selected-window (selected-window))
 226          (scroll-window
 227           (or (catch 'found
 228                 (let* ((window (if mouse-wheel-follow-mouse
 229                                    (mwheel-event-window event)
 230                                  (selected-window)))
 231                        (frame (when (window-live-p window)
 232                                 (frame-parameter
 233                                  (window-frame window) 'mouse-wheel-frame))))
 234                   (when (frame-live-p frame)
 235                     (let* ((pos (mouse-absolute-pixel-position))
 236                            (pos-x (car pos))
 237                            (pos-y (cdr pos)))
 238                       (walk-window-tree
 239                        (lambda (window-1)
 240                          (let ((edges (window-edges window-1 nil t t)))
 241                            (when (and (<= (nth 0 edges) pos-x)
 242                                       (<= pos-x (nth 2 edges))
 243                                       (<= (nth 1 edges) pos-y)
 244                                       (<= pos-y (nth 3 edges)))
 245                              (throw 'found window-1))))
 246                        frame nil t)))))
 247               (mwheel-event-window event)))
 248          (old-point
 249           (and (eq scroll-window selected-window)
 250                (eq (car-safe transient-mark-mode) 'only)
 251                (window-point)))
 252          (mods
 253           (delq 'click (delq 'double (delq 'triple (event-modifiers event)))))
 254          (amt (assoc mods mouse-wheel-scroll-amount)))
 255     (unless (eq scroll-window selected-window)
 256       ;; Mark window to be scrolled for redisplay.
 257       (select-window scroll-window 'mark-for-redisplay))
 258     ;; Extract the actual amount or find the element that has no modifiers.
 259     (if amt (setq amt (cdr amt))
 260       (let ((list-elt mouse-wheel-scroll-amount))
 261         (while (consp (setq amt (pop list-elt))))))
 262     (if (floatp amt) (setq amt (1+ (truncate (* amt (window-height))))))
 263     (when (and mouse-wheel-progressive-speed (numberp amt))
 264       ;; When the double-mouse-N comes in, a mouse-N has been executed already,
 265       ;; So by adding things up we get a squaring up (1, 3, 6, 10, 15, ...).
 266       (setq amt (* amt (event-click-count event))))
 267     (when (numberp amt) (setq amt (* amt (event-line-count event))))
 268     (unwind-protect
 269         (let ((button (mwheel-event-button event)))
 270           (cond ((eq button mouse-wheel-down-event)
 271                  (condition-case nil (funcall mwheel-scroll-down-function amt)
 272                    ;; Make sure we do indeed scroll to the beginning of
 273                    ;; the buffer.
 274                    (beginning-of-buffer
 275                     (unwind-protect
 276                         (funcall mwheel-scroll-down-function)
 277                       ;; If the first scroll succeeded, then some scrolling
 278                       ;; is possible: keep scrolling til the beginning but
 279                       ;; do not signal an error.  For some reason, we have
 280                       ;; to do it even if the first scroll signaled an
 281                       ;; error, because otherwise the window is recentered
 282                       ;; for a reason that escapes me.  This problem seems
 283                       ;; to only affect scroll-down.  --Stef
 284                       (set-window-start (selected-window) (point-min))))))
 285                 ((eq button mouse-wheel-up-event)
 286                  (condition-case nil (funcall mwheel-scroll-up-function amt)
 287                    ;; Make sure we do indeed scroll to the end of the buffer.
 288                    (end-of-buffer (while t (funcall mwheel-scroll-up-function)))))
 289                 ((eq button mouse-wheel-left-event) ; for tilt scroll
 290                  (when mouse-wheel-tilt-scroll
 291                    (funcall (if mouse-wheel-flip-direction
 292                                 mwheel-scroll-right-function
 293                               mwheel-scroll-left-function) amt)))
 294                 ((eq button mouse-wheel-right-event) ; for tilt scroll
 295                  (when mouse-wheel-tilt-scroll
 296                    (funcall (if mouse-wheel-flip-direction
 297                                 mwheel-scroll-left-function
 298                               mwheel-scroll-right-function) amt)))
 299                 (t (error "Bad binding in mwheel-scroll"))))
 300       (if (eq scroll-window selected-window)
 301           ;; If there is a temporarily active region, deactivate it if
 302           ;; scrolling moved point.
 303           (when (and old-point (/= old-point (window-point)))
 304             ;; Call `deactivate-mark' at the original position, so that
 305             ;; the original region is saved to the X selection.
 306             (let ((new-point (window-point)))
 307               (goto-char old-point)
 308               (deactivate-mark)
 309               (goto-char new-point)))
 310         (select-window selected-window t))))
 311
 312   (when (and mouse-wheel-click-event mouse-wheel-inhibit-click-time)
 313     (if mwheel-inhibit-click-event-timer
 314         (cancel-timer mwheel-inhibit-click-event-timer)
 315       (add-hook 'pre-command-hook 'mwheel-filter-click-events))
 316     (setq mwheel-inhibit-click-event-timer
 317           (run-with-timer mouse-wheel-inhibit-click-time nil
 318                           'mwheel-inhibit-click-timeout))))
 319
 320 (put 'mwheel-scroll 'scroll-command t)
 321
 322 (defvar mwheel-installed-bindings nil)
 323
 324 (define-minor-mode mouse-wheel-mode
 325   "Toggle mouse wheel support (Mouse Wheel mode).
 326 With a prefix argument ARG, enable Mouse Wheel mode if ARG is
 327 positive, and disable it otherwise.  If called from Lisp, enable
 328 the mode if ARG is omitted or nil."
 329   :init-value t
 330   ;; We'd like to use custom-initialize-set here so the setup is done
 331   ;; before dumping, but at the point where the defcustom is evaluated,
 332   ;; the corresponding function isn't defined yet, so
 333   ;; custom-initialize-set signals an error.
 334   :initialize 'custom-initialize-delay
 335   :global t
 336   :group 'mouse
 337   ;; Remove previous bindings, if any.
 338   (while mwheel-installed-bindings
 339     (let ((key (pop mwheel-installed-bindings)))
 340       (when (eq (lookup-key (current-global-map) key) 'mwheel-scroll)
 341         (global-unset-key key))))
 342   ;; Setup bindings as needed.
 343   (when mouse-wheel-mode
 344     (dolist (event (list mouse-wheel-down-event mouse-wheel-up-event mouse-wheel-right-event mouse-wheel-left-event))
 345       (dolist (key (mapcar (lambda (amt) `[(,@(if (consp amt) (car amt)) ,event)])
 346                            mouse-wheel-scroll-amount))
 347         (global-set-key key 'mwheel-scroll)
 348         (push key mwheel-installed-bindings)))))
 349
 350 ;;; Compatibility entry point
 351 ;; preloaded ;;;###autoload
 352 (defun mwheel-install (&optional uninstall)
 353   "Enable mouse wheel support."
 354   (mouse-wheel-mode (if uninstall -1 1)))
 355
 356 (provide 'mwheel)
 357
 358 ;;; mwheel.el ends here