* doc/emacs/custom.texi (Directory Variables): Fix paren typo.
[emacs.git] / lisp / facemenu.el
blobe86c1c23d66ed44f6ef3490571f91b11a5757f59
1 ;;; facemenu.el --- create a face menu for interactively adding fonts to text
3 ;; Copyright (C) 1994-1996, 2001-2013 Free Software Foundation, Inc.
5 ;; Author: Boris Goldowsky <boris@gnu.org>
6 ;; Keywords: faces
7 ;; Package: emacs
9 ;; This file is part of GNU Emacs.
11 ;; GNU Emacs is free software: you can redistribute it and/or modify
12 ;; it under the terms of the GNU General Public License as published by
13 ;; the Free Software Foundation, either version 3 of the License, or
14 ;; (at your option) any later version.
16 ;; GNU Emacs is distributed in the hope that it will be useful,
17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
19 ;; GNU General Public License for more details.
21 ;; You should have received a copy of the GNU General Public License
22 ;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
24 ;;; Commentary:
26 ;; This file defines a menu of faces (bold, italic, etc) which allows you to
27 ;; set the face used for a region of the buffer. Some faces also have
28 ;; keybindings, which are shown in the menu.
30 ;; The menu also contains submenus for indentation and justification-changing
31 ;; commands.
33 ;;; Usage:
34 ;; Selecting a face from the menu or typing the keyboard equivalent will
35 ;; change the region to use that face. If you use transient-mark-mode and the
36 ;; region is not active, the face will be remembered and used for the next
37 ;; insertion. It will be forgotten if you move point or make other
38 ;; modifications before inserting or typing anything.
40 ;; Faces can be selected from the keyboard as well.
41 ;; The standard keybindings are M-o (or ESC o) + letter:
42 ;; M-o i = "set italic", M-o b = "set bold", etc.
44 ;;; Customization:
45 ;; An alternative set of keybindings that may be easier to type can be set up
46 ;; using "Alt" or "Hyper" keys. This requires that you either have or create
47 ;; an Alt or Hyper key on your keyboard. On my keyboard, there is a key
48 ;; labeled "Alt", but to make it act as an Alt key I have to put this command
49 ;; into my .xinitrc:
50 ;; xmodmap -e "add Mod3 = Alt_L"
51 ;; Or, I can make it into a Hyper key with this:
52 ;; xmodmap -e "keysym Alt_L = Hyper_L" -e "add Mod2 = Hyper_L"
53 ;; Check with local X-perts for how to do it on your system.
54 ;; Then you can define your keybindings with code like this in your .emacs:
55 ;; (setq facemenu-keybindings
56 ;; '((default . [?\H-d])
57 ;; (bold . [?\H-b])
58 ;; (italic . [?\H-i])
59 ;; (bold-italic . [?\H-l])
60 ;; (underline . [?\H-u])))
61 ;; (facemenu-update)
62 ;; (setq facemenu-keymap global-map)
63 ;; (define-key global-map [?\H-c] 'facemenu-set-foreground) ; set fg color
64 ;; (define-key global-map [?\H-C] 'facemenu-set-background) ; set bg color
66 ;; The order of the faces that appear in the menu and their keybindings can be
67 ;; controlled by setting the variables `facemenu-keybindings' and
68 ;; `facemenu-new-faces-at-end'. List faces that you want to use in documents
69 ;; in `facemenu-listed-faces'.
71 ;;; Known Problems:
72 ;; Bold and Italic do not combine to create bold-italic if you select them
73 ;; both, although most other combinations (eg bold + underline + some color)
74 ;; do the intuitive thing.
76 ;; There is at present no way to display what the faces look like in
77 ;; the menu itself.
79 ;; `list-faces-display' shows the faces in a different order than
80 ;; this menu, which could be confusing. I do /not/ sort the list
81 ;; alphabetically, because I like the default order: it puts the most
82 ;; basic, common fonts first.
84 ;; Please send me any other problems, comments or ideas.
86 ;;; Code:
88 (eval-when-compile
89 (require 'help)
90 (require 'button))
92 ;; Global bindings:
93 (define-key global-map [C-down-mouse-2] 'facemenu-menu)
94 (define-key global-map "\M-o" 'facemenu-keymap)
96 (defgroup facemenu nil
97 "Create a face menu for interactively adding fonts to text."
98 :group 'faces
99 :prefix "facemenu-")
101 (defcustom facemenu-keybindings
102 (mapcar 'purecopy
103 '((default . "d")
104 (bold . "b")
105 (italic . "i")
106 (bold-italic . "l") ; {bold} intersect {italic} = {l}
107 (underline . "u")))
108 "Alist of interesting faces and keybindings.
109 Each element is itself a list: the car is the name of the face,
110 the next element is the key to use as a keyboard equivalent of the menu item;
111 the binding is made in `facemenu-keymap'.
113 The faces specifically mentioned in this list are put at the top of
114 the menu, in the order specified. All other faces which are defined
115 in `facemenu-listed-faces' are listed after them, but get no
116 keyboard equivalents.
118 If you change this variable after loading facemenu.el, you will need to call
119 `facemenu-update' to make it take effect."
120 :type '(repeat (cons face string))
121 :group 'facemenu)
123 (defcustom facemenu-new-faces-at-end t
124 "Where in the menu to insert newly-created faces.
125 This should be nil to put them at the top of the menu, or t to put them
126 just before \"Other\" at the end."
127 :type 'boolean
128 :group 'facemenu)
130 (defcustom facemenu-listed-faces nil
131 "List of faces to include in the Face menu.
132 Each element should be a symbol, the name of a face.
133 The \"basic \" faces in `facemenu-keybindings' are automatically
134 added to the Face menu, and need not be in this list.
136 This value takes effect when you load facemenu.el. If the
137 list includes symbols which are not defined as faces, they
138 are ignored; however, subsequently defining or creating
139 those faces adds them to the menu then. You can call
140 `facemenu-update' to recalculate the menu contents, such as
141 if you change the value of this variable,
143 If this variable is t, all faces that you apply to text
144 using the face menu commands (even by name), and all faces
145 that you define or create, are added to the menu. You may
146 find it useful to set this variable to t temporarily while
147 you define some faces, so that they will be added. However,
148 if the value is no longer t and you call `facemenu-update',
149 it will remove any faces not explicitly in the list."
150 :type '(choice (const :tag "List all faces" t)
151 (const :tag "None" nil)
152 (repeat symbol))
153 :group 'facemenu
154 :version "22.1")
156 (defvar facemenu-face-menu
157 (let ((map (make-sparse-keymap "Face")))
158 (define-key map "o" (cons (purecopy "Other...") 'facemenu-set-face))
159 map)
160 "Menu keymap for faces.")
161 (defalias 'facemenu-face-menu facemenu-face-menu)
162 (put 'facemenu-face-menu 'menu-enable '(facemenu-enable-faces-p))
164 (defvar facemenu-foreground-menu
165 (let ((map (make-sparse-keymap "Foreground Color")))
166 (define-key map "o" (cons (purecopy "Other...") 'facemenu-set-foreground))
167 map)
168 "Menu keymap for foreground colors.")
169 (defalias 'facemenu-foreground-menu facemenu-foreground-menu)
170 (put 'facemenu-foreground-menu 'menu-enable '(facemenu-enable-faces-p))
172 (defvar facemenu-background-menu
173 (let ((map (make-sparse-keymap "Background Color")))
174 (define-key map "o" (cons (purecopy "Other...") 'facemenu-set-background))
175 map)
176 "Menu keymap for background colors.")
177 (defalias 'facemenu-background-menu facemenu-background-menu)
178 (put 'facemenu-background-menu 'menu-enable '(facemenu-enable-faces-p))
180 ;;; Condition for enabling menu items that set faces.
181 (defun facemenu-enable-faces-p ()
182 ;; Enable the facemenu if facemenu-add-face-function is defined
183 ;; (e.g. in Tex-mode and SGML mode), or if font-lock is off.
184 (or (not (and font-lock-mode font-lock-defaults))
185 facemenu-add-face-function))
187 (defvar facemenu-special-menu
188 (let ((map (make-sparse-keymap "Special")))
189 (define-key map [?s] (cons (purecopy "Remove Special")
190 'facemenu-remove-special))
191 (define-key map [?t] (cons (purecopy "Intangible")
192 'facemenu-set-intangible))
193 (define-key map [?v] (cons (purecopy "Invisible")
194 'facemenu-set-invisible))
195 (define-key map [?r] (cons (purecopy "Read-Only")
196 'facemenu-set-read-only))
197 map)
198 "Menu keymap for non-face text-properties.")
199 (defalias 'facemenu-special-menu facemenu-special-menu)
201 (defvar facemenu-justification-menu
202 (let ((map (make-sparse-keymap "Justification")))
203 (define-key map [?c] (cons (purecopy "Center") 'set-justification-center))
204 (define-key map [?b] (cons (purecopy "Full") 'set-justification-full))
205 (define-key map [?r] (cons (purecopy "Right") 'set-justification-right))
206 (define-key map [?l] (cons (purecopy "Left") 'set-justification-left))
207 (define-key map [?u] (cons (purecopy "Unfilled") 'set-justification-none))
208 map)
209 "Submenu for text justification commands.")
210 (defalias 'facemenu-justification-menu facemenu-justification-menu)
212 (defvar facemenu-indentation-menu
213 (let ((map (make-sparse-keymap "Indentation")))
214 (define-key map [decrease-right-margin]
215 (cons (purecopy "Indent Right Less") 'decrease-right-margin))
216 (define-key map [increase-right-margin]
217 (cons (purecopy "Indent Right More") 'increase-right-margin))
218 (define-key map [decrease-left-margin]
219 (cons (purecopy "Indent Less") 'decrease-left-margin))
220 (define-key map [increase-left-margin]
221 (cons (purecopy "Indent More") 'increase-left-margin))
222 map)
223 "Submenu for indentation commands.")
224 (defalias 'facemenu-indentation-menu facemenu-indentation-menu)
226 ;; This is split up to avoid an overlong line in loaddefs.el.
227 (defvar facemenu-menu nil
228 "Facemenu top-level menu keymap.")
229 (setq facemenu-menu (make-sparse-keymap "Text Properties"))
230 (let ((map facemenu-menu))
231 (define-key map [dc] (cons (purecopy "Display Colors") 'list-colors-display))
232 (define-key map [df] (cons (purecopy "Display Faces") 'list-faces-display))
233 (define-key map [dp] (cons (purecopy "Describe Properties")
234 'describe-text-properties))
235 (define-key map [ra] (list 'menu-item (purecopy "Remove Text Properties")
236 'facemenu-remove-all
237 :enable 'mark-active))
238 (define-key map [rm] (list 'menu-item (purecopy "Remove Face Properties")
239 'facemenu-remove-face-props
240 :enable 'mark-active))
241 (define-key map [s1] (list (purecopy "--"))))
242 (let ((map facemenu-menu))
243 (define-key map [in] (cons (purecopy "Indentation")
244 'facemenu-indentation-menu))
245 (define-key map [ju] (cons (purecopy "Justification")
246 'facemenu-justification-menu))
247 (define-key map [s2] (list (purecopy "--")))
248 (define-key map [sp] (cons (purecopy "Special Properties")
249 'facemenu-special-menu))
250 (define-key map [bg] (cons (purecopy "Background Color")
251 'facemenu-background-menu))
252 (define-key map [fg] (cons (purecopy "Foreground Color")
253 'facemenu-foreground-menu))
254 (define-key map [fc] (cons (purecopy "Face")
255 'facemenu-face-menu)))
256 (defalias 'facemenu-menu facemenu-menu)
258 (defvar facemenu-keymap
259 (let ((map (make-sparse-keymap "Set face")))
260 (define-key map "o" (cons (purecopy "Other...") 'facemenu-set-face))
261 (define-key map "\M-o" 'font-lock-fontify-block)
262 map)
263 "Keymap for face-changing commands.
264 `Facemenu-update' fills in the keymap according to the bindings
265 requested in `facemenu-keybindings'.")
266 (defalias 'facemenu-keymap facemenu-keymap)
269 (defcustom facemenu-add-face-function nil
270 "Function called at beginning of text to change or nil.
271 This function is passed the FACE to set and END of text to change, and must
272 return a string which is inserted. It may set `facemenu-end-add-face'."
273 :type '(choice (const :tag "None" nil)
274 function)
275 :group 'facemenu)
277 (defcustom facemenu-end-add-face nil
278 "String to insert or function called at end of text to change or nil.
279 This function is passed the FACE to set, and must return a string which is
280 inserted."
281 :type '(choice (const :tag "None" nil)
282 string
283 function)
284 :group 'facemenu)
286 (defcustom facemenu-remove-face-function nil
287 "When non-nil, this is a function called to remove faces.
288 This function is passed the START and END of text to change.
289 May also be t meaning to use `facemenu-add-face-function'."
290 :type '(choice (const :tag "None" nil)
291 (const :tag "Use add-face" t)
292 function)
293 :group 'facemenu)
295 ;;; Internal Variables
297 (defvar facemenu-color-alist nil
298 "Alist of colors, used for completion.
299 If this is nil, then the value of (defined-colors) is used.")
301 (defun facemenu-update ()
302 "Add or update the \"Face\" menu in the menu bar.
303 You can call this to update things if you change any of the menu configuration
304 variables."
305 (interactive)
307 ;; Add each defined face to the menu.
308 (facemenu-iterate 'facemenu-add-new-face
309 (facemenu-complete-face-list facemenu-keybindings)))
311 (defun facemenu-set-face (face &optional start end)
312 "Apply FACE to the region or next character typed.
314 If the region is active (normally true except in Transient
315 Mark mode) and nonempty, and there is no prefix argument,
316 this command applies FACE to the region. Otherwise, it applies FACE
317 to the faces to use for the next character
318 inserted. (Moving point or switching buffers before typing
319 a character to insert cancels the specification.)
321 If FACE is `default', to \"apply\" it means clearing
322 the list of faces to be used. For any other value of FACE,
323 to \"apply\" it means putting FACE at the front of the list
324 of faces to be used, and removing any faces further
325 along in the list that would be completely overridden by
326 preceding faces (including FACE).
328 This command can also add FACE to the menu of faces,
329 if `facemenu-listed-faces' says to do that."
330 (interactive (list (progn
331 (barf-if-buffer-read-only)
332 (read-face-name "Use face"))
333 (if (and mark-active (not current-prefix-arg))
334 (region-beginning))
335 (if (and mark-active (not current-prefix-arg))
336 (region-end))))
337 (facemenu-add-new-face face)
338 (facemenu-add-face face start end))
340 (defun facemenu-set-foreground (color &optional start end)
341 "Set the foreground COLOR of the region or next character typed.
342 This command reads the color in the minibuffer.
344 If the region is active (normally true except in Transient Mark mode)
345 and there is no prefix argument, this command sets the region to the
346 requested face.
348 Otherwise, this command specifies the face for the next character
349 inserted. Moving point or switching buffers before
350 typing a character to insert cancels the specification."
351 (interactive (list (progn
352 (barf-if-buffer-read-only)
353 (read-color "Foreground color: "))
354 (if (and mark-active (not current-prefix-arg))
355 (region-beginning))
356 (if (and mark-active (not current-prefix-arg))
357 (region-end))))
358 (facemenu-set-face-from-menu
359 (facemenu-add-new-color color 'facemenu-foreground-menu)
360 start end))
362 (defun facemenu-set-background (color &optional start end)
363 "Set the background COLOR of the region or next character typed.
364 This command reads the color in the minibuffer.
366 If the region is active (normally true except in Transient Mark mode)
367 and there is no prefix argument, this command sets the region to the
368 requested face.
370 Otherwise, this command specifies the face for the next character
371 inserted. Moving point or switching buffers before
372 typing a character to insert cancels the specification."
373 (interactive (list (progn
374 (barf-if-buffer-read-only)
375 (read-color "Background color: "))
376 (if (and mark-active (not current-prefix-arg))
377 (region-beginning))
378 (if (and mark-active (not current-prefix-arg))
379 (region-end))))
380 (facemenu-set-face-from-menu
381 (facemenu-add-new-color color 'facemenu-background-menu)
382 start end))
384 (defun facemenu-set-face-from-menu (face start end)
385 "Set the FACE of the region or next character typed.
386 This function is designed to be called from a menu; FACE is determined
387 using the event type of the menu entry. If FACE is a symbol whose
388 name starts with \"fg:\" or \"bg:\", then this functions sets the
389 foreground or background to the color specified by the rest of the
390 symbol's name. Any other symbol is considered the name of a face.
392 If the region is active (normally true except in Transient Mark mode)
393 and there is no prefix argument, this command sets the region to the
394 requested face.
396 Otherwise, this command specifies the face for the next character
397 inserted. Moving point or switching buffers before typing a character
398 to insert cancels the specification."
399 (interactive (list last-command-event
400 (if (and mark-active (not current-prefix-arg))
401 (region-beginning))
402 (if (and mark-active (not current-prefix-arg))
403 (region-end))))
404 (barf-if-buffer-read-only)
405 (facemenu-add-face
406 (let ((fn (symbol-name face)))
407 (if (string-match "\\`\\([fb]\\)g:\\(.+\\)" fn)
408 (list (list (if (string= (match-string 1 fn) "f")
409 :foreground
410 :background)
411 (match-string 2 fn)))
412 face))
413 start end))
415 (defun facemenu-set-invisible (start end)
416 "Make the region invisible.
417 This sets the `invisible' text property; it can be undone with
418 `facemenu-remove-special'."
419 (interactive "r")
420 (add-text-properties start end '(invisible t)))
422 (defun facemenu-set-intangible (start end)
423 "Make the region intangible: disallow moving into it.
424 This sets the `intangible' text property; it can be undone with
425 `facemenu-remove-special'."
426 (interactive "r")
427 (add-text-properties start end '(intangible t)))
429 (defun facemenu-set-read-only (start end)
430 "Make the region unmodifiable.
431 This sets the `read-only' text property; it can be undone with
432 `facemenu-remove-special'."
433 (interactive "r")
434 (add-text-properties start end '(read-only t)))
436 (defun facemenu-remove-face-props (start end)
437 "Remove `face' and `mouse-face' text properties."
438 (interactive "*r") ; error if buffer is read-only despite the next line.
439 (let ((inhibit-read-only t))
440 (remove-text-properties
441 start end '(face nil mouse-face nil))))
443 (defun facemenu-remove-all (start end)
444 "Remove all text properties from the region."
445 (interactive "*r") ; error if buffer is read-only despite the next line.
446 (let ((inhibit-read-only t))
447 (set-text-properties start end nil)))
449 (defun facemenu-remove-special (start end)
450 "Remove all the \"special\" text properties from the region.
451 These special properties include `invisible', `intangible' and `read-only'."
452 (interactive "*r") ; error if buffer is read-only despite the next line.
453 (let ((inhibit-read-only t))
454 (remove-text-properties
455 start end '(invisible nil intangible nil read-only nil))))
457 (defalias 'facemenu-read-color 'read-color)
459 (defcustom list-colors-sort nil
460 "Color sort order for `list-colors-display'.
461 `nil' means default implementation-dependent order (defined in `x-colors').
462 `name' sorts by color name.
463 `rgb' sorts by red, green, blue components.
464 `(rgb-dist . COLOR)' sorts by the RGB distance to the specified color.
465 `hsv' sorts by hue, saturation, value.
466 `(hsv-dist . COLOR)' sorts by the HSV distance to the specified color
467 and excludes grayscale colors.
468 `luminance' sorts by relative luminance in the CIE XYZ color space."
469 :type '(choice (const :tag "Unsorted" nil)
470 (const :tag "Color Name" name)
471 (const :tag "Red-Green-Blue" rgb)
472 (cons :tag "Distance on RGB cube"
473 (const :tag "Distance from Color" rgb-dist)
474 (color :tag "Source Color Name"))
475 (const :tag "Hue-Saturation-Value" hsv)
476 (cons :tag "Distance on HSV cylinder"
477 (const :tag "Distance from Color" hsv-dist)
478 (color :tag "Source Color Name"))
479 (const :tag "Luminance" luminance))
480 :group 'facemenu
481 :version "24.1")
483 (defun list-colors-sort-key (color)
484 "Return a list of keys for sorting colors depending on `list-colors-sort'.
485 COLOR is the name of the color. When return value is nil,
486 filter out the color from the output."
487 (require 'color)
488 (cond
489 ((null list-colors-sort) color)
490 ((eq list-colors-sort 'name)
491 (downcase color))
492 ((eq list-colors-sort 'rgb)
493 (color-values color))
494 ((eq (car-safe list-colors-sort) 'rgb-dist)
495 (color-distance color (cdr list-colors-sort)))
496 ((eq list-colors-sort 'hsv)
497 (apply 'color-rgb-to-hsv (color-name-to-rgb color)))
498 ((eq (car-safe list-colors-sort) 'hsv-dist)
499 (let* ((c-rgb (color-name-to-rgb color))
500 (c-hsv (apply 'color-rgb-to-hsv c-rgb))
501 (o-hsv (apply 'color-rgb-to-hsv
502 (color-name-to-rgb (cdr list-colors-sort)))))
503 (unless (and (eq (nth 0 c-rgb) (nth 1 c-rgb)) ; exclude grayscale
504 (eq (nth 1 c-rgb) (nth 2 c-rgb)))
505 ;; 3D Euclidean distance (sqrt is not needed for sorting)
506 (+ (expt (- 180 (abs (- 180 (abs (- (nth 0 c-hsv) ; wrap hue
507 (nth 0 o-hsv)))))) 2)
508 (expt (- (nth 1 c-hsv) (nth 1 o-hsv)) 2)
509 (expt (- (nth 2 c-hsv) (nth 2 o-hsv)) 2)))))
510 ((eq list-colors-sort 'luminance)
511 (let ((c-rgb (color-name-to-rgb color)))
512 (+ (* (nth 0 c-rgb) 0.21266729)
513 (* (nth 1 c-rgb) 0.7151522)
514 (* (nth 2 c-rgb) 0.0721750))))))
516 (defun list-colors-display (&optional list buffer-name callback)
517 "Display names of defined colors, and show what they look like.
518 If the optional argument LIST is non-nil, it should be a list of
519 colors to display. Otherwise, this command computes a list of
520 colors that the current display can handle. Customize
521 `list-colors-sort' to change the order in which colors are shown.
523 If the optional argument BUFFER-NAME is nil, it defaults to *Colors*.
525 If the optional argument CALLBACK is non-nil, it should be a
526 function to call each time the user types RET or clicks on a
527 color. The function should accept a single argument, the color name."
528 (interactive)
529 (when (and (null list) (> (display-color-cells) 0))
530 (setq list (list-colors-duplicates (defined-colors)))
531 (when list-colors-sort
532 ;; Schwartzian transform with `(color key1 key2 key3 ...)'.
533 (setq list (mapcar
534 'car
535 (sort (delq nil (mapcar
536 (lambda (c)
537 (let ((key (list-colors-sort-key
538 (car c))))
539 (when key
540 (cons c (if (consp key) key
541 (list key))))))
542 list))
543 (lambda (a b)
544 (let* ((a-keys (cdr a))
545 (b-keys (cdr b))
546 (a-key (car a-keys))
547 (b-key (car b-keys)))
548 ;; Skip common keys at the beginning of key lists.
549 (while (and a-key b-key (equal a-key b-key))
550 (setq a-keys (cdr a-keys) a-key (car a-keys)
551 b-keys (cdr b-keys) b-key (car b-keys)))
552 (cond
553 ((and (numberp a-key) (numberp b-key))
554 (< a-key b-key))
555 ((and (stringp a-key) (stringp b-key))
556 (string< a-key b-key)))))))))
557 (when (memq (display-visual-class) '(gray-scale pseudo-color direct-color))
558 ;; Don't show more than what the display can handle.
559 (let ((lc (nthcdr (1- (display-color-cells)) list)))
560 (if lc
561 (setcdr lc nil)))))
562 (unless buffer-name
563 (setq buffer-name "*Colors*"))
564 (with-help-window buffer-name
565 (with-current-buffer standard-output
566 (erase-buffer)
567 (list-colors-print list callback)
568 (set-buffer-modified-p nil)
569 (setq truncate-lines t)))
570 (when callback
571 (pop-to-buffer buffer-name)
572 (message "Click on a color to select it.")))
574 (defun list-colors-print (list &optional callback)
575 (let ((callback-fn
576 (if callback
577 `(lambda (button)
578 (funcall ,callback (button-get button 'color-name))))))
579 (dolist (color list)
580 (if (consp color)
581 (if (cdr color)
582 (setq color (sort color (lambda (a b)
583 (string< (downcase a)
584 (downcase b))))))
585 (setq color (list color)))
586 (let* ((opoint (point))
587 (color-values (color-values (car color)))
588 (light-p (>= (apply 'max color-values)
589 (* (car (color-values "white")) .5))))
590 (insert (car color))
591 (indent-to 22)
592 (put-text-property opoint (point) 'face `(:background ,(car color)))
593 (put-text-property
594 (prog1 (point)
595 (insert " ")
596 ;; Insert all color names.
597 (insert (mapconcat 'identity color ",")))
598 (point)
599 'face (list :foreground (car color)))
600 (insert (propertize " " 'display '(space :align-to (- right 9))))
601 (insert " ")
602 (insert (propertize
603 (apply 'format "#%02x%02x%02x"
604 (mapcar (lambda (c) (lsh c -8))
605 color-values))
606 'mouse-face 'highlight
607 'help-echo
608 (let ((hsv (apply 'color-rgb-to-hsv
609 (color-name-to-rgb (car color)))))
610 (format "H:%d S:%d V:%d"
611 (nth 0 hsv) (nth 1 hsv) (nth 2 hsv)))))
612 (when callback
613 (make-text-button
614 opoint (point)
615 'follow-link t
616 'mouse-face (list :background (car color)
617 :foreground (if light-p "black" "white"))
618 'color-name (car color)
619 'action callback-fn)))
620 (insert "\n"))
621 (goto-char (point-min))))
624 (defun list-colors-duplicates (&optional list)
625 "Return a list of colors with grouped duplicate colors.
626 If a color has no duplicates, then the element of the returned list
627 has the form '(COLOR-NAME). The element of the returned list with
628 duplicate colors has the form '(COLOR-NAME DUPLICATE-COLOR-NAME ...).
629 This function uses the predicate `facemenu-color-equal' to compare
630 color names. If the optional argument LIST is non-nil, it should
631 be a list of colors to display. Otherwise, this function uses
632 a list of colors that the current display can handle."
633 (let* ((list (mapcar 'list (or list (defined-colors))))
634 (l list))
635 (while (cdr l)
636 (if (and (facemenu-color-equal (car (car l)) (car (car (cdr l))))
637 ;; On MS-Windows, there are logical colors that might have
638 ;; the same value but different names and meanings. For
639 ;; example, `SystemMenuText' (the color w32 uses for the
640 ;; text in menu entries) and `SystemWindowText' (the default
641 ;; color w32 uses for the text in windows and dialogs) may
642 ;; be the same display color and be adjacent in the list.
643 ;; These system colors all have names prefixed with "System",
644 ;; which is hardcoded in w32fns.c (SYSTEM_COLOR_PREFIX).
645 ;; This makes them different to any other color. Bug#9722
646 (not (and (eq system-type 'windows-nt)
647 (string-match-p "^System" (car (car l))))))
648 (progn
649 (setcdr (car l) (cons (car (car (cdr l))) (cdr (car l))))
650 (setcdr l (cdr (cdr l))))
651 (setq l (cdr l))))
652 list))
654 (defun facemenu-color-equal (a b)
655 "Return t if colors A and B are the same color.
656 A and B should be strings naming colors.
657 This function queries the display system to find out what the color
658 names mean. It returns nil if the colors differ or if it can't
659 determine the correct answer."
660 (cond ((equal a b) t)
661 ((equal (color-values a) (color-values b)))))
664 (defvar facemenu-self-insert-data nil)
666 (defun facemenu-post-self-insert-function ()
667 (when (and (car facemenu-self-insert-data)
668 (eq last-command (cdr facemenu-self-insert-data)))
669 (put-text-property (1- (point)) (point)
670 'face (car facemenu-self-insert-data))
671 (setq facemenu-self-insert-data nil))
672 (remove-hook 'post-self-insert-hook 'facemenu-post-self-insert-function))
674 (defun facemenu-set-self-insert-face (face)
675 "Arrange for the next self-inserted char to have face `face'."
676 (setq facemenu-self-insert-data (cons face this-command))
677 (add-hook 'post-self-insert-hook 'facemenu-post-self-insert-function))
679 (defun facemenu-add-face (face &optional start end)
680 "Add FACE to text between START and END.
681 If START is nil or START to END is empty, add FACE to next typed character
682 instead. For each section of that region that has a different face property,
683 FACE will be consed onto it, and other faces that are completely hidden by
684 that will be removed from the list.
685 If `facemenu-add-face-function' and maybe `facemenu-end-add-face' are non-nil,
686 they are used to set the face information.
688 As a special case, if FACE is `default', then the region is left with NO face
689 text property. Otherwise, selecting the default face would not have any
690 effect. See `facemenu-remove-face-function'."
691 (interactive "*xFace: \nr")
692 (cond
693 ((and (eq face 'default)
694 (not (eq facemenu-remove-face-function t)))
695 (if facemenu-remove-face-function
696 (funcall facemenu-remove-face-function start end)
697 (if (and start (< start end))
698 (remove-text-properties start end '(face default))
699 (facemenu-set-self-insert-face 'default))))
700 (facemenu-add-face-function
701 (save-excursion
702 (if end (goto-char end))
703 (save-excursion
704 (if start (goto-char start))
705 (insert-before-markers
706 (funcall facemenu-add-face-function face end)))
707 (if facemenu-end-add-face
708 (insert (if (stringp facemenu-end-add-face)
709 facemenu-end-add-face
710 (funcall facemenu-end-add-face face))))))
711 ((and start (< start end))
712 (let ((part-start start) part-end)
713 (while (not (= part-start end))
714 (setq part-end (next-single-property-change part-start 'face
715 nil end))
716 (let ((prev (get-text-property part-start 'face)))
717 (put-text-property part-start part-end 'face
718 (if (null prev)
719 face
720 (facemenu-active-faces
721 (cons face
722 (if (listp prev)
723 prev
724 (list prev)))
725 ;; Specify the selected frame
726 ;; because nil would mean to use
727 ;; the new-frame default settings,
728 ;; and those are usually nil.
729 (selected-frame)))))
730 (setq part-start part-end))))
732 (facemenu-set-self-insert-face
733 (if (eq last-command (cdr facemenu-self-insert-data))
734 (cons face (if (listp (car facemenu-self-insert-data))
735 (car facemenu-self-insert-data)
736 (list (car facemenu-self-insert-data))))
737 face))))
738 (unless (facemenu-enable-faces-p)
739 (message "Font-lock mode will override any faces you set in this buffer")))
741 (defun facemenu-active-faces (face-list &optional frame)
742 "Return from FACE-LIST those faces that would be used for display.
743 This means each face attribute is not specified in a face earlier in FACE-LIST
744 and such a face is therefore active when used to display text.
745 If the optional argument FRAME is given, use the faces in that frame; otherwise
746 use the selected frame. If t, then the global, non-frame faces are used."
747 (let* ((mask-atts (copy-sequence
748 (if (consp (car face-list))
749 (face-attributes-as-vector (car face-list))
750 (or (internal-lisp-face-p (car face-list) frame)
751 (check-face (car face-list))))))
752 (active-list (list (car face-list)))
753 (face-list (cdr face-list))
754 (mask-len (length mask-atts)))
755 (while face-list
756 (if (let ((face-atts
757 (if (consp (car face-list))
758 (face-attributes-as-vector (car face-list))
759 (or (internal-lisp-face-p (car face-list) frame)
760 (check-face (car face-list)))))
761 (i mask-len)
762 (useful nil))
763 (while (>= (setq i (1- i)) 0)
764 (and (not (memq (aref face-atts i) '(nil unspecified)))
765 (memq (aref mask-atts i) '(nil unspecified))
766 (aset mask-atts i (setq useful t))))
767 useful)
768 (setq active-list (cons (car face-list) active-list)))
769 (setq face-list (cdr face-list)))
770 (nreverse active-list)))
772 (defun facemenu-add-new-face (face)
773 "Add FACE (a face) to the Face menu if `facemenu-listed-faces' says so.
774 This is called whenever you create a new face, and at other times."
775 (let* (name
776 symbol
777 menu docstring
778 (key (cdr (assoc face facemenu-keybindings)))
779 function menu-val)
780 (if (symbolp face)
781 (setq name (symbol-name face)
782 symbol face)
783 (setq name face
784 symbol (intern name)))
785 (setq menu 'facemenu-face-menu)
786 (setq docstring
787 (purecopy (format "Select face `%s' for subsequent insertion.
788 If the mark is active and there is no prefix argument,
789 apply face `%s' to the region instead.
790 This command was defined by `facemenu-add-new-face'."
791 name name)))
792 (cond ((facemenu-iterate ; check if equivalent face is already in the menu
793 (lambda (m) (and (listp m)
794 (symbolp (car m))
795 ;; Avoid error in face-equal
796 ;; when a non-face is erroneously present.
797 (facep (car m))
798 (face-equal (car m) symbol)))
799 (cdr (symbol-function menu))))
800 ;; Faces with a keyboard equivalent. These go at the front.
801 (key
802 (setq function (intern (concat "facemenu-set-" name)))
803 (fset function
804 `(lambda ()
805 ,docstring
806 (interactive)
807 (facemenu-set-face
808 (quote ,symbol)
809 (if (and mark-active (not current-prefix-arg))
810 (region-beginning))
811 (if (and mark-active (not current-prefix-arg))
812 (region-end)))))
813 (define-key 'facemenu-keymap key (cons name function))
814 (define-key menu key (cons name function)))
815 ;; Faces with no keyboard equivalent. Figure out where to put it:
816 ((or (eq t facemenu-listed-faces)
817 (memq symbol facemenu-listed-faces))
818 (setq key (vector symbol)
819 function 'facemenu-set-face-from-menu
820 menu-val (symbol-function menu))
821 (if (and facemenu-new-faces-at-end
822 (> (length menu-val) 3))
823 (define-key-after menu-val key (cons name function)
824 (car (nth (- (length menu-val) 3) menu-val)))
825 (define-key menu key (cons name function))))))
826 nil) ; Return nil for facemenu-iterate
828 (defun facemenu-add-new-color (color menu)
829 "Add COLOR (a color name string) to the appropriate Face menu.
830 MENU should be `facemenu-foreground-menu' or `facemenu-background-menu'.
831 Return the event type (a symbol) of the added menu entry.
833 This is called whenever you use a new color."
834 (let (symbol)
835 (unless (color-defined-p color)
836 (error "Color `%s' undefined" color))
837 (cond ((eq menu 'facemenu-foreground-menu)
838 (setq symbol (intern (concat "fg:" color))))
839 ((eq menu 'facemenu-background-menu)
840 (setq symbol (intern (concat "bg:" color))))
841 (t (error "MENU should be `facemenu-foreground-menu' or `facemenu-background-menu'")))
842 (unless (facemenu-iterate ; Check if color is already in the menu.
843 (lambda (m) (and (listp m)
844 (eq (car m) symbol)))
845 (cdr (symbol-function menu)))
846 ;; Color is not in the menu. Figure out where to put it.
847 (let ((key (vector symbol))
848 (function 'facemenu-set-face-from-menu)
849 (menu-val (symbol-function menu)))
850 (if (and facemenu-new-faces-at-end
851 (> (length menu-val) 3))
852 (define-key-after menu-val key (cons color function)
853 (car (nth (- (length menu-val) 3) menu-val)))
854 (define-key menu key (cons color function)))))
855 symbol))
857 (defun facemenu-complete-face-list (&optional oldlist)
858 "Return list of all faces that look different.
859 Starts with given ALIST of faces, and adds elements only if they display
860 differently from any face already on the list.
861 The faces on ALIST will end up at the end of the returned list, in reverse
862 order."
863 (let ((list (nreverse (mapcar 'car oldlist))))
864 (facemenu-iterate
865 (lambda (new-face)
866 (if (not (memq new-face list))
867 (setq list (cons new-face list)))
868 nil)
869 (nreverse (face-list)))
870 list))
872 (defun facemenu-iterate (func list)
873 "Apply FUNC to each element of LIST until one returns non-nil.
874 Returns the non-nil value it found, or nil if all were nil."
875 (while (and list (not (funcall func (car list))))
876 (setq list (cdr list)))
877 (car list))
879 (facemenu-update)
881 (provide 'facemenu)
883 ;;; facemenu.el ends here