lisp/macros.el

   1 ;;; macros.el --- non-primitive commands for keyboard macros
   2
   3 ;; Copyright (C) 1985, 1986, 1987, 1992, 1994, 1995, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: abbrev
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Extension commands for keyboard macros.  These permit you to assign
  27 ;; a name to the last-defined keyboard macro, expand and insert the
  28 ;; lisp corresponding to a macro, query the user from within a macro,
  29 ;; or apply a macro to each line in the reason.
  30
  31 ;;; Code:
  32
  33 ;;;###autoload
  34 (defun name-last-kbd-macro (symbol)
  35   "Assign a name to the last keyboard macro defined.
  36 Argument SYMBOL is the name to define.
  37 The symbol's function definition becomes the keyboard macro string.
  38 Such a \"function\" cannot be called from Lisp, but it is a valid editor command."
  39   (interactive "SName for last kbd macro: ")
  40   (or last-kbd-macro
  41       (error "No keyboard macro defined"))
  42   (and (fboundp symbol)
  43        (not (stringp (symbol-function symbol)))
  44        (not (vectorp (symbol-function symbol)))
  45        (error "Function %s is already defined and not a keyboard macro"
  46               symbol))
  47   (if (string-equal symbol "")
  48       (error "No command name given"))
  49   (fset symbol last-kbd-macro))
  50
  51 ;;;###autoload
  52 (defun insert-kbd-macro (macroname &optional keys)
  53   "Insert in buffer the definition of kbd macro NAME, as Lisp code.
  54 Optional second arg KEYS means also record the keys it is on
  55 \(this is the prefix argument, when calling interactively).
  56
  57 This Lisp code will, when executed, define the kbd macro with the same
  58 definition it has now.  If you say to record the keys, the Lisp code
  59 will also rebind those keys to the macro.  Only global key bindings
  60 are recorded since executing this Lisp code always makes global
  61 bindings.
  62
  63 To save a kbd macro, visit a file of Lisp code such as your `~/.emacs',
  64 use this command, and then save the file."
  65   (interactive (list (intern (completing-read "Insert kbd macro (name): "
  66                                               obarray
  67                                               (lambda (elt)
  68                                                 (and (fboundp elt)
  69                                                      (or (stringp (symbol-function elt))
  70                                                          (vectorp (symbol-function elt))
  71                                                          (get elt 'kmacro))))
  72                                               t))
  73                      current-prefix-arg))
  74   (let (definition)
  75     (if (string= (symbol-name macroname) "")
  76         (progn
  77           (setq macroname 'last-kbd-macro definition last-kbd-macro)
  78           (insert "(setq "))
  79       (setq definition (symbol-function macroname))
  80       (insert "(fset '"))
  81     (prin1 macroname (current-buffer))
  82     (insert "\n   ")
  83     (if (stringp definition)
  84         (let ((beg (point)) end)
  85           (prin1 definition (current-buffer))
  86           (setq end (point-marker))
  87           (goto-char beg)
  88           (while (< (point) end)
  89             (let ((char (following-char)))
  90               (cond ((= char 0)
  91                      (delete-region (point) (1+ (point)))
  92                      (insert "\\C-@"))
  93                     ((< char 27)
  94                      (delete-region (point) (1+ (point)))
  95                      (insert "\\C-" (+ 96 char)))
  96                     ((= char ?\C-\\)
  97                      (delete-region (point) (1+ (point)))
  98                      (insert "\\C-\\\\"))
  99                     ((< char 32)
 100                      (delete-region (point) (1+ (point)))
 101                      (insert "\\C-" (+ 64 char)))
 102                     ((< char 127)
 103                      (forward-char 1))
 104                     ((= char 127)
 105                      (delete-region (point) (1+ (point)))
 106                      (insert "\\C-?"))
 107                     ((= char 128)
 108                      (delete-region (point) (1+ (point)))
 109                      (insert "\\M-\\C-@"))
 110                     ((= char (aref "\M-\C-\\" 0))
 111                      (delete-region (point) (1+ (point)))
 112                      (insert "\\M-\\C-\\\\"))
 113                     ((< char 155)
 114                      (delete-region (point) (1+ (point)))
 115                      (insert "\\M-\\C-" (- char 32)))
 116                     ((< char 160)
 117                      (delete-region (point) (1+ (point)))
 118                      (insert "\\M-\\C-" (- char 64)))
 119                     ((= char (aref "\M-\\" 0))
 120                      (delete-region (point) (1+ (point)))
 121                      (insert "\\M-\\\\"))
 122                     ((< char 255)
 123                      (delete-region (point) (1+ (point)))
 124                      (insert "\\M-" (- char 128)))
 125                     ((= char 255)
 126                      (delete-region (point) (1+ (point)))
 127                      (insert "\\M-\\C-?"))))))
 128       (if (vectorp definition)
 129           (let ((len (length definition)) (i 0) char mods)
 130             (while (< i len)
 131               (insert (if (zerop i) ?\[ ?\s))
 132               (setq char (aref definition i)
 133                     i (1+ i))
 134               (cond ((not (numberp char))
 135                      (prin1 char (current-buffer)))
 136                     (t
 137                      (insert "?")
 138                      (setq mods (event-modifiers char)
 139                            char (event-basic-type char))
 140                      (while mods
 141                        (cond ((eq (car mods) 'control)
 142                               (insert "\\C-"))
 143                              ((eq (car mods) 'meta)
 144                               (insert "\\M-"))
 145                              ((eq (car mods) 'hyper)
 146                               (insert "\\H-"))
 147                              ((eq (car mods) 'super)
 148                               (insert "\\s-"))
 149                              ((eq (car mods) 'alt)
 150                               (insert "\\A-"))
 151                              ((and (eq (car mods) 'shift)
 152                                    (>= char ?a)
 153                                    (<= char ?z))
 154                               (setq char (upcase char)))
 155                              ((eq (car mods) 'shift)
 156                               (insert "\\S-")))
 157                        (setq mods (cdr mods)))
 158                      (cond ((= char ?\\)
 159                             (insert "\\\\"))
 160                            ((= char ?\")
 161                             (insert "\\\""))
 162                            ((= char ?\;)
 163                             (insert "\\;"))
 164                            ((= char 127)
 165                             (insert "\\C-?"))
 166                            ((< char 127)
 167                             (insert char))
 168                            (t (insert "\\" (format "%o" char)))))))
 169             (insert ?\]))
 170         (prin1 definition (current-buffer))))
 171     (insert ")\n")
 172     (if keys
 173         (let ((keys (where-is-internal macroname '(keymap))))
 174           (while keys
 175             (insert "(global-set-key ")
 176             (prin1 (car keys) (current-buffer))
 177             (insert " '")
 178             (prin1 macroname (current-buffer))
 179             (insert ")\n")
 180             (setq keys (cdr keys)))))))
 181
 182 ;;;###autoload
 183 (defun kbd-macro-query (flag)
 184   "Query user during kbd macro execution.
 185   With prefix argument, enters recursive edit, reading keyboard
 186 commands even within a kbd macro.  You can give different commands
 187 each time the macro executes.
 188   Without prefix argument, asks whether to continue running the macro.
 189 Your options are: \\<query-replace-map>
 190 \\[act] Finish this iteration normally and continue with the next.
 191 \\[skip]        Skip the rest of this iteration, and start the next.
 192 \\[exit]        Stop the macro entirely right now.
 193 \\[recenter]    Redisplay the screen, then ask again.
 194 \\[edit]        Enter recursive edit; ask again when you exit from that."
 195   (interactive "P")
 196   (or executing-kbd-macro
 197       defining-kbd-macro
 198       (error "Not defining or executing kbd macro"))
 199   (if flag
 200       (let (executing-kbd-macro defining-kbd-macro)
 201         (recursive-edit))
 202     (if (not executing-kbd-macro)
 203         nil
 204       (let ((loop t)
 205             (msg (substitute-command-keys
 206                   "Proceed with macro?\\<query-replace-map>\
 207  (\\[act], \\[skip], \\[exit], \\[recenter], \\[edit]) ")))
 208         (while loop
 209           (let ((key (let ((executing-kbd-macro nil)
 210                            (defining-kbd-macro nil))
 211                        (message "%s" msg)
 212                        (read-event)))
 213                 def)
 214             (setq key (vector key))
 215             (setq def (lookup-key query-replace-map key))
 216             (cond ((eq def 'act)
 217                    (setq loop nil))
 218                   ((eq def 'skip)
 219                    (setq loop nil)
 220                    (setq executing-kbd-macro ""))
 221                   ((eq def 'exit)
 222                    (setq loop nil)
 223                    (setq executing-kbd-macro t))
 224                   ((eq def 'recenter)
 225                    (recenter nil))
 226                   ((eq def 'edit)
 227                    (let (executing-kbd-macro defining-kbd-macro)
 228                      (recursive-edit)))
 229                   ((eq def 'quit)
 230                    (setq quit-flag t))
 231                   (t
 232                    (or (eq def 'help)
 233                        (ding))
 234                    (with-output-to-temp-buffer "*Help*"
 235                      (princ
 236                       (substitute-command-keys
 237                        "Specify how to proceed with keyboard macro execution.
 238 Possibilities: \\<query-replace-map>
 239 \\[act] Finish this iteration normally and continue with the next.
 240 \\[skip]        Skip the rest of this iteration, and start the next.
 241 \\[exit]        Stop the macro entirely right now.
 242 \\[recenter]    Redisplay the screen, then ask again.
 243 \\[edit]        Enter recursive edit; ask again when you exit from that."))
 244                      (save-excursion
 245                        (set-buffer standard-output)
 246                        (help-mode)))))))))))
 247
 248 ;;;###autoload
 249 (defun apply-macro-to-region-lines (top bottom &optional macro)
 250   "Apply last keyboard macro to all lines in the region.
 251 For each line that begins in the region, move to the beginning of
 252 the line, and run the last keyboard macro.
 253
 254 When called from lisp, this function takes two arguments TOP and
 255 BOTTOM, describing the current region.  TOP must be before BOTTOM.
 256 The optional third argument MACRO specifies a keyboard macro to
 257 execute.
 258
 259 This is useful for quoting or unquoting included text, adding and
 260 removing comments, or producing tables where the entries are regular.
 261
 262 For example, in Usenet articles, sections of text quoted from another
 263 author are indented, or have each line start with `>'.  To quote a
 264 section of text, define a keyboard macro which inserts `>', put point
 265 and mark at opposite ends of the quoted section, and use
 266 `\\[apply-macro-to-region-lines]' to mark the entire section.
 267
 268 Suppose you wanted to build a keyword table in C where each entry
 269 looked like this:
 270
 271     { \"foo\", foo_data, foo_function },
 272     { \"bar\", bar_data, bar_function },
 273     { \"baz\", baz_data, baz_function },
 274
 275 You could enter the names in this format:
 276
 277     foo
 278     bar
 279     baz
 280
 281 and write a macro to massage a word into a table entry:
 282
 283     \\C-x (
 284        \\M-d { \"\\C-y\", \\C-y_data, \\C-y_function },
 285     \\C-x )
 286
 287 and then select the region of un-tablified names and use
 288 `\\[apply-macro-to-region-lines]' to build the table from the names."
 289   (interactive "r")
 290   (or macro
 291       (progn
 292         (if (null last-kbd-macro)
 293             (error "No keyboard macro has been defined"))
 294         (setq macro last-kbd-macro)))
 295   (save-excursion
 296     (let ((end-marker (copy-marker bottom))
 297           next-line-marker)
 298       (goto-char top)
 299       (if (not (bolp))
 300           (forward-line 1))
 301       (setq next-line-marker (point-marker))
 302       (while (< next-line-marker end-marker)
 303         (goto-char next-line-marker)
 304         (save-excursion
 305           (forward-line 1)
 306           (set-marker next-line-marker (point)))
 307         (save-excursion
 308           (let ((mark-active nil))
 309             (execute-kbd-macro (or macro last-kbd-macro)))))
 310       (set-marker end-marker nil)
 311       (set-marker next-line-marker nil))))
 312
 313 ;;;###autoload (define-key ctl-x-map "q" 'kbd-macro-query)
 314
 315 (provide 'macros)
 316
 317 ;; arch-tag: 346ed1a5-1220-4bc8-b533-961ee704361f
 318 ;;; macros.el ends here