lisp/vc-svn.el

   1 ;;; vc-svn.el --- non-resident support for Subversion version-control
   2
   3 ;; Copyright (C) 1995,98,99,2000,2001,02,2003  Free Software Foundation, Inc.
   4
   5 ;; Author:      FSF (see vc.el for full credits)
   6 ;; Maintainer:  Stefan Monnier <monnier@gnu.org>
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This is preliminary support for Subversion (http://subversion.tigris.org/).
  28 ;; It started as `sed s/cvs/svn/ vc.cvs.el' (from version 1.56)
  29 ;; and hasn't been completely fixed since.
  30
  31 ;; Sync'd with Subversion's vc-svn.el as of revision 5801.
  32
  33 ;;; Bugs:
  34
  35 ;; - VC-dired is (really) slow.
  36
  37 ;;; Code:
  38
  39 (eval-when-compile
  40   (require 'vc))
  41
  42 ;;;
  43 ;;; Customization options
  44 ;;;
  45
  46 (defcustom vc-svn-global-switches nil
  47   "*Global switches to pass to any SVN command."
  48   :type '(choice (const :tag "None" nil)
  49                  (string :tag "Argument String")
  50                  (repeat :tag "Argument List"
  51                          :value ("")
  52                          string))
  53   :version "21.4"
  54   :group 'vc)
  55
  56 (defcustom vc-svn-register-switches nil
  57   "*Extra switches for registering a file into SVN.
  58 A string or list of strings passed to the checkin program by
  59 \\[vc-register]."
  60   :type '(choice (const :tag "None" nil)
  61                  (string :tag "Argument String")
  62                  (repeat :tag "Argument List"
  63                          :value ("")
  64                          string))
  65   :version "21.4"
  66   :group 'vc)
  67
  68 (defcustom vc-svn-diff-switches
  69   t                        ;`svn' doesn't support common args like -c or -b.
  70   "String or list of strings specifying extra switches for svn diff under VC.
  71 If nil, use the value of `vc-diff-switches'.
  72 If you want to force an empty list of arguments, use t."
  73   :type '(choice (const :tag "Unspecified" nil)
  74                  (const :tag "None" t)
  75                  (string :tag "Argument String")
  76                  (repeat :tag "Argument List"
  77                          :value ("")
  78                          string))
  79   :version "21.4"
  80   :group 'vc)
  81
  82 (defcustom vc-svn-header (or (cdr (assoc 'SVN vc-header-alist)) '("\$Id\$"))
  83   "*Header keywords to be inserted by `vc-insert-headers'."
  84   :version "21.4"
  85   :type '(repeat string)
  86   :group 'vc)
  87
  88 (defconst vc-svn-use-edit nil
  89   ;; Subversion does not provide this feature (yet).
  90   "*Non-nil means to use `svn edit' to \"check out\" a file.
  91 This is only meaningful if you don't use the implicit checkout model
  92 \(i.e. if you have $SVNREAD set)."
  93   ;; :type 'boolean
  94   ;; :version "21.4"
  95   ;; :group 'vc
  96   )
  97
  98 ;;;
  99 ;;; State-querying functions
 100 ;;;
 101
 102 ;;;###autoload (defun vc-svn-registered (f)
 103 ;;;###autoload   (when (file-readable-p (expand-file-name
 104 ;;;###autoload                    ".svn/entries" (file-name-directory f)))
 105 ;;;###autoload       (load "vc-svn")
 106 ;;;###autoload       (vc-svn-registered f)))
 107
 108 ;;;###autoload
 109 (add-to-list 'completion-ignored-extensions ".svn/")
 110
 111 (defun vc-svn-registered (file)
 112   "Check if FILE is SVN registered."
 113   (when (file-readable-p (expand-file-name ".svn/entries"
 114                                            (file-name-directory file)))
 115     (with-temp-buffer
 116       (cd (file-name-directory file))
 117       (condition-case nil
 118           (vc-svn-command t 0 file "status" "-v")
 119         ;; We can't find an `svn' executable.  We could also deregister SVN.
 120         (file-error nil))
 121       (vc-svn-parse-status t)
 122       (eq 'SVN (vc-file-getprop file 'vc-backend)))))
 123
 124 (defun vc-svn-state (file &optional localp)
 125   "SVN-specific version of `vc-state'."
 126   (setq localp (or localp (vc-stay-local-p file)))
 127   (with-temp-buffer
 128     (cd (file-name-directory file))
 129     (vc-svn-command t 0 file "status" (if localp "-v" "-u"))
 130     (vc-svn-parse-status localp)
 131     (vc-file-getprop file 'vc-state)))
 132
 133 (defun vc-svn-state-heuristic (file)
 134   "SVN-specific state heuristic."
 135   (vc-svn-state file 'local))
 136
 137 (defun vc-svn-dir-state (dir &optional localp)
 138   "Find the SVN state of all files in DIR."
 139   (setq localp (or localp (vc-stay-local-p dir)))
 140   (let ((default-directory dir))
 141     ;; Don't specify DIR in this command, the default-directory is
 142     ;; enough.  Otherwise it might fail with remote repositories.
 143     (with-temp-buffer
 144       (vc-svn-command t 0 nil "status" (if localp "-v" "-u"))
 145       (vc-svn-parse-status localp))))
 146
 147 (defun vc-svn-workfile-version (file)
 148   "SVN-specific version of `vc-workfile-version'."
 149   ;; There is no need to consult RCS headers under SVN, because we
 150   ;; get the workfile version for free when we recognize that a file
 151   ;; is registered in SVN.
 152   (vc-svn-registered file)
 153   (vc-file-getprop file 'vc-workfile-version))
 154
 155 (defun vc-svn-checkout-model (file)
 156   "SVN-specific version of `vc-checkout-model'."
 157   ;; It looks like Subversion has no equivalent of CVSREAD.
 158   'implicit)
 159
 160 ;; vc-svn-mode-line-string doesn't exist because the default implementation
 161 ;; works just fine.
 162
 163 (defun vc-svn-dired-state-info (file)
 164   "SVN-specific version of `vc-dired-state-info'."
 165   (let ((svn-state (vc-state file)))
 166     (cond ((eq svn-state 'edited)
 167            (if (equal (vc-workfile-version file) "0")
 168                "(added)" "(modified)"))
 169           ((eq svn-state 'needs-patch) "(patch)")
 170           ((eq svn-state 'needs-merge) "(merge)"))))
 171
 172
 173 ;;;
 174 ;;; State-changing functions
 175 ;;;
 176
 177 (defun vc-svn-register (file &optional rev comment)
 178   "Register FILE into the SVN version-control system.
 179 COMMENT can be used to provide an initial description of FILE.
 180
 181 `vc-register-switches' and `vc-svn-register-switches' are passed to
 182 the SVN command (in that order)."
 183   (apply 'vc-svn-command nil 0 file "add" (vc-switches 'SVN 'register)))
 184
 185 (defun vc-svn-responsible-p (file)
 186   "Return non-nil if SVN thinks it is responsible for FILE."
 187   (file-directory-p (expand-file-name ".svn"
 188                                       (if (file-directory-p file)
 189                                           file
 190                                         (file-name-directory file)))))
 191
 192 (defalias 'vc-svn-could-register 'vc-svn-responsible-p
 193   "Return non-nil if FILE could be registered in SVN.
 194 This is only possible if SVN is responsible for FILE's directory.")
 195
 196 (defun vc-svn-checkin (file rev comment)
 197   "SVN-specific version of `vc-backend-checkin'."
 198   (let ((status (apply
 199                  'vc-svn-command nil 1 file "ci"
 200                  (nconc (list "-m" comment) (vc-switches 'SVN 'checkin)))))
 201     (set-buffer "*vc*")
 202     (goto-char (point-min))
 203     (unless (equal status 0)
 204       ;; Check checkin problem.
 205       (cond
 206        ((search-forward "Transaction is out of date" nil t)
 207         (vc-file-setprop file 'vc-state 'needs-merge)
 208         (error (substitute-command-keys
 209                 (concat "Up-to-date check failed: "
 210                         "type \\[vc-next-action] to merge in changes"))))
 211        (t
 212         (pop-to-buffer (current-buffer))
 213         (goto-char (point-min))
 214         (shrink-window-if-larger-than-buffer)
 215         (error "Check-in failed"))))
 216     ;; Update file properties
 217     ;; (vc-file-setprop
 218     ;;  file 'vc-workfile-version
 219     ;;  (vc-parse-buffer "^\\(new\\|initial\\) revision: \\([0-9.]+\\)" 2))
 220     ))
 221
 222 (defun vc-svn-find-version (file rev buffer)
 223   (apply 'vc-svn-command
 224          buffer 0 file
 225          "cat"
 226          (and rev (not (string= rev ""))
 227               (concat "-r" rev))
 228          (vc-switches 'SVN 'checkout)))
 229
 230 (defun vc-svn-checkout (file &optional editable rev)
 231   (message "Checking out %s..." file)
 232   (with-current-buffer (or (get-file-buffer file) (current-buffer))
 233     (vc-call update file editable rev (vc-switches 'SVN 'checkout)))
 234   (vc-mode-line file)
 235   (message "Checking out %s...done" file))
 236
 237 (defun vc-svn-update (file editable rev switches)
 238   (if (and (file-exists-p file) (not rev))
 239       ;; If no revision was specified, just make the file writable
 240       ;; if necessary (using `svn-edit' if requested).
 241       (and editable (not (eq (vc-svn-checkout-model file) 'implicit))
 242            (if vc-svn-use-edit
 243                (vc-svn-command nil 0 file "edit")
 244              (set-file-modes file (logior (file-modes file) 128))
 245              (if (equal file buffer-file-name) (toggle-read-only -1))))
 246     ;; Check out a particular version (or recreate the file).
 247     (vc-file-setprop file 'vc-workfile-version nil)
 248     (apply 'vc-svn-command nil 0 file
 249            "update"
 250            ;; default for verbose checkout: clear the sticky tag so
 251            ;; that the actual update will get the head of the trunk
 252            (cond
 253             ((null rev) "-rBASE")
 254             ((or (eq rev t) (equal rev "")) nil)
 255             (t (concat "-r" rev)))
 256            switches)))
 257
 258 (defun vc-svn-delete-file (file)
 259   (vc-svn-command nil 0 file "remove"))
 260
 261 (defun vc-svn-rename-file (old new)
 262   (vc-svn-command nil 0 new "move" (file-relative-name old)))
 263
 264 (defun vc-svn-revert (file &optional contents-done)
 265   "Revert FILE to the version it was based on."
 266   (unless contents-done
 267     (vc-svn-command nil 0 file "revert"))
 268   (unless (eq (vc-checkout-model file) 'implicit)
 269     (if vc-svn-use-edit
 270         (vc-svn-command nil 0 file "unedit")
 271       ;; Make the file read-only by switching off all w-bits
 272       (set-file-modes file (logand (file-modes file) 3950)))))
 273
 274 (defun vc-svn-merge (file first-version &optional second-version)
 275   "Merge changes into current working copy of FILE.
 276 The changes are between FIRST-VERSION and SECOND-VERSION."
 277   (vc-svn-command nil 0 file
 278                  "merge"
 279                  "-r" (if second-version
 280                         (concat first-version ":" second-version)
 281                       first-version))
 282   (vc-file-setprop file 'vc-state 'edited)
 283   (with-current-buffer (get-buffer "*vc*")
 284     (goto-char (point-min))
 285     (if (looking-at "C  ")
 286         1                               ; signal conflict
 287       0)))                              ; signal success
 288
 289 (defun vc-svn-merge-news (file)
 290   "Merge in any new changes made to FILE."
 291   (message "Merging changes into %s..." file)
 292   ;; (vc-file-setprop file 'vc-workfile-version nil)
 293   (vc-file-setprop file 'vc-checkout-time 0)
 294   (vc-svn-command nil 0 file "update")
 295   ;; Analyze the merge result reported by SVN, and set
 296   ;; file properties accordingly.
 297   (with-current-buffer (get-buffer "*vc*")
 298     (goto-char (point-min))
 299     ;; get new workfile version
 300     (if (re-search-forward
 301          "^\\(Updated to\\|At\\) revision \\([0-9]+\\)" nil t)
 302         (vc-file-setprop file 'vc-workfile-version (match-string 2))
 303       (vc-file-setprop file 'vc-workfile-version nil))
 304     ;; get file status
 305     (goto-char (point-min))
 306     (prog1
 307         (if (looking-at "At revision")
 308             0 ;; there were no news; indicate success
 309           (if (re-search-forward
 310                (concat "^\\([CGDU]  \\)?"
 311                        (regexp-quote (file-name-nondirectory file)))
 312                nil t)
 313               (cond
 314                ;; Merge successful, we are in sync with repository now
 315                ((string= (match-string 1) "U  ")
 316                 (vc-file-setprop file 'vc-state 'up-to-date)
 317                 (vc-file-setprop file 'vc-checkout-time
 318                                  (nth 5 (file-attributes file)))
 319                 0);; indicate success to the caller
 320                ;; Merge successful, but our own changes are still in the file
 321                ((string= (match-string 1) "G  ")
 322                 (vc-file-setprop file 'vc-state 'edited)
 323                 0);; indicate success to the caller
 324                ;; Conflicts detected!
 325                (t
 326                 (vc-file-setprop file 'vc-state 'edited)
 327                 1);; signal the error to the caller
 328                )
 329             (pop-to-buffer "*vc*")
 330             (error "Couldn't analyze svn update result")))
 331       (message "Merging changes into %s...done" file))))
 332
 333
 334 ;;;
 335 ;;; History functions
 336 ;;;
 337
 338 (defun vc-svn-print-log (file &optional buffer)
 339   "Get change log associated with FILE."
 340   (save-current-buffer
 341     (vc-setup-buffer buffer)
 342     (let ((inhibit-read-only t))
 343       (goto-char (point-min))
 344       ;; Add a line to tell log-view-mode what file this is.
 345       (insert "Working file: " (file-relative-name file) "\n"))
 346     (vc-svn-command
 347      buffer
 348      (if (and (vc-stay-local-p file) (fboundp 'start-process)) 'async 0)
 349      file "log")))
 350
 351 (defun vc-svn-diff (file &optional oldvers newvers buffer)
 352   "Get a difference report using SVN between two versions of FILE."
 353   (unless buffer (setq buffer "*vc-diff*"))
 354   (if (string= (vc-workfile-version file) "0")
 355       ;; This file is added but not yet committed; there is no master file.
 356       (if (or oldvers newvers)
 357           (error "No revisions of %s exist" file)
 358         ;; We regard this as "changed".
 359         ;; Diff it against /dev/null.
 360         ;; Note: this is NOT a "svn diff".
 361         (apply 'vc-do-command buffer
 362                1 "diff" file
 363                (append (vc-switches nil 'diff) '("/dev/null")))
 364         ;; Even if it's empty, it's locally modified.
 365         1)
 366     (let* ((switches (vc-switches 'SVN 'diff))
 367            (async (and (vc-stay-local-p file)
 368                        (or oldvers newvers) ; Svn diffs those locally.
 369                        (fboundp 'start-process))))
 370       (apply 'vc-svn-command buffer
 371              (if async 'async 0)
 372              file "diff"
 373              (append
 374               (when switches
 375                 (list "-x" (mapconcat 'identity switches " ")))
 376               (when oldvers
 377                 (list "-r" (if newvers (concat oldvers ":" newvers)
 378                              oldvers)))))
 379       (if async 1                     ; async diff => pessimistic assumption
 380         ;; For some reason `svn diff' does not return a useful
 381         ;; status w.r.t whether the diff was empty or not.
 382         (buffer-size (get-buffer buffer))))))
 383
 384 (defun vc-svn-diff-tree (dir &optional rev1 rev2)
 385   "Diff all files at and below DIR."
 386   (vc-svn-diff (file-name-as-directory dir) rev1 rev2))
 387
 388 ;;;
 389 ;;; Snapshot system
 390 ;;;
 391
 392 (defun vc-svn-create-snapshot (dir name branchp)
 393   "Assign to DIR's current version a given NAME.
 394 If BRANCHP is non-nil, the name is created as a branch (and the current
 395 workspace is immediately moved to that new branch).
 396 NAME is assumed to be a URL."
 397   (vc-svn-command nil 0 dir "copy" name)
 398   (when branchp (vc-svn-retrieve-snapshot dir name nil)))
 399
 400 (defun vc-svn-retrieve-snapshot (dir name update)
 401   "Retrieve a snapshot at and below DIR.
 402 NAME is the name of the snapshot; if it is empty, do a `svn update'.
 403 If UPDATE is non-nil, then update (resynch) any affected buffers.
 404 NAME is assumed to be a URL."
 405   (vc-svn-command nil 0 dir "switch" name)
 406   ;; FIXME: parse the output and obey `update'.
 407   )
 408
 409 ;;;
 410 ;;; Miscellaneous
 411 ;;;
 412
 413 ;; Subversion makes backups for us, so don't bother.
 414 ;; (defalias 'vc-svn-make-version-backups-p 'vc-stay-local-p
 415 ;;   "Return non-nil if version backups should be made for FILE.")
 416
 417 (defun vc-svn-check-headers ()
 418   "Check if the current file has any headers in it."
 419   (save-excursion
 420     (goto-char (point-min))
 421     (re-search-forward "\\$[A-Za-z\300-\326\330-\366\370-\377]+\
 422 \\(: [\t -#%-\176\240-\377]*\\)?\\$" nil t)))
 423
 424
 425 ;;;
 426 ;;; Internal functions
 427 ;;;
 428
 429 (defun vc-svn-command (buffer okstatus file &rest flags)
 430   "A wrapper around `vc-do-command' for use in vc-svn.el.
 431 The difference to vc-do-command is that this function always invokes `svn',
 432 and that it passes `vc-svn-global-switches' to it before FLAGS."
 433   (apply 'vc-do-command buffer okstatus "svn" file
 434          (if (stringp vc-svn-global-switches)
 435              (cons vc-svn-global-switches flags)
 436            (append vc-svn-global-switches
 437                    flags))))
 438
 439 (defun vc-svn-repository-hostname (dirname)
 440   (with-temp-buffer
 441     (let ((coding-system-for-read
 442            (or file-name-coding-system
 443                default-file-name-coding-system)))
 444       (vc-insert-file (expand-file-name ".svn/entries" dirname)))
 445     (goto-char (point-min))
 446     (when (re-search-forward
 447            (concat "name=\"svn:this_dir\"[\n\t ]*"
 448                    "\\([-a-z]+=\"[^\"]*\"[\n\t ]*\\)*?"
 449                    "url=\"\\([^\"]+\\)\"") nil t)
 450       (match-string 2))))
 451
 452 (defun vc-svn-parse-status (localp)
 453   "Parse output of \"svn status\" command in the current buffer.
 454 Set file properties accordingly.  Unless FULL is t, parse only
 455 essential information."
 456   (let (file status)
 457     (goto-char (point-min))
 458     (while (re-search-forward
 459             "^[ ADMCI?!~][ MC][ L][ +][ S]..\\([ *]\\) +\\([-0-9]+\\) +\\([0-9?]+\\) +\\([^ ]+\\) +" nil t)
 460       (setq file (expand-file-name
 461                   (buffer-substring (point) (line-end-position))))
 462       (setq status (char-after (line-beginning-position)))
 463       (unless (eq status ??)
 464         (vc-file-setprop file 'vc-backend 'SVN)
 465         ;; Use the last-modified revision, so that searching in vc-print-log
 466         ;; output works.
 467         (vc-file-setprop file 'vc-workfile-version (match-string 3))
 468         (vc-file-setprop
 469          file 'vc-state
 470          (cond
 471           ((eq status ?\ )
 472            (if (eq (char-after (match-beginning 1)) ?*)
 473                'needs-patch
 474              (vc-file-setprop file 'vc-checkout-time
 475                               (nth 5 (file-attributes file)))
 476              'up-to-date))
 477           ((eq status ?A)
 478            ;; If the file was actually copied, (match-string 2) is "-".
 479            (vc-file-setprop file 'vc-workfile-version "0")
 480            (vc-file-setprop file 'vc-checkout-time 0)
 481            'edited)
 482           ((memq status '(?M ?C))
 483            (if (eq (char-after (match-beginning 1)) ?*)
 484                'needs-merge
 485              'edited))
 486           (t 'edited)))))))
 487
 488 (defun vc-svn-dir-state-heuristic (dir)
 489   "Find the SVN state of all files in DIR, using only local information."
 490   (vc-svn-dir-state dir 'local))
 491
 492 (defun vc-svn-valid-symbolic-tag-name-p (tag)
 493   "Return non-nil if TAG is a valid symbolic tag name."
 494   ;; According to the SVN manual, a valid symbolic tag must start with
 495   ;; an uppercase or lowercase letter and can contain uppercase and
 496   ;; lowercase letters, digits, `-', and `_'.
 497   (and (string-match "^[a-zA-Z]" tag)
 498        (not (string-match "[^a-z0-9A-Z-_]" tag))))
 499
 500 (defun vc-svn-valid-version-number-p (tag)
 501   "Return non-nil if TAG is a valid version number."
 502   (and (string-match "^[0-9]" tag)
 503        (not (string-match "[^0-9]" tag))))
 504
 505 (provide 'vc-svn)
 506
 507 ;;; arch-tag: 02f10c68-2b4d-453a-90fc-1eee6cfb268d
 508 ;;; vc-svn.el ends here