lisp/ibuf-ext.el

   1 ;;; ibuf-ext.el --- extensions for ibuffer
   2
   3 ;; Copyright (C) 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007,
   4 ;;   2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Colin Walters <walters@verbum.org>
   7 ;; Maintainer: John Paul Wallington <jpw@gnu.org>
   8 ;; Created: 2 Dec 2001
   9 ;; Keywords: buffer, convenience
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; These functions should be automatically loaded when called, but you
  29 ;; can explicity (require 'ibuf-ext) in your ~/.emacs to have them
  30 ;; preloaded.
  31
  32 ;;; Code:
  33
  34 (require 'ibuffer)
  35
  36 (eval-when-compile
  37   (require 'ibuf-macs)
  38   (require 'cl))
  39
  40 ;;; Utility functions
  41 (defun ibuffer-delete-alist (key alist)
  42   "Delete all entries in ALIST that have a key equal to KEY."
  43   (let (entry)
  44     (while (setq entry (assoc key alist))
  45       (setq alist (delete entry alist)))
  46     alist))
  47
  48 ;; borrowed from Gnus
  49 (defun ibuffer-remove-duplicates (list)
  50   "Return a copy of LIST with duplicate elements removed."
  51   (let ((new nil)
  52         (tail list))
  53     (while tail
  54       (or (member (car tail) new)
  55           (setq new (cons (car tail) new)))
  56       (setq tail (cdr tail)))
  57     (nreverse new)))
  58
  59 (defun ibuffer-split-list (ibuffer-split-list-fn ibuffer-split-list-elts)
  60   (let ((hip-crowd nil)
  61         (lamers nil))
  62     (dolist (ibuffer-split-list-elt ibuffer-split-list-elts)
  63       (if (funcall ibuffer-split-list-fn ibuffer-split-list-elt)
  64           (push ibuffer-split-list-elt hip-crowd)
  65         (push ibuffer-split-list-elt lamers)))
  66     ;; Too bad Emacs Lisp doesn't have multiple values.
  67     (list (nreverse hip-crowd) (nreverse lamers))))
  68
  69 (defcustom ibuffer-never-show-predicates nil
  70   "A list of predicates (a regexp or function) for buffers not to display.
  71 If a regexp, then it will be matched against the buffer's name.
  72 If a function, it will be called with the buffer as an argument, and
  73 should return non-nil if this buffer should not be shown."
  74   :type '(repeat (choice regexp function))
  75   :require 'ibuf-ext
  76   :group 'ibuffer)
  77
  78 (defcustom ibuffer-always-show-predicates nil
  79   "A list of predicates (a regexp or function) for buffers to always display.
  80 If a regexp, then it will be matched against the buffer's name.
  81 If a function, it will be called with the buffer as an argument, and
  82 should return non-nil if this buffer should be shown.
  83 Note that buffers matching one of these predicates will be shown
  84 regardless of any active filters in this buffer."
  85   :type '(repeat (choice regexp function))
  86   :group 'ibuffer)
  87
  88 (defvar ibuffer-tmp-hide-regexps nil
  89   "A list of regexps which should match buffer names to not show.")
  90
  91 (defvar ibuffer-tmp-show-regexps nil
  92   "A list of regexps which should match buffer names to always show.")
  93
  94 (defvar ibuffer-auto-mode nil
  95   "If non-nil, Ibuffer auto-mode should be enabled for this buffer.
  96 Do not set this variable directly!  Use the function
  97 `ibuffer-auto-mode' instead.")
  98
  99 (defvar ibuffer-auto-buffers-changed nil)
 100
 101 (defcustom ibuffer-saved-filters '(("gnus"
 102                                     ((or (mode . message-mode)
 103                                          (mode . mail-mode)
 104                                          (mode . gnus-group-mode)
 105                                          (mode . gnus-summary-mode)
 106                                          (mode . gnus-article-mode))))
 107                                    ("programming"
 108                                     ((or (mode . emacs-lisp-mode)
 109                                          (mode . cperl-mode)
 110                                          (mode . c-mode)
 111                                          (mode . java-mode)
 112                                          (mode . idl-mode)
 113                                          (mode . lisp-mode)))))
 114
 115   "An alist of filter qualifiers to switch between.
 116
 117 This variable should look like ((\"STRING\" QUALIFIERS)
 118                                 (\"STRING\" QUALIFIERS) ...), where
 119 QUALIFIERS is a list of the same form as
 120 `ibuffer-filtering-qualifiers'.
 121 See also the variables `ibuffer-filtering-qualifiers',
 122 `ibuffer-filtering-alist', and the functions
 123 `ibuffer-switch-to-saved-filters', `ibuffer-save-filters'."
 124   :type '(repeat sexp)
 125   :group 'ibuffer)
 126
 127 (defvar ibuffer-filtering-qualifiers nil
 128   "A list like (SYMBOL . QUALIFIER) which filters the current buffer list.
 129 See also `ibuffer-filtering-alist'.")
 130
 131 ;; This is now frobbed by `define-ibuffer-filter'.
 132 (defvar ibuffer-filtering-alist nil
 133   "An alist of (SYMBOL DESCRIPTION FUNCTION) which describes a filter.
 134
 135 You most likely do not want to modify this variable directly; see
 136 `define-ibuffer-filter'.
 137
 138 SYMBOL is the symbolic name of the filter.  DESCRIPTION is used when
 139 displaying information to the user.  FUNCTION is given a buffer and
 140 the value of the qualifier, and returns non-nil if and only if the
 141 buffer should be displayed.")
 142
 143 (defcustom ibuffer-filter-format-alist nil
 144   "An alist which has special formats used when a filter is active.
 145 The contents of this variable should look like:
 146  ((FILTER (FORMAT FORMAT ...)) (FILTER (FORMAT FORMAT ...)) ...)
 147
 148 For example, suppose that when you add a filter for buffers whose
 149 major mode is `emacs-lisp-mode', you only want to see the mark and the
 150 name of the buffer.  You could accomplish that by adding:
 151  (mode ((mark \" \" name)))
 152 to this variable."
 153   :type '(repeat (list :tag "Association" (symbol :tag "Filter")
 154                        (list :tag "Formats" (repeat (sexp :tag "Format")))))
 155   :group 'ibuffer)
 156
 157 (defvar ibuffer-cached-filter-formats nil)
 158 (defvar ibuffer-compiled-filter-formats nil)
 159
 160 (defvar ibuffer-filter-groups nil
 161   "A list like ((\"NAME\" ((SYMBOL . QUALIFIER) ...) ...) which groups buffers.
 162 The SYMBOL should be one from `ibuffer-filtering-alist'.
 163 The QUALIFIER should be the same as QUALIFIER in
 164 `ibuffer-filtering-qualifiers'.")
 165
 166 (defcustom ibuffer-show-empty-filter-groups t
 167   "If non-nil, then show the names of filter groups which are empty."
 168   :type 'boolean
 169   :group 'ibuffer)
 170
 171 (defcustom ibuffer-saved-filter-groups nil
 172   "An alist of filtering groups to switch between.
 173
 174 This variable should look like ((\"STRING\" QUALIFIERS)
 175                                 (\"STRING\" QUALIFIERS) ...), where
 176 QUALIFIERS is a list of the same form as
 177 `ibuffer-filtering-qualifiers'.
 178
 179 See also the variables `ibuffer-filter-groups',
 180 `ibuffer-filtering-qualifiers', `ibuffer-filtering-alist', and the
 181 functions `ibuffer-switch-to-saved-filter-groups',
 182 `ibuffer-save-filter-groups'."
 183   :type '(repeat sexp)
 184   :group 'ibuffer)
 185
 186 (defvar ibuffer-hidden-filter-groups nil
 187   "A list of filtering groups which are currently hidden.")
 188
 189 (defvar ibuffer-filter-group-kill-ring nil)
 190
 191 (defcustom ibuffer-old-time 72
 192   "The number of hours before a buffer is considered \"old\"."
 193   :type '(choice (const :tag "72 hours (3 days)" 72)
 194                  (const :tag "48 hours (2 days)" 48)
 195                  (const :tag "24 hours (1 day)" 24)
 196                  (integer :tag "hours"))
 197   :group 'ibuffer)
 198
 199 (defcustom ibuffer-save-with-custom t
 200   "If non-nil, then use Custom to save interactively changed variables.
 201 Currently, this only applies to `ibuffer-saved-filters' and
 202 `ibuffer-saved-filter-groups'."
 203   :type 'boolean
 204   :group 'ibuffer)
 205
 206 (defun ibuffer-ext-visible-p (buf all &optional ibuffer-buf)
 207   (or
 208    (ibuffer-buf-matches-predicates buf ibuffer-tmp-show-regexps)
 209    (and (not
 210          (or
 211           (ibuffer-buf-matches-predicates buf ibuffer-tmp-hide-regexps)
 212           (ibuffer-buf-matches-predicates buf ibuffer-never-show-predicates)))
 213         (or all
 214             (not
 215              (ibuffer-buf-matches-predicates buf ibuffer-maybe-show-predicates)))
 216         (or ibuffer-view-ibuffer
 217             (and ibuffer-buf
 218                  (not (eq ibuffer-buf buf))))
 219         (or
 220          (ibuffer-included-in-filters-p buf ibuffer-filtering-qualifiers)
 221          (ibuffer-buf-matches-predicates buf ibuffer-always-show-predicates)))))
 222
 223 (defun ibuffer-auto-update-changed ()
 224   (when (frame-or-buffer-changed-p 'ibuffer-auto-buffers-changed)
 225     (dolist (buf (buffer-list))
 226       (ignore-errors
 227         (with-current-buffer buf
 228           (when (and ibuffer-auto-mode
 229                      (derived-mode-p 'ibuffer-mode))
 230             (ibuffer-update nil t)))))))
 231
 232 ;;;###autoload
 233 (defun ibuffer-auto-mode (&optional arg)
 234   "Toggle use of Ibuffer's auto-update facility.
 235 With numeric ARG, enable auto-update if and only if ARG is positive."
 236   (interactive)
 237   (unless (derived-mode-p 'ibuffer-mode)
 238     (error "This buffer is not in Ibuffer mode"))
 239   (set (make-local-variable 'ibuffer-auto-mode)
 240        (if arg
 241            (plusp arg)
 242          (not ibuffer-auto-mode)))
 243   (frame-or-buffer-changed-p 'ibuffer-auto-buffers-changed) ; Initialize state vector
 244   (add-hook 'post-command-hook 'ibuffer-auto-update-changed))
 245
 246 ;;;###autoload
 247 (defun ibuffer-mouse-filter-by-mode (event)
 248   "Enable or disable filtering by the major mode chosen via mouse."
 249   (interactive "e")
 250   (ibuffer-interactive-filter-by-mode event))
 251
 252 ;;;###autoload
 253 (defun ibuffer-interactive-filter-by-mode (event-or-point)
 254   "Enable or disable filtering by the major mode at point."
 255   (interactive "d")
 256   (if (eventp event-or-point)
 257       (posn-set-point (event-end event-or-point))
 258     (goto-char event-or-point))
 259   (let ((buf (ibuffer-current-buffer)))
 260     (if (assq 'mode ibuffer-filtering-qualifiers)
 261         (setq ibuffer-filtering-qualifiers
 262               (ibuffer-delete-alist 'mode ibuffer-filtering-qualifiers))
 263       (ibuffer-push-filter (cons 'mode
 264                                 (with-current-buffer buf
 265                                   major-mode)))))
 266   (ibuffer-update nil t))
 267
 268 ;;;###autoload
 269 (defun ibuffer-mouse-toggle-filter-group (event)
 270   "Toggle the display status of the filter group chosen with the mouse."
 271   (interactive "e")
 272   (ibuffer-toggle-filter-group-1 (save-excursion
 273                                    (mouse-set-point event)
 274                                    (point))))
 275
 276 ;;;###autoload
 277 (defun ibuffer-toggle-filter-group ()
 278   "Toggle the display status of the filter group on this line."
 279   (interactive)
 280   (ibuffer-toggle-filter-group-1 (point)))
 281
 282 (defun ibuffer-toggle-filter-group-1 (posn)
 283   (let ((name (get-text-property posn 'ibuffer-filter-group-name)))
 284     (unless (stringp name)
 285       (error "No filtering group name present"))
 286     (if (member name ibuffer-hidden-filter-groups)
 287         (setq ibuffer-hidden-filter-groups
 288               (delete name ibuffer-hidden-filter-groups))
 289       (push name ibuffer-hidden-filter-groups))
 290     (ibuffer-update nil t)))
 291
 292 ;;;###autoload
 293 (defun ibuffer-forward-filter-group (&optional count)
 294   "Move point forwards by COUNT filtering groups."
 295   (interactive "P")
 296   (unless count
 297     (setq count 1))
 298   (when (> count 0)
 299     (when (get-text-property (point) 'ibuffer-filter-group-name)
 300       (goto-char (next-single-property-change
 301                   (point) 'ibuffer-filter-group-name
 302                   nil (point-max))))
 303     (goto-char (next-single-property-change
 304                 (point) 'ibuffer-filter-group-name
 305                 nil (point-max)))
 306     (ibuffer-forward-filter-group (1- count)))
 307   (ibuffer-forward-line 0))
 308
 309 ;;;###autoload
 310 (defun ibuffer-backward-filter-group (&optional count)
 311   "Move point backwards by COUNT filtering groups."
 312   (interactive "P")
 313   (unless count
 314     (setq count 1))
 315   (when (> count 0)
 316     (when (get-text-property (point) 'ibuffer-filter-group-name)
 317       (goto-char (previous-single-property-change
 318                   (point) 'ibuffer-filter-group-name
 319                   nil (point-min))))
 320     (goto-char (previous-single-property-change
 321                 (point) 'ibuffer-filter-group-name
 322                 nil (point-min)))
 323     (ibuffer-backward-filter-group (1- count)))
 324   (when (= (point) (point-min))
 325     (goto-char (point-max))
 326     (ibuffer-backward-filter-group 1))
 327   (ibuffer-forward-line 0))
 328
 329 ;;;###autoload (autoload 'ibuffer-do-shell-command-pipe "ibuf-ext")
 330 (define-ibuffer-op shell-command-pipe (command)
 331   "Pipe the contents of each marked buffer to shell command COMMAND."
 332   (:interactive "sPipe to shell command: "
 333    :opstring "Shell command executed on"
 334    :modifier-p nil)
 335   (shell-command-on-region
 336    (point-min) (point-max) command
 337    (get-buffer-create "* ibuffer-shell-output*")))
 338
 339 ;;;###autoload (autoload 'ibuffer-do-shell-command-pipe-replace "ibuf-ext")
 340 (define-ibuffer-op shell-command-pipe-replace (command)
 341   "Replace the contents of marked buffers with output of pipe to COMMAND."
 342   (:interactive "sPipe to shell command (replace): "
 343    :opstring "Buffer contents replaced in"
 344    :active-opstring "replace buffer contents in"
 345    :dangerous t
 346    :modifier-p t)
 347   (with-current-buffer buf
 348     (shell-command-on-region (point-min) (point-max)
 349                              command nil t)))
 350
 351 ;;;###autoload (autoload 'ibuffer-do-shell-command-file "ibuf-ext")
 352 (define-ibuffer-op shell-command-file (command)
 353   "Run shell command COMMAND separately on files of marked buffers."
 354   (:interactive "sShell command on buffer's file: "
 355    :opstring "Shell command executed on"
 356    :modifier-p nil)
 357   (shell-command (concat command " "
 358                          (shell-quote-argument
 359                           (if buffer-file-name
 360                               buffer-file-name
 361                             (make-temp-file
 362                              (substring (buffer-name) 0 (min 10 (length (buffer-name))))))))))
 363
 364 ;;;###autoload (autoload 'ibuffer-do-eval "ibuf-ext")
 365 (define-ibuffer-op eval (form)
 366   "Evaluate FORM in each of the buffers.
 367 Does not display the buffer during evaluation. See
 368 `ibuffer-do-view-and-eval' for that."
 369   (:interactive
 370    (list
 371     (read-from-minibuffer
 372      "Eval in buffers (form): "
 373      nil read-expression-map t 'read-expression-history))
 374    :opstring "evaluated in"
 375    :modifier-p :maybe)
 376   (eval form))
 377
 378 ;;;###autoload (autoload 'ibuffer-do-view-and-eval "ibuf-ext")
 379 (define-ibuffer-op view-and-eval (form)
 380   "Evaluate FORM while displaying each of the marked buffers.
 381 To evaluate a form without viewing the buffer, see `ibuffer-do-eval'."
 382   (:interactive
 383    (list
 384     (read-from-minibuffer
 385      "Eval viewing in buffers (form): "
 386      nil read-expression-map t 'read-expression-history))
 387    :opstring "evaluated in"
 388    :complex t
 389    :modifier-p :maybe)
 390   (let ((ibuffer-buf (current-buffer)))
 391     (unwind-protect
 392         (progn
 393           (switch-to-buffer buf)
 394           (eval form))
 395       (switch-to-buffer ibuffer-buf))))
 396
 397 ;;;###autoload (autoload 'ibuffer-do-rename-uniquely "ibuf-ext")
 398 (define-ibuffer-op rename-uniquely ()
 399   "Rename marked buffers as with `rename-uniquely'."
 400   (:opstring "renamed"
 401    :modifier-p t)
 402   (rename-uniquely))
 403
 404 ;;;###autoload (autoload 'ibuffer-do-revert "ibuf-ext")
 405 (define-ibuffer-op revert ()
 406   "Revert marked buffers as with `revert-buffer'."
 407   (:dangerous t
 408    :opstring "reverted"
 409    :active-opstring "revert"
 410    :modifier-p :maybe)
 411   (revert-buffer t t))
 412
 413 ;;;###autoload (autoload 'ibuffer-do-replace-regexp "ibuf-ext")
 414 (define-ibuffer-op replace-regexp (from-str to-str)
 415   "Perform a `replace-regexp' in marked buffers."
 416   (:interactive
 417    (let* ((from-str (read-from-minibuffer "Replace regexp: "))
 418           (to-str (read-from-minibuffer (concat "Replace " from-str
 419                                                 " with: "))))
 420      (list from-str to-str))
 421    :opstring "replaced in"
 422    :complex t
 423    :modifier-p :maybe)
 424   (save-window-excursion
 425     (switch-to-buffer buf)
 426     (save-excursion
 427       (goto-char (point-min))
 428       (let ((case-fold-search ibuffer-case-fold-search))
 429         (while (re-search-forward from-str nil t)
 430           (replace-match to-str))))
 431     t))
 432
 433 ;;;###autoload (autoload 'ibuffer-do-query-replace "ibuf-ext")
 434 (define-ibuffer-op query-replace (&rest args)
 435   "Perform a `query-replace' in marked buffers."
 436   (:interactive
 437    (query-replace-read-args "Query replace" t t)
 438    :opstring "replaced in"
 439    :complex t
 440    :modifier-p :maybe)
 441   (save-window-excursion
 442     (switch-to-buffer buf)
 443     (save-excursion
 444       (let ((case-fold-search ibuffer-case-fold-search))
 445         (goto-char (point-min))
 446         (apply #'query-replace args)))
 447     t))
 448
 449 ;;;###autoload (autoload 'ibuffer-do-query-replace-regexp "ibuf-ext")
 450 (define-ibuffer-op query-replace-regexp (&rest args)
 451   "Perform a `query-replace-regexp' in marked buffers."
 452   (:interactive
 453    (query-replace-read-args "Query replace regexp" t t)
 454    :opstring "replaced in"
 455    :complex t
 456    :modifier-p :maybe)
 457   (save-window-excursion
 458     (switch-to-buffer buf)
 459     (save-excursion
 460       (let ((case-fold-search ibuffer-case-fold-search))
 461         (goto-char (point-min))
 462         (apply #'query-replace-regexp args)))
 463     t))
 464
 465 ;;;###autoload (autoload 'ibuffer-do-print "ibuf-ext")
 466 (define-ibuffer-op print ()
 467   "Print marked buffers as with `print-buffer'."
 468   (:opstring "printed"
 469    :modifier-p nil)
 470   (print-buffer))
 471
 472 ;;;###autoload
 473 (defun ibuffer-included-in-filters-p (buf filters)
 474   (not
 475    (memq nil ;; a filter will return nil if it failed
 476          (mapcar
 477           ;; filter should be like (TYPE . QUALIFIER), or
 478           ;; (or (TYPE . QUALIFIER) (TYPE . QUALIFIER) ...)
 479           #'(lambda (qual)
 480               (ibuffer-included-in-filter-p buf qual))
 481           filters))))
 482
 483 (defun ibuffer-included-in-filter-p (buf filter)
 484   (if (eq (car filter) 'not)
 485       (not (ibuffer-included-in-filter-p-1 buf (cdr filter)))
 486     (ibuffer-included-in-filter-p-1 buf filter)))
 487
 488 (defun ibuffer-included-in-filter-p-1 (buf filter)
 489   (not
 490    (not
 491     (case (car filter)
 492       (or
 493        (memq t (mapcar #'(lambda (x)
 494                            (ibuffer-included-in-filter-p buf x))
 495                        (cdr filter))))
 496       (saved
 497        (let ((data
 498               (assoc (cdr filter)
 499                      ibuffer-saved-filters)))
 500          (unless data
 501            (ibuffer-filter-disable)
 502            (error "Unknown saved filter %s" (cdr filter)))
 503          (ibuffer-included-in-filters-p buf (cadr data))))
 504       (t
 505        (let ((filterdat (assq (car filter)
 506                               ibuffer-filtering-alist)))
 507          ;; filterdat should be like (TYPE DESCRIPTION FUNC)
 508          ;; just a sanity check
 509         (unless filterdat
 510           (ibuffer-filter-disable)
 511           (error "Undefined filter %s" (car filter)))
 512         (not
 513          (not
 514           (funcall (caddr filterdat)
 515                    buf
 516                    (cdr filter))))))))))
 517
 518 (defun ibuffer-generate-filter-groups (bmarklist &optional noempty nodefault)
 519   (let ((filter-group-alist (if nodefault
 520                                 ibuffer-filter-groups
 521                               (append ibuffer-filter-groups
 522                                       (list (cons "Default" nil))))))
 523 ;;     (dolist (hidden ibuffer-hidden-filter-groups)
 524 ;;       (setq filter-group-alist (ibuffer-delete-alist
 525 ;;                                 hidden filter-group-alist)))
 526     (let ((vec (make-vector (length filter-group-alist) nil))
 527           (i 0))
 528       (dolist (filtergroup filter-group-alist)
 529         (let ((filterset (cdr filtergroup)))
 530           (multiple-value-bind (hip-crowd lamers)
 531               (ibuffer-split-list (lambda (bufmark)
 532                                     (ibuffer-included-in-filters-p (car bufmark)
 533                                                                    filterset))
 534                                   bmarklist)
 535             (aset vec i hip-crowd)
 536             (incf i)
 537             (setq bmarklist lamers))))
 538       (let (ret)
 539         (dotimes (j i ret)
 540           (let ((bufs (aref vec j)))
 541             (unless (and noempty (null bufs))
 542               (push (cons (car (nth j filter-group-alist))
 543                           bufs)
 544                     ret))))))))
 545
 546 ;;;###autoload
 547 (defun ibuffer-filters-to-filter-group (name)
 548   "Make the current filters into a filtering group."
 549   (interactive "sName for filtering group: ")
 550   (when (null ibuffer-filtering-qualifiers)
 551     (error "No filters in effect"))
 552   (push (cons name ibuffer-filtering-qualifiers) ibuffer-filter-groups)
 553   (ibuffer-filter-disable))
 554
 555 ;;;###autoload
 556 (defun ibuffer-set-filter-groups-by-mode ()
 557   "Set the current filter groups to filter by mode."
 558   (interactive)
 559   (setq ibuffer-filter-groups
 560         (mapcar (lambda (mode)
 561                   (cons (format "%s" mode) `((mode . ,mode))))
 562                 (let ((modes
 563                        (ibuffer-remove-duplicates
 564                         (mapcar (lambda (buf)
 565                                   (with-current-buffer buf major-mode))
 566                                 (buffer-list)))))
 567                   (if ibuffer-view-ibuffer
 568                       modes
 569                     (delq 'ibuffer-mode modes)))))
 570   (ibuffer-update nil t))
 571
 572 ;;;###autoload
 573 (defun ibuffer-pop-filter-group ()
 574   "Remove the first filter group."
 575   (interactive)
 576   (when (null ibuffer-filter-groups)
 577     (error "No filter groups active"))
 578   (setq ibuffer-hidden-filter-groups
 579         (delete (pop ibuffer-filter-groups)
 580                 ibuffer-hidden-filter-groups))
 581   (ibuffer-update nil t))
 582
 583 (defun ibuffer-read-filter-group-name (msg &optional nodefault noerror)
 584   (when (and (not noerror) (null ibuffer-filter-groups))
 585     (error "No filter groups active"))
 586   ;; `ibuffer-generate-filter-groups' returns all non-hidden filter
 587   ;; groups, possibly excluding empty groups or Default.
 588   ;; We add `ibuffer-hidden-filter-groups' to the list, excluding
 589   ;; Default if necessary.
 590   (completing-read msg (nconc
 591                         (ibuffer-generate-filter-groups
 592                          (ibuffer-current-state-list)
 593                          (not ibuffer-show-empty-filter-groups)
 594                          nodefault)
 595                         (if nodefault
 596                             (remove "Default" ibuffer-hidden-filter-groups)
 597                           ibuffer-hidden-filter-groups))
 598                    nil t))
 599
 600 ;;;###autoload
 601 (defun ibuffer-decompose-filter-group (group)
 602   "Decompose the filter group GROUP into active filters."
 603   (interactive
 604    (list (ibuffer-read-filter-group-name "Decompose filter group: " t)))
 605   (let ((data (cdr (assoc group ibuffer-filter-groups))))
 606     (setq ibuffer-filter-groups (ibuffer-delete-alist
 607                                  group ibuffer-filter-groups)
 608           ibuffer-filtering-qualifiers data))
 609   (ibuffer-update nil t))
 610
 611 ;;;###autoload
 612 (defun ibuffer-clear-filter-groups ()
 613   "Remove all filter groups."
 614   (interactive)
 615   (setq ibuffer-filter-groups nil
 616         ibuffer-hidden-filter-groups nil)
 617   (ibuffer-update nil t))
 618
 619 (defun ibuffer-current-filter-groups-with-position ()
 620   (save-excursion
 621     (goto-char (point-min))
 622     (let ((pos nil)
 623           (result nil))
 624       (while (and (not (eobp))
 625                   (setq pos (next-single-property-change
 626                              (point) 'ibuffer-filter-group-name)))
 627         (goto-char pos)
 628         (push (cons (get-text-property (point) 'ibuffer-filter-group-name)
 629                     pos)
 630               result)
 631         (goto-char (next-single-property-change
 632                     pos 'ibuffer-filter-group-name)))
 633       (nreverse result))))
 634
 635 ;;;###autoload
 636 (defun ibuffer-jump-to-filter-group (name)
 637   "Move point to the filter group whose name is NAME."
 638   (interactive
 639    (list (ibuffer-read-filter-group-name "Jump to filter group: ")))
 640   (ibuffer-aif (assoc name (ibuffer-current-filter-groups-with-position))
 641       (goto-char (cdr it))
 642     (error "No filter group with name %s" name)))
 643
 644 ;;;###autoload
 645 (defun ibuffer-kill-filter-group (name)
 646   "Kill the filter group named NAME.
 647 The group will be added to `ibuffer-filter-group-kill-ring'."
 648   (interactive (list (ibuffer-read-filter-group-name "Kill filter group: " t)))
 649   (when (equal name "Default")
 650     (error "Can't kill default filter group"))
 651   (ibuffer-aif (assoc name ibuffer-filter-groups)
 652       (progn
 653         (push (copy-tree it) ibuffer-filter-group-kill-ring)
 654         (setq ibuffer-filter-groups (ibuffer-delete-alist
 655                                      name ibuffer-filter-groups))
 656         (setq ibuffer-hidden-filter-groups
 657               (delete name ibuffer-hidden-filter-groups)))
 658     (error "No filter group with name \"%s\"" name))
 659   (ibuffer-update nil t))
 660
 661 ;;;###autoload
 662 (defun ibuffer-kill-line (&optional arg interactive-p)
 663   "Kill the filter group at point.
 664 See also `ibuffer-kill-filter-group'."
 665   (interactive "P\np")
 666   (ibuffer-aif (save-excursion
 667                  (ibuffer-forward-line 0)
 668                  (get-text-property (point) 'ibuffer-filter-group-name))
 669       (progn
 670         (ibuffer-kill-filter-group it))
 671       (funcall (if interactive-p #'call-interactively #'funcall)
 672                #'kill-line arg)))
 673
 674 (defun ibuffer-insert-filter-group-before (newgroup group)
 675   (let* ((found nil)
 676          (pos (let ((groups (mapcar #'car ibuffer-filter-groups))
 677                     (res 0))
 678                 (while groups
 679                   (if (equal (car groups) group)
 680                       (setq found t
 681                             groups nil)
 682                     (incf res)
 683                     (setq groups (cdr groups))))
 684                 res)))
 685     (cond ((not found)
 686            (setq ibuffer-filter-groups
 687                  (nconc ibuffer-filter-groups (list newgroup))))
 688           ((zerop pos)
 689            (push newgroup ibuffer-filter-groups))
 690           (t
 691            (let ((cell (nthcdr pos ibuffer-filter-groups)))
 692              (setf (cdr cell) (cons (car cell) (cdr cell)))
 693              (setf (car cell) newgroup))))))
 694
 695 ;;;###autoload
 696 (defun ibuffer-yank ()
 697   "Yank the last killed filter group before group at point."
 698   (interactive)
 699   (ibuffer-yank-filter-group
 700    (or (get-text-property (point) 'ibuffer-filter-group-name)
 701        (get-text-property (point) 'ibuffer-filter-group)
 702        (error "No filter group at point"))))
 703
 704 ;;;###autoload
 705 (defun ibuffer-yank-filter-group (name)
 706   "Yank the last killed filter group before group named NAME."
 707   (interactive (list (ibuffer-read-filter-group-name
 708                         "Yank filter group before group: ")))
 709   (unless ibuffer-filter-group-kill-ring
 710     (error "The Ibuffer filter group kill-ring is empty"))
 711   (save-excursion
 712     (ibuffer-forward-line 0)
 713     (ibuffer-insert-filter-group-before (pop ibuffer-filter-group-kill-ring)
 714                                         name))
 715   (ibuffer-update nil t))
 716
 717 ;;;###autoload
 718 (defun ibuffer-save-filter-groups (name groups)
 719   "Save all active filter groups GROUPS as NAME.
 720 They are added to `ibuffer-saved-filter-groups'.  Interactively,
 721 prompt for NAME, and use the current filters."
 722   (interactive
 723    (if (null ibuffer-filter-groups)
 724        (error "No filter groups active")
 725      (list
 726       (read-from-minibuffer "Save current filter groups as: ")
 727       ibuffer-filter-groups)))
 728   (ibuffer-aif (assoc name ibuffer-saved-filter-groups)
 729       (setcdr it groups)
 730     (push (cons name groups) ibuffer-saved-filter-groups))
 731   (ibuffer-maybe-save-stuff))
 732
 733 ;;;###autoload
 734 (defun ibuffer-delete-saved-filter-groups (name)
 735   "Delete saved filter groups with NAME.
 736 They are removed from `ibuffer-saved-filter-groups'."
 737   (interactive
 738    (list
 739     (if (null ibuffer-saved-filter-groups)
 740         (error "No saved filter groups")
 741       (completing-read "Delete saved filter group: "
 742                        ibuffer-saved-filter-groups nil t))))
 743   (setq ibuffer-saved-filter-groups
 744         (ibuffer-delete-alist name ibuffer-saved-filter-groups))
 745   (ibuffer-maybe-save-stuff)
 746   (ibuffer-update nil t))
 747
 748 ;;;###autoload
 749 (defun ibuffer-switch-to-saved-filter-groups (name)
 750   "Set this buffer's filter groups to saved version with NAME.
 751 The value from `ibuffer-saved-filter-groups' is used."
 752   (interactive
 753    (list
 754     (if (null ibuffer-saved-filter-groups)
 755         (error "No saved filters")
 756       (completing-read "Switch to saved filter group: "
 757                        ibuffer-saved-filter-groups nil t))))
 758   (setq ibuffer-filter-groups (cdr (assoc name ibuffer-saved-filter-groups))
 759         ibuffer-hidden-filter-groups nil)
 760   (ibuffer-update nil t))
 761
 762 ;;;###autoload
 763 (defun ibuffer-filter-disable ()
 764   "Disable all filters currently in effect in this buffer."
 765   (interactive)
 766   (setq ibuffer-filtering-qualifiers nil)
 767   (let ((buf (ibuffer-current-buffer)))
 768     (ibuffer-update nil t)
 769     (when buf
 770       (ibuffer-jump-to-buffer (buffer-name buf)))))
 771
 772 ;;;###autoload
 773 (defun ibuffer-pop-filter ()
 774   "Remove the top filter in this buffer."
 775   (interactive)
 776   (when (null ibuffer-filtering-qualifiers)
 777     (error "No filters in effect"))
 778   (pop ibuffer-filtering-qualifiers)
 779   (let ((buf (ibuffer-current-buffer)))
 780     (ibuffer-update nil t)
 781     (when buf
 782       (ibuffer-jump-to-buffer (buffer-name buf)))))
 783
 784 (defun ibuffer-push-filter (qualifier)
 785   "Add QUALIFIER to `ibuffer-filtering-qualifiers'."
 786   (push qualifier ibuffer-filtering-qualifiers))
 787
 788 ;;;###autoload
 789 (defun ibuffer-decompose-filter ()
 790   "Separate the top compound filter (OR, NOT, or SAVED) in this buffer.
 791
 792 This means that the topmost filter on the filtering stack, which must
 793 be a complex filter like (OR [name: foo] [mode: bar-mode]), will be
 794 turned into two separate filters [name: foo] and [mode: bar-mode]."
 795   (interactive)
 796   (when (null ibuffer-filtering-qualifiers)
 797     (error "No filters in effect"))
 798   (let ((lim (pop ibuffer-filtering-qualifiers)))
 799     (case (car lim)
 800       (or
 801        (setq ibuffer-filtering-qualifiers (append
 802                                           (cdr lim)
 803                                           ibuffer-filtering-qualifiers)))
 804       (saved
 805        (let ((data
 806               (assoc (cdr lim)
 807                      ibuffer-saved-filters)))
 808          (unless data
 809            (ibuffer-filter-disable)
 810            (error "Unknown saved filter %s" (cdr lim)))
 811          (setq ibuffer-filtering-qualifiers (append
 812                                             (cadr data)
 813                                             ibuffer-filtering-qualifiers))))
 814       (not
 815        (push (cdr lim)
 816              ibuffer-filtering-qualifiers))
 817       (t
 818        (error "Filter type %s is not compound" (car lim)))))
 819   (ibuffer-update nil t))
 820
 821 ;;;###autoload
 822 (defun ibuffer-exchange-filters ()
 823   "Exchange the top two filters on the stack in this buffer."
 824   (interactive)
 825   (when (< (length ibuffer-filtering-qualifiers)
 826            2)
 827     (error "Need two filters to exchange"))
 828   (let ((first (pop ibuffer-filtering-qualifiers))
 829         (second (pop ibuffer-filtering-qualifiers)))
 830     (push first ibuffer-filtering-qualifiers)
 831     (push second ibuffer-filtering-qualifiers))
 832   (ibuffer-update nil t))
 833
 834 ;;;###autoload
 835 (defun ibuffer-negate-filter ()
 836   "Negate the sense of the top filter in the current buffer."
 837   (interactive)
 838   (when (null ibuffer-filtering-qualifiers)
 839     (error "No filters in effect"))
 840   (let ((lim (pop ibuffer-filtering-qualifiers)))
 841     (push (if (eq (car lim) 'not)
 842               (cdr lim)
 843             (cons 'not lim))
 844           ibuffer-filtering-qualifiers))
 845   (ibuffer-update nil t))
 846
 847 ;;;###autoload
 848 (defun ibuffer-or-filter (&optional reverse)
 849   "Replace the top two filters in this buffer with their logical OR.
 850 If optional argument REVERSE is non-nil, instead break the top OR
 851 filter into parts."
 852   (interactive "P")
 853   (if reverse
 854       (progn
 855         (when (or (null ibuffer-filtering-qualifiers)
 856                   (not (eq 'or (caar ibuffer-filtering-qualifiers))))
 857           (error "Top filter is not an OR"))
 858         (let ((lim (pop ibuffer-filtering-qualifiers)))
 859           (setq ibuffer-filtering-qualifiers
 860                 (nconc (cdr lim) ibuffer-filtering-qualifiers))))
 861     (when (< (length ibuffer-filtering-qualifiers) 2)
 862       (error "Need two filters to OR"))
 863     ;; If the second filter is an OR, just add to it.
 864     (let ((first (pop ibuffer-filtering-qualifiers))
 865           (second (pop ibuffer-filtering-qualifiers)))
 866       (if (eq 'or (car second))
 867           (push (nconc (list 'or first) (cdr second))
 868                 ibuffer-filtering-qualifiers)
 869         (push (list 'or first second)
 870               ibuffer-filtering-qualifiers))))
 871   (ibuffer-update nil t))
 872
 873 (defun ibuffer-maybe-save-stuff ()
 874   (when ibuffer-save-with-custom
 875     (if (fboundp 'customize-save-variable)
 876         (progn
 877           (customize-save-variable 'ibuffer-saved-filters
 878                                    ibuffer-saved-filters)
 879           (customize-save-variable 'ibuffer-saved-filter-groups
 880                                    ibuffer-saved-filter-groups))
 881       (message "Not saved permanently: Customize not available"))))
 882
 883 ;;;###autoload
 884 (defun ibuffer-save-filters (name filters)
 885   "Save FILTERS in this buffer with name NAME in `ibuffer-saved-filters'.
 886 Interactively, prompt for NAME, and use the current filters."
 887   (interactive
 888    (if (null ibuffer-filtering-qualifiers)
 889        (error "No filters currently in effect")
 890      (list
 891       (read-from-minibuffer "Save current filters as: ")
 892       ibuffer-filtering-qualifiers)))
 893   (ibuffer-aif (assoc name ibuffer-saved-filters)
 894       (setcdr it filters)
 895     (push (list name filters) ibuffer-saved-filters))
 896   (ibuffer-maybe-save-stuff))
 897
 898 ;;;###autoload
 899 (defun ibuffer-delete-saved-filters (name)
 900   "Delete saved filters with NAME from `ibuffer-saved-filters'."
 901   (interactive
 902    (list
 903     (if (null ibuffer-saved-filters)
 904         (error "No saved filters")
 905       (completing-read "Delete saved filters: "
 906                        ibuffer-saved-filters nil t))))
 907   (setq ibuffer-saved-filters
 908         (ibuffer-delete-alist name ibuffer-saved-filters))
 909   (ibuffer-maybe-save-stuff)
 910   (ibuffer-update nil t))
 911
 912 ;;;###autoload
 913 (defun ibuffer-add-saved-filters (name)
 914   "Add saved filters from `ibuffer-saved-filters' to this buffer's filters."
 915   (interactive
 916    (list
 917     (if (null ibuffer-saved-filters)
 918         (error "No saved filters")
 919       (completing-read "Add saved filters: "
 920                        ibuffer-saved-filters nil t))))
 921   (push (cons 'saved name) ibuffer-filtering-qualifiers)
 922   (ibuffer-update nil t))
 923
 924 ;;;###autoload
 925 (defun ibuffer-switch-to-saved-filters (name)
 926   "Set this buffer's filters to filters with NAME from `ibuffer-saved-filters'."
 927   (interactive
 928    (list
 929     (if (null ibuffer-saved-filters)
 930         (error "No saved filters")
 931       (completing-read "Switch to saved filters: "
 932                        ibuffer-saved-filters nil t))))
 933   (setq ibuffer-filtering-qualifiers (list (cons 'saved name)))
 934   (ibuffer-update nil t))
 935
 936 (defun ibuffer-format-filter-group-data (filter)
 937   (if (equal filter "Default")
 938       ""
 939     (concat "Filter:" (mapconcat #'ibuffer-format-qualifier
 940                                  (cdr (assq filter ibuffer-filter-groups))
 941                                  " "))))
 942
 943 (defun ibuffer-format-qualifier (qualifier)
 944   (if (eq (car-safe qualifier) 'not)
 945       (concat " [NOT" (ibuffer-format-qualifier-1 (cdr qualifier)) "]")
 946     (ibuffer-format-qualifier-1 qualifier)))
 947
 948 (defun ibuffer-format-qualifier-1 (qualifier)
 949   (case (car qualifier)
 950     (saved
 951      (concat " [filter: " (cdr qualifier) "]"))
 952     (or
 953      (concat " [OR" (mapconcat #'ibuffer-format-qualifier
 954                                (cdr qualifier) "") "]"))
 955     (t
 956      (let ((type (assq (car qualifier) ibuffer-filtering-alist)))
 957        (unless qualifier
 958          (error "Ibuffer: bad qualifier %s" qualifier))
 959        (concat " [" (cadr type) ": " (format "%s]" (cdr qualifier)))))))
 960
 961
 962 (defun ibuffer-list-buffer-modes ()
 963   "Create an alist of buffer modes currently in use.
 964 The list returned will be of the form (\"MODE-NAME\" . MODE-SYMBOL)."
 965   (let ((bufs (buffer-list))
 966         (modes)
 967         (this-mode))
 968     (while bufs
 969       (setq this-mode
 970             (with-current-buffer
 971                 (car bufs)
 972               major-mode)
 973             bufs (cdr bufs))
 974       (add-to-list
 975        'modes
 976        `(,(symbol-name this-mode) .
 977          ,this-mode)))
 978     modes))
 979
 980
 981 ;;; Extra operation definitions
 982
 983 ;;;###autoload (autoload 'ibuffer-filter-by-mode "ibuf-ext")
 984 (define-ibuffer-filter mode
 985   "Toggle current view to buffers with major mode QUALIFIER."
 986   (:description "major mode"
 987    :reader
 988    (intern
 989     (completing-read "Filter by major mode: " obarray
 990                      #'(lambda (e)
 991                          (string-match "-mode$"
 992                                        (symbol-name e)))
 993                      t
 994                      (let ((buf (ibuffer-current-buffer)))
 995                        (if (and buf (buffer-live-p buf))
 996                            (with-current-buffer buf
 997                              (symbol-name major-mode))
 998                          "")))))
 999   (eq qualifier (with-current-buffer buf major-mode)))
1000
1001 ;;;###autoload (autoload 'ibuffer-filter-by-used-mode "ibuf-ext")
1002 (define-ibuffer-filter used-mode
1003   "Toggle current view to buffers with major mode QUALIFIER.
1004 Called interactively, this function allows selection of modes
1005 currently used by buffers."
1006   (:description "major mode in use"
1007                 :reader
1008                 (intern
1009                  (completing-read "Filter by major mode: "
1010                                   (ibuffer-list-buffer-modes)
1011                                   nil
1012                                   t
1013                                   (let ((buf (ibuffer-current-buffer)))
1014                                     (if (and buf (buffer-live-p buf))
1015                                         (with-current-buffer buf
1016                                           (symbol-name major-mode))
1017                                       "")))))
1018   (eq qualifier (with-current-buffer buf major-mode)))
1019
1020 ;;;###autoload (autoload 'ibuffer-filter-by-name "ibuf-ext")
1021 (define-ibuffer-filter name
1022   "Toggle current view to buffers with name matching QUALIFIER."
1023   (:description "buffer name"
1024    :reader (read-from-minibuffer "Filter by name (regexp): "))
1025   (string-match qualifier (buffer-name buf)))
1026
1027 ;;;###autoload (autoload 'ibuffer-filter-by-filename "ibuf-ext")
1028 (define-ibuffer-filter filename
1029   "Toggle current view to buffers with filename matching QUALIFIER."
1030   (:description "filename"
1031    :reader (read-from-minibuffer "Filter by filename (regexp): "))
1032   (ibuffer-awhen (with-current-buffer buf
1033                    (or buffer-file-name
1034                        (and (boundp 'dired-directory)
1035                             (let ((dired-dir
1036                                    (if (stringp dired-directory)
1037                                        dired-directory
1038                                      (car dired-directory))))
1039                               (and dired-dir
1040                                    (expand-file-name dired-dir))))
1041                        (and (eq major-mode 'vc-dir-mode)
1042                             (bound-and-true-p default-directory))))
1043                  (string-match qualifier it)))
1044
1045 ;;;###autoload (autoload 'ibuffer-filter-by-size-gt  "ibuf-ext")
1046 (define-ibuffer-filter size-gt
1047   "Toggle current view to buffers with size greater than QUALIFIER."
1048   (:description "size greater than"
1049    :reader
1050    (string-to-number (read-from-minibuffer "Filter by size greater than: ")))
1051   (> (with-current-buffer buf (buffer-size))
1052      qualifier))
1053
1054 ;;;###autoload (autoload 'ibuffer-filter-by-size-lt  "ibuf-ext")
1055 (define-ibuffer-filter size-lt
1056    "Toggle current view to buffers with size less than QUALIFIER."
1057   (:description "size less than"
1058    :reader
1059    (string-to-number (read-from-minibuffer "Filter by size less than: ")))
1060   (< (with-current-buffer buf (buffer-size))
1061      qualifier))
1062
1063 ;;;###autoload (autoload 'ibuffer-filter-by-content "ibuf-ext")
1064 (define-ibuffer-filter content
1065    "Toggle current view to buffers whose contents match QUALIFIER."
1066   (:description "content"
1067    :reader (read-from-minibuffer "Filter by content (regexp): "))
1068   (with-current-buffer buf
1069     (save-excursion
1070       (goto-char (point-min))
1071       (re-search-forward qualifier nil t))))
1072
1073 ;;;###autoload (autoload 'ibuffer-filter-by-predicate "ibuf-ext")
1074 (define-ibuffer-filter predicate
1075    "Toggle current view to buffers for which QUALIFIER returns non-nil."
1076   (:description "predicate"
1077    :reader (read-minibuffer "Filter by predicate (form): "))
1078   (with-current-buffer buf
1079     (eval qualifier)))
1080
1081 ;;; Sorting
1082
1083 ;;;###autoload
1084 (defun ibuffer-toggle-sorting-mode ()
1085   "Toggle the current sorting mode.
1086 Default sorting modes are:
1087  Recency - the last time the buffer was viewed
1088  Name - the name of the buffer
1089  Major Mode - the name of the major mode of the buffer
1090  Size - the size of the buffer"
1091   (interactive)
1092   (let ((modes (mapcar 'car ibuffer-sorting-functions-alist)))
1093     (add-to-list 'modes 'recency)
1094     (setq modes (sort modes 'string-lessp))
1095     (let ((next (or (car-safe (cdr-safe (memq ibuffer-sorting-mode modes)))
1096                     (car modes))))
1097       (setq ibuffer-sorting-mode next)
1098       (message "Sorting by %s" next)))
1099   (ibuffer-redisplay t))
1100
1101 ;;;###autoload
1102 (defun ibuffer-invert-sorting ()
1103   "Toggle whether or not sorting is in reverse order."
1104   (interactive)
1105   (setq ibuffer-sorting-reversep (not ibuffer-sorting-reversep))
1106   (message "Sorting order %s"
1107            (if ibuffer-sorting-reversep
1108                "reversed"
1109              "normal"))
1110   (ibuffer-redisplay t))
1111
1112 ;;;###autoload (autoload 'ibuffer-do-sort-by-major-mode "ibuf-ext")
1113 (define-ibuffer-sorter major-mode
1114   "Sort the buffers by major modes.
1115 Ordering is lexicographic."
1116   (:description "major mode")
1117   (string-lessp (downcase
1118                  (symbol-name (with-current-buffer
1119                                   (car a)
1120                                 major-mode)))
1121                 (downcase
1122                  (symbol-name (with-current-buffer
1123                                   (car b)
1124                                 major-mode)))))
1125
1126 ;;;###autoload (autoload 'ibuffer-do-sort-by-mode-name "ibuf-ext")
1127 (define-ibuffer-sorter mode-name
1128   "Sort the buffers by their mode name.
1129 Ordering is lexicographic."
1130   (:description "major mode name")
1131   (string-lessp (downcase
1132                   (with-current-buffer
1133                       (car a)
1134                     (format-mode-line mode-name)))
1135                 (downcase
1136                  (with-current-buffer
1137                      (car b)
1138                    (format-mode-line mode-name)))))
1139
1140 ;;;###autoload (autoload 'ibuffer-do-sort-by-alphabetic "ibuf-ext")
1141 (define-ibuffer-sorter alphabetic
1142   "Sort the buffers by their names.
1143 Ordering is lexicographic."
1144   (:description "buffer name")
1145   (string-lessp
1146    (buffer-name (car a))
1147    (buffer-name (car b))))
1148
1149 ;;;###autoload (autoload 'ibuffer-do-sort-by-size "ibuf-ext")
1150 (define-ibuffer-sorter size
1151  "Sort the buffers by their size."
1152   (:description "size")
1153   (< (with-current-buffer (car a)
1154        (buffer-size))
1155      (with-current-buffer (car b)
1156        (buffer-size))))
1157
1158 ;;;###autoload (autoload 'ibuffer-do-sort-by-filename/process "ibuf-ext")
1159 (define-ibuffer-sorter filename/process
1160  "Sort the buffers by their file name/process name."
1161   (:description "file name")
1162   (string-lessp
1163    ;; FIXME: For now just compare the file name and the process name
1164    ;; (if it exists).  Is there a better way to do this?
1165    (or (buffer-file-name (car a))
1166        (let ((pr-a (get-buffer-process (car a))))
1167          (and (processp pr-a) (process-name pr-a))))
1168    (or (buffer-file-name (car b))
1169        (let ((pr-b (get-buffer-process (car b))))
1170          (and (processp pr-b) (process-name pr-b))))))
1171
1172 ;;; Functions to emulate bs.el
1173
1174 ;;;###autoload
1175 (defun ibuffer-bs-show ()
1176   "Emulate `bs-show' from the bs.el package."
1177   (interactive)
1178   (ibuffer t "*Ibuffer-bs*" '((filename . ".*")) nil t)
1179   (define-key (current-local-map) "a" 'ibuffer-bs-toggle-all))
1180
1181 (defun ibuffer-bs-toggle-all ()
1182   "Emulate `bs-toggle-show-all' from the bs.el package."
1183   (interactive)
1184   (if ibuffer-filtering-qualifiers
1185       (ibuffer-pop-filter)
1186     (progn (ibuffer-push-filter '(filename . ".*"))
1187            (ibuffer-update nil t))))
1188
1189 ;;; Handy functions
1190
1191 ;;;###autoload
1192 (defun ibuffer-add-to-tmp-hide (regexp)
1193   "Add REGEXP to `ibuffer-tmp-hide-regexps'.
1194 This means that buffers whose name matches REGEXP will not be shown
1195 for this Ibuffer session."
1196   (interactive
1197    (list
1198     (read-from-minibuffer "Never show buffers matching: "
1199                           (regexp-quote (buffer-name (ibuffer-current-buffer t))))))
1200   (push regexp ibuffer-tmp-hide-regexps))
1201
1202 ;;;###autoload
1203 (defun ibuffer-add-to-tmp-show (regexp)
1204   "Add REGEXP to `ibuffer-tmp-show-regexps'.
1205 This means that buffers whose name matches REGEXP will always be shown
1206 for this Ibuffer session."
1207   (interactive
1208    (list
1209     (read-from-minibuffer "Always show buffers matching: "
1210                           (regexp-quote (buffer-name (ibuffer-current-buffer t))))))
1211   (push regexp ibuffer-tmp-show-regexps))
1212
1213 ;;;###autoload
1214 (defun ibuffer-forward-next-marked (&optional count mark direction)
1215   "Move forward by COUNT marked buffers (default 1).
1216
1217 If MARK is non-nil, it should be a character denoting the type of mark
1218 to move by.  The default is `ibuffer-marked-char'.
1219
1220 If DIRECTION is non-nil, it should be an integer; negative integers
1221 mean move backwards, non-negative integers mean move forwards."
1222   (interactive "P")
1223   (unless count
1224     (setq count 1))
1225   (unless mark
1226     (setq mark ibuffer-marked-char))
1227   (unless direction
1228     (setq direction 1))
1229   ;; Skip the title
1230   (ibuffer-forward-line 0)
1231   (let ((opos (point))
1232         curmark)
1233     (ibuffer-forward-line direction)
1234     (while (not (or (= (point) opos)
1235                     (eq (setq curmark (ibuffer-current-mark))
1236                         mark)))
1237       (ibuffer-forward-line direction))
1238     (when (and (= (point) opos)
1239                (not (eq (ibuffer-current-mark) mark)))
1240       (error "No buffers with mark %c" mark))))
1241
1242 ;;;###autoload
1243 (defun ibuffer-backwards-next-marked (&optional count mark)
1244    "Move backwards by COUNT marked buffers (default 1).
1245
1246 If MARK is non-nil, it should be a character denoting the type of mark
1247 to move by.  The default is `ibuffer-marked-char'."
1248    (interactive "P")
1249    (ibuffer-forward-next-marked count mark -1))
1250
1251 ;;;###autoload
1252 (defun ibuffer-do-kill-lines ()
1253   "Hide all of the currently marked lines."
1254   (interactive)
1255   (if (= (ibuffer-count-marked-lines) 0)
1256       (message "No buffers marked; use 'm' to mark a buffer")
1257     (let ((count
1258            (ibuffer-map-marked-lines
1259             #'(lambda (buf mark)
1260                 'kill))))
1261       (message "Killed %s lines" count))))
1262
1263 ;;;###autoload
1264 (defun ibuffer-jump-to-buffer (name)
1265   "Move point to the buffer whose name is NAME.
1266
1267 If called interactively, prompt for a buffer name and go to the
1268 corresponding line in the Ibuffer buffer.  If said buffer is in a
1269 hidden group filter, open it.
1270
1271 If `ibuffer-jump-offer-only-visible-buffers' is non-nil, only offer
1272 visible buffers in the completion list.  Calling the command with
1273 a prefix argument reverses the meaning of that variable."
1274   (interactive (list
1275                 (let ((only-visible ibuffer-jump-offer-only-visible-buffers))
1276                   (when current-prefix-arg
1277                     (setq only-visible (not only-visible)))
1278                   (if only-visible
1279                       (let ((table (mapcar #'(lambda (x)
1280                                                (buffer-name (car x)))
1281                                            (ibuffer-current-state-list))))
1282                         (when (null table)
1283                           (error "No buffers!"))
1284                         (completing-read "Jump to buffer: "
1285                                          table nil t))
1286                     (read-buffer "Jump to buffer: " nil t)))))
1287   (when (not (string= "" name))
1288     (let (buf-point)
1289       ;; Blindly search for our buffer: it is very likely that it is
1290       ;; not in a hidden filter group.
1291       (ibuffer-map-lines #'(lambda (buf marks)
1292                              (when (string= (buffer-name buf) name)
1293                                (setq buf-point (point))
1294                                nil))
1295                          t nil)
1296       (when (and
1297              (null buf-point)
1298              (not (null ibuffer-hidden-filter-groups)))
1299         ;; We did not find our buffer.  It must be in a hidden filter
1300         ;; group, so go through all hidden filter groups to find it.
1301         (catch 'found
1302           (dolist (group ibuffer-hidden-filter-groups)
1303             (ibuffer-jump-to-filter-group group)
1304             (ibuffer-toggle-filter-group)
1305             (ibuffer-map-lines #'(lambda (buf marks)
1306                                    (when (string= (buffer-name buf) name)
1307                                      (setq buf-point (point))
1308                                      nil))
1309                                t group)
1310             (if buf-point
1311                 (throw 'found nil)
1312               (ibuffer-toggle-filter-group)))))
1313       (if (null buf-point)
1314           ;; Still not found even though we expanded all hidden filter
1315           ;; groups: that must be because it's hidden by predicate:
1316           ;; we won't bother trying to display it.
1317           (error "No buffer with name %s" name)
1318         (goto-char buf-point)))))
1319
1320 ;;;###autoload
1321 (defun ibuffer-diff-with-file ()
1322   "View the differences between this buffer and its associated file.
1323 This requires the external program \"diff\" to be in your `exec-path'."
1324   (interactive)
1325   (let ((buf (ibuffer-current-buffer)))
1326     (unless (buffer-live-p buf)
1327       (error "Buffer %s has been killed" buf))
1328     (diff-buffer-with-file buf)))
1329
1330 ;;;###autoload
1331 (defun ibuffer-copy-filename-as-kill (&optional arg)
1332   "Copy filenames of marked buffers into the kill ring.
1333
1334 The names are separated by a space.
1335 If a buffer has no filename, it is ignored.
1336
1337 With no prefix arg, use the filename sans its directory of each marked file.
1338 With a zero prefix arg, use the complete filename of each marked file.
1339 With \\[universal-argument], use the filename of each marked file relative
1340 to `ibuffer-default-directory' if non-nil, otherwise `default-directory'.
1341
1342 You can then feed the file name(s) to other commands with \\[yank]."
1343   (interactive "p")
1344   (if (zerop (ibuffer-count-marked-lines))
1345       (message "No buffers marked; use 'm' to mark a buffer")
1346     (let ((ibuffer-copy-filename-as-kill-result "")
1347           (type (cond ((zerop arg)
1348                        'full)
1349                       ((= arg 4)
1350                        'relative)
1351                       (t
1352                        'name))))
1353       (ibuffer-map-marked-lines
1354        #'(lambda (buf mark)
1355            (setq ibuffer-copy-filename-as-kill-result
1356                  (concat ibuffer-copy-filename-as-kill-result
1357                          (let ((name (buffer-file-name buf)))
1358                            (if name
1359                                (case type
1360                                  (full
1361                                   name)
1362                                  (relative
1363                                   (file-relative-name
1364                                    name (or ibuffer-default-directory
1365                                             default-directory)))
1366                                  (t
1367                                   (file-name-nondirectory name)))
1368                              ""))
1369                          " "))))
1370       (kill-new ibuffer-copy-filename-as-kill-result))))
1371
1372 (defun ibuffer-mark-on-buffer (func &optional ibuffer-mark-on-buffer-mark group)
1373   (let ((count
1374          (ibuffer-map-lines
1375           #'(lambda (buf mark)
1376               (when (funcall func buf)
1377                 (ibuffer-set-mark-1 (or ibuffer-mark-on-buffer-mark
1378                                         ibuffer-marked-char))
1379                 t))
1380           nil
1381           group)))
1382     (ibuffer-redisplay t)
1383     (message "Marked %s buffers" count)))
1384
1385 ;;;###autoload
1386 (defun ibuffer-mark-by-name-regexp (regexp)
1387   "Mark all buffers whose name matches REGEXP."
1388   (interactive "sMark by name (regexp): ")
1389   (ibuffer-mark-on-buffer
1390    #'(lambda (buf)
1391        (string-match regexp (buffer-name buf)))))
1392
1393 ;;;###autoload
1394 (defun ibuffer-mark-by-mode-regexp (regexp)
1395   "Mark all buffers whose major mode matches REGEXP."
1396   (interactive "sMark by major mode (regexp): ")
1397   (ibuffer-mark-on-buffer
1398    #'(lambda (buf)
1399        (with-current-buffer buf
1400          (string-match regexp (format-mode-line mode-name nil nil buf))))))
1401
1402 ;;;###autoload
1403 (defun ibuffer-mark-by-file-name-regexp (regexp)
1404   "Mark all buffers whose file name matches REGEXP."
1405   (interactive "sMark by file name (regexp): ")
1406   (ibuffer-mark-on-buffer
1407    #'(lambda (buf)
1408        (let ((name (or (buffer-file-name buf)
1409                        (with-current-buffer buf
1410                          (and
1411                           (boundp 'dired-directory)
1412                           (stringp dired-directory)
1413                           dired-directory)))))
1414          (when name
1415            (string-match regexp name))))))
1416
1417 ;;;###autoload
1418 (defun ibuffer-mark-by-mode (mode)
1419   "Mark all buffers whose major mode equals MODE."
1420   (interactive
1421    (list (intern (completing-read "Mark by major mode: " obarray
1422                                   #'(lambda (e)
1423                                       ;; kind of a hack...
1424                                       (and (fboundp e)
1425                                            (string-match "-mode$"
1426                                                          (symbol-name e))))
1427                                   t
1428                                   (let ((buf (ibuffer-current-buffer)))
1429                                     (if (and buf (buffer-live-p buf))
1430                                         (with-current-buffer buf
1431                                           (cons (symbol-name major-mode)
1432                                                 0))
1433                                       ""))))))
1434   (ibuffer-mark-on-buffer
1435    #'(lambda (buf)
1436        (with-current-buffer buf
1437          (eq major-mode mode)))))
1438
1439 ;;;###autoload
1440 (defun ibuffer-mark-modified-buffers ()
1441   "Mark all modified buffers."
1442   (interactive)
1443   (ibuffer-mark-on-buffer
1444    #'(lambda (buf) (buffer-modified-p buf))))
1445
1446 ;;;###autoload
1447 (defun ibuffer-mark-unsaved-buffers ()
1448   "Mark all modified buffers that have an associated file."
1449   (interactive)
1450   (ibuffer-mark-on-buffer
1451    #'(lambda (buf) (and (with-current-buffer buf buffer-file-name)
1452                         (buffer-modified-p buf)))))
1453
1454 ;;;###autoload
1455 (defun ibuffer-mark-dissociated-buffers ()
1456   "Mark all buffers whose associated file does not exist."
1457   (interactive)
1458   (ibuffer-mark-on-buffer
1459    #'(lambda (buf)
1460        (with-current-buffer buf
1461          (or
1462           (and buffer-file-name
1463                (not (file-exists-p buffer-file-name)))
1464           (and (eq major-mode 'dired-mode)
1465                (boundp 'dired-directory)
1466                (stringp dired-directory)
1467                (not (file-exists-p (file-name-directory dired-directory)))))))))
1468
1469 ;;;###autoload
1470 (defun ibuffer-mark-help-buffers ()
1471   "Mark buffers like *Help*, *Apropos*, *Info*."
1472   (interactive)
1473   (ibuffer-mark-on-buffer
1474    #'(lambda (buf)
1475        (with-current-buffer buf
1476          (memq major-mode ibuffer-help-buffer-modes)))))
1477
1478 ;;;###autoload
1479 (defun ibuffer-mark-compressed-file-buffers ()
1480   "Mark buffers whose associated file is compressed."
1481   (interactive)
1482   (ibuffer-mark-on-buffer
1483    #'(lambda (buf)
1484        (with-current-buffer buf
1485          (and buffer-file-name
1486               (string-match ibuffer-compressed-file-name-regexp
1487                            buffer-file-name))))))
1488
1489 ;;;###autoload
1490 (defun ibuffer-mark-old-buffers ()
1491   "Mark buffers which have not been viewed in `ibuffer-old-time' hours."
1492   (interactive)
1493   (ibuffer-mark-on-buffer
1494    #'(lambda (buf)
1495        (with-current-buffer buf
1496          ;; hacked from midnight.el
1497          (when buffer-display-time
1498            (let* ((tm (current-time))
1499                   (now (+ (* (float (ash 1 16)) (car tm))
1500                           (float (cadr tm)) (* 0.0000001 (caddr tm))))
1501                   (then (+ (* (float (ash 1 16))
1502                               (car buffer-display-time))
1503                            (float (cadr buffer-display-time))
1504                            (* 0.0000001 (caddr buffer-display-time)))))
1505              (> (- now then) (* 60 60 ibuffer-old-time))))))))
1506
1507 ;;;###autoload
1508 (defun ibuffer-mark-special-buffers ()
1509   "Mark all buffers whose name begins and ends with '*'."
1510   (interactive)
1511   (ibuffer-mark-on-buffer
1512    #'(lambda (buf) (string-match "^\\*.+\\*$"
1513                                  (buffer-name buf)))))
1514
1515 ;;;###autoload
1516 (defun ibuffer-mark-read-only-buffers ()
1517   "Mark all read-only buffers."
1518   (interactive)
1519   (ibuffer-mark-on-buffer
1520    #'(lambda (buf)
1521        (with-current-buffer buf
1522          buffer-read-only))))
1523
1524 ;;;###autoload
1525 (defun ibuffer-mark-dired-buffers ()
1526   "Mark all `dired' buffers."
1527   (interactive)
1528   (ibuffer-mark-on-buffer
1529    #'(lambda (buf)
1530        (with-current-buffer buf
1531          (eq major-mode 'dired-mode)))))
1532
1533 ;;;###autoload
1534 (defun ibuffer-do-occur (regexp &optional nlines)
1535   "View lines which match REGEXP in all marked buffers.
1536 Optional argument NLINES says how many lines of context to display: it
1537 defaults to one."
1538   (interactive (occur-read-primary-args))
1539   (if (or (not (integerp nlines))
1540           (< nlines 0))
1541       (setq nlines 0))
1542   (when (zerop (ibuffer-count-marked-lines))
1543     (ibuffer-set-mark ibuffer-marked-char))
1544   (let ((ibuffer-do-occur-bufs nil))
1545     ;; Accumulate a list of marked buffers
1546     (ibuffer-map-marked-lines
1547      #'(lambda (buf mark)
1548          (push buf ibuffer-do-occur-bufs)))
1549     (occur-1 regexp nlines ibuffer-do-occur-bufs)))
1550
1551 (provide 'ibuf-ext)
1552
1553 ;; arch-tag: 9af21953-deda-4c30-b76d-f81d9128e76d
1554 ;;; ibuf-ext.el ends here