lisp/textmodes/spell.el

   1 ;;; spell.el --- spelling correction interface for Emacs.
   2
   3 ;; Maintainer: FSF
   4 ;; Last-Modified: 09 May 1991
   5
   6 ;; Copyright (C) 1985 Free Software Foundation, Inc.
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Code:
  25
  26 (defvar spell-command "spell"
  27   "*Command to run the spell program.")
  28
  29 (defvar spell-filter nil
  30   "*Filter function to process text before passing it to spell program.
  31 This function might remove text-processor commands.
  32 nil means don't alter the text before checking it.")
  33
  34 ;;;###autoload
  35 (defun spell-buffer ()
  36   "Check spelling of every word in the buffer.
  37 For each incorrect word, you are asked for the correct spelling
  38 and then put into a query-replace to fix some or all occurrences.
  39 If you do not want to change a word, just give the same word
  40 as its \"correct\" spelling; then the query replace is skipped."
  41   (interactive)
  42   (spell-region (point-min) (point-max) "buffer"))
  43
  44 ;;;###autoload
  45 (defun spell-word ()
  46   "Check spelling of word at or before point.
  47 If it is not correct, ask user for the correct spelling
  48 and query-replace the entire buffer to substitute it."
  49   (interactive)
  50   (let (beg end spell-filter)
  51     (save-excursion
  52      (if (not (looking-at "\\<"))
  53          (forward-word -1))
  54      (setq beg (point))
  55      (forward-word 1)
  56      (setq end (point)))
  57     (spell-region beg end (buffer-substring beg end))))
  58
  59 ;;;###autoload
  60 (defun spell-region (start end &optional description)
  61   "Like spell-buffer but applies only to region.
  62 Used in a program, applies from START to END.
  63 DESCRIPTION is an optional string naming the unit being checked:
  64 for example, \"word\"."
  65   (interactive "r")
  66   (let ((filter spell-filter)
  67         (buf (get-buffer-create " *temp*")))
  68     (save-excursion
  69      (set-buffer buf)
  70      (widen)
  71      (erase-buffer))
  72     (message "Checking spelling of %s..." (or description "region"))
  73     (if (and (null filter) (= ?\n (char-after (1- end))))
  74         (if (string= "spell" spell-command)
  75             (call-process-region start end "spell" nil buf)
  76           (call-process-region start end shell-file-name
  77                                nil buf nil "-c" spell-command))
  78       (let ((oldbuf (current-buffer)))
  79         (save-excursion
  80          (set-buffer buf)
  81          (insert-buffer-substring oldbuf start end)
  82          (or (bolp) (insert ?\n))
  83          (if filter (funcall filter))
  84          (if (string= "spell" spell-command)
  85              (call-process-region (point-min) (point-max) "spell" t buf)
  86            (call-process-region (point-min) (point-max) shell-file-name
  87                                 t buf nil "-c" spell-command)))))
  88     (message "Checking spelling of %s...%s"
  89              (or description "region")
  90              (if (save-excursion
  91                   (set-buffer buf)
  92                   (> (buffer-size) 0))
  93                  "not correct"
  94                "correct"))
  95     (let (word newword
  96           (case-fold-search t)
  97           (case-replace t))
  98       (while (save-excursion
  99               (set-buffer buf)
 100               (> (buffer-size) 0))
 101         (save-excursion
 102          (set-buffer buf)
 103          (goto-char (point-min))
 104          (setq word (downcase
 105                      (buffer-substring (point)
 106                                        (progn (end-of-line) (point)))))
 107          (forward-char 1)
 108          (delete-region (point-min) (point))
 109          (setq newword
 110                (read-input (concat "`" word
 111                                    "' not recognized; edit a replacement: ")
 112                            word))
 113          (flush-lines (concat "^" (regexp-quote word) "$")))
 114         (if (not (equal word newword))
 115             (progn
 116              (goto-char (point-min))
 117              (query-replace-regexp (concat "\\b" (regexp-quote word) "\\b")
 118                                    newword)))))))
 119
 120
 121 ;;;###autoload
 122 (defun spell-string (string)
 123   "Check spelling of string supplied as argument."
 124   (interactive "sSpell string: ")
 125   (let ((buf (get-buffer-create " *temp*")))
 126     (save-excursion
 127      (set-buffer buf)
 128      (widen)
 129      (erase-buffer)
 130      (insert string "\n")
 131      (if (string= "spell" spell-command)
 132          (call-process-region (point-min) (point-max) "spell"
 133                               t t)
 134        (call-process-region (point-min) (point-max) shell-file-name
 135                             t t nil "-c" spell-command))
 136      (if (= 0 (buffer-size))
 137          (message "%s is correct" string)
 138        (goto-char (point-min))
 139        (while (search-forward "\n" nil t)
 140          (replace-match " "))
 141        (message "%sincorrect" (buffer-substring 1 (point-max)))))))
 142
 143 ;;; spell.el ends here