build-aux/gitlog-to-changelog

   1 eval '(exit $?0)' && eval 'exec perl -wS "$0" ${1+"$@"}'
   2   & eval 'exec perl -wS "$0" $argv:q'
   3     if 0;
   4 # Convert git log output to ChangeLog format.
   5
   6 my $VERSION = '2015-05-19 01:37'; # UTC
   7 # The definition above must lie within the first 8 lines in order
   8 # for the Emacs time-stamp write hook (at end) to update it.
   9 # If you change this file with Emacs, please let the write hook
  10 # do its job.  Otherwise, update this string manually.
  11
  12 # Copyright (C) 2008-2015 Free Software Foundation, Inc.
  13
  14 # This program is free software: you can redistribute it and/or modify
  15 # it under the terms of the GNU General Public License as published by
  16 # the Free Software Foundation, either version 3 of the License, or
  17 # (at your option) any later version.
  18
  19 # This program is distributed in the hope that it will be useful,
  20 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 # GNU General Public License for more details.
  23
  24 # You should have received a copy of the GNU General Public License
  25 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 # Written by Jim Meyering
  28
  29 use strict;
  30 use warnings;
  31 use Getopt::Long;
  32 use POSIX qw(strftime);
  33
  34 (my $ME = $0) =~ s|.*/||;
  35
  36 # use File::Coda; # http://meyering.net/code/Coda/
  37 END {
  38   defined fileno STDOUT or return;
  39   close STDOUT and return;
  40   warn "$ME: failed to close standard output: $!\n";
  41   $? ||= 1;
  42 }
  43
  44 sub usage ($)
  45 {
  46   my ($exit_code) = @_;
  47   my $STREAM = ($exit_code == 0 ? *STDOUT : *STDERR);
  48   if ($exit_code != 0)
  49     {
  50       print $STREAM "Try '$ME --help' for more information.\n";
  51     }
  52   else
  53     {
  54       print $STREAM <<EOF;
  55 Usage: $ME [OPTIONS] [ARGS]
  56
  57 Convert git log output to ChangeLog format.  If present, any ARGS
  58 are passed to "git log".  To avoid ARGS being parsed as options to
  59 $ME, they may be preceded by '--'.
  60
  61 OPTIONS:
  62
  63    --amend=FILE FILE maps from an SHA1 to perl code (i.e., s/old/new/) that
  64                   makes a change to SHA1's commit log text or metadata.
  65    --append-dot append a dot to the first line of each commit message if
  66                   there is no other punctuation or blank at the end.
  67    --no-cluster never cluster commit messages under the same date/author
  68                   header; the default is to cluster adjacent commit messages
  69                   if their headers are the same and neither commit message
  70                   contains multiple paragraphs.
  71    --srcdir=DIR the root of the source tree, from which the .git/
  72                   directory can be derived.
  73    --since=DATE convert only the logs since DATE;
  74                   the default is to convert all log entries.
  75    --until=DATE convert only the logs older than DATE.
  76    --ignore-matching=PAT ignore commit messages whose first lines match PAT.
  77    --ignore-line=PAT ignore lines of commit messages that match PAT.
  78    --format=FMT set format string for commit subject and body;
  79                   see 'man git-log' for the list of format metacharacters;
  80                   the default is '%s%n%b%n'
  81    --strip-tab  remove one additional leading TAB from commit message lines.
  82    --strip-cherry-pick  remove data inserted by "git cherry-pick";
  83                   this includes the "cherry picked from commit ..." line,
  84                   and the possible final "Conflicts:" paragraph.
  85    --help       display this help and exit
  86    --version    output version information and exit
  87
  88 EXAMPLE:
  89
  90   $ME --since=2008-01-01 > ChangeLog
  91   $ME -- -n 5 foo > last-5-commits-to-branch-foo
  92
  93 SPECIAL SYNTAX:
  94
  95 The following types of strings are interpreted specially when they appear
  96 at the beginning of a log message line.  They are not copied to the output.
  97
  98   Copyright-paperwork-exempt: Yes
  99     Append the "(tiny change)" notation to the usual "date name email"
 100     ChangeLog header to mark a change that does not require a copyright
 101     assignment.
 102   Co-authored-by: Joe User <user\@example.com>
 103     List the specified name and email address on a second
 104     ChangeLog header, denoting a co-author.
 105   Signed-off-by: Joe User <user\@example.com>
 106     These lines are simply elided.
 107
 108 In a FILE specified via --amend, comment lines (starting with "#") are ignored.
 109 FILE must consist of <SHA,CODE+> pairs where SHA is a 40-byte SHA1 (alone on
 110 a line) referring to a commit in the current project, and CODE refers to one
 111 or more consecutive lines of Perl code.  Pairs must be separated by one or
 112 more blank line.
 113
 114 Here is sample input for use with --amend=FILE, from coreutils:
 115
 116 3a169f4c5d9159283548178668d2fae6fced3030
 117 # fix typo in title:
 118 s/all tile types/all file types/
 119
 120 1379ed974f1fa39b12e2ffab18b3f7a607082202
 121 # Due to a bug in vc-dwim, I mis-attributed a patch by Paul to myself.
 122 # Change the author to be Paul.  Note the escaped "@":
 123 s,Jim .*>,Paul Eggert <eggert\\\@cs.ucla.edu>,
 124
 125 EOF
 126     }
 127   exit $exit_code;
 128 }
 129
 130 # If the string $S is a well-behaved file name, simply return it.
 131 # If it contains white space, quotes, etc., quote it, and return the new string.
 132 sub shell_quote($)
 133 {
 134   my ($s) = @_;
 135   if ($s =~ m![^\w+/.,-]!)
 136     {
 137       # Convert each single quote to '\''
 138       $s =~ s/\'/\'\\\'\'/g;
 139       # Then single quote the string.
 140       $s = "'$s'";
 141     }
 142   return $s;
 143 }
 144
 145 sub quoted_cmd(@)
 146 {
 147   return join (' ', map {shell_quote $_} @_);
 148 }
 149
 150 # Parse file F.
 151 # Comment lines (starting with "#") are ignored.
 152 # F must consist of <SHA,CODE+> pairs where SHA is a 40-byte SHA1
 153 # (alone on a line) referring to a commit in the current project, and
 154 # CODE refers to one or more consecutive lines of Perl code.
 155 # Pairs must be separated by one or more blank line.
 156 sub parse_amend_file($)
 157 {
 158   my ($f) = @_;
 159
 160   open F, '<', $f
 161     or die "$ME: $f: failed to open for reading: $!\n";
 162
 163   my $fail;
 164   my $h = {};
 165   my $in_code = 0;
 166   my $sha;
 167   while (defined (my $line = <F>))
 168     {
 169       $line =~ /^\#/
 170         and next;
 171       chomp $line;
 172       $line eq ''
 173         and $in_code = 0, next;
 174
 175       if (!$in_code)
 176         {
 177           $line =~ /^([0-9a-fA-F]{40})$/
 178             or (warn "$ME: $f:$.: invalid line; expected an SHA1\n"),
 179               $fail = 1, next;
 180           $sha = lc $1;
 181           $in_code = 1;
 182           exists $h->{$sha}
 183             and (warn "$ME: $f:$.: duplicate SHA1\n"),
 184               $fail = 1, next;
 185         }
 186       else
 187         {
 188           $h->{$sha} ||= '';
 189           $h->{$sha} .= "$line\n";
 190         }
 191     }
 192   close F;
 193
 194   $fail
 195     and exit 1;
 196
 197   return $h;
 198 }
 199
 200 # git_dir_option $SRCDIR
 201 #
 202 # From $SRCDIR, the --git-dir option to pass to git (none if $SRCDIR
 203 # is undef).  Return as a list (0 or 1 element).
 204 sub git_dir_option($)
 205 {
 206   my ($srcdir) = @_;
 207   my @res = ();
 208   if (defined $srcdir)
 209     {
 210       my $qdir = shell_quote $srcdir;
 211       my $cmd = "cd $qdir && git rev-parse --show-toplevel";
 212       my $qcmd = shell_quote $cmd;
 213       my $git_dir = qx($cmd);
 214       defined $git_dir
 215         or die "$ME: cannot run $qcmd: $!\n";
 216       $? == 0
 217         or die "$ME: $qcmd had unexpected exit code or signal ($?)\n";
 218       chomp $git_dir;
 219       push @res, "--git-dir=$git_dir/.git";
 220     }
 221   @res;
 222 }
 223
 224 {
 225   my $since_date;
 226   my $until_date;
 227   my $format_string = '%s%n%b%n';
 228   my $amend_file;
 229   my $append_dot = 0;
 230   my $cluster = 1;
 231   my $ignore_matching;
 232   my $ignore_line;
 233   my $strip_tab = 0;
 234   my $strip_cherry_pick = 0;
 235   my $srcdir;
 236   GetOptions
 237     (
 238      help => sub { usage 0 },
 239      version => sub { print "$ME version $VERSION\n"; exit },
 240      'since=s' => \$since_date,
 241      'until=s' => \$until_date,
 242      'format=s' => \$format_string,
 243      'amend=s' => \$amend_file,
 244      'append-dot' => \$append_dot,
 245      'cluster!' => \$cluster,
 246      'ignore-matching=s' => \$ignore_matching,
 247      'ignore-line=s' => \$ignore_line,
 248      'strip-tab' => \$strip_tab,
 249      'strip-cherry-pick' => \$strip_cherry_pick,
 250      'srcdir=s' => \$srcdir,
 251     ) or usage 1;
 252
 253   defined $since_date
 254     and unshift @ARGV, "--since=$since_date";
 255   defined $until_date
 256     and unshift @ARGV, "--until=$until_date";
 257
 258   # This is a hash that maps an SHA1 to perl code (i.e., s/old/new/)
 259   # that makes a correction in the log or attribution of that commit.
 260   my $amend_code = defined $amend_file ? parse_amend_file $amend_file : {};
 261
 262   my @cmd = ('git',
 263              git_dir_option $srcdir,
 264              qw(log --log-size),
 265              '--pretty=format:%H:%ct  %an  <%ae>%n%n'.$format_string, @ARGV);
 266   open PIPE, '-|', @cmd
 267     or die ("$ME: failed to run '". quoted_cmd (@cmd) ."': $!\n"
 268             . "(Is your Git too old?  Version 1.5.1 or later is required.)\n");
 269
 270   my $prev_multi_paragraph;
 271   my $prev_date_line = '';
 272   my @prev_coauthors = ();
 273   while (1)
 274     {
 275       defined (my $in = <PIPE>)
 276         or last;
 277       $in =~ /^log size (\d+)$/
 278         or die "$ME:$.: Invalid line (expected log size):\n$in";
 279       my $log_nbytes = $1;
 280
 281       my $log;
 282       my $n_read = read PIPE, $log, $log_nbytes;
 283       $n_read == $log_nbytes
 284         or die "$ME:$.: unexpected EOF\n";
 285
 286       # Extract leading hash.
 287       my ($sha, $rest) = split ':', $log, 2;
 288       defined $sha
 289         or die "$ME:$.: malformed log entry\n";
 290       $sha =~ /^[0-9a-fA-F]{40}$/
 291         or die "$ME:$.: invalid SHA1: $sha\n";
 292
 293       # If this commit's log requires any transformation, do it now.
 294       my $code = $amend_code->{$sha};
 295       if (defined $code)
 296         {
 297           eval 'use Safe';
 298           my $s = new Safe;
 299           # Put the unpreprocessed entry into "$_".
 300           $_ = $rest;
 301
 302           # Let $code operate on it, safely.
 303           my $r = $s->reval("$code")
 304             or die "$ME:$.:$sha: failed to eval \"$code\":\n$@\n";
 305
 306           # Note that we've used this entry.
 307           delete $amend_code->{$sha};
 308
 309           # Update $rest upon success.
 310           $rest = $_;
 311         }
 312
 313       # Remove lines inserted by "git cherry-pick".
 314       if ($strip_cherry_pick)
 315         {
 316           $rest =~ s/^\s*Conflicts:\n.*//sm;
 317           $rest =~ s/^\s*\(cherry picked from commit [\da-f]+\)\n//m;
 318         }
 319
 320       my @line = split /\s*\n/, $rest;
 321       my $author_line = shift @line;
 322       defined $author_line
 323         or die "$ME:$.: unexpected EOF\n";
 324       $author_line =~ /^(\d+)  (.*>)$/
 325         or die "$ME:$.: Invalid line "
 326           . "(expected date/author/email):\n$author_line\n";
 327
 328       # Format 'Copyright-paperwork-exempt: Yes' as a standard ChangeLog
 329       # `(tiny change)' annotation.
 330       my $tiny = (grep (/^(?:Copyright-paperwork-exempt|Tiny-change):\s+[Yy]es$/, @line)
 331                   ? '  (tiny change)' : '');
 332
 333       my $date_line = sprintf "%s  %s$tiny\n",
 334         strftime ("%Y-%m-%d", localtime ($1)), $2;
 335
 336       my @coauthors = grep /^Co-authored-by:.*$/, @line;
 337       # Omit meta-data lines we've already interpreted.
 338       @line = grep !/^(?:Signed-off-by:[ ].*>$
 339                        |Co-authored-by:[ ]
 340                        |Copyright-paperwork-exempt:[ ]
 341                        |Tiny-change:[ ]
 342                        )/x, @line;
 343
 344       # Remove leading and trailing blank lines.
 345       if (@line)
 346         {
 347           while ($line[0] =~ /^\s*$/) { shift @line; }
 348           while ($line[$#line] =~ /^\s*$/) { pop @line; }
 349         }
 350
 351       # Ignore commits that match the --ignore-matching pattern, if specified.
 352       if (! (defined $ignore_matching
 353              && @line && $line[0] =~ /$ignore_matching/))
 354         {
 355           if (defined $ignore_line && @line)
 356             {
 357               @line = grep ! /$ignore_line/, @line;
 358               while ($line[$#line] =~ /^\s*$/) { pop @line; }
 359             }
 360
 361           # Record whether there are two or more paragraphs.
 362           my $multi_paragraph = grep /^\s*$/, @line;
 363
 364           # Format 'Co-authored-by: A U Thor <email@example.com>' lines in
 365           # standard multi-author ChangeLog format.
 366           for (@coauthors)
 367             {
 368               s/^Co-authored-by:\s*/\t    /;
 369               s/\s*</  </;
 370
 371               /<.*?@.*\..*>/
 372                 or warn "$ME: warning: missing email address for "
 373                   . substr ($_, 5) . "\n";
 374             }
 375
 376           # If clustering of commit messages has been disabled, if this header
 377           # would be different from the previous date/name/etc. header,
 378           # or if this or the previous entry consists of two or more paragraphs,
 379           # then print the header.
 380           if ( ! $cluster
 381               || $date_line ne $prev_date_line
 382               || "@coauthors" ne "@prev_coauthors"
 383               || $multi_paragraph
 384               || $prev_multi_paragraph)
 385             {
 386               $prev_date_line eq ''
 387                 or print "\n";
 388               print $date_line;
 389               @coauthors
 390                 and print join ("\n", @coauthors), "\n";
 391             }
 392           $prev_date_line = $date_line;
 393           @prev_coauthors = @coauthors;
 394           $prev_multi_paragraph = $multi_paragraph;
 395
 396           # If there were any lines
 397           if (@line == 0)
 398             {
 399               warn "$ME: warning: empty commit message:\n  $date_line\n";
 400             }
 401           else
 402             {
 403               if ($append_dot)
 404                 {
 405                   # If the first line of the message has enough room, then
 406                   if (length $line[0] < 72)
 407                     {
 408                       # append a dot if there is no other punctuation or blank
 409                       # at the end.
 410                       $line[0] =~ /[[:punct:]\s]$/
 411                         or $line[0] .= '.';
 412                     }
 413                 }
 414
 415               # Remove one additional leading TAB from each line.
 416               $strip_tab
 417                 and map { s/^\t// } @line;
 418
 419               # Prefix each non-empty line with a TAB.
 420               @line = map { length $_ ? "\t$_" : '' } @line;
 421
 422               print "\n", join ("\n", @line), "\n";
 423             }
 424         }
 425
 426       defined ($in = <PIPE>)
 427         or last;
 428       $in ne "\n"
 429         and die "$ME:$.: unexpected line:\n$in";
 430     }
 431
 432   close PIPE
 433     or die "$ME: error closing pipe from " . quoted_cmd (@cmd) . "\n";
 434   # FIXME-someday: include $PROCESS_STATUS in the diagnostic
 435
 436   # Complain about any unused entry in the --amend=F specified file.
 437   my $fail = 0;
 438   foreach my $sha (keys %$amend_code)
 439     {
 440       warn "$ME:$amend_file: unused entry: $sha\n";
 441       $fail = 1;
 442     }
 443
 444   exit $fail;
 445 }
 446
 447 # Local Variables:
 448 # mode: perl
 449 # indent-tabs-mode: nil
 450 # eval: (add-hook 'write-file-hooks 'time-stamp)
 451 # time-stamp-start: "my $VERSION = '"
 452 # time-stamp-format: "%:y-%02m-%02d %02H:%02M"
 453 # time-stamp-time-zone: "UTC"
 454 # time-stamp-end: "'; # UTC"
 455 # End: