lisp/dired-x.el

   1 ;;; dired-x.el --- extra Dired functionality -*-byte-compile-dynamic: t;-*-
   2
   3 ;; Copyright (C) 1993, 1994, 1997, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Sebastian Kremer <sk@thp.uni-koeln.de>
   7 ;;      Lawrence R. Dodd <dodd@roebling.poly.edu>
   8 ;; Maintainer: Romain Francoise <rfrancoise@gnu.org>
   9 ;; Keywords: dired extensions files
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; This is Sebastian Kremer's excellent dired-x.el (Dired Extra), version
  29 ;; 1.191, hacked up for GNU Emacs.  Redundant or conflicting material has
  30 ;; been removed or renamed in order to work properly with dired of GNU
  31 ;; Emacs.  All suggestions or comments are most welcomed.
  32
  33 ;;
  34 ;; Please, PLEASE, *PLEASE* see the info pages.
  35 ;;
  36
  37 ;; BUGS: Type M-x dired-x-submit-report and a report will be generated.
  38
  39 ;; INSTALLATION: In your ~/.emacs,
  40 ;;
  41 ;; (add-hook 'dired-load-hook
  42 ;;           (function (lambda ()
  43 ;;                       (load "dired-x")
  44 ;;                       ;; Set global variables here.  For example:
  45 ;;                       ;; (setq dired-guess-shell-gnutar "gtar")
  46 ;;                       )))
  47 ;; (add-hook 'dired-mode-hook
  48 ;;           (function (lambda ()
  49 ;;                       ;; Set buffer-local variables here.  For example:
  50 ;;                       ;; (dired-omit-mode 1)
  51 ;;                       )))
  52 ;;
  53 ;; At load time dired-x.el will install itself, redefine some functions, and
  54 ;; bind some dired keys.  *Please* see the info pages for more details.
  55
  56 ;; *Please* see the info pages for more details.
  57
  58 ;; User defined variables:
  59 ;;
  60 ;;      dired-bind-vm
  61 ;;      dired-vm-read-only-folders
  62 ;;      dired-bind-jump
  63 ;;      dired-bind-info
  64 ;;      dired-bind-man
  65 ;;      dired-x-hands-off-my-keys
  66 ;;      dired-find-subdir
  67 ;;      dired-enable-local-variables
  68 ;;      dired-local-variables-file
  69 ;;      dired-guess-shell-gnutar
  70 ;;      dired-guess-shell-gzip-quiet
  71 ;;      dired-guess-shell-znew-switches
  72 ;;      dired-guess-shell-alist-user
  73 ;;      dired-clean-up-buffers-too
  74 ;;      dired-omit-mode
  75 ;;      dired-omit-files
  76 ;;      dired-omit-extensions
  77 ;;      dired-omit-size-limit
  78 ;;
  79 ;; To find out more about these variables, load this file, put your cursor at
  80 ;; the end of any of the variable names, and hit C-h v [RET].  *Please* see
  81 ;; the info pages for more details.
  82
  83 ;; When loaded this code redefines the following functions of GNU Emacs
  84 ;;
  85 ;;   Function                         Found in this file of GNU Emacs
  86 ;;   --------                         -------------------------------
  87 ;;   dired-clean-up-after-deletion    ../lisp/dired.el
  88 ;;   dired-find-buffer-nocreate       ../lisp/dired.el
  89 ;;   dired-initial-position           ../lisp/dired.el
  90 ;;
  91 ;;   dired-add-entry                  ../lisp/dired-aux.el
  92 ;;   dired-read-shell-command         ../lisp/dired-aux.el
  93
  94 \f
  95 ;;; Code:
  96
  97 ;; LOAD.
  98
  99 ;; This is a no-op if dired-x is being loaded via `dired-load-hook'.  It is
 100 ;; here in case the user has autoloaded dired-x via the dired-jump key binding
 101 ;; (instead of autoloading to dired as is suggested in the info-pages).
 102
 103 (require 'dired)
 104
 105 ;; We will redefine some functions and also need some macros so we need to
 106 ;; load dired stuff of GNU Emacs.
 107
 108 (require 'dired-aux)
 109
 110 (defvar vm-folder-directory)
 111 (eval-when-compile (require 'man))
 112
 113 ;;; User-defined variables.
 114
 115 (defgroup dired-x nil
 116   "Extended directory editing (dired-x)."
 117   :group 'dired)
 118
 119 (defgroup dired-keys nil
 120   "Dired keys customizations."
 121   :prefix "dired-"
 122   :group 'dired-x)
 123
 124 (defcustom dired-bind-vm nil
 125   "*Non-nil means \"V\" runs `dired-vm', otherwise \"V\" runs `dired-rmail'.
 126 Also, RMAIL files contain -*- rmail -*- at the top so \"f\",
 127 `dired-advertised-find-file', will run rmail."
 128   :type 'boolean
 129   :group 'dired-keys)
 130
 131 (defcustom dired-bind-jump t
 132   "*Non-nil means bind `dired-jump' to C-x C-j, otherwise do not."
 133   :type 'boolean
 134   :group 'dired-keys)
 135
 136 (defcustom dired-bind-man t
 137   "*Non-nil means bind `dired-man' to \"N\" in dired-mode, otherwise do not."
 138   :type 'boolean
 139   :group 'dired-keys)
 140
 141 (defcustom dired-bind-info t
 142   "*Non-nil means bind `dired-info' to \"I\" in dired-mode, otherwise do not."
 143   :type 'boolean
 144   :group 'dired-keys)
 145
 146 (defcustom dired-vm-read-only-folders nil
 147   "*If non-nil, \\[dired-vm] will visit all folders read-only.
 148 If neither nil nor t, e.g. the symbol `if-file-read-only', only
 149 files not writable by you are visited read-only.
 150
 151 Read-only folders only work in VM 5, not in VM 4."
 152   :type '(choice (const :tag "off" nil)
 153                  (const :tag "on" t)
 154                  (other :tag "non-writable only" if-file-read-only))
 155   :group 'dired-x)
 156
 157 (define-minor-mode dired-omit-mode
 158   "Toggle Dired-Omit mode.
 159 With numeric ARG, enable Dired-Omit mode if ARG is positive, disable
 160 otherwise.  Enabling and disabling is buffer-local.
 161 If enabled, \"uninteresting\" files are not listed.
 162 Uninteresting files are those whose filenames match regexp `dired-omit-files',
 163 plus those ending with extensions in `dired-omit-extensions'."
 164   :group 'dired-x
 165   (if dired-omit-mode
 166       ;; This will mention how many lines were omitted:
 167       (let ((dired-omit-size-limit nil)) (dired-omit-expunge))
 168     (revert-buffer)))
 169
 170 ;; For backward compatibility
 171 (define-obsolete-variable-alias 'dired-omit-files-p 'dired-omit-mode "22.1")
 172
 173 (defcustom dired-omit-files "^\\.?#\\|^\\.$\\|^\\.\\.$"
 174   "*Filenames matching this regexp will not be displayed.
 175 This only has effect when `dired-omit-mode' is t.  See interactive function
 176 `dired-omit-mode' \(\\[dired-omit-mode]\) and variable
 177 `dired-omit-extensions'.  The default is to omit  `.', `..', auto-save
 178 files and lock files."
 179   :type 'regexp
 180   :group 'dired-x)
 181
 182 (defcustom dired-find-subdir nil           ; t is pretty near to DWIM...
 183   "*If non-nil, Dired always finds a directory in a buffer of its own.
 184 If nil, Dired finds the directory as a subdirectory in some other buffer
 185 if it is present as one.
 186
 187 If there are several dired buffers for a directory, the most recently
 188 used is chosen.
 189
 190 Dired avoids switching to the current buffer, so that if you have
 191 a normal and a wildcard buffer for the same directory, \\[dired] will
 192 toggle between those two."
 193   :type 'boolean
 194   :group 'dired-x)
 195
 196 (defcustom dired-omit-size-limit 30000
 197   "*Maximum size for the \"omitting\" feature.
 198 If nil, there is no maximum size."
 199   :type '(choice (const :tag "no maximum" nil) integer)
 200   :group 'dired-x)
 201
 202 (defcustom dired-enable-local-variables t
 203   "*Control use of local-variables lists in Dired.
 204 The value can be t, nil or something else.
 205 A value of t means local-variables lists are obeyed;
 206 nil means they are ignored; anything else means query.
 207
 208 This temporarily overrides the value of `enable-local-variables' when listing
 209 a directory.  See also `dired-local-variables-file'."
 210   :type 'boolean
 211   :group 'dired-x)
 212
 213 (defcustom dired-guess-shell-gnutar (when (or (eq system-type 'gnu)
 214                                               (eq system-type 'gnu/linux))
 215                                       "tar")
 216   "*If non-nil, name of GNU tar executable.
 217 \(E.g., \"tar\" or \"gtar\").  The `z' switch will be used with it for
 218 compressed or gzip'ed tar files.  If you don't have GNU tar, set this
 219 to nil: a pipe using `zcat' or `gunzip -c' will be used."
 220   :type '(choice (const :tag "Not GNU tar" nil)
 221                  (string :tag "Command name"))
 222   :group 'dired-x)
 223
 224 (defcustom dired-guess-shell-gzip-quiet t
 225   "*Non-nil says pass -q to gzip overriding verbose GZIP environment."
 226   :type 'boolean
 227   :group 'dired-x)
 228
 229 (defcustom dired-guess-shell-znew-switches nil
 230   "*If non-nil, then string of switches passed to `znew', example: \"-K\"."
 231   :type '(choice (const :tag "None" nil)
 232                  (string :tag "Switches"))
 233   :group 'dired-x)
 234
 235 (defcustom dired-clean-up-buffers-too t
 236   "*Non-nil means offer to kill buffers visiting files and dirs deleted in Dired."
 237   :type 'boolean
 238   :group 'dired-x)
 239
 240 ;;; KEY BINDINGS.
 241
 242 (define-key dired-mode-map "\M-o" 'dired-omit-mode)
 243 (define-key dired-mode-map "*O" 'dired-mark-omitted)
 244 (define-key dired-mode-map "\M-(" 'dired-mark-sexp)
 245 (define-key dired-mode-map "*(" 'dired-mark-sexp)
 246 (define-key dired-mode-map "*." 'dired-mark-extension)
 247 (define-key dired-mode-map "\M-!" 'dired-smart-shell-command)
 248 (define-key dired-mode-map "w" 'dired-copy-filename-as-kill)
 249 (define-key dired-mode-map "\M-G" 'dired-goto-subdir)
 250 (define-key dired-mode-map "F" 'dired-do-find-marked-files)
 251 (define-key dired-mode-map "Y"  'dired-do-relsymlink)
 252 (define-key dired-mode-map "%Y" 'dired-do-relsymlink-regexp)
 253 (define-key dired-mode-map "V" 'dired-do-run-mail)
 254
 255 (if dired-bind-man
 256     (define-key dired-mode-map "N" 'dired-man))
 257
 258 (if dired-bind-info
 259     (define-key dired-mode-map "I" 'dired-info))
 260
 261 ;;; MENU BINDINGS
 262
 263 (let ((menu-bar (lookup-key dired-mode-map [menu-bar])))
 264   (let ((menu (lookup-key menu-bar [operate])))
 265     (define-key-after
 266       menu
 267       [find-files]
 268       '(menu-item
 269         "Find files"
 270         dired-do-find-marked-files
 271         :help "Find current or marked files")
 272       'delete)
 273     (define-key-after
 274       menu
 275       [relsymlink]
 276       '(menu-item
 277         "Relative symlink to..."
 278         dired-do-relsymlink
 279         :visible (fboundp 'make-symbolic-link)
 280         :help "Make relative symbolic links for current or marked files")
 281       'symlink))
 282   (let ((menu (lookup-key menu-bar [mark])))
 283     (define-key-after
 284       menu
 285       [flag-extension]
 286       '(menu-item
 287         "Flag extension..."
 288         dired-flag-extension
 289         :help "Flag files with a certain extension for deletion")
 290       'garbage-files)
 291     (define-key-after
 292       menu
 293       [mark-extension]
 294       '(menu-item
 295         "Mark extension..."
 296         dired-mark-extension
 297         :help "Mark files with a certain extension")
 298       'symlinks)
 299     (define-key-after
 300       menu
 301       [mark-omitted]
 302       '(menu-item
 303         "Mark omitted"
 304         dired-mark-omitted
 305         :help "Mark files matching `dired-omit-files' and `dired-omit-extensions'")
 306       'mark-extension))
 307   (let ((menu (lookup-key menu-bar [regexp])))
 308     (define-key-after
 309       menu
 310       [relsymlink-regexp]
 311       '(menu-item
 312         "Relative symlink..."
 313         dired-do-relsymlink-regexp
 314         :visible (fboundp 'make-symbolic-link)
 315         :help "Make relative symbolic links for files matching regexp")
 316       'symlink))
 317   (let ((menu (lookup-key menu-bar [immediate])))
 318     (define-key-after
 319       menu
 320       [omit-mode]
 321       '(menu-item
 322         "Omit mode" dired-omit-mode
 323         :button (:toggle . dired-omit-mode)
 324         :help "Enable or disable omitting \"uninteresting\" files")
 325       'dashes)))
 326
 327 ;;; GLOBAL BINDING.
 328 (if dired-bind-jump
 329     (progn
 330       (define-key global-map "\C-x\C-j" 'dired-jump)
 331       (define-key global-map "\C-x4\C-j" 'dired-jump-other-window)))
 332
 333 \f
 334 ;;; Install into appropriate hooks.
 335
 336 (add-hook 'dired-mode-hook 'dired-extra-startup)
 337 (add-hook 'dired-after-readin-hook 'dired-omit-expunge)
 338
 339 (defun dired-extra-startup ()
 340   "Automatically put on `dired-mode-hook' to get extra Dired features:
 341 \\<dired-mode-map>
 342   \\[dired-do-run-mail]\t-- run mail on folder (see `dired-bind-vm')
 343   \\[dired-info]\t-- run info on file
 344   \\[dired-man]\t-- run man on file
 345   \\[dired-do-find-marked-files]\t-- visit all marked files simultaneously
 346   \\[dired-omit-mode]\t-- toggle omitting of files
 347   \\[dired-mark-sexp]\t-- mark by Lisp expression
 348   \\[dired-copy-filename-as-kill]\t-- copy the file or subdir names into the kill ring;
 349   \t   you can feed it to other commands using \\[yank]
 350
 351 For more features, see variables
 352
 353   `dired-bind-vm'
 354   `dired-bind-jump'
 355   `dired-bind-info'
 356   `dired-bind-man'
 357   `dired-vm-read-only-folders'
 358   `dired-omit-mode'
 359   `dired-omit-files'
 360   `dired-omit-extensions'
 361   `dired-omit-size-limit'
 362   `dired-find-subdir'
 363   `dired-enable-local-variables'
 364   `dired-local-variables-file'
 365   `dired-guess-shell-gnutar'
 366   `dired-guess-shell-gzip-quiet'
 367   `dired-guess-shell-znew-switches'
 368   `dired-guess-shell-alist-user'
 369   `dired-clean-up-buffers-too'
 370
 371 See also functions
 372
 373   `dired-flag-extension'
 374   `dired-virtual'
 375   `dired-jump'
 376   `dired-man'
 377   `dired-vm'
 378   `dired-rmail'
 379   `dired-info'
 380   `dired-do-find-marked-files'"
 381   (interactive)
 382
 383   ;; These must be done in each new dired buffer.
 384   (dired-hack-local-variables)
 385   (dired-omit-startup))
 386
 387 \f
 388 ;;; BUFFER CLEANING.
 389
 390 ;; REDEFINE.
 391 (defun dired-clean-up-after-deletion (fn)
 392   "Clean up after a deleted file or directory FN.
 393 Remove expanded subdir of deleted dir, if any."
 394   (save-excursion (and (cdr dired-subdir-alist)
 395                        (dired-goto-subdir fn)
 396                        (dired-kill-subdir)))
 397
 398   ;; Offer to kill buffer of deleted file FN.
 399   (if dired-clean-up-buffers-too
 400       (progn
 401         (let ((buf (get-file-buffer fn)))
 402           (and buf
 403                (funcall (function y-or-n-p)
 404                         (format "Kill buffer of %s, too? "
 405                                 (file-name-nondirectory fn)))
 406                (save-excursion ; you never know where kill-buffer leaves you
 407                  (kill-buffer buf))))
 408         (let ((buf-list (dired-buffers-for-dir (expand-file-name fn)))
 409               (buf nil))
 410           (and buf-list
 411                (y-or-n-p (format "Kill dired buffer%s of %s, too? "
 412                                  (dired-plural-s (length buf-list))
 413                                  (file-name-nondirectory fn)))
 414                (while buf-list
 415                  (save-excursion (kill-buffer (car buf-list)))
 416                  (setq buf-list (cdr buf-list)))))))
 417   ;; Anything else?
 418   )
 419
 420 \f
 421 ;;; EXTENSION MARKING FUNCTIONS.
 422
 423 ;;; Mark files with some extension.
 424 (defun dired-mark-extension (extension &optional marker-char)
 425   "Mark all files with a certain EXTENSION for use in later commands.
 426 A `.' is *not* automatically prepended to the string entered."
 427   ;; EXTENSION may also be a list of extensions instead of a single one.
 428   ;; Optional MARKER-CHAR is marker to use.
 429   (interactive "sMarking extension: \nP")
 430   (or (listp extension)
 431       (setq extension (list extension)))
 432   (dired-mark-files-regexp
 433    (concat ".";; don't match names with nothing but an extension
 434            "\\("
 435            (mapconcat 'regexp-quote extension "\\|")
 436            "\\)$")
 437    marker-char))
 438
 439 (defun dired-flag-extension (extension)
 440   "In dired, flag all files with a certain EXTENSION for deletion.
 441 A `.' is *not* automatically prepended to the string entered."
 442   (interactive "sFlagging extension: ")
 443   (dired-mark-extension extension dired-del-marker))
 444
 445 ;;; Define some unpopular file extensions.  Used for cleaning and omitting.
 446
 447 (defvar dired-patch-unclean-extensions
 448   '(".rej" ".orig")
 449   "List of extensions of dispensable files created by the `patch' program.")
 450
 451 (defvar dired-tex-unclean-extensions
 452   '(".toc" ".log" ".aux");; these are already in completion-ignored-extensions
 453   "List of extensions of dispensable files created by TeX.")
 454
 455 (defvar dired-latex-unclean-extensions
 456   '(".idx" ".lof" ".lot" ".glo")
 457   "List of extensions of dispensable files created by LaTeX.")
 458
 459 (defvar dired-bibtex-unclean-extensions
 460   '(".blg" ".bbl")
 461   "List of extensions of dispensable files created by BibTeX.")
 462
 463 (defvar dired-texinfo-unclean-extensions
 464   '(".cp" ".cps" ".fn" ".fns" ".ky" ".kys" ".pg" ".pgs"
 465     ".tp" ".tps" ".vr" ".vrs")
 466   "List of extensions of dispensable files created by texinfo.")
 467
 468 (defun dired-clean-patch ()
 469   "Flag dispensable files created by patch for deletion.
 470 See variable `dired-patch-unclean-extensions'."
 471   (interactive)
 472   (dired-flag-extension dired-patch-unclean-extensions))
 473
 474 (defun dired-clean-tex ()
 475   "Flag dispensable files created by [La]TeX etc. for deletion.
 476 See variables `dired-tex-unclean-extensions',
 477 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 478 `dired-texinfo-unclean-extensions'."
 479   (interactive)
 480   (dired-flag-extension (append dired-texinfo-unclean-extensions
 481                                 dired-latex-unclean-extensions
 482                                 dired-bibtex-unclean-extensions
 483                                 dired-tex-unclean-extensions)))
 484
 485 (defun dired-very-clean-tex ()
 486   "Flag dispensable files created by [La]TeX *and* \".dvi\" for deletion.
 487 See variables `dired-texinfo-unclean-extensions',
 488 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 489 `dired-texinfo-unclean-extensions'."
 490   (interactive)
 491   (dired-flag-extension (append dired-texinfo-unclean-extensions
 492                                 dired-latex-unclean-extensions
 493                                 dired-bibtex-unclean-extensions
 494                                 dired-tex-unclean-extensions
 495                                 (list ".dvi"))))
 496 \f
 497 ;;; JUMP.
 498
 499 ;;;###autoload
 500 (defun dired-jump (&optional other-window)
 501   "Jump to dired buffer corresponding to current buffer.
 502 If in a file, dired the current directory and move to file's line.
 503 If in Dired already, pop up a level and goto old directory's line.
 504 In case the proper dired file line cannot be found, refresh the dired
 505 buffer and try again."
 506   (interactive "P")
 507   (let* ((file buffer-file-name)
 508          (dir (if file (file-name-directory file) default-directory)))
 509     (if (eq major-mode 'dired-mode)
 510         (progn
 511           (setq dir (dired-current-directory))
 512           (dired-up-directory other-window)
 513           (or (dired-goto-file dir)
 514               ;; refresh and try again
 515               (progn
 516                 (dired-insert-subdir (file-name-directory dir))
 517                 (dired-goto-file dir))))
 518       (if other-window
 519           (dired-other-window dir)
 520         (dired dir))
 521       (if file
 522           (or (dired-goto-file file)
 523               ;; refresh and try again
 524               (progn
 525                 (dired-insert-subdir (file-name-directory file))
 526                 (dired-goto-file file))
 527               ;; Toggle omitting, if it is on, and try again.
 528               (if dired-omit-mode
 529                   (progn
 530                     (dired-omit-mode)
 531                     (dired-goto-file file))))))))
 532
 533 (defun dired-jump-other-window ()
 534   "Like \\[dired-jump] (`dired-jump') but in other window."
 535   (interactive)
 536   (dired-jump t))
 537 \f
 538 ;;; OMITTING.
 539
 540 ;;; Enhanced omitting of lines from directory listings.
 541 ;;; Marked files are never omitted.
 542
 543 ;; should probably get rid of this and always use 'no-dir.
 544 ;; sk 28-Aug-1991 09:37
 545 (defvar dired-omit-localp 'no-dir
 546   "The LOCALP argument `dired-omit-expunge' passes to `dired-get-filename'.
 547 If it is `no-dir', omitting is much faster, but you can only match
 548 against the non-directory part of the file name.  Set it to nil if you
 549 need to match the entire file name.")
 550
 551 ;; \017=^O for Omit - other packages can chose other control characters.
 552 (defvar dired-omit-marker-char ?\017
 553   "Temporary marker used by dired-omit.
 554 Should never be used as marker by the user or other packages.")
 555
 556 (defun dired-omit-startup ()
 557   (or (assq 'dired-omit-mode minor-mode-alist)
 558       (setq minor-mode-alist
 559             (append '((dired-omit-mode
 560                        (:eval (if (eq major-mode 'dired-mode)
 561                                   " Omit" ""))))
 562                     minor-mode-alist))))
 563
 564 (defun dired-mark-omitted ()
 565   "Mark files matching `dired-omit-files' and `dired-omit-extensions'."
 566   (interactive)
 567   (let ((dired-omit-mode nil)) (revert-buffer)) ;; Show omitted files
 568   (dired-mark-unmarked-files (dired-omit-regexp) nil nil dired-omit-localp))
 569
 570 (defvar dired-omit-extensions
 571   (append completion-ignored-extensions
 572           dired-latex-unclean-extensions
 573           dired-bibtex-unclean-extensions
 574           dired-texinfo-unclean-extensions)
 575   "If non-nil, a list of extensions \(strings\) to omit from Dired listings.
 576 Defaults to elements of `completion-ignored-extensions',
 577 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions', and
 578 `dired-texinfo-unclean-extensions'.
 579
 580 See interactive function `dired-omit-mode' \(\\[dired-omit-mode]\) and
 581 variables `dired-omit-mode' and `dired-omit-files'.")
 582
 583 (defun dired-omit-expunge (&optional regexp)
 584   "Erases all unmarked files matching REGEXP.
 585 Does nothing if global variable `dired-omit-mode' is nil, or if called
 586   non-interactively and buffer is bigger than `dired-omit-size-limit'.
 587 If REGEXP is nil or not specified, uses `dired-omit-files', and also omits
 588   filenames ending in `dired-omit-extensions'.
 589 If REGEXP is the empty string, this function is a no-op.
 590
 591 This functions works by temporarily binding `dired-marker-char' to
 592 `dired-omit-marker-char' and calling `dired-do-kill-lines'."
 593   (interactive "sOmit files (regexp): ")
 594   (if (and dired-omit-mode
 595            (or (interactive-p)
 596                (not dired-omit-size-limit)
 597                (< (buffer-size) dired-omit-size-limit)
 598                (progn
 599                  (message "Not omitting: directory larger than %d characters."
 600                           dired-omit-size-limit)
 601                  (setq dired-omit-mode nil)
 602                  nil)))
 603       (let ((omit-re (or regexp (dired-omit-regexp)))
 604             (old-modified-p (buffer-modified-p))
 605             count)
 606         (or (string= omit-re "")
 607             (let ((dired-marker-char dired-omit-marker-char))
 608               (message "Omitting...")
 609               (if (dired-mark-unmarked-files omit-re nil nil dired-omit-localp)
 610                   (progn
 611                     (setq count (dired-do-kill-lines nil "Omitted %d line%s."))
 612                     (force-mode-line-update))
 613                 (message "(Nothing to omit)"))))
 614         ;; Try to preserve modified state of buffer.  So `%*' doesn't appear
 615         ;; in mode-line of omitted buffers.
 616         (set-buffer-modified-p (and old-modified-p
 617                                     (save-excursion
 618                                       (goto-char (point-min))
 619                                       (re-search-forward dired-re-mark nil t))))
 620         count)))
 621
 622 (defun dired-omit-regexp ()
 623   (concat (if dired-omit-files (concat "\\(" dired-omit-files "\\)") "")
 624           (if (and dired-omit-files dired-omit-extensions) "\\|" "")
 625           (if dired-omit-extensions
 626               (concat ".";; a non-extension part should exist
 627                       "\\("
 628                       (mapconcat 'regexp-quote dired-omit-extensions "\\|")
 629                       "\\)$")
 630             "")))
 631
 632 ;; Returns t if any work was done, nil otherwise.
 633 (defun dired-mark-unmarked-files (regexp msg &optional unflag-p localp)
 634   "Mark unmarked files matching REGEXP, displaying MSG.
 635 REGEXP is matched against the entire file name.
 636 Does not re-mark files which already have a mark.
 637 With prefix argument, unflag all those files.
 638 Optional fourth argument LOCALP is as in `dired-get-filename'."
 639   (interactive "P")
 640   (let ((dired-marker-char (if unflag-p ?\s dired-marker-char)))
 641     (dired-mark-if
 642      (and
 643       ;; not already marked
 644       (looking-at " ")
 645       ;; uninteresting
 646       (let ((fn (dired-get-filename localp t)))
 647         (and fn (string-match regexp fn))))
 648      msg)))
 649
 650 ;; Compiler does not get fset.
 651 (declare-function dired-omit-old-add-entry "dired-x")
 652
 653 ;;; REDEFINE.
 654 ;;; Redefine dired-aux.el's version of `dired-add-entry'
 655 ;;; Save old defun if not already done:
 656 (or (fboundp 'dired-omit-old-add-entry)
 657     (fset 'dired-omit-old-add-entry (symbol-function 'dired-add-entry)))
 658
 659 ;;; REDEFINE.
 660 (defun dired-omit-new-add-entry (filename &optional marker-char relative)
 661   ;; This redefines dired-aux.el's dired-add-entry to avoid calling ls for
 662   ;; files that are going to be omitted anyway.
 663   (if dired-omit-mode
 664       ;; perhaps return t without calling ls
 665       (let ((omit-re (dired-omit-regexp)))
 666         (if (or (string= omit-re "")
 667                 (not
 668                  (string-match omit-re
 669                                (cond
 670                                 ((eq 'no-dir dired-omit-localp)
 671                                  filename)
 672                                 ((eq t dired-omit-localp)
 673                                  (dired-make-relative filename))
 674                                 (t
 675                                  (dired-make-absolute
 676                                   filename
 677                                   (file-name-directory filename)))))))
 678             ;; if it didn't match, go ahead and add the entry
 679             (dired-omit-old-add-entry filename marker-char relative)
 680           ;; dired-add-entry returns t for success, perhaps we should
 681           ;; return file-exists-p
 682           t))
 683     ;; omitting is not turned on at all
 684     (dired-omit-old-add-entry filename marker-char relative)))
 685
 686 ;; Redefine it.
 687 (fset 'dired-add-entry 'dired-omit-new-add-entry)
 688
 689 \f
 690 ;;; VIRTUAL DIRED MODE.
 691
 692 ;;; For browsing `ls -lR' listings in a dired-like fashion.
 693
 694 (defalias 'virtual-dired 'dired-virtual)
 695 (defun dired-virtual (dirname &optional switches)
 696   "Put this buffer into Virtual Dired mode.
 697
 698 In Virtual Dired mode, all commands that do not actually consult the
 699 filesystem will work.
 700
 701 This is useful if you want to peruse and move around in an ls -lR
 702 output file, for example one you got from an ftp server.  With
 703 ange-ftp, you can even dired a directory containing an ls-lR file,
 704 visit that file and turn on virtual dired mode.  But don't try to save
 705 this file, as dired-virtual indents the listing and thus changes the
 706 buffer.
 707
 708 If you have save a Dired buffer in a file you can use \\[dired-virtual] to
 709 resume it in a later session.
 710
 711 Type \\<dired-mode-map>\\[revert-buffer] \
 712 in the Virtual Dired buffer and answer `y' to convert
 713 the virtual to a real dired buffer again.  You don't have to do this, though:
 714 you can relist single subdirs using \\[dired-do-redisplay]."
 715
 716   ;; DIRNAME is the top level directory of the buffer.  It will become
 717   ;; its `default-directory'.  If nil, the old value of
 718   ;; default-directory is used.
 719
 720   ;; Optional SWITCHES are the ls switches to use.
 721
 722   ;; Shell wildcards will be used if there already is a `wildcard'
 723   ;; line in the buffer (thus it is a saved Dired buffer), but there
 724   ;; is no other way to get wildcards.  Insert a `wildcard' line by
 725   ;; hand if you want them.
 726
 727   (interactive
 728    (list (read-string "Virtual Dired directory: " (dired-virtual-guess-dir))))
 729   (goto-char (point-min))
 730   (or (looking-at "  ")
 731       ;; if not already indented, do it now:
 732       (indent-region (point-min) (point-max) 2))
 733   (or dirname (setq dirname default-directory))
 734   (setq dirname (expand-file-name (file-name-as-directory dirname)))
 735   (setq default-directory dirname)      ; contains no wildcards
 736   (let ((wildcard (save-excursion
 737                     (goto-char (point-min))
 738                     (forward-line 1)
 739                     (and (looking-at "^  wildcard ")
 740                          (buffer-substring (match-end 0)
 741                                            (progn (end-of-line) (point)))))))
 742   (if wildcard
 743         (setq dirname (expand-file-name wildcard default-directory))))
 744   ;; If raw ls listing (not a saved old dired buffer), give it a
 745   ;; decent subdir headerline:
 746   (goto-char (point-min))
 747   (or (looking-at dired-subdir-regexp)
 748       (insert "  "
 749               (directory-file-name (file-name-directory default-directory))
 750               ":\n"))
 751   (dired-mode dirname (or switches dired-listing-switches))
 752   (setq mode-name "Virtual Dired"
 753         revert-buffer-function 'dired-virtual-revert)
 754   (set (make-local-variable 'dired-subdir-alist) nil)
 755   (dired-build-subdir-alist)
 756   (goto-char (point-min))
 757   (dired-initial-position dirname))
 758
 759 (defun dired-virtual-guess-dir ()
 760   "Guess and return appropriate working directory of this buffer.
 761 The buffer is assumed to be in Dired or ls -lR format.  The guess is
 762 based upon buffer contents.  If nothing could be guessed, returns
 763 nil."
 764
 765   (let ((regexp "^\\(  \\)?\\([^ \n\r]*\\)\\(:\\)[\n\r]")
 766         (subexpr 2))
 767     (goto-char (point-min))
 768     (cond ((looking-at regexp)
 769            ;; If a saved dired buffer, look to which dir and
 770            ;; perhaps wildcard it belongs:
 771            (let ((dir (buffer-substring (match-beginning subexpr)
 772                                         (match-end subexpr))))
 773              (file-name-as-directory dir)))
 774           ;; Else no match for headerline found.  It's a raw ls listing.
 775           ;; In raw ls listings the directory does not have a headerline
 776           ;; try parent of first subdir, if any
 777           ((re-search-forward regexp nil t)
 778            (file-name-directory
 779             (directory-file-name
 780              (file-name-as-directory
 781               (buffer-substring (match-beginning subexpr)
 782                                 (match-end subexpr))))))
 783           (t                            ; if all else fails
 784            nil))))
 785
 786
 787 (defun dired-virtual-revert (&optional arg noconfirm)
 788   (if (not
 789        (y-or-n-p "Cannot revert a Virtual Dired buffer - switch to Real Dired mode? "))
 790       (error "Cannot revert a Virtual Dired buffer")
 791     (setq mode-name "Dired"
 792           revert-buffer-function 'dired-revert)
 793     (revert-buffer)))
 794
 795 ;; A zero-arg version of dired-virtual.
 796 (defun dired-virtual-mode ()
 797   "Put current buffer into Virtual Dired mode (see `dired-virtual').
 798 Useful on `magic-mode-alist' with the regexp
 799
 800   \"^  \\\\(/[^ /]+\\\\)+/?:$\"
 801
 802 to put saved dired buffers automatically into Virtual Dired mode.
 803
 804 Also useful for `auto-mode-alist' like this:
 805
 806   (add-to-list 'auto-mode-alist
 807                '(\"[^/]\\\\.dired\\\\'\" . dired-virtual-mode))"
 808   (interactive)
 809   (dired-virtual (dired-virtual-guess-dir)))
 810
 811 \f
 812 ;;; SMART SHELL.
 813
 814 ;;; An Emacs buffer can have but one working directory, stored in the
 815 ;;; buffer-local variable `default-directory'.  A Dired buffer may have
 816 ;;; several subdirectories inserted, but still has but one working directory:
 817 ;;; that of the top level Dired directory in that buffer.  For some commands
 818 ;;; it is appropriate that they use the current Dired directory instead of
 819 ;;; `default-directory', e.g., `find-file' and `compile'.  This is a general
 820 ;;; mechanism is provided for special handling of the working directory in
 821 ;;; special major modes.
 822
 823 ;; It's easier to add to this alist than redefine function
 824 ;; default-directory while keeping the old information.
 825 (defconst default-directory-alist
 826   '((dired-mode . (if (fboundp 'dired-current-directory)
 827                       (dired-current-directory)
 828                     default-directory)))
 829   "Alist of major modes and their opinion on `default-directory'.
 830 This is given as a Lisp expression to evaluate.  A resulting value of
 831 nil is ignored in favor of `default-directory'.")
 832
 833 (defun dired-default-directory ()
 834   "Usage like variable `default-directory'.
 835 Knows about the special cases in variable `default-directory-alist'."
 836   (or (eval (cdr (assq major-mode default-directory-alist)))
 837       default-directory))
 838
 839 (defun dired-smart-shell-command (command &optional output-buffer error-buffer)
 840   "Like function `shell-command', but in the current Virtual Dired directory."
 841   (interactive
 842    (list
 843     (minibuffer-with-setup-hook
 844         (lambda ()
 845           (set (make-local-variable 'minibuffer-default-add-function)
 846                'minibuffer-default-add-shell-commands))
 847       (read-shell-command "Shell command: " nil nil
 848                           (cond
 849                            (buffer-file-name (file-relative-name buffer-file-name))
 850                            ((eq major-mode 'dired-mode) (dired-get-filename t t)))))
 851     current-prefix-arg
 852     shell-command-default-error-buffer))
 853   (let ((default-directory (dired-default-directory)))
 854     (shell-command command output-buffer error-buffer)))
 855
 856 \f
 857 ;;; LOCAL VARIABLES FOR DIRED BUFFERS.
 858
 859 ;;; Brief Description:
 860 ;;;
 861 ;;; * `dired-extra-startup' is part of the `dired-mode-hook'.
 862 ;;;
 863 ;;; * `dired-extra-startup' calls `dired-hack-local-variables'
 864 ;;;
 865 ;;; * `dired-hack-local-variables' checks the value of
 866 ;;;   `dired-local-variables-file'
 867 ;;;
 868 ;;; * Check if `dired-local-variables-file' is a non-nil string and is a
 869 ;;;   filename found in the directory of the Dired Buffer being created.
 870 ;;;
 871 ;;; * If `dired-local-variables-file' satisfies the above, then temporarily
 872 ;;;   include it in the Dired Buffer at the bottom.
 873 ;;;
 874 ;;; * Set `enable-local-variables' temporarily to the user variable
 875 ;;;   `dired-enable-local-variables' and run `hack-local-variables' on the
 876 ;;;   Dired Buffer.
 877
 878 (defvar dired-local-variables-file (convert-standard-filename ".dired")
 879   "Filename, as string, containing local dired buffer variables to be hacked.
 880 If this file found in current directory, then it will be inserted into dired
 881 buffer and `hack-local-variables' will be run.  See Info node
 882 `(emacs)File Variables' for more information on local variables.
 883 See also `dired-enable-local-variables'.")
 884
 885 (defun dired-hack-local-variables ()
 886   "Evaluate local variables in `dired-local-variables-file' for dired buffer."
 887   (if (and dired-local-variables-file
 888            (stringp dired-local-variables-file)
 889            (file-exists-p dired-local-variables-file))
 890       (let ((opoint (point-max))
 891             buffer-read-only
 892             ;; In case user has `enable-local-variables' set to nil we
 893             ;; override it locally with dired's variable.
 894             (enable-local-variables dired-enable-local-variables))
 895         ;; Insert 'em.
 896         (save-excursion
 897           (goto-char opoint)
 898           (insert "\^L\n")
 899           (insert-file-contents dired-local-variables-file))
 900         ;; Hack 'em.
 901         (let ((buffer-file-name dired-local-variables-file))
 902           (hack-local-variables))
 903         ;; Make sure that the modeline shows the proper information.
 904         (dired-sort-set-modeline)
 905         ;; Delete this stuff: `eobp' is used to find last subdir by dired.el.
 906         (delete-region opoint (point-max)))))
 907
 908 (defun dired-omit-here-always ()
 909   "Create `dired-local-variables-file' for omitting and reverts directory.
 910 Sets `dired-omit-mode' to t in a local variables file that is readable by
 911 dired."
 912   (interactive)
 913   (if (file-exists-p dired-local-variables-file)
 914       (message "File `./%s' already exists." dired-local-variables-file)
 915
 916     ;; Create `dired-local-variables-file'.
 917     (save-excursion
 918       (set-buffer (get-buffer-create " *dot-dired*"))
 919       (erase-buffer)
 920       (insert "Local Variables:\ndired-omit-mode: t\nEnd:\n")
 921       (write-file dired-local-variables-file)
 922       (kill-buffer (current-buffer)))
 923
 924     ;; Run extra-hooks and revert directory.
 925     (dired-extra-startup)
 926     (dired-revert)))
 927
 928 \f
 929 ;;; GUESS SHELL COMMAND.
 930
 931 ;;; Brief Description:
 932 ;;;
 933 ;;; `dired-do-shell-command' is bound to `!' by dired.el.
 934 ;;;
 935 ;;; * Redefine `dired-read-shell-command' so it calls
 936 ;;;   `dired-guess-shell-command'.
 937 ;;;
 938 ;;; * `dired-guess-shell-command' calls `dired-guess-default' with list of
 939 ;;;    marked files.
 940 ;;;
 941 ;;; * Parse `dired-guess-shell-alist-user' and
 942 ;;;   `dired-guess-shell-alist-default' (in that order) for the first REGEXP
 943 ;;;   that matches the first file in the file list.
 944 ;;;
 945 ;;; * If the REGEXP matches all the entries of the file list then evaluate
 946 ;;;   COMMAND, which is either a string or a Lisp expression returning a
 947 ;;;   string.  COMMAND may be a list of commands.
 948 ;;;
 949 ;;; * Return this command to `dired-guess-shell-command' which prompts user
 950 ;;;   with it.  The list of commands is put into the list of default values.
 951 ;;;   If a command is used successfully then it is stored permanently in
 952 ;;;   `dired-shell-command-history'.
 953
 954 ;;; Guess what shell command to apply to a file.
 955 (defvar dired-shell-command-history nil
 956   "History list for commands that read dired-shell commands.")
 957
 958 ;;; Default list of shell commands.
 959
 960 ;;; NOTE: Use `gunzip -c' instead of `zcat' on `.gz' files.  Some do not
 961 ;;; install GNU zip's version of zcat.
 962
 963 (defvar dired-guess-shell-alist-default
 964   (list
 965    (list "\\.tar$"
 966          '(if dired-guess-shell-gnutar
 967               (concat dired-guess-shell-gnutar " xvf")
 968             "tar xvf")
 969          ;; Extract files into a separate subdirectory
 970          '(if dired-guess-shell-gnutar
 971               (concat "mkdir " (file-name-sans-extension file)
 972                       "; " dired-guess-shell-gnutar " -C "
 973                       (file-name-sans-extension file) " -xvf")
 974             (concat "mkdir " (file-name-sans-extension file)
 975                     "; tar -C " (file-name-sans-extension file) " -xvf"))
 976          ;; List archive contents.
 977          '(if dired-guess-shell-gnutar
 978               (concat dired-guess-shell-gnutar " tvf")
 979             "tar tvf"))
 980
 981    ;; REGEXPS for compressed archives must come before the .Z rule to
 982    ;; be recognized:
 983    (list "\\.tar\\.Z$"
 984          ;; Untar it.
 985          '(if dired-guess-shell-gnutar
 986               (concat dired-guess-shell-gnutar " zxvf")
 987             (concat "zcat * | tar xvf -"))
 988          ;; Optional conversion to gzip format.
 989          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 990                   " " dired-guess-shell-znew-switches))
 991
 992    ;; gzip'ed archives
 993    (list "\\.t\\(ar\\.\\)?gz$"
 994          '(if dired-guess-shell-gnutar
 995               (concat dired-guess-shell-gnutar " zxvf")
 996             (concat "gunzip -qc * | tar xvf -"))
 997          ;; Extract files into a separate subdirectory
 998          '(if dired-guess-shell-gnutar
 999               (concat "mkdir " (file-name-sans-extension file)
1000                       "; " dired-guess-shell-gnutar " -C "
1001                       (file-name-sans-extension file) " -zxvf")
1002             (concat "mkdir " (file-name-sans-extension file)
1003                     "; gunzip -qc * | tar -C "
1004                     (file-name-sans-extension file) " -xvf -"))
1005          ;; Optional decompression.
1006          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q" ""))
1007          ;; List archive contents.
1008          '(if dired-guess-shell-gnutar
1009               (concat dired-guess-shell-gnutar " ztvf")
1010             (concat "gunzip -qc * | tar tvf -")))
1011
1012    ;; bzip2'ed archives
1013    (list "\\.t\\(ar\\.bz2\\|bz\\)$"
1014          "bunzip2 -c * | tar xvf -"
1015          ;; Extract files into a separate subdirectory
1016          '(concat "mkdir " (file-name-sans-extension file)
1017                   "; bunzip2 -c * | tar -C "
1018                   (file-name-sans-extension file) " -xvf -")
1019          ;; Optional decompression.
1020          "bunzip2")
1021
1022    '("\\.shar\\.Z$" "zcat * | unshar")
1023    '("\\.shar\\.g?z$" "gunzip -qc * | unshar")
1024
1025    '("\\.e?ps$" "ghostview" "xloadimage" "lpr")
1026    (list "\\.e?ps\\.g?z$" "gunzip -qc * | ghostview -"
1027          ;; Optional decompression.
1028          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1029    (list "\\.e?ps\\.Z$" "zcat * | ghostview -"
1030          ;; Optional conversion to gzip format.
1031          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1032                   " " dired-guess-shell-znew-switches))
1033
1034    '("\\.patch$" "cat * | patch")
1035    (list "\\.patch\\.g?z$" "gunzip -qc * | patch"
1036          ;; Optional decompression.
1037          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1038    (list "\\.patch\\.Z$" "zcat * | patch"
1039          ;; Optional conversion to gzip format.
1040          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1041                   " " dired-guess-shell-znew-switches))
1042
1043    ;; The following four extensions are useful with dired-man ("N" key)
1044    (list "\\.\\(?:[0-9]\\|man\\)$" '(progn (require 'man)
1045                                            (if (Man-support-local-filenames)
1046                                                "man -l"
1047                                              "cat * | tbl | nroff -man -h")))
1048    (list "\\.\\(?:[0-9]\\|man\\)\\.g?z$" '(progn (require 'man)
1049                                                  (if (Man-support-local-filenames)
1050                                                      "man -l"
1051                                                    "gunzip -qc * | tbl | nroff -man -h"))
1052          ;; Optional decompression.
1053          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1054    (list "\\.[0-9]\\.Z$" '(progn (require 'man)
1055                                  (if (Man-support-local-filenames)
1056                                      "man -l"
1057                                    "zcat * | tbl | nroff -man -h"))
1058          ;; Optional conversion to gzip format.
1059          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1060                   " " dired-guess-shell-znew-switches))
1061    '("\\.pod$" "perldoc" "pod2man * | nroff -man")
1062
1063    '("\\.dvi$" "xdvi" "dvips")          ; preview and printing
1064    '("\\.au$" "play")                   ; play Sun audiofiles
1065    '("\\.mpe?g$\\|\\.avi$" "xine -p")
1066    '("\\.wav$" "play")
1067    '("\\.uu$" "uudecode")               ; for uudecoded files
1068    '("\\.hqx$" "mcvert")
1069    '("\\.sh$" "sh")                     ; execute shell scripts
1070    '("\\.xbm$" "bitmap")                ; view X11 bitmaps
1071    '("\\.gp$" "gnuplot")
1072    '("\\.p[bgpn]m$" "xloadimage")
1073    '("\\.gif$" "xloadimage")            ; view gif pictures
1074    '("\\.tif$" "xloadimage")
1075    '("\\.png$" "display")               ; xloadimage 4.1 doesn't grok PNG
1076    '("\\.jpe?g$" "xloadimage")
1077    '("\\.fig$" "xfig")                  ; edit fig pictures
1078    '("\\.out$" "xgraph")                ; for plotting purposes.
1079    '("\\.tex$" "latex" "tex")
1080    '("\\.texi\\(nfo\\)?$" "makeinfo" "texi2dvi")
1081    '("\\.pdf$" "xpdf")
1082    '("\\.doc$" "antiword" "strings")
1083    '("\\.rpm$" "rpm -qilp" "rpm -ivh")
1084    '("\\.dia$" "dia")
1085    '("\\.mgp$" "mgp")
1086
1087    ;; Some other popular archivers.
1088    (list "\\.zip$" "unzip" "unzip -l"
1089          ;; Extract files into a separate subdirectory
1090          '(concat "unzip" (if dired-guess-shell-gzip-quiet " -q")
1091                   " -d " (file-name-sans-extension file)))
1092    '("\\.zoo$" "zoo x//")
1093    '("\\.lzh$" "lharc x")
1094    '("\\.arc$" "arc x")
1095    '("\\.shar$" "unshar")
1096
1097    ;; Compression.
1098    (list "\\.g?z$" '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1099    (list "\\.dz$" "dictunzip")
1100    (list "\\.bz2$" "bunzip2")
1101    (list "\\.Z$" "uncompress"
1102          ;; Optional conversion to gzip format.
1103          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1104                   " " dired-guess-shell-znew-switches))
1105
1106    '("\\.sign?$" "gpg --verify"))
1107
1108   "Default alist used for shell command guessing.
1109 See `dired-guess-shell-alist-user'.")
1110
1111 (defcustom dired-guess-shell-alist-user nil
1112   "User-defined alist of rules for suggested commands.
1113 These rules take precedence over the predefined rules in the variable
1114 `dired-guess-shell-alist-default' (to which they are prepended).
1115
1116 Each element of this list looks like
1117
1118     \(REGEXP COMMAND...\)
1119
1120 where each COMMAND can either be a string or a Lisp expression that evaluates
1121 to a string.  If several COMMANDs are given, the first one will be the default
1122 and the rest will be added temporarily to the history and can be retrieved
1123 with \\[previous-history-element] (M-p) .
1124
1125 You can set this variable in your ~/.emacs.  For example, to add rules for
1126 `.foo' and `.bar' files, write
1127
1128  \(setq dired-guess-shell-alist-user
1129        (list (list \"\\\\.foo\\\\'\" \"FOO-COMMAND\");; fixed rule
1130               ;; possibly more rules ...
1131               (list \"\\\\.bar\\\'\";; rule with condition test
1132                     '(if condition
1133                           \"BAR-COMMAND-1\"
1134                         \"BAR-COMMAND-2\")))\)"
1135   :group 'dired-x
1136   :type '(alist :key-type regexp :value-type (repeat sexp)))
1137
1138 (defcustom dired-guess-shell-case-fold-search t
1139   "If non-nil, `dired-guess-shell-alist-default' and
1140 `dired-guess-shell-alist-user' are matched case-insensitively."
1141   :group 'dired-x
1142   :type 'boolean)
1143
1144 (defun dired-guess-default (files)
1145   "Guess a shell commands for FILES.  Return command or list of commands.
1146 See `dired-guess-shell-alist-user'."
1147
1148   (let* ((case-fold-search dired-guess-shell-case-fold-search)
1149          ;; Prepend the user's alist to the default alist.
1150          (alist (append dired-guess-shell-alist-user
1151                         dired-guess-shell-alist-default))
1152          (file (car files))
1153          (flist (cdr files))
1154          elt regexp cmds)
1155
1156     ;; Find the first match in the alist for first file in FILES.
1157     (while alist
1158       (setq elt (car alist)
1159             regexp (car elt)
1160             alist (cdr alist))
1161       (if (string-match regexp file)
1162           (setq cmds (cdr elt)
1163                 alist nil)))
1164
1165     ;; If more than one file, see if all of FILES match regular expression.
1166     (while (and flist
1167                 (string-match regexp (car flist)))
1168       (setq flist (cdr flist)))
1169
1170     ;; If flist is still non-nil, then do not guess since this means that not
1171     ;; all the files in FILES were matched by the regexp.
1172     (setq cmds (and (not flist) cmds))
1173
1174     ;; Return commands or nil if flist is still non-nil.
1175     ;; Evaluate the commands in order that any logical testing will be done.
1176     (cond ((not (cdr cmds))
1177            (eval (car cmds))) ; single command
1178           (t
1179            (mapcar (function eval) cmds)))))
1180
1181 (defun dired-guess-shell-command (prompt files)
1182   "Ask user with PROMPT for a shell command, guessing a default from FILES."
1183   (let ((default (dired-guess-default files))
1184         default-list val)
1185     (if (null default)
1186         ;; Nothing to guess
1187         (read-from-minibuffer prompt nil nil nil 'dired-shell-command-history)
1188       (if (listp default)
1189           ;; More than one guess
1190           (setq default-list default
1191                 default (car default)
1192                 prompt (concat
1193                         prompt
1194                         (format "{%d guesses} " (length default-list))))
1195         ;; Just one guess
1196         (setq default-list (list default)))
1197       ;; Put the first guess in the prompt but not in the initial value.
1198       (setq prompt (concat prompt (format "[%s] " default)))
1199       ;; All guesses can be retrieved with M-n
1200       (setq val (read-from-minibuffer prompt nil nil nil
1201                                       'dired-shell-command-history
1202                                       default-list))
1203       ;; If we got a return, then return default.
1204       (if (equal val "") default val))))
1205
1206 ;;; REDEFINE.
1207 ;;; Redefine dired-aux.el's version:
1208 (defun dired-read-shell-command (prompt arg files)
1209   "Read a dired shell command prompting with PROMPT (using read-string).
1210 ARG is the prefix arg and may be used to indicate in the prompt which
1211   files are affected.
1212 This is an extra function so that you can redefine it."
1213   (dired-mark-pop-up
1214    nil 'shell files
1215    'dired-guess-shell-command
1216    (format prompt (dired-mark-prompt arg files)) ; PROMPT
1217    files))                                       ; FILES
1218
1219 \f
1220 ;;; RELATIVE SYMBOLIC LINKS.
1221
1222 (declare-function make-symbolic-link "fileio.c")
1223
1224 (defvar dired-keep-marker-relsymlink ?S
1225   "See variable `dired-keep-marker-move'.")
1226
1227 (defun dired-make-relative-symlink (file1 file2 &optional ok-if-already-exists)
1228   "Make a symbolic link (pointing to FILE1) in FILE2.
1229 The link is relative (if possible), for example
1230
1231     \"/vol/tex/bin/foo\" \"/vol/local/bin/foo\"
1232
1233 results in
1234
1235     \"../../tex/bin/foo\" \"/vol/local/bin/foo\""
1236   (interactive "FRelSymLink: \nFRelSymLink %s: \np")
1237   (let (name1 name2 len1 len2 (index 0) sub)
1238     (setq file1 (expand-file-name file1)
1239           file2 (expand-file-name file2)
1240           len1 (length file1)
1241           len2 (length file2))
1242     ;; Find common initial file name components:
1243     (let (next)
1244       (while (and (setq next (string-match "/" file1 index))
1245                   (setq next (1+ next))
1246                   (< next (min len1 len2))
1247                   ;; For the comparison, both substrings must end in
1248                   ;; `/', so NEXT is *one plus* the result of the
1249                   ;; string-match.
1250                   ;; E.g., consider the case of linking "/tmp/a/abc"
1251                   ;; to "/tmp/abc" erroneously giving "/tmp/a" instead
1252                   ;; of "/tmp/" as common initial component
1253                   (string-equal (substring file1 0 next)
1254                                 (substring file2 0 next)))
1255         (setq index next))
1256       (setq name2 file2
1257             sub (substring file1 0 index)
1258             name1 (substring file1 index)))
1259     (if (string-equal sub "/")
1260         ;; No common initial file name found
1261         (setq name1 file1)
1262       ;; Else they have a common parent directory
1263       (let ((tem (substring file2 index))
1264             (start 0)
1265             (count 0))
1266         ;; Count number of slashes we must compensate for ...
1267         (while (setq start (string-match "/" tem start))
1268           (setq count (1+ count)
1269                 start (1+ start)))
1270         ;; ... and prepend a "../" for each slash found:
1271         (while (> count 0)
1272           (setq count (1- count)
1273                 name1 (concat "../" name1)))))
1274     (make-symbolic-link
1275      (directory-file-name name1)        ; must not link to foo/
1276                                         ; (trailing slash!)
1277      name2 ok-if-already-exists)))
1278
1279 ;;;###autoload
1280 (defun dired-do-relsymlink (&optional arg)
1281    "Relative symlink all marked (or next ARG) files into a directory.
1282 Otherwise make a relative symbolic link to the current file.
1283 This creates relative symbolic links like
1284
1285     foo -> ../bar/foo
1286
1287 not absolute ones like
1288
1289     foo -> /ugly/file/name/that/may/change/any/day/bar/foo
1290
1291 For absolute symlinks, use \\[dired-do-symlink]."
1292   (interactive "P")
1293   (dired-do-create-files 'relsymlink (function dired-make-relative-symlink)
1294                            "RelSymLink" arg dired-keep-marker-relsymlink))
1295
1296 (defun dired-do-relsymlink-regexp (regexp newname &optional arg whole-name)
1297   "RelSymlink all marked files containing REGEXP to NEWNAME.
1298 See functions `dired-do-rename-regexp' and `dired-do-relsymlink'
1299 for more info."
1300   (interactive (dired-mark-read-regexp "RelSymLink"))
1301   (dired-do-create-files-regexp
1302    (function dired-make-relative-symlink)
1303    "RelSymLink" arg regexp newname whole-name dired-keep-marker-relsymlink))
1304
1305 \f
1306 ;;; VISIT ALL MARKED FILES SIMULTANEOUSLY.
1307
1308 ;;; Brief Description:
1309 ;;;
1310 ;;; `dired-do-find-marked-files' is bound to `F' by dired-x.el.
1311 ;;;
1312 ;;; * Use `dired-get-marked-files' to collect the marked files in the current
1313 ;;;   Dired Buffer into a list of filenames `FILE-LIST'.
1314 ;;;
1315 ;;; * Pass FILE-LIST to `dired-simultaneous-find-file' all with
1316 ;;;   `dired-do-find-marked-files''s prefix argument NOSELECT.
1317 ;;;
1318 ;;; * `dired-simultaneous-find-file' runs through FILE-LIST decrementing the
1319 ;;;   list each time.
1320 ;;;
1321 ;;; * If NOSELECT is non-nil then just run `find-file-noselect'  on each
1322 ;;;   element of FILE-LIST.
1323 ;;;
1324 ;;; * If NOSELECT is nil then calculate the `size' of the window for each file
1325 ;;;   by dividing the `window-height' by length of FILE-LIST.  Thus, `size' is
1326 ;;;   cognizant of the window-configuration.
1327 ;;;
1328 ;;; * If `size' is too small abort, otherwise run `find-file' on each element
1329 ;;;   of FILE-LIST giving each a window of height `size'.
1330
1331 (defun dired-do-find-marked-files (&optional noselect)
1332   "Find all marked files displaying all of them simultaneously.
1333 With optional NOSELECT just find files but do not select them.
1334
1335 The current window is split across all files marked, as evenly as possible.
1336 Remaining lines go to bottom-most window.  The number of files that can be
1337 displayed this way is restricted by the height of the current window and
1338 `window-min-height'.
1339
1340 To keep dired buffer displayed, type \\[split-window-vertically] first.
1341 To display just marked files, type \\[delete-other-windows] first."
1342
1343   (interactive "P")
1344   (dired-simultaneous-find-file (dired-get-marked-files) noselect))
1345
1346 (defun dired-simultaneous-find-file (file-list noselect)
1347
1348   "Visit all files in FILE-LIST and display them simultaneously.
1349 The current window is split across all files in FILE-LIST, as evenly as
1350 possible.  Remaining lines go to the bottom-most window.  The number of
1351 files that can be displayed this way is restricted by the height of the
1352 current window and the variable `window-min-height'.  With non-nil
1353 NOSELECT the files are merely found but not selected."
1354
1355   ;; We don't make this function interactive because it is usually too clumsy
1356   ;; to specify FILE-LIST interactively unless via dired.
1357
1358   (let (size)
1359
1360     (if noselect
1361         ;; Do not select the buffer.
1362         (find-file-noselect (car file-list))
1363
1364       ;; We will have to select the buffer.  Calculate and check window size.
1365       (setq size (/ (window-height) (length file-list)))
1366       (or (<= window-min-height size)
1367           (error "Too many files to visit simultaneously.  Try C-u prefix"))
1368       (find-file (car file-list)))
1369
1370     ;; Decrement.
1371     (setq file-list (cdr file-list))
1372
1373     (while file-list
1374
1375       (if noselect
1376           ;; Do not select the buffer.
1377           (find-file-noselect (car file-list))
1378
1379         ;; Vertically split off a window of desired size.  Upper window will
1380         ;; have SIZE lines.  Select lower (larger) window.  We split it again.
1381         (select-window (split-window nil size))
1382         (find-file (car file-list)))
1383
1384       ;; Decrement.
1385       (setq file-list (cdr file-list)))))
1386
1387 \f
1388 ;;; MISCELLANEOUS COMMANDS.
1389
1390 ;;; Run man on files.
1391
1392 (defun dired-man ()
1393   "Run man on this file.  Display old buffer if buffer name matches filename.
1394 Uses `man.el' of \\[manual-entry] fame."
1395   (interactive)
1396   (require 'man)
1397   (let* ((file (dired-get-filename))
1398          (manual-program (replace-regexp-in-string "\\*" "%s"
1399                           (dired-guess-shell-command
1400                            "Man command: " (list file)))))
1401     (Man-getpage-in-background file)))
1402
1403 ;;; Run Info on files.
1404
1405 (defun dired-info ()
1406   "Run info on this file."
1407   (interactive)
1408   (info (dired-get-filename)))
1409
1410 ;;; Run mail on mail folders.
1411
1412 ;; Avoid compiler warning.
1413 (eval-when-compile
1414   (when (not (fboundp 'vm-visit-folder))
1415     (defun vm-visit-folder (file &optional arg)
1416       nil)))
1417
1418 (defun dired-vm (&optional read-only)
1419   "Run VM on this file.
1420 With prefix arg, visit folder read-only (this requires at least VM 5).
1421 See also variable `dired-vm-read-only-folders'."
1422   (interactive "P")
1423   (let ((dir (dired-current-directory))
1424         (fil (dired-get-filename)))
1425     ;; take care to supply 2nd arg only if requested - may still run VM 4!
1426     (cond (read-only (vm-visit-folder fil t))
1427           ((eq t dired-vm-read-only-folders) (vm-visit-folder fil t))
1428           ((null dired-vm-read-only-folders) (vm-visit-folder fil))
1429           (t (vm-visit-folder fil (not (file-writable-p fil)))))
1430     ;; so that pressing `v' inside VM does prompt within current directory:
1431     (set (make-local-variable 'vm-folder-directory) dir)))
1432
1433 (defun dired-rmail ()
1434   "Run RMAIL on this file."
1435   (interactive)
1436   (rmail (dired-get-filename)))
1437
1438 (defun dired-do-run-mail ()
1439   "If `dired-bind-vm' is t, then function `dired-vm', otherwise `dired-rmail'."
1440   (interactive)
1441   (if dired-bind-vm
1442       ;; Read mail folder using vm.
1443       (dired-vm)
1444     ;; Read mail folder using rmail.
1445     (dired-rmail)))
1446
1447 \f
1448 ;;; MISCELLANEOUS INTERNAL FUNCTIONS.
1449
1450 (declare-function dired-old-find-buffer-nocreate "dired-x")
1451
1452 (or (fboundp 'dired-old-find-buffer-nocreate)
1453     (fset 'dired-old-find-buffer-nocreate
1454           (symbol-function 'dired-find-buffer-nocreate)))
1455
1456 ;;; REDEFINE.
1457 ;;; Redefines dired.el's version of `dired-find-buffer-nocreate'
1458 (defun dired-find-buffer-nocreate (dirname &optional mode)
1459   (if (and dired-find-subdir
1460            ;; don't try to find a wildcard as a subdirectory
1461            (string-equal dirname (file-name-directory dirname)))
1462       (let* ((cur-buf (current-buffer))
1463              (buffers (nreverse
1464                        (dired-buffers-for-dir (expand-file-name dirname))))
1465              (cur-buf-matches (and (memq cur-buf buffers)
1466                                    ;; wildcards must match, too:
1467                                    (equal dired-directory dirname))))
1468         ;; We don't want to switch to the same buffer---
1469         (setq buffers (delq cur-buf buffers));;need setq with delq
1470         (or (car (sort buffers (function dired-buffer-more-recently-used-p)))
1471             ;; ---unless it's the only possibility:
1472             (and cur-buf-matches cur-buf)))
1473     (dired-old-find-buffer-nocreate dirname mode)))
1474
1475 ;; This should be a builtin
1476 (defun dired-buffer-more-recently-used-p (buffer1 buffer2)
1477   "Return t if BUFFER1 is more recently used than BUFFER2."
1478   (if (equal buffer1 buffer2)
1479       nil
1480     (let ((more-recent nil)
1481           (list (buffer-list)))
1482       (while (and list
1483                   (not (setq more-recent (equal buffer1 (car list))))
1484                   (not (equal buffer2 (car list))))
1485         (setq list (cdr list)))
1486       more-recent)))
1487
1488 ;;; Same thing as `dired-buffers-for-dir' of dired.el? - lrd 11/23/93
1489 ;;; (defun dired-buffers-for-dir-exact (dir)
1490 ;;; ;; Return a list of buffers that dired DIR (a directory or wildcard)
1491 ;;; ;; at top level, or as subdirectory.
1492 ;;; ;; Top level matches must match the wildcard part too, if any.
1493 ;;; ;; The list is in reverse order of buffer creation, most recent last.
1494 ;;; ;; As a side effect, killed dired buffers for DIR are removed from
1495 ;;; ;; dired-buffers.
1496 ;;;   (let ((alist dired-buffers) result elt)
1497 ;;;     (while alist
1498 ;;;       (setq elt (car alist)
1499 ;;;             alist (cdr alist))
1500 ;;;       (let ((buf (cdr elt)))
1501 ;;;         (if (buffer-name buf)
1502 ;;;             ;; Top level must match exactly against dired-directory in
1503 ;;;             ;; case one of them is a wildcard.
1504 ;;;             (if (or (equal dir (save-excursion (set-buffer buf)
1505 ;;;                                                dired-directory))
1506 ;;;                     (assoc dir (save-excursion (set-buffer buf)
1507 ;;;                                                dired-subdir-alist)))
1508 ;;;                 (setq result (cons buf result)))
1509 ;;;           ;; else buffer is killed - clean up:
1510 ;;;           (setq dired-buffers (delq elt dired-buffers)))))
1511 ;;;     result))
1512
1513 ;;; REDEFINE.
1514 ;;; Redefines dired.el's version of `dired-initial-position'
1515 (defun dired-initial-position (dirname)
1516   "Where point should go in a new listing of DIRNAME.
1517 Point assumed at beginning of new subdir line.
1518 You may redefine this function as you wish, e.g. like in `dired-x.el'."
1519   (end-of-line)
1520   (if dired-find-subdir (dired-goto-subdir dirname)) ; new
1521   (if dired-trivial-filenames (dired-goto-next-nontrivial-file)))
1522
1523 \f
1524 ;; Does anyone use this? - lrd 6/29/93.
1525 ;; Apparently people do use it. - lrd 12/22/97.
1526 (defun dired-mark-sexp (predicate &optional unflag-p)
1527   "Mark files for which PREDICATE returns non-nil.
1528 With a prefix arg, unflag those files instead.
1529
1530 PREDICATE is a lisp expression that can refer to the following symbols:
1531
1532     inode  [integer] the inode of the file (only for ls -i output)
1533     s      [integer] the size of the file for ls -s output
1534                      (usually in blocks or, with -k, in KByte)
1535     mode   [string]  file permission bits, e.g. \"-rw-r--r--\"
1536     nlink  [integer] number of links to file
1537     uid    [string]  owner
1538     gid    [string]  group  (If the gid is not displayed by ls,
1539                      this will still be set (to the same as uid))
1540     size   [integer] file size in bytes
1541     time   [string]  the time that ls displays, e.g. \"Feb 12 14:17\"
1542     name   [string]  the name of the file
1543     sym    [string]  if file is a symbolic link, the linked-to name, else \"\"
1544
1545 For example, use
1546
1547         (equal 0 size)
1548
1549 to mark all zero length files."
1550   ;; Using sym="" instead of nil avoids the trap of
1551   ;; (string-match "foo" sym) into which a user would soon fall.
1552   ;; Give `equal' instead of `=' in the example, as this works on
1553   ;; integers and strings.
1554   (interactive "xMark if (lisp expr): \nP")
1555   (message "%s" predicate)
1556   (let ((dired-marker-char (if unflag-p ?\040 dired-marker-char))
1557         inode s mode nlink uid gid size time name sym)
1558     (dired-mark-if
1559      (save-excursion
1560        (and
1561         ;; Sets vars
1562         ;;                inode s mode nlink uid gid size time name sym
1563
1564         ;; according to current file line.  Returns t for success, nil if
1565         ;; there is no file line.  Upon success, all variables are set, either
1566         ;; to nil or the appropriate value, so they need not be initialized.
1567         ;; Moves point within the current line.
1568         (if (dired-move-to-filename)
1569             (let (pos
1570                   (mode-len 10) ; length of mode string
1571                   ;; like in dired.el, but with subexpressions \1=inode, \2=s:
1572                   (dired-re-inode-size "\\s *\\([0-9]*\\)\\s *\\([0-9]*\\) ?"))
1573               (beginning-of-line)
1574               (forward-char 2)
1575               (if (looking-at dired-re-inode-size)
1576                   (progn
1577                     (goto-char (match-end 0))
1578                     (setq inode (string-to-number (buffer-substring (match-beginning 1)
1579                                                                     (match-end 1)))
1580                           s (string-to-number (buffer-substring (match-beginning 2)
1581                                                                 (match-end 2)))))
1582                 (setq inode nil
1583                       s nil))
1584               (setq mode (buffer-substring (point) (+ mode-len (point))))
1585               (forward-char mode-len)
1586               (setq nlink (read (current-buffer)))
1587               ;; Karsten Wenger <kw@cis.uni-muenchen.de> fixed uid.
1588               (setq uid (buffer-substring (+ (point) 1)
1589                                           (progn (forward-word 1) (point))))
1590               (re-search-forward directory-listing-before-filename-regexp)
1591               (goto-char (match-beginning 1))
1592               (forward-char -1)
1593               (setq size (string-to-number (buffer-substring (save-excursion
1594                                                                (backward-word 1)
1595                                                                (setq pos (point)))
1596                                                              (point))))
1597               (goto-char pos)
1598               (backward-word 1)
1599               ;; if no gid is displayed, gid will be set to uid
1600               ;; but user will then not reference it anyway in PREDICATE.
1601               (setq gid (buffer-substring (save-excursion
1602                                             (forward-word 1) (point))
1603                                           (point))
1604                     time (buffer-substring (match-beginning 1)
1605                                            (1- (dired-move-to-filename)))
1606                     name (buffer-substring (point)
1607                                            (or
1608                                             (dired-move-to-end-of-filename t)
1609                                             (point)))
1610                     sym  (progn
1611                            (if (looking-at " -> ")
1612                                (buffer-substring
1613                                 (progn (forward-char 4) (point))
1614                                 (progn (end-of-line) (point)))
1615                              "")))
1616               t)
1617           nil)
1618                       (eval predicate)))
1619      (format "'%s file" predicate))))
1620
1621 \f
1622 ;;; FIND FILE AT POINT.
1623
1624 (defvar dired-x-hands-off-my-keys t
1625   "*Non-nil means don't bind `dired-x-find-file' over `find-file' on keyboard.
1626 Similarly for `dired-x-find-file-other-window' over `find-file-other-window'.
1627 If you change this variable after `dired-x.el' is loaded then do
1628 \\[dired-x-bind-find-file].")
1629
1630 ;;; Bind `dired-x-find-file{-other-window}' over wherever
1631 ;;; `find-file{-other-window}' is bound?
1632 (defun dired-x-bind-find-file ()
1633   "Bind `dired-x-find-file' in place of `find-file' \(or reverse\).
1634 Similarly for `dired-x-find-file-other-window' and `find-file-other-window'.
1635 Binding direction based on `dired-x-hands-off-my-keys'.
1636 This function is part of `after-init-hook'."
1637   (interactive)
1638   (if (interactive-p)
1639       (setq dired-x-hands-off-my-keys
1640             (not (y-or-n-p "Bind dired-x-find-file over find-file? "))))
1641   (cond ((not dired-x-hands-off-my-keys)
1642          (substitute-key-definition 'find-file
1643                                     'dired-x-find-file
1644                                     (current-global-map))
1645          (substitute-key-definition 'find-file-other-window
1646                                     'dired-x-find-file-other-window
1647                                     (current-global-map)))
1648         (t
1649          (substitute-key-definition 'dired-x-find-file
1650                                     'find-file
1651                                     (current-global-map))
1652          (substitute-key-definition 'dired-x-find-file-other-window
1653                                     'find-file-other-window
1654                                     (current-global-map))))
1655   ;; Clear mini-buffer.
1656   (message nil))
1657
1658 ;;; Now call it so binding is correct and put on `after-init-hook' in case
1659 ;;; user changes binding.
1660 (dired-x-bind-find-file)
1661 (add-hook 'after-init-hook 'dired-x-bind-find-file)
1662
1663 (defun dired-x-find-file (filename)
1664   "Edit file FILENAME.
1665 May create a new window, or reuse an existing one.
1666 See the function `display-buffer'.
1667
1668 Identical to `find-file' except when called interactively, with a prefix arg
1669 \(e.g., \\[universal-argument]\), in which case it guesses filename near point.
1670 Useful for editing file mentioned in buffer you are viewing,
1671 or to test if that file exists.  Use minibuffer after snatching filename."
1672   (interactive (list (read-filename-at-point "Find file: ")))
1673   (find-file (expand-file-name filename)))
1674
1675 (defun dired-x-find-file-other-window (filename)
1676   "Edit file FILENAME, in another window.
1677 May create a new window, or reuse an existing one.
1678 See the function `display-buffer'.
1679
1680 Identical to `find-file-other-window' except when called interactively, with a
1681 prefix arg \(e.g., \\[universal-argument]\), in which case it guesses filename near point.
1682 Useful for editing file mentioned in buffer you are viewing,
1683 or to test if that file exists.  Use minibuffer after snatching filename."
1684   (interactive (list (read-filename-at-point "Find file: ")))
1685   (find-file-other-window (expand-file-name filename)))
1686
1687 ;;; Internal functions.
1688
1689 ;; Fixme: This should probably use `thing-at-point'.  -- fx
1690 (defun dired-filename-at-point ()
1691   "Get the filename closest to point, but do not change position.
1692 Has a preference for looking backward when not directly on a symbol.  Not
1693 perfect - point must be in middle of or end of filename."
1694
1695   (let ((filename-chars "-.[:alnum:]_/:$+@")
1696         start end filename prefix)
1697
1698     (save-excursion
1699       ;; First see if just past a filename.
1700       (if (not (eobp))
1701           (if (looking-at "[] \t\n[{}()]") ; whitespace or some parens
1702               (progn
1703                 (skip-chars-backward " \n\t\r({[]})")
1704                 (if (not (bobp))
1705                     (backward-char 1)))))
1706
1707       (if (string-match (concat "[" filename-chars "]")
1708                         (char-to-string (following-char)))
1709           (progn
1710             (if (re-search-backward (concat "[^" filename-chars "]") nil t)
1711                 (forward-char)
1712               (goto-char (point-min)))
1713             (setq start (point))
1714             (setq prefix
1715                   (and (string-match
1716                         "^\\w+@"
1717                         (buffer-substring start (line-beginning-position)))
1718                        "/"))
1719             (goto-char start)
1720             (if (string-match "[/~]" (char-to-string (preceding-char)))
1721                 (setq start (1- start)))
1722             (re-search-forward (concat "\\=[" filename-chars "]*") nil t))
1723
1724         (error "No file found around point!"))
1725
1726       ;; Return string.
1727       (expand-file-name (concat prefix (buffer-substring start (point)))))))
1728
1729 (defun read-filename-at-point (prompt)
1730   "Return filename prompting with PROMPT with completion.
1731 If `current-prefix-arg' is non-nil, uses name at point as guess."
1732   (if current-prefix-arg
1733       (let ((guess (dired-filename-at-point)))
1734         (read-file-name prompt
1735                         (file-name-directory guess)
1736                         guess
1737                         nil (file-name-nondirectory guess)))
1738     (read-file-name prompt default-directory)))
1739 \f
1740 ;;; BUG REPORTS
1741
1742 ;; Fixme: get rid of this later.
1743
1744 ;;; This section is provided for reports.  It uses Barry A. Warsaw's
1745 ;;; reporter.el which is bundled with GNU Emacs v19.
1746
1747 (defconst dired-x-help-address "bug-gnu-emacs@gnu.org"
1748   "Address(es) accepting submission of reports on dired-x.el.")
1749
1750 (defconst dired-x-variable-list
1751   (list
1752    'dired-bind-vm
1753    'dired-vm-read-only-folders
1754    'dired-bind-jump
1755    'dired-bind-info
1756    'dired-bind-man
1757    'dired-find-subdir
1758    'dired-enable-local-variables
1759    'dired-local-variables-file
1760    'dired-guess-shell-gnutar
1761    'dired-guess-shell-gzip-quiet
1762    'dired-guess-shell-znew-switches
1763    'dired-guess-shell-alist-user
1764    'dired-clean-up-buffers-too
1765    'dired-omit-mode
1766    'dired-omit-files
1767    'dired-omit-extensions
1768    )
1769   "List of variables to be appended to reports sent by `dired-x-submit-report'.")
1770
1771 (defun dired-x-submit-report ()
1772   "Submit via `reporter.el' a bug report on program.
1773 Send report on `dired-x-file' version `dired-x-version,' to
1774 `dired-x-maintainer' at address `dired-x-help-address' listing
1775 variables `dired-x-variable-list' in the message."
1776   (interactive)
1777
1778   (reporter-submit-bug-report
1779    dired-x-help-address                 ; address
1780    "dired-x"                            ; pkgname
1781    dired-x-variable-list                ; varlist
1782    nil nil                              ; pre-/post-hooks
1783    ""))
1784
1785 \f
1786 ;; As Barry Warsaw would say: "This might be useful..."
1787 (provide 'dired-x)
1788
1789 ;; arch-tag: 71a43ba2-7a00-4793-a028-0613dd7765ae
1790 ;;; dired-x.el ends here