lisp/scroll-lock.el

   1 ;;; scroll-lock.el --- Scroll lock scrolling.
   2
   3 ;; Copyright (C) 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   4
   5 ;; Author: Ralf Angeli <angeli@iwi.uni-sb.de>
   6 ;; Maintainer: FSF
   7 ;; Created: 2005-06-18
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; By activating Scroll Lock mode, keys for moving point by line or
  27 ;; paragraph will scroll the buffer by the respective amount of lines
  28 ;; instead.  Point will be kept vertically fixed relative to window
  29 ;; boundaries.
  30
  31 ;;; Code:
  32
  33 (defvar scroll-lock-mode-map
  34   (let ((map (make-sparse-keymap)))
  35     (define-key map [remap next-line] 'scroll-lock-next-line)
  36     (define-key map [remap previous-line] 'scroll-lock-previous-line)
  37     (define-key map [remap forward-paragraph] 'scroll-lock-forward-paragraph)
  38     (define-key map [remap backward-paragraph] 'scroll-lock-backward-paragraph)
  39     map)
  40   "Keymap for Scroll Lock mode.")
  41
  42 (defvar scroll-lock-preserve-screen-pos-save scroll-preserve-screen-position
  43   "Used for saving the state of `scroll-preserve-screen-position'.")
  44 (make-variable-buffer-local 'scroll-lock-preserve-screen-pos-save)
  45
  46 (defvar scroll-lock-temporary-goal-column 0
  47   "Like `temporary-goal-column' but for scroll-lock-* commands.")
  48
  49 ;;;###autoload
  50 (define-minor-mode scroll-lock-mode
  51   "Buffer-local minor mode for pager-like scrolling.
  52 Keys which normally move point by line or paragraph will scroll
  53 the buffer by the respective amount of lines instead and point
  54 will be kept vertically fixed relative to window boundaries
  55 during scrolling."
  56   :lighter " ScrLck"
  57   :keymap scroll-lock-mode-map
  58   (if scroll-lock-mode
  59       (progn
  60         (setq scroll-lock-preserve-screen-pos-save
  61               scroll-preserve-screen-position)
  62         (set (make-local-variable 'scroll-preserve-screen-position) 'always))
  63     (setq scroll-preserve-screen-position
  64           scroll-lock-preserve-screen-pos-save)))
  65
  66 (defun scroll-lock-update-goal-column ()
  67   "Update `scroll-lock-temporary-goal-column' if necessary."
  68   (unless (memq last-command '(scroll-lock-next-line
  69                                scroll-lock-previous-line
  70                                scroll-lock-forward-paragraph
  71                                scroll-lock-backward-paragraph))
  72     (setq scroll-lock-temporary-goal-column (current-column))))
  73
  74 (defun scroll-lock-move-to-column (column)
  75   "Like `move-to-column' but cater for wrapped lines."
  76   (if (or (bolp)
  77           ;; Start of a screen line.
  78           (not (zerop (mod (- (point) (line-beginning-position))
  79                            (window-width)))))
  80       (move-to-column column)
  81     (forward-char (min column (- (line-end-position) (point))))))
  82
  83 (defun scroll-lock-next-line (&optional arg)
  84   "Scroll up ARG lines keeping point fixed."
  85   (interactive "p")
  86   (or arg (setq arg 1))
  87   (scroll-lock-update-goal-column)
  88   (if (pos-visible-in-window-p (point-max))
  89       (forward-line arg)
  90     (scroll-up arg))
  91   (scroll-lock-move-to-column scroll-lock-temporary-goal-column))
  92
  93 (defun scroll-lock-previous-line (&optional arg)
  94   "Scroll up ARG lines keeping point fixed."
  95   (interactive "p")
  96   (or arg (setq arg 1))
  97   (scroll-lock-update-goal-column)
  98   (condition-case nil
  99       (scroll-down arg)
 100     (beginning-of-buffer (forward-line (- arg))))
 101   (scroll-lock-move-to-column scroll-lock-temporary-goal-column))
 102
 103 (defun scroll-lock-forward-paragraph (&optional arg)
 104   "Scroll down ARG paragraphs keeping point fixed."
 105   (interactive "p")
 106   (or arg (setq arg 1))
 107   (scroll-lock-update-goal-column)
 108   (scroll-up (count-screen-lines (point) (save-excursion
 109                                            (forward-paragraph arg)
 110                                            (point))))
 111   (scroll-lock-move-to-column scroll-lock-temporary-goal-column))
 112
 113 (defun scroll-lock-backward-paragraph (&optional arg)
 114   "Scroll up ARG paragraphs keeping point fixed."
 115   (interactive "p")
 116   (or arg (setq arg 1))
 117   (scroll-lock-update-goal-column)
 118   (let ((goal (save-excursion (backward-paragraph arg) (point))))
 119     (condition-case nil
 120         (scroll-down (count-screen-lines goal (point)))
 121       (beginning-of-buffer (goto-char goal))))
 122   (scroll-lock-move-to-column scroll-lock-temporary-goal-column))
 123
 124 (provide 'scroll-lock)
 125
 126 ;; arch-tag: 148fc8e8-67e0-4638-bb34-3291595ab7e1
 127 ;;; scroll-lock.el ends here