| blob | e71fbc37919eb2378a9137ac64fd9a1d0152f0f7 |
1 dnl Autoconf script for GNU Emacs
2 dnl To rebuild the `configure' script from this, execute the command
3 dnl autoconf
4 dnl in the directory containing this script.
5 dnl
6 dnl Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003
7 dnl Free Software Foundation, Inc.
8 dnl
9 dnl This file is part of GNU Emacs.
10 dnl
11 dnl GNU Emacs is free software; you can redistribute it and/or modify
12 dnl it under the terms of the GNU General Public License as published by
13 dnl the Free Software Foundation; either version 2, or (at your option)
14 dnl any later version.
15 dnl
16 dnl GNU Emacs is distributed in the hope that it will be useful,
17 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
18 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
19 dnl GNU General Public License for more details.
20 dnl
21 dnl You should have received a copy of the GNU General Public License
22 dnl along with GNU Emacs; see the file COPYING. If not, write to the
23 dnl Free Software Foundation, Inc., 59 Temple Place - Suite 330,
24 dnl Boston, MA 02111-1307, USA.
26 AC_PREREQ(2.54)dnl
27 AC_INIT(src/lisp.h)
28 AC_CONFIG_HEADER(src/config.h:src/config.in)
30 dnl Support for --program-prefix, --program-suffix and
31 dnl --program-transform-name options
32 AC_ARG_PROGRAM
34 lispdir='${datadir}/emacs/${version}/lisp'
35 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
36 '${datadir}/emacs/site-lisp:${datadir}/emacs/${version}/leim'
37 lisppath='${locallisppath}:${lispdir}'
38 etcdir='${datadir}/emacs/${version}/etc'
39 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
40 docdir='${datadir}/emacs/${version}/etc'
41 gamedir='${localstatedir}/games/emacs'
43 gameuser=games
45 AC_ARG_WITH(gcc,
46 [ --without-gcc don't use GCC to compile Emacs if GCC is found])
47 AC_ARG_WITH(pop,
48 [ --without-pop don't support POP mail retrieval with movemail],
49 [if test "$withval" = yes; then
50 AC_DEFINE(MAIL_USE_POP)
51 else :
52 fi],
53 AC_DEFINE(MAIL_USE_POP))
54 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
55 AC_ARG_WITH(kerberos,
56 [ --with-kerberos support Kerberos-authenticated POP],
57 [AC_DEFINE(KERBEROS)])
58 AH_TEMPLATE(KERBEROS,
59 [Define to support Kerberos-authenticated POP mail retrieval.])dnl
60 AC_ARG_WITH(kerberos5,
61 [ --with-kerberos5 support Kerberos version 5 authenticated POP],
62 [if test "${with_kerberos5+set}" = set; then
63 if test "${with_kerberos+set}" != set; then
64 with_kerberos=yes
65 AC_DEFINE(KERBEROS)
66 fi
67 fi
68 AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])])
69 AC_ARG_WITH(hesiod,
70 [ --with-hesiod support Hesiod to get the POP server host],
71 [AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])])
73 AC_ARG_WITH(sound,
74 [ --without-sound don't compile with sound support])
76 dnl This should be the last --with option, because --with-x is
77 dnl added later on when we find the path of X, and it's best to
78 dnl keep them together visually.
79 AC_ARG_WITH(x-toolkit,
80 [ --with-x-toolkit=KIT use an X toolkit
81 (KIT = yes/lucid/athena/motif/gtk/no)],
82 [ case "${withval}" in
83 y | ye | yes ) val=athena ;;
84 n | no ) val=no ;;
85 l | lu | luc | luci | lucid ) val=lucid ;;
86 a | at | ath | athe | athen | athena ) val=athena ;;
87 m | mo | mot | moti | motif ) val=motif ;;
88 g | gt | gtk ) val=gtk ;;
89 dnl These don't currently work.
90 dnl o | op | ope | open | open- | open-l | open-lo \
91 dnl | open-loo | open-look ) val=open-look ;;
92 * )
93 dnl AC_MSG_ERROR([the `--with-x-toolkit' option is supposed to have a value
94 dnl which is `yes', `no', `lucid', `athena', `motif' or `open-look'.])
95 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid\;
96 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
97 Currently, `yes', `athena' and `lucid' are synonyms.])
98 ;;
99 esac
100 with_x_toolkit=$val
101 ])
102 AC_ARG_WITH(xpm,
103 [ --with-xpm use -lXpm for displaying XPM images])
104 AC_ARG_WITH(jpeg,
105 [ --with-jpeg use -ljpeg for displaying JPEG images])
106 AC_ARG_WITH(tiff,
107 [ --with-tiff use -ltiff for displaying TIFF images])
108 AC_ARG_WITH(gif,
109 [ --with-gif use -lungif for displaying GIF images])
110 AC_ARG_WITH(png,
111 [ --with-png use -lpng for displaying PNG images])
112 AC_ARG_WITH(gtk,
113 [ --with-gtk use GTK (same as --with-x-toolkit=gtk)])
114 AC_ARG_WITH(pkg-config-prog,
115 [ --with-pkg-config-prog Path to pkg-config to use for finding GTK])
116 AC_ARG_WITH(toolkit-scroll-bars,
117 [ --without-toolkit-scroll-bars
118 don't use Motif or Xaw3d scroll bars])
119 AC_ARG_WITH(xim,
120 [ --without-xim don't use X11 XIM])
121 AC_ARG_WITH(carbon,
122 [ --without-carbon don't use Carbon GUI on Mac OS X])
123 AC_ARG_ENABLE(carbon-app,
124 [[ --enable-carbon-app[=DIR] [DIR=/Application]
125 specify install directory for Emacs.app on Mac OS X]],
126 [ carbon_appdir_x=${enableval}])
128 #### Make srcdir absolute, if it isn't already. It's important to
129 #### avoid running the path through pwd unnecessarily, since pwd can
130 #### give you automounter prefixes, which can go away. We do all this
131 #### so Emacs can find its files when run uninstalled.
132 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
133 unset CDPATH
134 case "${srcdir}" in
135 /* ) ;;
136 . )
137 ## We may be able to use the $PWD environment variable to make this
138 ## absolute. But sometimes PWD is inaccurate.
139 ## Note: we used to use ${PWD} at the end instead of `pwd`,
140 ## but that tested only for a well-formed and valid PWD,
141 ## it did not object when PWD was well-formed and valid but just wrong.
142 if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`" ;
143 then
144 srcdir="$PWD"
145 else
146 srcdir="`(cd ${srcdir}; pwd)`"
147 fi
148 ;;
149 * ) srcdir="`(cd ${srcdir}; pwd)`" ;;
150 esac
152 #### Check if the source directory already has a configured system in it.
153 if test `pwd` != `(cd ${srcdir} && pwd)` \
154 && test -f "${srcdir}/src/config.h" ; then
155 AC_MSG_WARN([[The directory tree `${srcdir}' is being used
156 as a build directory right now; it has been configured in its own
157 right. To configure in another directory as well, you MUST
158 use GNU make. If you do not have GNU make, then you must
159 now do `make distclean' in ${srcdir},
160 and then run $0 again.]])
162 [extrasub='/^VPATH[ ]*=/c\
163 vpath %.c $(srcdir)\
164 vpath %.h $(srcdir)\
165 vpath %.y $(srcdir)\
166 vpath %.l $(srcdir)\
167 vpath %.s $(srcdir)\
168 vpath %.in $(srcdir)\
169 vpath %.texi $(srcdir)']
170 fi
172 #### Given the configuration name, set machfile and opsysfile to the
173 #### names of the m/*.h and s/*.h files we should use.
175 ### Canonicalize the configuration name.
177 AC_CANONICAL_HOST
178 canonical=$host
179 configuration=${host_alias-$host}
181 dnl This used to use changequote, but, apart from `changequote is evil'
182 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
183 dnl the great gob of text. Thus it's not processed for possible expansion.
184 dnl Just make sure the brackets remain balanced.
185 dnl
186 dnl Since Emacs can't find matching pairs of quotes, boundaries are
187 dnl indicated by comments.
188 dnl quotation begins
189 [
191 ### If you add support for a new configuration, add code to this
192 ### switch statement to recognize your configuration name and select
193 ### the appropriate operating system and machine description files.
195 ### You would hope that you could choose an m/*.h file pretty much
196 ### based on the machine portion of the configuration name, and an s-
197 ### file based on the operating system portion. However, it turns out
198 ### that each m/*.h file is pretty manufacturer-specific - for
199 ### example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
200 ### all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
201 ### machines. So we basically have to have a special case for each
202 ### configuration name.
203 ###
204 ### As far as handling version numbers on operating systems is
205 ### concerned, make sure things will fail in a fixable way. If
206 ### /etc/MACHINES doesn't say anything about version numbers, be
207 ### prepared to handle anything reasonably. If version numbers
208 ### matter, be sure /etc/MACHINES says something about it.
209 ###
210 ### Eric Raymond says we should accept strings like "sysvr4" to mean
211 ### "System V Release 4"; he writes, "The old convention encouraged
212 ### confusion between `system' and `release' levels'."
214 machine='' opsys='' unported=no
215 case "${canonical}" in
217 ## FreeBSD ports
218 *-*-freebsd* )
219 opsys=freebsd
220 case "${canonical}" in
221 alpha*-*-freebsd*) machine=alpha ;;
222 i[3456]86-*-freebsd*) machine=intel386 ;;
223 esac
224 ;;
226 ## NetBSD ports
227 *-*-netbsd* )
228 opsys=netbsd
229 if test -f /usr/lib/crti.o; then]
230 dnl The close and open brackets here are because this section is quoted --
231 dnl see the `changequote' comment above.
232 AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
233 [ fi
235 case "${canonical}" in
236 alpha*-*-netbsd*) machine=alpha ;;
237 i[3456]86-*-netbsd*) machine=intel386 ;;
238 m68k-*-netbsd*)
239 # This is somewhat bogus.
240 machine=hp9000s300 ;;
241 powerpc-apple-netbsd*) machine=macppc ;;
242 mips-*-netbsd*) machine=pmax ;;
243 mipsel-*-netbsd*) machine=pmax ;;
244 mipseb-*-netbsd*) machine=pmax ;;
245 ns32k-*-netbsd*) machine=ns32000 ;;
246 powerpc-*-netbsd*) machine=macppc ;;
247 sparc*-*-netbsd*) machine=sparc ;;
248 vax-*-netbsd*) machine=vax ;;
249 arm-*-netbsd*) machine=arm ;;
250 esac
251 ;;
253 ## OpenBSD ports
254 *-*-openbsd* )
255 opsys=openbsd
256 case "${canonical}" in
257 alpha*-*-openbsd*) machine=alpha ;;
258 i386-*-openbsd*) machine=intel386 ;;
259 m68k-*-openbsd*) machine=hp9000s300 ;;
260 mipsel-*-openbsd*) machine=pmax ;;
261 ns32k-*-openbsd*) machine=ns32000 ;;
262 sparc-*-openbsd*) machine=sparc ;;
263 vax-*-openbsd*) machine=vax ;;
264 esac
265 ;;
267 ## Acorn RISCiX:
268 arm-acorn-riscix1.1* )
269 machine=acorn opsys=riscix1-1
270 ;;
271 arm-acorn-riscix1.2* | arm-acorn-riscix )
272 ## This name is riscix12 instead of riscix1.2
273 ## to avoid a file name conflict on MSDOS.
274 machine=acorn opsys=riscix12
275 ;;
277 ## BSDI ports
278 *-*-bsdi* )
279 opsys=bsdi
280 case "${canonical}" in
281 i[345]86-*-bsdi*) machine=intel386 ;;
282 sparc-*-bsdi*) machine=sparc ;;
283 powerpc-*-bsdi*) machine=macppc ;;
284 esac
285 case "${canonical}" in
286 *-*-bsd386* | *-*-bsdi1* ) opsys=bsd386 ;;
287 *-*-bsdi2.0* ) opsys=bsdos2 ;;
288 *-*-bsdi2* ) opsys=bsdos2-1 ;;
289 *-*-bsdi3* ) opsys=bsdos3 ;;
290 *-*-bsdi[45]* ) opsys=bsdos4 ;;
291 esac
292 ;;
294 ## Alliant machines
295 ## Strictly speaking, we need the version of the alliant operating
296 ## system to choose the right machine file, but currently the
297 ## configuration name doesn't tell us enough to choose the right
298 ## one; we need to give alliants their own operating system name to
299 ## do this right. When someone cares, they can help us.
300 fx80-alliant-* )
301 machine=alliant4 opsys=bsd4-2
302 ;;
303 i860-alliant-* )
304 machine=alliant-2800 opsys=bsd4-3
305 ;;
307 ## Alpha (DEC) machines.
308 alpha*-dec-osf* )
309 machine=alpha opsys=osf1
310 # This is needed to find X11R6.1 libraries for certain tests.
311 NON_GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
312 GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
313 # NON_GNU_CPP is necessary on 5.0 to avoid mangling src/Makefile
314 # due to non-traditional preprocessing with the current compiler
315 # defaults. OSF 4 can also have that compiler version, and there
316 # seems always to have been a usable /usr/bin/cpp.
317 NON_GNU_CPP=/usr/bin/cpp
318 case "${canonical}" in
319 alpha*-dec-osf[5-9]*)
320 opsys=osf5-0 ;;
321 esac
322 ;;
324 alpha*-*-linux-gnu* )
325 machine=alpha opsys=gnu-linux
326 ;;
328 arm*-*-linux-gnu* )
329 machine=arm opsys=gnu-linux
330 ;;
332 ppc-*-linux | \
333 powerpc-*-linux* )
334 machine=macppc opsys=gnu-linux
335 ;;
337 ## Altos 3068
338 m68*-altos-sysv* )
339 machine=altos opsys=usg5-2
340 ;;
342 ## Amdahl UTS
343 580-amdahl-sysv* )
344 machine=amdahl opsys=usg5-2-2
345 ;;
347 ## Apollo, Domain/OS
348 m68*-apollo-* )
349 machine=apollo opsys=bsd4-3
350 ;;
352 ## AT&T 3b2, 3b5, 3b15, 3b20
353 we32k-att-sysv* )
354 machine=att3b opsys=usg5-2-2
355 ;;
357 ## AT&T 3b1 - The Mighty Unix PC!
358 m68*-att-sysv* )
359 machine=7300 opsys=usg5-2-2
360 ;;
362 ## Bull dpx20
363 rs6000-bull-bosx* )
364 machine=ibmrs6000 opsys=aix3-2
365 ;;
367 ## Bull dpx2
368 m68*-bull-sysv3* )
369 machine=dpx2 opsys=usg5-3
370 ;;
372 ## Bull sps7
373 m68*-bull-sysv2* )
374 machine=sps7 opsys=usg5-2
375 ;;
377 ## CCI 5/32, 6/32 -- see "Tahoe".
379 ## Celerity
380 ## I don't know what configuration name to use for this; config.sub
381 ## doesn't seem to know anything about it. Hey, Celerity users, get
382 ## in touch with us!
383 celerity-celerity-bsd* )
384 machine=celerity opsys=bsd4-2
385 ;;
387 ## Clipper
388 ## What operating systems does this chip run that Emacs has been
389 ## tested on?
390 clipper-* )
391 machine=clipper
392 ## We'll use the catch-all code at the bottom to guess the
393 ## operating system.
394 ;;
396 ## Compaq Nonstop
397 mips-compaq-nonstopux* )
398 machine=nonstopux opsys=nonstopux
399 ;;
401 ## Convex
402 *-convex-bsd* | *-convex-convexos* )
403 machine=convex opsys=bsd4-3
404 ## Prevents spurious white space in makefiles - d.m.cooke@larc.nasa.gov
405 NON_GNU_CPP="cc -E -P"
406 ;;
408 ## Cubix QBx/386
409 i[3456]86-cubix-sysv* )
410 machine=intel386 opsys=usg5-3
411 ;;
413 ## Cydra 5
414 cydra*-cydrome-sysv* )
415 machine=cydra5 opsys=usg5-3
416 ;;
418 ## Data General AViiON Machines
419 ## DG changed naming conventions with the release of 5.4.4.10, they
420 ## dropped the initial 5.4 but left the intervening R. Because of the
421 ## R this shouldn't conflict with older versions of the OS (which I
422 ## think were named like dgux4.*). In addition, DG new AViiONs series
423 ## uses either Motorola M88k or Intel Pentium CPUs.
424 m88k-dg-dguxR4.* | m88k-dg-dgux4* )
425 machine=aviion opsys=dgux4
426 ;;
427 m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* )
428 ## This name is dgux5-4-3 instead of dgux5-4r3
429 ## to avoid a file name conflict on MSDOS.
430 machine=aviion opsys=dgux5-4-3
431 ;;
432 m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* )
433 machine=aviion opsys=dgux5-4r2
434 ;;
435 m88k-dg-dgux* )
436 machine=aviion opsys=dgux
437 ;;
439 ## Data General AViiON Intel (x86) Machines
440 ## Exists from 5.4.3 (current i586-dg-dguxR4.11)
441 ## Ehud Karni, 1998-may-30, ehud@unix.simonwiesel.co.il
442 i[345]86-dg-dguxR4* )
443 machine=aviion-intel opsys=dgux4
444 ;;
446 ## DECstations
447 mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
448 machine=pmax opsys=bsd4-2
449 ;;
450 mips-dec-ultrix4.[12]* | mips-dec-bsd* )
451 machine=pmax opsys=bsd4-3
452 ;;
453 mips-dec-ultrix* )
454 machine=pmax opsys=ultrix4-3
455 ;;
456 mips-dec-osf* )
457 machine=pmax opsys=osf1
458 ;;
459 mips-dec-mach_bsd4.3* )
460 machine=pmax opsys=mach-bsd4-3
461 ;;
463 ## Motorola Delta machines
464 m68k-motorola-sysv* | m68000-motorola-sysv* )
465 machine=delta opsys=usg5-3
466 if test -z "`type gnucc | grep 'not found'`"
467 then
468 if test -s /etc/167config
469 then CC="gnucc -m68040"
470 else CC="gnucc -m68881"
471 fi
472 else
473 if test -z "`type gcc | grep 'not found'`"
474 then CC=gcc
475 else CC=cc
476 fi
477 fi
478 ;;
479 m88k-motorola-sysv4* )
480 # jbotte@bnr.ca says that UNIX_System_V <hostName> 4.0 R40V4.3 m88k mc88110
481 # needs POSIX_SIGNALS and therefore needs usg5-4-2.
482 # I hope there are not other 4.0 versions for this machine
483 # which really need usg5-4 instead.
484 machine=delta88k opsys=usg5-4-2
485 ;;
486 m88k-motorola-sysv* | m88k-motorola-m88kbcs* )
487 machine=delta88k opsys=usg5-3
488 ;;
490 ## Dual machines
491 m68*-dual-sysv* )
492 machine=dual opsys=usg5-2
493 ;;
494 m68*-dual-uniplus* )
495 machine=dual opsys=unipl5-2
496 ;;
498 ## Elxsi 6400
499 elxsi-elxsi-sysv* )
500 machine=elxsi opsys=usg5-2
501 ;;
503 ## Encore machines
504 ns16k-encore-bsd* )
505 machine=ns16000 opsys=umax
506 ;;
508 ## The GEC 63 - apparently, this port isn't really finished yet.
509 # I'm sure we finished off the last of the machines, though. -- fx
511 ## Gould Power Node and NP1
512 pn-gould-bsd4.2* )
513 machine=gould opsys=bsd4-2
514 ;;
515 pn-gould-bsd4.3* )
516 machine=gould opsys=bsd4-3
517 ;;
518 np1-gould-bsd* )
519 machine=gould-np1 opsys=bsd4-3
520 ;;
522 ## Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
523 ## as far as Emacs is concerned).
524 m88k-harris-cxux* )
525 # Build needs to be different on 7.0 and later releases
526 case "`uname -r`" in
527 [56].[0-9] ) machine=nh4000 opsys=cxux ;;
528 [7].[0-9] ) machine=nh4000 opsys=cxux7 ;;
529 esac
530 NON_GNU_CPP="/lib/cpp"
531 ;;
532 ## Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
533 m68k-harris-cxux* )
534 machine=nh3000 opsys=cxux
535 ;;
536 ## Harris power pc NightHawk running Power UNIX (Series 6000)
537 powerpc-harris-powerunix )
538 machine=nh6000 opsys=powerunix
539 NON_GNU_CPP="cc -Xo -E -P"
540 ;;
541 ## SR2001/SR2201 running HI-UX/MPP
542 hppa1.1-hitachi-hiuxmpp* )
543 machine=sr2k opsys=hiuxmpp
544 ;;
545 hppa1.1-hitachi-hiuxwe2* )
546 machine=sr2k opsys=hiuxwe2
547 ;;
548 ## Honeywell XPS100
549 xps*-honeywell-sysv* )
550 machine=xps100 opsys=usg5-2
551 ;;
553 ## HP 9000 series 200 or 300
554 m68*-hp-bsd* )
555 machine=hp9000s300 opsys=bsd4-3
556 ;;
557 ## HP/UX 7, 8, 9, and 10 are supported on these machines.
558 m68*-hp-hpux* )
559 case "`uname -r`" in
560 ## Someone's system reports A.B8.05 for this.
561 ## I wonder what other possibilities there are.
562 *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
563 *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
564 *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
565 *.1[0-9].* ) machine=hp9000s300 opsys=hpux9shr ;;
566 *) machine=hp9000s300 opsys=hpux ;;
567 esac
568 ;;
570 ## HP 9000 series 700 and 800, running HP/UX
571 hppa*-hp-hpux7* )
572 machine=hp800 opsys=hpux
573 ;;
574 hppa*-hp-hpux8* )
575 machine=hp800 opsys=hpux8
576 ;;
577 hppa*-hp-hpux9shr* )
578 machine=hp800 opsys=hpux9shr
579 ;;
580 hppa*-hp-hpux9* )
581 machine=hp800 opsys=hpux9
582 ;;
583 hppa*-hp-hpux10.2* )
584 machine=hp800 opsys=hpux10-20
585 ;;
586 hppa*-hp-hpux10* )
587 machine=hp800 opsys=hpux10
588 ;;
589 hppa*-hp-hpux1[1-9]* )
590 machine=hp800 opsys=hpux11
591 ;;
593 hppa*-*-linux-gnu* )
594 machine=hp800 opsys=gnu-linux
595 ;;
597 ## HP 9000 series 700 and 800, running HP/UX
598 hppa*-hp-hpux* )
599 ## Cross-compilation? Nah!
600 case "`uname -r`" in
601 ## Someone's system reports A.B8.05 for this.
602 ## I wonder what other possibilities there are.
603 *.B8.* ) machine=hp800 opsys=hpux8 ;;
604 *.08.* ) machine=hp800 opsys=hpux8 ;;
605 *.09.* ) machine=hp800 opsys=hpux9 ;;
606 *) machine=hp800 opsys=hpux10 ;;
607 esac
608 ;;
609 hppa*-*-nextstep* )
610 machine=hp800 opsys=nextstep
611 ;;
613 ## Orion machines
614 orion-orion-bsd* )
615 machine=orion opsys=bsd4-2
616 ;;
617 clipper-orion-bsd* )
618 machine=orion105 opsys=bsd4-2
619 ;;
621 ## IBM machines
622 i[3456]86-ibm-aix1.1* )
623 machine=ibmps2-aix opsys=usg5-2-2
624 ;;
625 i[3456]86-ibm-aix1.[23]* | i[3456]86-ibm-aix* )
626 machine=ibmps2-aix opsys=usg5-3
627 ;;
628 i370-ibm-aix*)
629 machine=ibm370aix opsys=usg5-3
630 ;;
631 s390-*-linux-gnu* )
632 machine=ibms390 opsys=gnu-linux
633 ;;
634 rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1* )
635 machine=ibmrs6000 opsys=aix3-1
636 ;;
637 rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
638 machine=ibmrs6000 opsys=aix3-2-5
639 ;;
640 rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1* )
641 machine=ibmrs6000 opsys=aix4-1
642 ;;
643 rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2* )
644 machine=ibmrs6000 opsys=aix4-2
645 ;;
646 rs6000-ibm-aix5* | powerpc-ibm-aix5* )
647 machine=ibmrs6000 opsys=aix4-2
648 ;;
649 rs6000-ibm-aix4.0* | powerpc-ibm-aix4.0* )
650 machine=ibmrs6000 opsys=aix4
651 ;;
652 rs6000-ibm-aix4* | powerpc-ibm-aix4* )
653 machine=ibmrs6000 opsys=aix4-1
654 ;;
655 rs6000-ibm-aix* | powerpc-ibm-aix* )
656 machine=ibmrs6000 opsys=aix3-2
657 ;;
658 romp-ibm-bsd4.3* )
659 machine=ibmrt opsys=bsd4-3
660 ;;
661 romp-ibm-bsd4.2* )
662 machine=ibmrt opsys=bsd4-2
663 ;;
664 romp-ibm-aos4.3* )
665 machine=ibmrt opsys=bsd4-3
666 ;;
667 romp-ibm-aos4.2* )
668 machine=ibmrt opsys=bsd4-2
669 ;;
670 romp-ibm-aos* )
671 machine=ibmrt opsys=bsd4-3
672 ;;
673 romp-ibm-bsd* )
674 machine=ibmrt opsys=bsd4-3
675 ;;
676 romp-ibm-aix* )
677 machine=ibmrt-aix opsys=usg5-2-2
678 ;;
680 ## Integrated Solutions `Optimum V'
681 m68*-isi-bsd4.2* )
682 machine=isi-ov opsys=bsd4-2
683 ;;
684 m68*-isi-bsd4.3* )
685 machine=isi-ov opsys=bsd4-3
686 ;;
688 ## Intel 386 machines where we do care about the manufacturer
689 i[3456]86-intsys-sysv* )
690 machine=is386 opsys=usg5-2-2
691 ;;
693 ## Prime EXL
694 i[3456]86-prime-sysv* )
695 machine=i386 opsys=usg5-3
696 ;;
698 ## Sequent Symmetry running Dynix
699 i[3456]86-sequent-bsd* )
700 machine=symmetry opsys=bsd4-3
701 ;;
703 ## Sequent Symmetry running ptx 4, which is a modified SVR4.
704 i[3456]86-sequent-ptx4* | i[3456]86-sequent-sysv4* )
705 machine=sequent-ptx opsys=ptx4
706 NON_GNU_CPP=/lib/cpp
707 ;;
709 ## Sequent Symmetry running DYNIX/ptx
710 ## Use the old cpp rather than the newer ANSI one.
711 i[3456]86-sequent-ptx* )
712 machine=sequent-ptx opsys=ptx
713 NON_GNU_CPP="/lib/cpp"
714 ;;
716 ## ncr machine running svr4.3.
717 i[3456]86-ncr-sysv4.3 )
718 machine=ncr386 opsys=usg5-4-3
719 ;;
721 ## Unspecified sysv on an ncr machine defaults to svr4.2.
722 ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
723 i[3456]86-ncr-sysv* )
724 machine=ncr386 opsys=usg5-4-2
725 ;;
727 ## Intel Paragon OSF/1
728 i860-intel-osf1* )
729 machine=paragon opsys=osf1 NON_GNU_CPP=/usr/mach/lib/cpp
730 ;;
732 ## Intel 860
733 i860-*-sysv4* )
734 machine=i860 opsys=usg5-4
735 NON_GNU_CC="/bin/cc" # Ie, not the one in /usr/ucb/cc.
736 NON_GNU_CPP="/usr/ccs/lib/cpp" # cc -E tokenizes macro expansion.
737 ;;
739 ## Macintosh PowerPC
740 powerpc*-*-linux-gnu* )
741 machine=macppc opsys=gnu-linux
742 ;;
744 ## Masscomp machines
745 m68*-masscomp-rtu* )
746 machine=masscomp opsys=rtu
747 ;;
749 ## Megatest machines
750 m68*-megatest-bsd* )
751 machine=mega68 opsys=bsd4-2
752 ;;
754 ## Workstations sold by MIPS
755 ## This is not necessarily all workstations using the MIPS processor -
756 ## Irises are produced by SGI, and DECstations by DEC.
758 ## etc/MACHINES lists mips.h and mips4.h as possible machine files,
759 ## and usg5-2-2 and bsd4-3 as possible OS files. The only guidance
760 ## it gives for choosing between the alternatives seems to be "Use
761 ## -machine=mips4 for RISCOS version 4; use -opsystem=bsd4-3 with
762 ## the BSD world." I'll assume that these are instructions for
763 ## handling two odd situations, and that every other situation
764 ## should use mips.h and usg5-2-2, they being listed first.
765 mips-mips-usg* )
766 machine=mips4
767 ## Fall through to the general code at the bottom to decide on the OS.
768 ;;
769 mips-mips-riscos4* )
770 machine=mips4 opsys=bsd4-3
771 NON_GNU_CC="cc -systype bsd43"
772 NON_GNU_CPP="cc -systype bsd43 -E"
773 ;;
774 mips-mips-riscos5* )
775 machine=mips4 opsys=riscos5
776 NON_GNU_CC="cc -systype bsd43"
777 NON_GNU_CPP="cc -systype bsd43 -E"
778 ;;
779 mips-mips-bsd* )
780 machine=mips opsys=bsd4-3
781 ;;
782 mips-mips-* )
783 machine=mips opsys=usg5-2-2
784 ;;
786 ## NeXT
787 m68*-next-* | m68k-*-nextstep* )
788 machine=m68k opsys=nextstep
789 ;;
791 ## The complete machine from National Semiconductor
792 ns32k-ns-genix* )
793 machine=ns32000 opsys=usg5-2
794 ;;
796 ## NCR machines
797 m68*-ncr-sysv2* | m68*-ncr-sysvr2* )
798 machine=tower32 opsys=usg5-2-2
799 ;;
800 m68*-ncr-sysv3* | m68*-ncr-sysvr3* )
801 machine=tower32v3 opsys=usg5-3
802 ;;
804 ## NEC EWS4800
805 mips-nec-sysv4*)
806 machine=ews4800 opsys=ux4800
807 ;;
809 ## Nixdorf Targon 31
810 m68*-nixdorf-sysv* )
811 machine=targon31 opsys=usg5-2-2
812 ;;
814 ## Nu (TI or LMI)
815 m68*-nu-sysv* )
816 machine=nu opsys=usg5-2
817 ;;
819 ## Plexus
820 m68*-plexus-sysv* )
821 machine=plexus opsys=usg5-2
822 ;;
824 ## Pyramid machines
825 ## I don't really have any idea what sort of processor the Pyramid has,
826 ## so I'm assuming it is its own architecture.
827 pyramid-pyramid-bsd* )
828 machine=pyramid opsys=bsd4-2
829 ;;
831 ## Sequent Balance
832 ns32k-sequent-bsd4.2* )
833 machine=sequent opsys=bsd4-2
834 ;;
835 ns32k-sequent-bsd4.3* )
836 machine=sequent opsys=bsd4-3
837 ;;
839 ## Siemens Nixdorf
840 mips-siemens-sysv* | mips-sni-sysv*)
841 machine=mips-siemens opsys=usg5-4
842 NON_GNU_CC=/usr/ccs/bin/cc
843 NON_GNU_CPP=/usr/ccs/lib/cpp
844 ;;
846 ## Silicon Graphics machines
847 ## Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
848 m68*-sgi-iris3.5* )
849 machine=irist opsys=iris3-5
850 ;;
851 m68*-sgi-iris3.6* | m68*-sgi-iris*)
852 machine=irist opsys=iris3-6
853 ;;
854 ## Iris 4D
855 mips-sgi-irix3* )
856 machine=iris4d opsys=irix3-3
857 ;;
858 mips-sgi-irix4* )
859 machine=iris4d opsys=irix4-0
860 ;;
861 mips-sgi-irix6.5 )
862 machine=iris4d opsys=irix6-5
863 # Without defining _LANGUAGE_C, things get masked out in the headers
864 # so that, for instance, grepping for `free' in stdlib.h fails and
865 # AC_HEADER_STD_C fails. (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
866 NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
867 NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
868 ;;
869 mips-sgi-irix6* )
870 machine=iris4d opsys=irix6-0
871 # It's not clear whether -D_LANGUAGE_C is necessary as it is for 6.5,
872 # but presumably it does no harm.
873 NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
874 # -32 probably isn't necessary in later v.6s -- anyone know which?
875 NON_GCC_TEST_OPTIONS=-32
876 ;;
877 mips-sgi-irix5.[01]* )
878 machine=iris4d opsys=irix5-0
879 ;;
880 mips-sgi-irix5* | mips-sgi-irix* )
881 machine=iris4d opsys=irix5-2
882 ;;
884 ## SONY machines
885 m68*-sony-bsd4.2* )
886 machine=news opsys=bsd4-2
887 ;;
888 m68*-sony-bsd4.3* )
889 machine=news opsys=bsd4-3
890 ;;
891 m68*-sony-newsos3* | m68*-sony-news3*)
892 machine=news opsys=bsd4-3
893 ;;
894 mips-sony-bsd* | mips-sony-newsos4* | mips-sony-news4*)
895 machine=news-risc opsys=bsd4-3
896 ;;
897 mips-sony-newsos6* )
898 machine=news-r6 opsys=newsos6
899 ;;
900 mips-sony-news* )
901 machine=news-risc opsys=newsos5
902 ;;
904 ## Stride
905 m68*-stride-sysv* )
906 machine=stride opsys=usg5-2
907 ;;
909 ## Suns
910 sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
911 machine=sparc opsys=gnu-linux
912 ;;
914 *-auspex-sunos* | *-sun-sunos* | *-sun-bsd* | *-sun-solaris* \
915 | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* | powerpc*-*-solaris2* \
916 | rs6000-*-solaris2*)
917 case "${canonical}" in
918 m68*-sunos1* ) machine=sun1 ;;
919 m68*-sunos2* ) machine=sun2 ;;
920 m68* ) machine=sun3 ;;
921 i[3456]86-sun-sunos[34]* ) machine=sun386 ;;
922 i[3456]86-*-* ) machine=intel386 ;;
923 powerpcle* ) machine=powerpcle ;;
924 powerpc* | rs6000* ) machine=ibmrs6000 ;;
925 sparc* ) machine=sparc ;;
926 * ) unported=yes ;;
927 esac
928 case "${canonical}" in
929 ## The Sun386 didn't get past 4.0.
930 i[3456]86-*-sunos4 ) opsys=sunos4-0 ;;
931 *-sunos4.0* ) opsys=sunos4-0 ;;
932 *-sunos4.1.[3-9]*noshare )
933 ## This name is sunos413 instead of sunos4-1-3
934 ## to avoid a file name conflict on MSDOS.
935 opsys=sunos413
936 NON_GNU_CPP=/usr/lib/cpp
937 NON_GCC_TEST_OPTIONS=-Bstatic
938 GCC_TEST_OPTIONS=-static
939 ;;
940 *-sunos4.1.[3-9]* | *-sunos4shr*)
941 opsys=sunos4shr
942 NON_GNU_CPP=/usr/lib/cpp
943 ;;
944 *-sunos4* | *-sunos )
945 opsys=sunos4-1
946 NON_GCC_TEST_OPTIONS=-Bstatic
947 GCC_TEST_OPTIONS=-static
948 ;;
949 *-sunos5.3* | *-solaris2.3* )
950 opsys=sol2-3
951 NON_GNU_CPP=/usr/ccs/lib/cpp
952 ;;
953 *-sunos5.4* | *-solaris2.4* )
954 opsys=sol2-4
955 NON_GNU_CPP=/usr/ccs/lib/cpp
956 RANLIB="ar -ts"
957 ;;
958 *-sunos5.5* | *-solaris2.5* )
959 opsys=sol2-5
960 NON_GNU_CPP=/usr/ccs/lib/cpp
961 RANLIB="ar -ts"
962 ;;
963 *-sunos5.6* | *-solaris2.6* )
964 opsys=sol2-6
965 NON_GNU_CPP=/usr/ccs/lib/cpp
966 RANLIB="ar -ts"
967 ;;
968 *-sunos5* | *-solaris* )
969 opsys=sol2-6
970 NON_GNU_CPP=/usr/ccs/lib/cpp
971 ;;
972 * ) opsys=bsd4-2 ;;
973 esac
974 ## Watch out for a compiler that we know will not work.
975 case "${canonical}" in
976 *-solaris* | *-sunos5* )
977 if [ "x$CC" = x/usr/ucb/cc ]; then
978 ## /usr/ucb/cc doesn't work;
979 ## we should find some other compiler that does work.
980 unset CC
981 fi
982 ;;
983 *) ;;
984 esac
985 ;;
986 sparc-*-nextstep* )
987 machine=sparc opsys=nextstep
988 ;;
990 ## Tadpole 68k
991 m68*-tadpole-sysv* )
992 machine=tad68k opsys=usg5-3
993 ;;
995 ## Tahoe machines
996 tahoe-tahoe-bsd4.2* )
997 machine=tahoe opsys=bsd4-2
998 ;;
999 tahoe-tahoe-bsd4.3* )
1000 machine=tahoe opsys=bsd4-3
1001 ;;
1003 ## Tandem Integrity S2
1004 mips-tandem-sysv* )
1005 machine=tandem-s2 opsys=usg5-3
1006 ;;
1008 ## Tektronix XD88
1009 m88k-tektronix-sysv3* )
1010 machine=tekxd88 opsys=usg5-3
1011 ;;
1013 ## Tektronix 16000 box (6130?)
1014 ns16k-tektronix-bsd* )
1015 machine=ns16000 opsys=bsd4-2
1016 ;;
1017 ## Tektronix 4300
1018 ## src/m/tek4300.h hints that this is a m68k machine.
1019 m68*-tektronix-bsd* )
1020 machine=tek4300 opsys=bsd4-3
1021 ;;
1023 ## Titan P2 or P3
1024 ## We seem to have lost the machine-description file titan.h!
1025 titan-titan-sysv* )
1026 machine=titan opsys=usg5-3
1027 ;;
1029 ## Ustation E30 (SS5E)
1030 m68*-unisys-uniplus* )
1031 machine=ustation opsystem=unipl5-2
1032 ;;
1034 ## Vaxen.
1035 vax-dec-* )
1036 machine=vax
1037 case "${canonical}" in
1038 *-bsd4.1* ) opsys=bsd4-1 ;;
1039 *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* ) opsys=bsd4-2 ;;
1040 *-bsd4.3* | *-ultrix* ) opsys=bsd4-3 ;;
1041 *-sysv[01]* | *-sysvr[01]* ) opsys=usg5-0 ;;
1042 *-sysv2* | *-sysvr2* ) opsys=usg5-2 ;;
1043 *-vms* ) opsys=vms ;;
1044 * ) unported=yes
1045 esac
1046 ;;
1048 ## Whitechapel MG1
1049 ns16k-whitechapel-* )
1050 machine=mg1
1051 ## We don't know what sort of OS runs on these; we'll let the
1052 ## operating system guessing code below try.
1053 ;;
1055 ## Wicat
1056 m68*-wicat-sysv* )
1057 machine=wicat opsys=usg5-2
1058 ;;
1060 ## IA-64
1061 ia64*-*-linux* )
1062 machine=ia64 opsys=gnu-linux
1063 ;;
1065 ## Intel 386 machines where we don't care about the manufacturer
1066 i[3456]86-*-* )
1067 machine=intel386
1068 case "${canonical}" in
1069 *-cygwin ) opsys=cygwin ;;
1070 *-lynxos* ) opsys=lynxos ;;
1071 *-isc1.* | *-isc2.[01]* ) opsys=386-ix ;;
1072 *-isc2.2* ) opsys=isc2-2 ;;
1073 *-isc4.0* ) opsys=isc4-0 ;;
1074 *-isc4.* ) opsys=isc4-1
1075 GCC_TEST_OPTIONS=-posix
1076 NON_GCC_TEST_OPTIONS=-Xp
1077 ;;
1078 *-isc* ) opsys=isc3-0 ;;
1079 *-esix5* ) opsys=esix5r4; NON_GNU_CPP=/usr/lib/cpp ;;
1080 *-esix* ) opsys=esix ;;
1081 *-xenix* ) opsys=xenix ;;
1082 *-linux-gnu* ) opsys=gnu-linux ;;
1083 *-sco3.2v4* ) opsys=sco4 ; NON_GNU_CPP=/lib/cpp ;;
1084 *-sco3.2v5* ) opsys=sco5
1085 NON_GNU_CPP=/lib/cpp
1086 # Prevent -belf from being passed to $CPP.
1087 # /lib/cpp does not accept it.
1088 OVERRIDE_CPPFLAGS=" "
1089 ;;
1090 *-sysv4.2uw* ) opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
1091 *-sysv5uw* ) opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
1092 *-sysv5OpenUNIX* ) opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
1093 *-386bsd* ) opsys=386bsd ;;
1094 *-nextstep* ) opsys=nextstep ;;
1095 ## Otherwise, we'll fall through to the generic opsys code at the bottom.
1096 esac
1097 ;;
1099 ## m68k Linux-based GNU system
1100 m68k-*-linux-gnu* )
1101 machine=m68k opsys=gnu-linux
1102 ;;
1104 ## Mips Linux-based GNU system
1105 mips-*-linux-gnu* | mipsel-*-linux-gnu* )
1106 machine=mips opsys=gnu-linux
1107 ;;
1109 ## UXP/DS
1110 sparc-fujitsu-sysv4* )
1111 machine=sparc opsys=uxpds
1112 NON_GNU_CPP=/usr/ccs/lib/cpp
1113 RANLIB="ar -ts"
1114 ;;
1116 ## UXP/V
1117 f301-fujitsu-uxpv4.1)
1118 machine=f301 opsys=uxpv
1119 ;;
1121 ## Darwin / Mac OS X
1122 powerpc-apple-darwin* )
1123 machine=powermac opsys=darwin
1124 # Define CPP as follows to make autoconf work correctly.
1125 CPP="cc -E -traditional-cpp"
1126 ;;
1128 ## AMD x86-64 Linux-based GNU system
1129 x86_64-*-linux-gnu* )
1130 machine=amdx86-64 opsys=gnu-linux
1131 ;;
1133 * )
1134 unported=yes
1135 ;;
1136 esac
1138 ### If the code above didn't choose an operating system, just choose
1139 ### an operating system based on the configuration name. You really
1140 ### only want to use this when you have no idea what the right
1141 ### operating system is; if you know what operating systems a machine
1142 ### runs, it's cleaner to make it explicit in the case statement
1143 ### above.
1144 if test x"${opsys}" = x; then
1145 case "${canonical}" in
1146 *-gnu* ) opsys=gnu ;;
1147 *-bsd4.[01] ) opsys=bsd4-1 ;;
1148 *-bsd4.2 ) opsys=bsd4-2 ;;
1149 *-bsd4.3 ) opsys=bsd4-3 ;;
1150 *-sysv0 | *-sysvr0 ) opsys=usg5-0 ;;
1151 *-sysv2 | *-sysvr2 ) opsys=usg5-2 ;;
1152 *-sysv2.2 | *-sysvr2.2 ) opsys=usg5-2-2 ;;
1153 *-sysv3* | *-sysvr3* ) opsys=usg5-3 ;;
1154 *-sysv4.2uw* ) opsys=unixware ;;
1155 *-sysv5uw* ) opsys=unixware ;;
1156 *-sysv5OpenUNIX* ) opsys=unixware ;;
1157 *-sysv4.1* | *-sysvr4.1* )
1158 NON_GNU_CPP=/usr/lib/cpp
1159 opsys=usg5-4 ;;
1160 *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
1161 if [ x$NON_GNU_CPP = x ]; then
1162 if [ -f /usr/ccs/lib/cpp ]; then
1163 NON_GNU_CPP=/usr/ccs/lib/cpp
1164 else
1165 NON_GNU_CPP=/lib/cpp
1166 fi
1167 fi
1168 opsys=usg5-4-2 ;;
1169 *-sysv4* | *-sysvr4* ) opsys=usg5-4 ;;
1170 * )
1171 unported=yes
1172 ;;
1173 esac
1174 fi
1176 ]
1177 dnl quotation ends
1179 if test $unported = yes; then
1180 AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
1181 Check `etc/MACHINES' for recognized configuration names.])
1182 fi
1184 machfile="m/${machine}.h"
1185 opsysfile="s/${opsys}.h"
1188 #### Choose a compiler.
1189 test -n "$CC" && cc_specified=yes
1191 # Save the value of CFLAGS that the user specified.
1192 SPECIFIED_CFLAGS="$CFLAGS"
1194 case ${with_gcc} in
1195 "yes" ) CC="gcc" GCC=yes ;;
1196 "no" ) : ${CC=cc} ;;
1197 * )
1198 esac
1199 AC_PROG_CC
1201 # On Suns, sometimes $CPP names a directory.
1202 if test -n "$CPP" && test -d "$CPP"; then
1203 CPP=
1204 fi
1206 #### Some systems specify a CPP to use unless we are using GCC.
1207 #### Now that we know whether we are using GCC, we can decide whether
1208 #### to use that one.
1209 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
1210 then
1211 CPP="$NON_GNU_CPP"
1212 fi
1214 #### Some systems specify a CC to use unless we are using GCC.
1215 #### Now that we know whether we are using GCC, we can decide whether
1216 #### to use that one.
1217 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
1218 test x$cc_specified != xyes
1219 then
1220 CC="$NON_GNU_CC"
1221 fi
1223 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
1224 then
1225 CC="$CC $GCC_TEST_OPTIONS"
1226 fi
1228 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
1229 then
1230 CC="$CC $NON_GCC_TEST_OPTIONS"
1231 fi
1233 #### Some other nice autoconf tests.
1235 dnl checks for programs
1236 AC_PROG_LN_S
1237 AC_PROG_CPP
1238 AC_PROG_INSTALL
1239 if test "x$RANLIB" = x; then
1240 AC_PROG_RANLIB
1241 fi
1242 AC_PATH_PROG(INSTALL_INFO, install-info)
1243 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
1244 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
1246 dnl Add our options to ac_link now, after it is set up.
1248 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
1249 then
1250 ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1251 fi
1253 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
1254 then
1255 ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1256 fi
1258 dnl checks for Unix variants
1259 AC_AIX
1261 #### Extract some information from the operating system and machine files.
1263 AC_CHECKING([the machine- and system-dependent files to find out
1264 - which libraries the lib-src programs will want, and
1265 - whether the GNU malloc routines are usable])
1267 ### First figure out CFLAGS (which we use for running the compiler here)
1268 ### and REAL_CFLAGS (which we use for real compilation).
1269 ### The two are the same except on a few systems, where they are made
1270 ### different to work around various lossages. For example,
1271 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
1272 ### as implying static linking.
1274 ### If the CFLAGS env var is specified, we use that value
1275 ### instead of the default.
1277 ### It's not important that this name contain the PID; you can't run
1278 ### two configures in the same directory and have anything work
1279 ### anyway.
1280 tempcname="conftest.c"
1282 echo '
1283 #include "'${srcdir}'/src/'${opsysfile}'"
1284 #include "'${srcdir}'/src/'${machfile}'"
1285 #ifndef LIBS_MACHINE
1286 #define LIBS_MACHINE
1287 #endif
1288 #ifndef LIBS_SYSTEM
1289 #define LIBS_SYSTEM
1290 #endif
1291 #ifndef C_SWITCH_SYSTEM
1292 #define C_SWITCH_SYSTEM
1293 #endif
1294 #ifndef C_SWITCH_MACHINE
1295 #define C_SWITCH_MACHINE
1296 #endif
1297 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
1298 configure___ c_switch_system=C_SWITCH_SYSTEM
1299 configure___ c_switch_machine=C_SWITCH_MACHINE
1301 #ifndef LIB_X11_LIB
1302 #define LIB_X11_LIB -lX11
1303 #endif
1305 #ifndef LIBX11_MACHINE
1306 #define LIBX11_MACHINE
1307 #endif
1309 #ifndef LIBX11_SYSTEM
1310 #define LIBX11_SYSTEM
1311 #endif
1312 configure___ LIBX=LIB_X11_LIB LIBX11_MACHINE LIBX11_SYSTEM
1314 #ifdef UNEXEC
1315 configure___ unexec=UNEXEC
1316 #else
1317 configure___ unexec=unexec.o
1318 #endif
1320 #ifdef SYSTEM_MALLOC
1321 configure___ system_malloc=yes
1322 #else
1323 configure___ system_malloc=no
1324 #endif
1326 #ifdef USE_MMAP_FOR_BUFFERS
1327 configure___ use_mmap_for_buffers=yes
1328 #else
1329 configure___ use_mmap_for_buffers=no
1330 #endif
1332 #ifndef C_DEBUG_SWITCH
1333 #define C_DEBUG_SWITCH -g
1334 #endif
1336 #ifndef C_OPTIMIZE_SWITCH
1337 #ifdef __GNUC__
1338 #define C_OPTIMIZE_SWITCH -O2
1339 #else
1340 #define C_OPTIMIZE_SWITCH -O
1341 #endif
1342 #endif
1344 #ifndef LD_SWITCH_MACHINE
1345 #define LD_SWITCH_MACHINE
1346 #endif
1348 #ifndef LD_SWITCH_SYSTEM
1349 #define LD_SWITCH_SYSTEM
1350 #endif
1352 #ifndef LD_SWITCH_X_SITE_AUX
1353 #define LD_SWITCH_X_SITE_AUX
1354 #endif
1356 configure___ ld_switch_system=LD_SWITCH_SYSTEM
1357 configure___ ld_switch_machine=LD_SWITCH_MACHINE
1359 #ifdef THIS_IS_CONFIGURE
1361 /* Get the CFLAGS for tests in configure. */
1362 #ifdef __GNUC__
1363 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1364 #else
1365 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1366 #endif
1368 #else /* not THIS_IS_CONFIGURE */
1370 /* Get the CFLAGS for real compilation. */
1371 #ifdef __GNUC__
1372 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1373 #else
1374 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1375 #endif
1377 #endif /* not THIS_IS_CONFIGURE */
1378 ' > ${tempcname}
1380 # The value of CPP is a quoted variable reference, so we need to do this
1381 # to get its actual value...
1382 CPP=`eval "echo $CPP"`
1383 [eval `${CPP} -Isrc ${tempcname} \
1384 | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1385 if test "x$SPECIFIED_CFLAGS" = x; then
1386 eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1387 | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1388 else
1389 REAL_CFLAGS="$CFLAGS"
1390 fi]
1391 rm ${tempcname}
1393 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
1395 ### Make sure subsequent tests use flags consistent with the build flags.
1397 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1398 CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1399 else
1400 CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1401 fi
1403 dnl For AC_FUNC_GETLOADAVG, at least:
1404 AC_CONFIG_LIBOBJ_DIR(src)
1406 AC_GNU_SOURCE
1408 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1409 AC_SYS_LARGEFILE
1411 if test "${with_sound}" != "no"; then
1412 # Sound support for GNU/Linux and the free BSDs.
1413 AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1414 # Emulation library used on NetBSD.
1415 AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1416 AC_SUBST(LIBSOUND)
1417 fi
1419 dnl checks for header files
1420 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1421 linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1422 termcap.h stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1423 sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h)
1424 dnl On Solaris 8 there's a compilation warning for term.h because
1425 dnl it doesn't define `bool'.
1426 AC_CHECK_HEADERS(term.h, , , -)
1427 AC_HEADER_STDC
1428 AC_HEADER_TIME
1429 AC_CHECK_DECLS([sys_siglist])
1430 if test $ac_cv_have_decl_sys_siglist != yes; then
1431 # For Tru64, at least:
1432 AC_CHECK_DECLS([__sys_siglist])
1433 if test $ac_cv_have_decl___sys_siglist = yes; then
1434 AC_DEFINE(sys_siglist, __sys_siglist,
1435 [Define to any substitute for sys_siglist.])
1436 fi
1437 fi
1438 AC_HEADER_SYS_WAIT
1440 dnl Some systems have utime.h but don't declare the struct anyplace.
1441 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1442 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1443 #include <sys/time.h>
1444 #include <time.h>
1445 #else
1446 #ifdef HAVE_SYS_TIME_H
1447 #include <sys/time.h>
1448 #else
1449 #include <time.h>
1450 #endif
1451 #endif
1452 #ifdef HAVE_UTIME_H
1453 #include <utime.h>
1454 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1455 emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1456 if test $emacs_cv_struct_utimbuf = yes; then
1457 AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1458 fi
1460 dnl checks for typedefs
1461 AC_TYPE_SIGNAL
1463 dnl Check for speed_t typedef.
1464 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1465 [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1466 emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1467 if test $emacs_cv_speed_t = yes; then
1468 AC_DEFINE(HAVE_SPEED_T, 1,
1469 [Define to 1 if `speed_t' is declared by <termios.h>.])
1470 fi
1472 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1473 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1474 #include <sys/time.h>
1475 #include <time.h>
1476 #else
1477 #ifdef HAVE_SYS_TIME_H
1478 #include <sys/time.h>
1479 #else
1480 #include <time.h>
1481 #endif
1482 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1483 emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1484 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1485 if test $emacs_cv_struct_timeval = yes; then
1486 AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1487 fi
1489 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1490 AC_TRY_COMPILE([#include <math.h>],
1491 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1492 emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1493 HAVE_EXCEPTION=$emacs_cv_struct_exception
1494 if test $emacs_cv_struct_exception != yes; then
1495 AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1496 fi
1498 dnl checks for structure members
1499 AC_STRUCT_TM
1500 AC_STRUCT_TIMEZONE
1501 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1502 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1503 [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1504 [#include <time.h>])
1506 dnl checks for compiler characteristics
1508 dnl Testing __STDC__ to determine prototype support isn't good enough.
1509 dnl DEC C, for instance, doesn't define it with default options, and
1510 dnl is used on 64-bit systems (OSF Alphas). Similarly for volatile
1511 dnl and void *.
1512 AC_C_PROTOTYPES
1513 AC_C_VOLATILE
1514 AC_C_CONST
1515 dnl This isn't useful because we can't turn on use of `inline' unless
1516 dnl the compiler groks `extern inline'.
1517 dnl AC_C_INLINE
1518 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1519 [AC_TRY_COMPILE(, [void * foo;],
1520 emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1521 if test $emacs_cv_void_star = yes; then
1522 AC_DEFINE(POINTER_TYPE, void)
1523 else
1524 AC_DEFINE(POINTER_TYPE, char)
1525 fi
1526 AH_TEMPLATE(POINTER_TYPE,
1527 [Define as `void' if your compiler accepts `void *'; otherwise
1528 define as `char'.])dnl
1530 dnl This could be used for targets which can have both byte sexes.
1531 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1532 dnl AC_C_BIGENDIAN
1534 dnl check for Make feature
1535 AC_PROG_MAKE_SET
1537 dnl checks for operating system services
1538 AC_SYS_LONG_FILE_NAMES
1540 #### Choose a window system.
1542 AC_PATH_X
1543 if test "$no_x" = yes; then
1544 window_system=none
1545 else
1546 window_system=x11
1547 fi
1549 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1550 LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1551 LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1552 x_default_search_path=""
1553 for x_library in `echo ${x_libraries} | sed -e "s/:/ /g"`; do
1554 x_search_path="\
1555 ${x_library}/X11/%L/%T/%N%C%S:\
1556 ${x_library}/X11/%l/%T/%N%C%S:\
1557 ${x_library}/X11/%T/%N%C%S:\
1558 ${x_library}/X11/%L/%T/%N%S:\
1559 ${x_library}/X11/%l/%T/%N%S:\
1560 ${x_library}/X11/%T/%N%S"
1561 if test x"${x_default_search_path}" = x; then
1562 x_default_search_path=${x_search_path}
1563 else
1564 x_default_search_path="${x_search_path}:${x_default_search_path}"
1565 fi
1566 done
1567 fi
1568 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1569 C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1570 fi
1572 if test x"${x_includes}" = x; then
1573 bitmapdir=/usr/include/X11/bitmaps
1574 else
1575 # accumulate include directories that have X11 bitmap subdirectories
1576 bmd_acc="dummyval"
1577 for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1578 if test -d "${bmd}/X11/bitmaps"; then
1579 bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1580 fi
1581 if test -d "${bmd}/bitmaps"; then
1582 bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1583 fi
1584 done
1585 if test ${bmd_acc} != "dummyval"; then
1586 bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1587 fi
1588 fi
1590 case "${window_system}" in
1591 x11 )
1592 HAVE_X_WINDOWS=yes
1593 HAVE_X11=yes
1594 case "${with_x_toolkit}" in
1595 athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1596 motif ) USE_X_TOOLKIT=MOTIF ;;
1597 dnl open-look ) USE_X_TOOLKIT=OPEN_LOOK ;;
1598 gtk ) with_gtk=yes
1599 dnl Dont set this for GTK. A lot of tests below assumes Xt when
1600 dnl USE_X_TOOLKIT is set.
1601 USE_X_TOOLKIT=none ;;
1602 no ) USE_X_TOOLKIT=none ;;
1603 dnl If user did not say whether to use a toolkit,
1604 dnl make this decision later: use the toolkit if we have X11R5 or newer.
1605 * ) USE_X_TOOLKIT=maybe ;;
1606 esac
1607 ;;
1608 none )
1609 HAVE_X_WINDOWS=no
1610 HAVE_X11=no
1611 USE_X_TOOLKIT=none
1612 ;;
1613 esac
1615 ### If we're using X11, we should use the X menu package.
1616 HAVE_MENUS=no
1617 case ${HAVE_X11} in
1618 yes ) HAVE_MENUS=yes ;;
1619 esac
1621 if test "${opsys}" = "hpux9"; then
1622 case "${x_libraries}" in
1623 *X11R4* )
1624 opsysfile="s/hpux9-x11r4.h"
1625 ;;
1626 esac
1627 fi
1629 if test "${opsys}" = "hpux9shr"; then
1630 case "${x_libraries}" in
1631 *X11R4* )
1632 opsysfile="s/hpux9shxr4.h"
1633 ;;
1634 esac
1635 fi
1637 ### Compute the unexec source name from the object name.
1638 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1640 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1641 # Assume not, until told otherwise.
1642 GNU_MALLOC=yes
1643 doug_lea_malloc=yes
1644 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1645 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1646 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1647 emacs_cv_var___after_morecore_hook,
1648 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1649 emacs_cv_var___after_morecore_hook=yes,
1650 emacs_cv_var___after_morecore_hook=no)])
1651 if test $emacs_cv_var___after_morecore_hook = no; then
1652 doug_lea_malloc=no
1653 fi
1654 if test "${system_malloc}" = "yes"; then
1655 GNU_MALLOC=no
1656 GNU_MALLOC_reason="
1657 (The GNU allocators don't work with this system configuration.)"
1658 fi
1659 if test "$doug_lea_malloc" = "yes" ; then
1660 if test "$GNU_MALLOC" = yes ; then
1661 GNU_MALLOC_reason="
1662 (Using Doug Lea's new malloc from the GNU C Library.)"
1663 fi
1664 AC_DEFINE(DOUG_LEA_MALLOC, 1,
1665 [Define to 1 if you are using the GNU C Library.])
1666 fi
1668 if test x"${REL_ALLOC}" = x; then
1669 REL_ALLOC=${GNU_MALLOC}
1670 fi
1672 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1673 dnl the system configuration file (s/*.h) to turn the use of mmap
1674 dnl in the relocating allocator on.
1676 AC_FUNC_MMAP
1677 if test $use_mmap_for_buffers = yes; then
1678 REL_ALLOC=no
1679 fi
1681 LIBS="$libsrc_libs $LIBS"
1683 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1684 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1685 AC_CHECK_LIB(dnet, dnet_ntoa)
1686 dnl This causes -lresolv to get used in subsequent tests,
1687 dnl which causes failures on some systems such as HPUX 9.
1688 dnl AC_CHECK_LIB(resolv, gethostbyname)
1690 dnl FIXME replace main with a function we actually want from this library.
1691 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1693 AC_CHECK_LIB(pthreads, cma_open)
1695 AC_MSG_CHECKING(for XFree86 in /usr/X386)
1696 if test -d /usr/X386/include; then
1697 HAVE_XFREE386=yes
1698 : ${C_SWITCH_X_SITE="-I/usr/X386/include"}
1699 else
1700 HAVE_XFREE386=no
1701 fi
1702 AC_MSG_RESULT($HAVE_XFREE386)
1704 dnl Check for need for bigtoc support on IBM AIX
1706 case ${host_os} in
1707 aix*)
1708 AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1709 case $GCC in
1710 yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1711 *) gdb_cv_bigtoc=-bbigtoc ;;
1712 esac
1714 LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1715 AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1716 ])
1717 ;;
1718 esac
1720 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1721 # used for the tests that follow. We set them back to REAL_CFLAGS and
1722 # REAL_CPPFLAGS later on.
1724 REAL_CPPFLAGS="$CPPFLAGS"
1726 if test "${HAVE_X11}" = "yes"; then
1727 DEFS="$C_SWITCH_X_SITE $DEFS"
1728 LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1729 LIBS="$LIBX $LIBS"
1730 CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1731 CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1733 # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1734 # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1735 # but it's more convenient here to set LD_RUN_PATH
1736 # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1737 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1738 LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1739 export LD_RUN_PATH
1740 fi
1742 if test "${opsys}" = "gnu-linux"; then
1743 AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1744 AC_TRY_LINK([],
1745 [XOpenDisplay ("foo");],
1746 [xlinux_first_failure=no],
1747 [xlinux_first_failure=yes])
1748 if test "${xlinux_first_failure}" = "yes"; then
1749 OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1750 OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1751 OLD_CPPFLAGS="$CPPFLAGS"
1752 OLD_LIBS="$LIBS"
1753 LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1754 C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1755 CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1756 LIBS="$LIBS -b i486-linuxaout"
1757 AC_TRY_LINK([],
1758 [XOpenDisplay ("foo");],
1759 [xlinux_second_failure=no],
1760 [xlinux_second_failure=yes])
1761 if test "${xlinux_second_failure}" = "yes"; then
1762 # If we get the same failure with -b, there is no use adding -b.
1763 # So take it out. This plays safe.
1764 LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1765 C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1766 CPPFLAGS="$OLD_CPPFLAGS"
1767 LIBS="$OLD_LIBS"
1768 AC_MSG_RESULT(no)
1769 else
1770 AC_MSG_RESULT(yes)
1771 fi
1772 else
1773 AC_MSG_RESULT(no)
1774 fi
1775 fi
1777 # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1778 # header files included from there.
1779 AC_MSG_CHECKING(for Xkb)
1780 AC_TRY_LINK([#include <X11/Xlib.h>
1781 #include <X11/XKBlib.h>],
1782 [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1783 emacs_xkb=yes, emacs_xkb=no)
1784 AC_MSG_RESULT($emacs_xkb)
1785 if test $emacs_xkb = yes; then
1786 AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1787 fi
1789 AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1790 XScreenNumberOfScreen XSetWMProtocols)
1791 fi
1793 if test "${window_system}" = "x11"; then
1794 AC_MSG_CHECKING(X11 version 6)
1795 AC_CACHE_VAL(emacs_cv_x11_version_6,
1796 [AC_TRY_LINK([#include <X11/Xlib.h>],
1797 [#if XlibSpecificationRelease < 6
1798 fail;
1799 #endif
1800 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1801 if test $emacs_cv_x11_version_6 = yes; then
1802 AC_MSG_RESULT(6 or newer)
1803 AC_DEFINE(HAVE_X11R6, 1,
1804 [Define to 1 if you have the X11R6 or newer version of Xlib.])
1805 else
1806 AC_MSG_RESULT(before 6)
1807 fi
1808 fi
1810 if test "${window_system}" = "x11"; then
1811 AC_MSG_CHECKING(X11 version 5)
1812 AC_CACHE_VAL(emacs_cv_x11_version_5,
1813 [AC_TRY_LINK([#include <X11/Xlib.h>],
1814 [#if XlibSpecificationRelease < 5
1815 fail;
1816 #endif
1817 ], emacs_cv_x11_version_5=yes, emacs_cv_x11_version_5=no)])
1818 if test $emacs_cv_x11_version_5 = yes; then
1819 AC_MSG_RESULT(5 or newer)
1820 HAVE_X11R5=yes
1821 AC_DEFINE(HAVE_X11R5, 1,
1822 [Define to 1 if you have the X11R5 or newer version of Xlib.])
1823 else
1824 HAVE_X11R5=no
1825 AC_MSG_RESULT(before 5)
1826 fi
1827 fi
1829 dnl This function defintion taken from Gnome 2.0
1830 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1831 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1832 dnl also defines GSTUFF_PKG_ERRORS on error
1833 AC_DEFUN(PKG_CHECK_MODULES, [
1834 succeeded=no
1836 if test -z "$PKG_CONFIG"; then
1837 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1838 fi
1840 if test "$PKG_CONFIG" = "no" ; then
1841 echo "*** The pkg-config script could not be found. Make sure it is"
1842 echo "*** in your path, or give the full path to pkg-config with"
1843 echo "*** the PKG_CONFIG environment variable or --with-pkg-config-prog."
1844 echo "*** Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config."
1845 else
1846 PKG_CONFIG_MIN_VERSION=0.9.0
1847 if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1848 AC_MSG_CHECKING(for $2)
1850 if $PKG_CONFIG --exists "$2" ; then
1851 AC_MSG_RESULT(yes)
1852 succeeded=yes
1854 AC_MSG_CHECKING($1_CFLAGS)
1855 $1_CFLAGS=`$PKG_CONFIG --cflags "$2"`
1856 AC_MSG_RESULT($$1_CFLAGS)
1858 AC_MSG_CHECKING($1_LIBS)
1859 $1_LIBS=`$PKG_CONFIG --libs "$2"`
1860 AC_MSG_RESULT($$1_LIBS)
1861 else
1862 $1_CFLAGS=""
1863 $1_LIBS=""
1864 ## If we have a custom action on failure, don't print errors, but
1865 ## do set a variable so people can do so.
1866 $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1867 ifelse([$4], ,echo $$1_PKG_ERRORS,)
1868 fi
1870 AC_SUBST($1_CFLAGS)
1871 AC_SUBST($1_LIBS)
1872 else
1873 echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1874 echo "*** See http://www.freedesktop.org/software/pkgconfig"
1875 fi
1876 fi
1878 if test $succeeded = yes; then
1879 ifelse([$3], , :, [$3])
1880 else
1881 ifelse([$4], , AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.]), [$4])
1882 fi
1883 ])
1885 HAVE_GTK=no
1886 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "gtk"; then
1887 if test "$USE_X_TOOLKIT" != "none" && test "$USE_X_TOOLKIT" != "maybe"; then
1888 AC_MSG_ERROR([Conflicting options, --with-gtk is incompatible with --with-x-toolkit=${with_x_toolkit}]);
1889 fi
1890 GLIB_REQUIRED=2.0.1
1891 GTK_REQUIRED=2.0.1
1892 GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1894 dnl Check if --with-pkg-config-prog has been given.
1895 if test "X${with_pkg_config_prog}" != X; then
1896 PKG_CONFIG="${with_pkg_config_prog}"
1897 fi
1898 dnl Checks for libraries.
1899 PKG_CHECK_MODULES(GTK, $GTK_MODULES)
1900 AC_SUBST(GTK_CFLAGS)
1901 AC_SUBST(GTK_LIBS)
1902 C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1903 HAVE_GTK=yes
1904 AC_DEFINE(HAVE_GTK, 1, [Define to 1 if using GTK.])
1905 USE_X_TOOLKIT=none
1907 dnl GTK scrollbars resembles toolkit scrollbars alot, so to avoid
1908 dnl a lot if #ifdef:s, say we have toolkit scrollbars.
1909 with_toolkit_scroll_bars=yes
1910 fi
1912 dnl Do not put whitespace before the #include statements below.
1913 dnl Older compilers (eg sunos4 cc) choke on it.
1914 if test x"${USE_X_TOOLKIT}" = xmaybe; then
1915 if test x"${HAVE_X11R5}" = xyes; then
1916 AC_MSG_CHECKING(X11 version 5 with Xaw)
1917 AC_CACHE_VAL(emacs_cv_x11_version_5_with_xaw,
1918 [AC_TRY_LINK([
1919 #include <X11/Intrinsic.h>
1920 #include <X11/Xaw/Simple.h>],
1921 [],
1922 emacs_cv_x11_version_5_with_xaw=yes,
1923 emacs_cv_x11_version_5_with_xaw=no)])
1924 if test $emacs_cv_x11_version_5_with_xaw = yes; then
1925 AC_MSG_RESULT([5 or newer, with Xaw; use toolkit by default])
1926 USE_X_TOOLKIT=LUCID
1927 else
1928 AC_MSG_RESULT(before 5 or no Xaw; do not use toolkit by default)
1929 USE_X_TOOLKIT=none
1930 fi
1931 else
1932 USE_X_TOOLKIT=none
1933 fi
1934 fi
1936 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1938 if test "${USE_X_TOOLKIT}" != "none"; then
1939 AC_MSG_CHECKING(X11 toolkit version)
1940 AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1941 [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1942 [#if XtSpecificationRelease < 6
1943 fail;
1944 #endif
1945 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1946 HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1947 if test $emacs_cv_x11_toolkit_version_6 = yes; then
1948 AC_MSG_RESULT(6 or newer)
1949 AC_DEFINE(HAVE_X11XTR6, 1,
1950 [Define to 1 if you have the X11R6 or newer version of Xt.])
1951 else
1952 AC_MSG_RESULT(before 6)
1953 fi
1955 dnl If using toolkit, check whether libXmu.a exists.
1956 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1957 OLDLIBS="$LIBS"
1958 if test x$HAVE_X11XTR6 = xyes; then
1959 LIBS="-lXt -lSM -lICE $LIBS"
1960 else
1961 LIBS="-lXt $LIBS"
1962 fi
1963 AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1964 test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1965 fi
1967 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1968 if test "${HAVE_X11}" = "yes"; then
1969 if test "${USE_X_TOOLKIT}" != "none"; then
1970 AC_CHECK_LIB(Xext, XShapeQueryExtension)
1971 fi
1972 fi
1974 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1975 AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1976 # We put this in CFLAGS temporarily to precede other -I options
1977 # that might be in CFLAGS temporarily.
1978 # We put this in CPPFLAGS where it precedes the other -I options.
1979 OLD_CPPFLAGS=$CPPFLAGS
1980 OLD_CFLAGS=$CFLAGS
1981 CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1982 CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1983 [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1984 [int x = 5;],
1985 emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1986 if test $emacs_cv_lesstif = yes; then
1987 # Make sure this -I option remains in CPPFLAGS after it is set
1988 # back to REAL_CPPFLAGS.
1989 # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1990 # have those other -I options anyway. Ultimately, having this
1991 # directory ultimately in CPPFLAGS will be enough.
1992 REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1993 LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1994 else
1995 CFLAGS=$OLD_CFLAGS
1996 CPPFLAGS=$OLD_CPPFLAGS
1997 fi
1998 AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1999 [AC_TRY_COMPILE([#include <Xm/Xm.h>],
2000 [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2001 int x = 5;
2002 #else
2003 Motif version prior to 2.1.
2004 #endif],
2005 emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2006 HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
2007 if test $emacs_cv_motif_version_2_1 = yes; then
2008 HAVE_LIBXP=no
2009 AC_DEFINE(HAVE_MOTIF_2_1, 1,
2010 [Define to 1 if you have Motif 2.1 or newer.])
2011 AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
2012 if test ${HAVE_LIBXP} = yes; then
2013 AC_DEFINE(HAVE_LIBXP, 1,
2014 [Define to 1 if you have the Xp library (-lXp).])
2015 fi
2016 fi
2017 fi
2019 ### Is -lXaw3d available?
2020 HAVE_XAW3D=no
2021 if test "${HAVE_X11}" = "yes"; then
2022 if test "${USE_X_TOOLKIT}" != "none"; then
2023 dnl Fixme: determine what Scrollbar.h needs to avoid compilation
2024 dnl errors from the test without the `-'.
2025 AC_CHECK_HEADER(X11/Xaw3d/Scrollbar.h,
2026 [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb, HAVE_XAW3D=yes)], , -)
2027 if test "${HAVE_XAW3D}" = "yes"; then
2028 AC_DEFINE(HAVE_XAW3D, 1,
2029 [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2030 fi
2031 fi
2032 fi
2034 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2035 dnl using Motif or Xaw3d is available, and unless
2036 dnl --with-toolkit-scroll-bars=no was specified.
2038 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2039 [Define to 1 if we should use toolkit scroll bars.])dnl
2040 USE_TOOLKIT_SCROLL_BARS=no
2041 if test "${with_toolkit_scroll_bars}" != "no"; then
2042 if test "${USE_X_TOOLKIT}" != "none"; then
2043 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2044 AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2045 HAVE_XAW3D=no
2046 USE_TOOLKIT_SCROLL_BARS=yes
2047 elif test "${HAVE_XAW3D}" = "yes"; then
2048 AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2049 USE_TOOLKIT_SCROLL_BARS=yes
2050 fi
2051 elif test "${HAVE_GTK}" = "yes"; then
2052 AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2053 USE_TOOLKIT_SCROLL_BARS=yes
2054 fi
2055 fi
2057 dnl Don't use X11 input methods if user specifies he doesn't want it
2058 dnl with `--with-xim=no'.
2060 if test "${with_xim}" != "no"; then
2061 AC_DEFINE(USE_XIM, 1,
2062 [Define to 1 if we should use XIM, if it is available.])
2063 late_CFLAGS=$CFLAGS
2064 if test "$GCC" = yes; then
2065 CFLAGS="$CFLAGS --pedantic-errors"
2066 fi
2067 fi
2068 if test "${HAVE_X11}" = "yes"; then
2069 AC_TRY_COMPILE([
2070 #include <X11/Xlib.h>
2071 #include <X11/Xresource.h>],
2072 [Display *display;
2073 XrmDatabase db;
2074 char *res_name;
2075 char *res_class;
2076 XIMProc callback;
2077 XPointer *client_data;
2078 #ifndef __GNUC__
2079 /* If we're not using GCC, it's probably not XFree86, and this is
2080 probably right, but we can't use something like --pedantic-errors. */
2081 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2082 char*, XIMProc, XPointer*);
2083 #endif
2084 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2085 client_data);],
2086 [emacs_cv_arg6_star=yes])
2087 AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2088 [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2089 either XPointer or XPointer*.])dnl
2090 if test "$emacs_cv_arg6_star" = yes; then
2091 AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2092 else
2093 AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2094 fi
2095 CFLAGS=$late_CFLAGS
2096 fi
2098 ### Use -lXpm if available, unless `--with-xpm=no'.
2099 HAVE_XPM=no
2100 if test "${HAVE_X11}" = "yes"; then
2101 if test "${with_xpm}" != "no"; then
2102 AC_CHECK_HEADER(X11/xpm.h,
2103 AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11))
2104 if test "${HAVE_XPM}" = "yes"; then
2105 AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2106 AC_EGREP_CPP(no_return_alloc_pixels,
2107 [#include "X11/xpm.h"
2108 #ifndef XpmReturnAllocPixels
2109 no_return_alloc_pixels
2110 #endif
2111 ], HAVE_XPM=no, HAVE_XPM=yes)
2113 if test "${HAVE_XPM}" = "yes"; then
2114 AC_MSG_RESULT(yes)
2115 else
2116 AC_MSG_RESULT(no)
2117 fi
2118 fi
2119 fi
2121 if test "${HAVE_XPM}" = "yes"; then
2122 AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2123 fi
2124 fi
2126 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2127 HAVE_JPEG=no
2128 if test "${HAVE_X11}" = "yes"; then
2129 if test "${with_jpeg}" != "no"; then
2130 dnl Checking for jpeglib.h can lose because of a redefinition of
2131 dnl HAVE_STDLIB_H.
2132 AC_CHECK_HEADER(jerror.h,
2133 AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes))
2134 fi
2136 AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2137 if test "${HAVE_JPEG}" = "yes"; then
2138 AC_DEFINE(HAVE_JPEG)
2139 AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2140 [#include <jpeglib.h>
2141 version=JPEG_LIB_VERSION
2142 ],
2143 AC_DEFINE(HAVE_JPEG),
2144 [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2145 HAVE_JPEG=no])
2146 fi
2147 fi
2149 ### Use -lpng if available, unless `--with-png=no'.
2150 HAVE_PNG=no
2151 if test "${HAVE_X11}" = "yes"; then
2152 if test "${with_png}" != "no"; then
2153 # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2154 # in /usr/include/libpng.
2155 AC_CHECK_HEADERS(png.h libpng/png.h)
2156 if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2157 AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2158 fi
2159 fi
2161 if test "${HAVE_PNG}" = "yes"; then
2162 AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2163 fi
2164 fi
2166 ### Use -ltiff if available, unless `--with-tiff=no'.
2167 HAVE_TIFF=no
2168 if test "${HAVE_X11}" = "yes"; then
2169 if test "${with_tiff}" != "no"; then
2170 AC_CHECK_HEADER(tiffio.h,
2171 tifflibs="-lz -lm"
2172 # At least one tiff package requires the jpeg library.
2173 if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2174 AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs))
2175 fi
2177 if test "${HAVE_TIFF}" = "yes"; then
2178 AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2179 fi
2180 fi
2182 ### Use -lgif if available, unless `--with-gif=no'.
2183 HAVE_GIF=no
2184 if test "${HAVE_X11}" = "yes"; then
2185 if test "${with_gif}" != "no"; then
2186 AC_CHECK_HEADER(gif_lib.h,
2187 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2188 # Earlier versions can crash Emacs.
2189 AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes))
2190 fi
2192 if test "${HAVE_GIF}" = "yes"; then
2193 AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have the ungif library (-lungif).])
2194 fi
2195 fi
2197 ### Use Mac OS X Carbon API to implement GUI.
2198 HAVE_CARBON=no
2199 if test "${with_carbon}" != "no"; then
2200 AC_CHECK_HEADER(Carbon/Carbon.h, HAVE_CARBON=yes)
2201 fi
2203 if test "${HAVE_CARBON}" = "yes"; then
2204 AC_DEFINE(HAVE_CARBON, 1, [Define to 1 if you are using the Carbon API on Mac OS X.])
2205 window_system=mac
2206 ## Specify the install directory
2207 carbon_appdir=
2208 if test "${carbon_appdir_x}" != ""; then
2209 case ${carbon_appdir_x} in
2210 y | ye | yes) carbon_appdir=/Applications ;;
2211 * ) carbon_appdir=${carbon_appdir_x} ;;
2212 esac
2213 fi
2214 # We also have mouse menus.
2215 HAVE_MENUS=yes
2216 fi
2218 ### Use session management (-lSM -lICE) if available
2219 HAVE_X_SM=no
2220 if test "${HAVE_X11}" = "yes"; then
2221 AC_CHECK_HEADER(X11/SM/SMlib.h,
2222 AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, -lICE))
2224 if test "${HAVE_X_SM}" = "yes"; then
2225 AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2226 case "$LIBS" in
2227 *-lSM*) ;;
2228 *) LIBS="-lSM -lICE $LIBS" ;;
2229 esac
2230 fi
2231 fi
2233 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2234 AC_CACHE_CHECK(whether netdb declares h_errno,
2235 emacs_cv_netdb_declares_h_errno,
2236 [AC_TRY_LINK([#include <netdb.h>],
2237 [return h_errno;],
2238 emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2239 if test $emacs_cv_netdb_declares_h_errno = yes; then
2240 AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2241 fi
2243 AC_FUNC_ALLOCA
2245 # fmod, logb, and frexp are found in -lm on most systems.
2246 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2247 AC_CHECK_LIB(m, sqrt)
2249 # Check for mail-locking functions in a "mail" library. Probably this should
2250 # have the same check as for liblockfile below.
2251 AC_CHECK_LIB(mail, maillock)
2252 dnl Debian, at least:
2253 AC_CHECK_LIB(lockfile, maillock)
2254 # If we have the shared liblockfile, assume we must use it for mail
2255 # locking (e.g. Debian). If we couldn't link against liblockfile
2256 # (no liblockfile.a installed), ensure that we don't need to.
2257 if test "$ac_cv_lib_lockfile_maillock" = no; then
2258 dnl This works for files generally, not just executables.
2259 dnl Should we look elsewhere for it? Maybe examine /etc/ld.so.conf?
2260 AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2261 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2262 if test $ac_cv_prog_liblockfile = yes; then
2263 AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2264 This probably means that movemail could lose mail.
2265 There may be a `development' package to install containing liblockfile.])
2266 else :
2267 fi
2268 fi
2269 AC_CHECK_FUNCS(touchlock)
2270 AC_CHECK_HEADERS(maillock.h)
2272 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2273 rename closedir mkdir rmdir sysinfo \
2274 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime res_init setsid \
2275 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2276 utimes setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2277 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2278 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2279 gai_strerror mkstemp getline getdelim mremap memmove fsync bzero \
2280 memset memcmp memmove difftime memcpy mempcpy mblen mbrlen posix_memalign)
2282 AC_CHECK_HEADERS(sys/un.h)
2284 AC_FUNC_MKTIME
2285 if test "$ac_cv_func_working_mktime" = no; then
2286 AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2287 fi
2289 AC_FUNC_GETLOADAVG
2291 AC_FUNC_FSEEKO
2293 AC_FUNC_GETPGRP
2295 AC_FUNC_STRFTIME
2297 # UNIX98 PTYs.
2298 AC_CHECK_FUNCS(grantpt)
2300 # PTY-related GNU extensions.
2301 AC_CHECK_FUNCS(getpt)
2303 # Check this now, so that we will NOT find the above functions in ncurses.
2304 # That is because we have not set up to link ncurses in lib-src.
2305 # It's better to believe a function is not available
2306 # than to expect to find it in ncurses.
2307 AC_CHECK_LIB(ncurses, tparm)
2309 # Do we need the Hesiod library to provide the support routines?
2310 if test "$with_hesiod" = yes ; then
2311 # Don't set $LIBS here -- see comments above.
2312 resolv=no
2313 AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2314 [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2315 [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2316 if test "$resolv" = yes ; then
2317 RESOLVLIB=-lresolv
2318 AC_DEFINE(HAVE_LIBRESOLV, 1,
2319 [Define to 1 if you have the resolv library (-lresolv).])
2320 else
2321 RESOLVLIB=
2322 fi
2323 AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2324 AC_DEFINE(HAVE_LIBHESIOD, 1,
2325 [Define to 1 if you have the hesiod library (-lhesiod).]),
2326 :, $RESOLVLIB)])
2327 fi
2329 # These tell us which Kerberos-related libraries to use.
2330 if test "${with_kerberos+set}" = set; then
2331 AC_CHECK_LIB(com_err, com_err)
2332 AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2333 AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2334 AC_CHECK_LIB(krb5, krb5_init_context)
2335 if test "${with_kerberos5+set}" != set; then
2336 AC_CHECK_LIB(des425, des_cbc_encrypt,,
2337 AC_CHECK_LIB(des, des_cbc_encrypt))
2338 AC_CHECK_LIB(krb4, krb_get_cred,,
2339 AC_CHECK_LIB(krb, krb_get_cred))
2340 fi
2342 if test "${with_kerberos5+set}" = set; then
2343 AC_CHECK_HEADERS(krb5.h)
2344 else
2345 AC_CHECK_HEADERS(des.h,,
2346 [AC_CHECK_HEADERS(kerberosIV/des.h,,
2347 [AC_CHECK_HEADERS(kerberos/des.h)])])
2348 AC_CHECK_HEADERS(krb.h,,
2349 [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2350 [AC_CHECK_HEADERS(kerberos/krb.h)])])
2351 fi
2352 AC_CHECK_HEADERS(com_err.h)
2353 fi
2355 # Solaris requires -lintl if you want strerror (which calls dgettext)
2356 # to return localized messages.
2357 AC_CHECK_LIB(intl, dgettext)
2359 AC_MSG_CHECKING(whether localtime caches TZ)
2360 AC_CACHE_VAL(emacs_cv_localtime_cache,
2361 [if test x$ac_cv_func_tzset = xyes; then
2362 AC_TRY_RUN([#include <time.h>
2363 extern char **environ;
2364 unset_TZ ()
2365 {
2366 char **from, **to;
2367 for (to = from = environ; (*to = *from); from++)
2368 if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2369 to++;
2370 }
2371 char TZ_GMT0[] = "TZ=GMT0";
2372 char TZ_PST8[] = "TZ=PST8";
2373 main()
2374 {
2375 time_t now = time ((time_t *) 0);
2376 int hour_GMT0, hour_unset;
2377 if (putenv (TZ_GMT0) != 0)
2378 exit (1);
2379 hour_GMT0 = localtime (&now)->tm_hour;
2380 unset_TZ ();
2381 hour_unset = localtime (&now)->tm_hour;
2382 if (putenv (TZ_PST8) != 0)
2383 exit (1);
2384 if (localtime (&now)->tm_hour == hour_GMT0)
2385 exit (1);
2386 unset_TZ ();
2387 if (localtime (&now)->tm_hour != hour_unset)
2388 exit (1);
2389 exit (0);
2390 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2391 [# If we have tzset, assume the worst when cross-compiling.
2392 emacs_cv_localtime_cache=yes])
2393 else
2394 # If we lack tzset, report that localtime does not cache TZ,
2395 # since we can't invalidate the cache if we don't have tzset.
2396 emacs_cv_localtime_cache=no
2397 fi])dnl
2398 AC_MSG_RESULT($emacs_cv_localtime_cache)
2399 if test $emacs_cv_localtime_cache = yes; then
2400 AC_DEFINE(LOCALTIME_CACHE, 1,
2401 [Define to 1 if localtime caches TZ.])
2402 fi
2404 if test "x$HAVE_TIMEVAL" = xyes; then
2405 AC_CHECK_FUNCS(gettimeofday)
2406 if test $ac_cv_func_gettimeofday = yes; then
2407 AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2408 emacs_cv_gettimeofday_two_arguments,
2409 [AC_TRY_COMPILE([
2410 #ifdef TIME_WITH_SYS_TIME
2411 #include <sys/time.h>
2412 #include <time.h>
2413 #else
2414 #ifdef HAVE_SYS_TIME_H
2415 #include <sys/time.h>
2416 #else
2417 #include <time.h>
2418 #endif
2419 #endif],
2420 [struct timeval time;
2421 gettimeofday (&time, 0);],
2422 emacs_cv_gettimeofday_two_arguments=yes,
2423 emacs_cv_gettimeofday_two_arguments=no)])
2424 if test $emacs_cv_gettimeofday_two_arguments = no; then
2425 AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2426 [Define to 1 if gettimeofday accepts only one argument.])
2427 fi
2428 fi
2429 fi
2431 # This defines (or not) HAVE_TZNAME and HAVE_TM_ZONE.
2432 AC_STRUCT_TIMEZONE
2434 dnl Note that AC_STRUCT_TIMEZONE doesn't do what you might expect.
2435 if test "$ac_cv_func_gettimeofday" = yes; then
2436 AC_CACHE_CHECK([for struct timezone], emacs_cv_struct_timezone,
2437 [AC_TRY_COMPILE([#include <sys/time.h>],
2438 [struct timezone tz;],
2439 dnl It may be that we can't call gettimeofday with a non-null pointer,
2440 dnl even though we have struct timezone (e.g. HPUX). In that case
2441 dnl we'll lie about struct timezone.
2442 [AC_TRY_RUN([
2443 #ifdef TIME_WITH_SYS_TIME
2444 #include <sys/time.h>
2445 #include <time.h>
2446 #else
2447 #ifdef HAVE_SYS_TIME_H
2448 #include <sys/time.h>
2449 #else
2450 #include <time.h>
2451 #endif
2452 #endif
2453 main () {
2454 struct timeval time;
2455 struct timezone dummy;
2456 exit (gettimeofday (&time, &dummy));
2457 }],
2458 emacs_cv_struct_timezone=yes,
2459 emacs_cv_struct_timezone=no, emacs_cv_struct_timezone=yes)],
2460 emacs_cv_struct_timezone=no)])
2461 fi
2463 ok_so_far=yes
2464 AC_CHECK_FUNC(socket, , ok_so_far=no)
2465 if test $ok_so_far = yes; then
2466 AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2467 fi
2468 if test $ok_so_far = yes; then
2469 AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2470 fi
2471 if test $ok_so_far = yes; then
2472 dnl Fixme: Not used. Should this be HAVE_SOCKETS?
2473 AC_DEFINE(HAVE_INET_SOCKETS, 1,
2474 [Define to 1 if you have inet sockets.])
2475 fi
2477 if test -f /usr/lpp/X11/bin/smt.exp; then
2478 AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2479 [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2480 fi
2482 AC_MSG_CHECKING(whether system supports dynamic ptys)
2483 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2484 AC_MSG_RESULT(yes)
2485 AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2486 else
2487 AC_MSG_RESULT(no)
2488 fi
2490 AC_FUNC_FORK
2492 dnl Adapted from Haible's version.
2493 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2494 [AC_TRY_LINK([#include <langinfo.h>],
2495 [char* cs = nl_langinfo(CODESET);],
2496 emacs_cv_langinfo_codeset=yes,
2497 emacs_cv_langinfo_codeset=no)
2498 ])
2499 if test $emacs_cv_langinfo_codeset = yes; then
2500 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2501 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2502 fi
2504 AC_CHECK_TYPES(size_t)
2506 AC_TYPE_MBSTATE_T
2508 dnl Restrict could probably be used effectively other than in regex.c.
2509 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2510 [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2511 emacs_cv_c_restrict=yes,
2512 [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2513 emacs_cv_c_restrict=__restrict,
2514 emacs_cv_c_restrict=no)])])
2515 case "$emacs_cv_c_restrict" in
2516 yes) emacs_restrict=restrict;;
2517 no) emacs_restrict="";;
2518 *) emacs_restrict="$emacs_cv_c_restrict";;
2519 esac
2520 if test "$emacs_restrict" != __restrict; then
2521 AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2522 [Define to compiler's equivalent of C99 restrict keyword.
2523 Don't define if equivalent is `__restrict'.])
2524 fi
2526 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2527 [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2528 emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2529 if test "$emacs_cv_c_restrict_arr" = yes; then
2530 AC_DEFINE(__restrict_arr, __restrict,
2531 [Define to compiler's equivalent of C99 restrict keyword in array
2532 declarations. Define as empty for no equivalent.])
2533 fi
2535 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2536 dnl how the tty code is related to POSIX and/or other versions of termios.
2537 dnl The following looks like a useful start.
2538 dnl
2539 dnl AC_SYS_POSIX_TERMIOS
2540 dnl if test $ac_cv_sys_posix_termios = yes; then
2541 dnl AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2542 dnl and macros for terminal control.])
2543 dnl AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2544 dnl fi
2546 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used. (Needs libobj replacement.)
2548 # Set up the CFLAGS for real compilation, so we can substitute it.
2549 CFLAGS="$REAL_CFLAGS"
2550 CPPFLAGS="$REAL_CPPFLAGS"
2552 #### Find out which version of Emacs this is.
2553 [version=`grep 'defconst[ ]*emacs-version' ${srcdir}/lisp/version.el \
2554 | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2555 if test x"${version}" = x; then
2556 AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2557 fi
2559 ### Specify what sort of things we'll be editing into Makefile and config.h.
2560 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2561 AC_SUBST(version)
2562 AC_SUBST(configuration)
2563 AC_SUBST(canonical)
2564 AC_SUBST(srcdir)
2565 AC_SUBST(prefix)
2566 AC_SUBST(exec_prefix)
2567 AC_SUBST(bindir)
2568 AC_SUBST(datadir)
2569 AC_SUBST(sharedstatedir)
2570 AC_SUBST(libexecdir)
2571 AC_SUBST(mandir)
2572 AC_SUBST(infodir)
2573 AC_SUBST(lispdir)
2574 AC_SUBST(locallisppath)
2575 AC_SUBST(lisppath)
2576 AC_SUBST(x_default_search_path)
2577 AC_SUBST(etcdir)
2578 AC_SUBST(archlibdir)
2579 AC_SUBST(docdir)
2580 AC_SUBST(bitmapdir)
2581 AC_SUBST(gamedir)
2582 AC_SUBST(gameuser)
2583 AC_SUBST(c_switch_system)
2584 AC_SUBST(c_switch_machine)
2585 AC_SUBST(LD_SWITCH_X_SITE)
2586 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2587 AC_SUBST(C_SWITCH_X_SITE)
2588 AC_SUBST(CFLAGS)
2589 AC_SUBST(X_TOOLKIT_TYPE)
2590 AC_SUBST(machfile)
2591 AC_SUBST(opsysfile)
2592 AC_SUBST(GETLOADAVG_LIBS)
2593 AC_SUBST(carbon_appdir)
2595 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION, "${canonical}",
2596 [Define to the canonical Emacs configuration name.])
2597 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2598 [Define to the options passed to configure.])
2599 AC_DEFINE_UNQUOTED(config_machfile, "${machfile}",
2600 [Define to the used machine dependent file.])
2601 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2602 [Define to the used os dependent file.])
2603 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2604 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2605 may need to deal with X Windows. For instance, if you've defined
2606 HAVE_X_WINDOWS above and your X libraries aren't in a place that
2607 your loader can find on its own, you might want to add "-L/..." or
2608 something similar.])
2609 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2610 [Define LD_SWITCH_X_SITE_AUX with an -R option
2611 in case it's needed (for Solaris, for example).])
2612 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE, ${C_SWITCH_X_SITE},
2613 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2614 may need to deal with X Windows. For instance, if you've defined
2615 HAVE_X_WINDOWS above and your X include files aren't in a place
2616 that your compiler can find on its own, you might want to add
2617 "-I/..." or something similar.])
2618 AC_DEFINE_UNQUOTED(UNEXEC_SRC, ${UNEXEC_SRC},
2619 [Define to the unexec source file name.])
2621 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2622 AC_DEFINE(HAVE_X_WINDOWS, 1,
2623 [Define to 1 if you want to use the X window system.])
2624 fi
2625 if test "${USE_X_TOOLKIT}" != "none" ; then
2626 AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2627 fi
2628 if test "${HAVE_X11}" = "yes" ; then
2629 AC_DEFINE(HAVE_X11, 1,
2630 [Define to 1 if you want to use version 11 of X windows.
2631 Otherwise, Emacs expects to use version 10.])
2632 fi
2633 if test "${HAVE_XFREE386}" = "yes" ; then
2634 AC_DEFINE(HAVE_XFREE386, 1, [Define to 1 if you're using XFree386.])
2635 fi
2636 if test "${HAVE_MENUS}" = "yes" ; then
2637 AC_DEFINE(HAVE_MENUS, 1,
2638 [Define to 1 if you have mouse menus.
2639 (This is automatic if you use X, but the option to specify it remains.)
2640 It is also defined with other window systems that support xmenu.c.])
2641 fi
2642 if test "${GNU_MALLOC}" = "yes" ; then
2643 AC_DEFINE(GNU_MALLOC, 1,
2644 [Define to 1 if you want to use the GNU memory allocator.])
2645 fi
2646 if test "${REL_ALLOC}" = "yes" ; then
2647 AC_DEFINE(REL_ALLOC, 1,
2648 [Define REL_ALLOC if you want to use the relocating allocator for
2649 buffer space.])
2650 fi
2652 AH_TOP([/* GNU Emacs site configuration template file.
2653 Copyright (C) 1988, 93, 94, 99, 2000, 2002 Free Software Foundation, Inc.
2655 This file is part of GNU Emacs.
2657 GNU Emacs is free software; you can redistribute it and/or modify
2658 it under the terms of the GNU General Public License as published by
2659 the Free Software Foundation; either version 2, or (at your option)
2660 any later version.
2662 GNU Emacs is distributed in the hope that it will be useful,
2663 but WITHOUT ANY WARRANTY; without even the implied warranty of
2664 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
2665 GNU General Public License for more details.
2667 You should have received a copy of the GNU General Public License
2668 along with GNU Emacs; see the file COPYING. If not, write to the
2669 Free Software Foundation, Inc., 59 Temple Place - Suite 330,
2670 Boston, MA 02111-1307, USA. */
2673 /* No code in Emacs #includes config.h twice, but some bits of code
2674 intended to work with other packages as well (like gmalloc.c)
2675 think they can include it as many times as they like. */
2676 #ifndef EMACS_CONFIG_H
2677 #define EMACS_CONFIG_H
2678 ])dnl
2680 AH_BOTTOM([
2681 /* If we're using any sort of window system, define some consequences. */
2682 #ifdef HAVE_X_WINDOWS
2683 #define HAVE_WINDOW_SYSTEM
2684 #define MULTI_KBOARD
2685 #define HAVE_MOUSE
2686 #endif
2688 /* If we're using the Carbon API on Mac OS X, define a few more
2689 variables as well. */
2690 #ifdef HAVE_CARBON
2691 #define HAVE_WINDOW_SYSTEM
2692 #define HAVE_MOUSE
2693 #endif
2695 /* Define USER_FULL_NAME to return a string
2696 that is the user's full name.
2697 It can assume that the variable `pw'
2698 points to the password file entry for this user.
2700 At some sites, the pw_gecos field contains
2701 the user's full name. If neither this nor any other
2702 field contains the right thing, use pw_name,
2703 giving the user's login name, since that is better than nothing. */
2704 #define USER_FULL_NAME pw->pw_gecos
2706 /* Define AMPERSAND_FULL_NAME if you use the convention
2707 that & in the full name stands for the login id. */
2708 /* Turned on June 1996 supposing nobody will mind it. */
2709 #define AMPERSAND_FULL_NAME
2711 /* We have blockinput.h. */
2712 #define DO_BLOCK_INPUT
2714 /* Define HAVE_SOUND if we have sound support. We know it works
2715 and compiles only on the specified platforms. For others,
2716 it probably doesn't make sense to try. */
2718 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2719 #ifdef HAVE_MACHINE_SOUNDCARD_H
2720 #define HAVE_SOUND 1
2721 #endif
2722 #ifdef HAVE_SYS_SOUNDCARD_H
2723 #define HAVE_SOUND 1
2724 #endif
2725 #ifdef HAVE_SOUNDCARD_H
2726 #define HAVE_SOUND 1
2727 #endif
2728 #endif /* __FreeBSD__ || __NetBSD__ || __linux__ */
2730 /* If using GNU, then support inline function declarations. */
2731 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2732 generally, because even if non-gcc compilers accept `inline', they
2733 may reject `extern inline'. */
2734 #ifdef __GNUC__
2735 #define INLINE __inline__
2736 #else
2737 #define INLINE
2738 #endif
2740 /* Include the os and machine dependent files. */
2741 #include config_opsysfile
2742 #include config_machfile
2744 /* Load in the conversion definitions if this system
2745 needs them and the source file being compiled has not
2746 said to inhibit this. There should be no need for you
2747 to alter these lines. */
2749 #ifdef SHORTNAMES
2750 #ifndef NO_SHORTNAMES
2751 #include "../shortnames/remap.h"
2752 #endif /* not NO_SHORTNAMES */
2753 #endif /* SHORTNAMES */
2755 /* If no remapping takes place, static variables cannot be dumped as
2756 pure, so don't worry about the `static' keyword. */
2757 #ifdef NO_REMAP
2758 #undef static
2759 #endif
2761 /* Define `subprocesses' should be defined if you want to
2762 have code for asynchronous subprocesses
2763 (as used in M-x compile and M-x shell).
2764 These do not work for some USG systems yet;
2765 for the ones where they work, the s/SYSTEM.h file defines this flag. */
2767 #ifndef VMS
2768 #ifndef USG
2769 /* #define subprocesses */
2770 #endif
2771 #endif
2773 /* SIGTYPE is the macro we actually use. */
2774 #ifndef SIGTYPE
2775 #define SIGTYPE RETSIGTYPE
2776 #endif
2778 #ifdef emacs /* Don't do this for lib-src. */
2779 /* Tell regex.c to use a type compatible with Emacs. */
2780 #define RE_TRANSLATE_TYPE Lisp_Object
2781 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2782 #define RE_TRANSLATE_P(TBL) (XFASTINT (TBL) != 0)
2783 #endif
2785 /* Avoid link-time collision with system mktime if we will use our own. */
2786 #if ! HAVE_MKTIME || BROKEN_MKTIME
2787 #define mktime emacs_mktime
2788 #endif
2790 #define my_strftime nstrftime /* for strftime.c */
2792 /* The rest of the code currently tests the CPP symbol BSTRING.
2793 Override any claims made by the system-description files.
2794 Note that on some SCO version it is possible to have bcopy and not bcmp. */
2795 #undef BSTRING
2796 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2797 #define BSTRING
2798 #endif
2800 /* Some of the files of Emacs which are intended for use with other
2801 programs assume that if you have a config.h file, you must declare
2802 the type of getenv.
2804 This declaration shouldn't appear when alloca.s or Makefile.in
2805 includes config.h. */
2806 #ifndef NOT_C_CODE
2807 extern char *getenv ();
2808 #endif
2810 /* These default definitions are good for almost all machines.
2811 The exceptions override them in m/MACHINE.h. */
2813 #ifndef BITS_PER_CHAR
2814 #define BITS_PER_CHAR 8
2815 #endif
2817 #ifndef BITS_PER_SHORT
2818 #define BITS_PER_SHORT 16
2819 #endif
2821 /* Note that lisp.h uses this in a preprocessor conditional, so it
2822 would not work to use sizeof. That being so, we do all of them
2823 without sizeof, for uniformity's sake. */
2824 #ifndef BITS_PER_INT
2825 #define BITS_PER_INT 32
2826 #endif
2828 #ifndef BITS_PER_LONG
2829 #ifdef _LP64
2830 #define BITS_PER_LONG 64
2831 #else
2832 #define BITS_PER_LONG 32
2833 #endif
2834 #endif
2836 /* Define if the compiler supports function prototypes. It may do so
2837 but not define __STDC__ (e.g. DEC C by default) or may define it as
2838 zero. */
2839 #undef PROTOTYPES
2840 /* For mktime.c: */
2841 #ifndef __P
2842 # if defined PROTOTYPES
2843 # define __P(args) args
2844 # else
2845 # define __P(args) ()
2846 # endif /* GCC. */
2847 #endif /* __P */
2849 /* Don't include "string.h" or <stdlib.h> in non-C code. */
2850 #ifndef NOT_C_CODE
2851 #ifdef HAVE_STRING_H
2852 #include "string.h"
2853 #endif
2854 #ifdef HAVE_STRINGS_H
2855 #include "strings.h" /* May be needed for bcopy & al. */
2856 #endif
2857 #ifdef HAVE_STDLIB_H
2858 #include <stdlib.h>
2859 #endif
2860 #ifndef __GNUC__
2861 # ifdef HAVE_ALLOCA_H
2862 # include <alloca.h>
2863 # else /* AIX files deal with #pragma. */
2864 # ifndef alloca /* predefined by HP cc +Olibcalls */
2865 char *alloca ();
2866 # endif
2867 # endif /* HAVE_ALLOCA_H */
2868 #endif /* __GNUC__ */
2869 #ifndef HAVE_SIZE_T
2870 typedef unsigned size_t;
2871 #endif
2872 #endif /* NOT_C_CODE */
2874 /* Define HAVE_X_I18N if we have usable i18n support. */
2876 #ifdef HAVE_X11R6
2877 #define HAVE_X_I18N
2878 #elif defined HAVE_X11R5 && !defined X11R5_INHIBIT_I18N
2879 #define HAVE_X_I18N
2880 #endif
2882 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support. */
2884 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
2885 #define HAVE_X11R6_XIM
2886 #endif
2888 /* Should we enable expensive run-time checking of data types? */
2889 #undef ENABLE_CHECKING
2891 #if defined __GNUC__ && (__GNUC__ > 2 \
2892 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
2893 #define NO_RETURN __attribute__ ((__noreturn__))
2894 #else
2895 #define NO_RETURN /* nothing */
2896 #endif
2898 /* These won't be used automatically yet. We also need to know, at least,
2899 that the stack is continuous. */
2900 #ifdef __GNUC__
2901 # ifndef GC_SETJMP_WORKS
2902 /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
2903 see NON_SAVING_SETJMP in the target descriptions. */
2904 /* Exceptions (see NON_SAVING_SETJMP in target description) are ns32k,
2905 SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
2906 Fixme: Deal with ns32k, SVR3. */
2907 # define GC_SETJMP_WORKS 1
2908 # endif
2909 # ifndef GC_LISP_OBJECT_ALIGNMENT
2910 # define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
2911 # endif
2912 #endif
2914 #ifndef HAVE_BCOPY
2915 #define bcopy(a,b,s) memcpy (b,a,s)
2916 #endif
2917 #ifndef HAVE_BZERO
2918 #define bzero(a,s) memset (a,0,s)
2919 #endif
2920 #ifndef HAVE_BCMP
2921 #define BCMP memcmp
2922 #endif
2924 #endif /* EMACS_CONFIG_H */
2926 /*
2927 Local Variables:
2928 mode: c
2929 End:
2930 */
2931 ])dnl
2933 #### Report on what we decided to do.
2934 #### Report GTK as a toolkit, even if it doesn't use Xt.
2935 #### It makes printing result more understandable as using GTK sets
2936 #### toolkit_scroll_bars to yes by default.
2937 if test "${HAVE_GTK}" = "yes"; then
2938 USE_X_TOOLKIT=GTK
2939 fi
2941 echo "
2942 Configured for \`${canonical}'.
2944 Where should the build process find the source code? ${srcdir}
2945 What operating system and machine description files should Emacs use?
2946 \`${opsysfile}' and \`${machfile}'
2947 What compiler should emacs be built with? ${CC} ${CFLAGS}
2948 Should Emacs use the GNU version of malloc? ${GNU_MALLOC}${GNU_MALLOC_reason}
2949 Should Emacs use a relocating allocator for buffers? ${REL_ALLOC}
2950 Should Emacs use mmap(2) for buffer allocation? $use_mmap_for_buffers
2951 What window system should Emacs use? ${window_system}
2952 What toolkit should Emacs use? ${USE_X_TOOLKIT}"
2954 if test -n "${x_includes}"; then
2955 echo " Where do we find X Windows header files? ${x_includes}"
2956 else
2957 echo " Where do we find X Windows header files? Standard dirs"
2958 fi
2959 if test -n "${x_libraries}"; then
2960 echo " Where do we find X Windows libraries? ${x_libraries}"
2961 else
2962 echo " Where do we find X Windows libraries? Standard dirs"
2963 fi
2965 echo " Does Emacs use -lXaw3d? ${HAVE_XAW3D}"
2966 echo " Does Emacs use -lXpm? ${HAVE_XPM}"
2967 echo " Does Emacs use -ljpeg? ${HAVE_JPEG}"
2968 echo " Does Emacs use -ltiff? ${HAVE_TIFF}"
2969 echo " Does Emacs use -lungif? ${HAVE_GIF}"
2970 echo " Does Emacs use -lpng? ${HAVE_PNG}"
2971 echo " Does Emacs use X toolkit scroll bars? ${USE_TOOLKIT_SCROLL_BARS}"
2972 echo
2974 # Remove any trailing slashes in these variables.
2975 [test "${prefix}" != NONE &&
2976 prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
2977 test "${exec_prefix}" != NONE &&
2978 exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
2980 ## Check if the C preprocessor will convert `..' to `. .'. If so, set
2981 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
2982 ## from Makefile.c can correctly provide the arg `-traditional' to the
2983 ## C preprocessor.
2985 AC_EGREP_CPP(yes..yes,
2986 [yes..yes],
2987 CPP_NEED_TRADITIONAL=no,
2988 CPP_NEED_TRADITIONAL=yes)
2990 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
2991 man/Makefile lwlib/Makefile src/Makefile.c:src/Makefile.in \
2992 lisp/Makefile lispref/Makefile lispintro/Makefile leim/Makefile, [
2994 ### Make the necessary directories, if they don't exist.
2995 for dir in etc lisp ; do
2996 test -d ${dir} || mkdir ${dir}
2997 done
2999 # Build src/Makefile from ${srcdir}/src/Makefile.c
3000 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
3001 # This must be done after src/config.h is built, since we rely on that file.
3003 # Now get this: Some word that is part of the ${srcdir} directory name
3004 # or the ${configuration} value might, just might, happen to be an
3005 # identifier like `sun4' or `i386' or something, and be predefined by
3006 # the C preprocessor to some helpful value like 1, or maybe the empty
3007 # string. Needless to say consequent macro substitutions are less
3008 # than conducive to the makefile finding the correct directory.
3009 [undefs="`echo $top_srcdir $configuration $canonical |
3010 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/ *$//' \
3011 -e 's/ */ -U/g' -e 's/-U[0-9][^ ]*//g' \
3012 `"]
3014 echo creating src/epaths.h
3015 ${MAKE-make} epaths-force
3017 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3018 # `..' to `. .' unless invoked with -traditional
3020 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3021 CPPFLAGS="$CPPFLAGS -traditional"
3022 fi
3024 echo creating lib-src/Makefile
3025 ( cd lib-src
3026 rm -f junk.c junk1.c junk2.c
3027 sed -e '/start of cpp stuff/q' \
3028 < Makefile.c > junk1.c
3029 sed -e '1,/start of cpp stuff/d'\
3030 -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3031 < Makefile.c > junk.c
3032 $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3033 sed -e 's/^ / /' -e '/^#/d' -e '/^[ \f]*$/d' > junk2.c
3034 cat junk1.c junk2.c > Makefile.new
3035 rm -f junk.c junk1.c junk2.c
3036 chmod 444 Makefile.new
3037 mv -f Makefile.new Makefile
3038 )
3040 echo creating src/Makefile
3041 ( cd src
3042 rm -f junk.c junk1.c junk2.c
3043 sed -e '/start of cpp stuff/q' \
3044 < Makefile.c > junk1.c
3045 sed -e '1,/start of cpp stuff/d'\
3046 -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3047 < Makefile.c > junk.c
3048 $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3049 sed -e 's/^ / /' -e '/^#/d' -e '/^[ \f]*$/d' > junk2.c
3050 cat junk1.c junk2.c > Makefile.new
3051 rm -f junk.c junk1.c junk2.c
3052 chmod 444 Makefile.new
3053 mv -f Makefile.new Makefile
3054 )
3056 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3057 echo creating src/.gdbinit
3058 echo source $srcdir/src/.gdbinit > src/.gdbinit
3059 fi
3061 # This is how we know whether to re-run configure in certain cases.
3062 touch src/config.stamp
3064 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS"])