lisp/battery.el

   1 ;;; battery.el --- display battery status information
   2
   3 ;; Copyright (C) 1997, 1998, 2000, 2001, 2003 Free Software Foundation, Inc.
   4
   5 ;; Author: Ralph Schleicher <rs@nunatak.allgaeu.org>
   6 ;; Keywords: hardware
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; There is at present support for interpreting the new `/proc/apm'
  28 ;; file format of Linux version 1.3.58 or newer and for the `/proc/acpi/'
  29 ;; directory structure of Linux 2.4.20 and 2.6.
  30
  31 ;;; Code:
  32
  33 (require 'timer)
  34
  35 \f
  36
  37 (defgroup battery nil
  38   "Display battery status information."
  39   :prefix "battery-"
  40   :group 'hardware)
  41
  42 (defcustom battery-status-function
  43   (cond ((and (eq system-type 'gnu/linux)
  44               (file-readable-p "/proc/apm"))
  45          'battery-linux-proc-apm)
  46         ((and (eq system-type 'gnu/linux)
  47               (file-directory-p "/proc/acpi/battery"))
  48          'battery-linux-proc-acpi))
  49   "*Function for getting battery status information.
  50 The function has to return an alist of conversion definitions.
  51 Its cons cells are of the form
  52
  53     (CONVERSION . REPLACEMENT-TEXT)
  54
  55 CONVERSION is the character code of a \"conversion specification\"
  56 introduced by a `%' character in a control string."
  57   :type '(choice (const nil) function)
  58   :group 'battery)
  59
  60 (defcustom battery-echo-area-format
  61   (cond ((eq battery-status-function 'battery-linux-proc-apm)
  62          "Power %L, battery %B (%p%% load, remaining time %t)")
  63         ((eq battery-status-function 'battery-linux-proc-acpi)
  64          "Power %L, battery %B at %r (%p%% load, remaining time %t)"))
  65   "*Control string formatting the string to display in the echo area.
  66 Ordinary characters in the control string are printed as-is, while
  67 conversion specifications introduced by a `%' character in the control
  68 string are substituted as defined by the current value of the variable
  69 `battery-status-function'."
  70   :type '(choice string (const nil))
  71   :group 'battery)
  72
  73 (defvar battery-mode-line-string nil
  74   "String to display in the mode line.")
  75
  76 (defcustom battery-mode-line-format
  77   (cond ((eq battery-status-function 'battery-linux-proc-apm)
  78          " [%b%p%%]")
  79         ((eq battery-status-function 'battery-linux-proc-acpi)
  80          " [%b%p%%,%d°C]"))
  81   "*Control string formatting the string to display in the mode line.
  82 Ordinary characters in the control string are printed as-is, while
  83 conversion specifications introduced by a `%' character in the control
  84 string are substituted as defined by the current value of the variable
  85 `battery-status-function'."
  86   :type '(choice string (const nil))
  87   :group 'battery)
  88
  89 (defcustom battery-update-interval 60
  90   "*Seconds after which the battery status will be updated."
  91   :type 'integer
  92   :group 'battery)
  93
  94 (defvar battery-update-timer nil
  95   "Interval timer object.")
  96
  97 ;;;###autoload
  98 (defun battery ()
  99   "Display battery status information in the echo area.
 100 The text being displayed in the echo area is controlled by the variables
 101 `battery-echo-area-format' and `battery-status-function'."
 102   (interactive)
 103   (message "%s" (if (and battery-echo-area-format battery-status-function)
 104                     (battery-format battery-echo-area-format
 105                                     (funcall battery-status-function))
 106                   "Battery status not available")))
 107
 108 ;;;###autoload
 109 (defun display-battery ()
 110   "Display battery status information in the mode line.
 111 The text being displayed in the mode line is controlled by the variables
 112 `battery-mode-line-format' and `battery-status-function'.
 113 The mode line will be updated automatically every `battery-update-interval'
 114 seconds."
 115   (interactive)
 116   (setq battery-mode-line-string "")
 117   (or global-mode-string (setq global-mode-string '("")))
 118   (add-to-list 'global-mode-string 'battery-mode-line-string t)
 119   (and battery-update-timer (cancel-timer battery-update-timer))
 120   (setq battery-update-timer (run-at-time nil battery-update-interval
 121                                           'battery-update-handler))
 122   (battery-update))
 123
 124 (defun battery-update-handler ()
 125   (battery-update)
 126   (sit-for 0))
 127
 128 (defun battery-update ()
 129   "Update battery status information in the mode line."
 130   (setq battery-mode-line-string (propertize (if (and battery-mode-line-format
 131                                                       battery-status-function)
 132                                                  (battery-format
 133                                                   battery-mode-line-format
 134                                                   (funcall battery-status-function))
 135                                                "")
 136                                              'help-echo "Battery status information"))
 137   (force-mode-line-update))
 138
 139 \f
 140 ;;; `/proc/apm' interface for Linux.
 141
 142 (defconst battery-linux-proc-apm-regexp
 143   (concat "^\\([^ ]+\\)"                ; Driver version.
 144           " \\([^ ]+\\)"                ; APM BIOS version.
 145           " 0x\\([0-9a-f]+\\)"          ; APM BIOS flags.
 146           " 0x\\([0-9a-f]+\\)"          ; AC line status.
 147           " 0x\\([0-9a-f]+\\)"          ; Battery status.
 148           " 0x\\([0-9a-f]+\\)"          ; Battery flags.
 149           " \\(-?[0-9]+\\)%"            ; Load percentage.
 150           " \\(-?[0-9]+\\)"             ; Remaining time.
 151           " \\(.*\\)"                   ; Time unit.
 152           "$")
 153   "Regular expression matching contents of `/proc/apm'.")
 154
 155 (defun battery-linux-proc-apm ()
 156   "Get APM status information from Linux kernel.
 157 This function works only with the new `/proc/apm' format introduced
 158 in Linux version 1.3.58.
 159
 160 The following %-sequences are provided:
 161 %v Linux driver version
 162 %V APM BIOS version
 163 %I APM BIOS status (verbose)
 164 %L AC line status (verbose)
 165 %B Battery status (verbose)
 166 %b Battery status, empty means high, `-' means low,
 167    `!' means critical, and `+' means charging
 168 %p battery load percentage
 169 %s Remaining time in seconds
 170 %m Remaining time in minutes
 171 %h Remaining time in hours
 172 %t Remaining time in the form `h:min'"
 173   (let (driver-version bios-version bios-interface line-status
 174         battery-status battery-status-symbol load-percentage
 175         seconds minutes hours remaining-time buffer tem)
 176     (unwind-protect
 177         (save-excursion
 178           (setq buffer (get-buffer-create " *battery*"))
 179           (set-buffer buffer)
 180           (erase-buffer)
 181           (insert-file-contents "/proc/apm")
 182           (re-search-forward battery-linux-proc-apm-regexp)
 183           (setq driver-version (match-string 1))
 184           (setq bios-version (match-string 2))
 185           (setq tem (battery-hex-to-int-2 (match-string 3)))
 186           (if (not (logand tem 2))
 187               (setq bios-interface "not supported")
 188             (setq bios-interface "enabled")
 189             (cond ((logand tem 16) (setq bios-interface "disabled"))
 190                   ((logand tem 32) (setq bios-interface "disengaged")))
 191             (setq tem (battery-hex-to-int-2 (match-string 4)))
 192             (cond ((= tem 0) (setq line-status "off-line"))
 193                   ((= tem 1) (setq line-status "on-line"))
 194                   ((= tem 2) (setq line-status "on backup")))
 195             (setq tem (battery-hex-to-int-2 (match-string 6)))
 196             (if (= tem 255)
 197                 (setq battery-status "N/A")
 198               (setq tem (battery-hex-to-int-2 (match-string 5)))
 199               (cond ((= tem 0) (setq battery-status "high"
 200                                      battery-status-symbol ""))
 201                     ((= tem 1) (setq battery-status "low"
 202                                      battery-status-symbol "-"))
 203                     ((= tem 2) (setq battery-status "critical"
 204                                      battery-status-symbol "!"))
 205                     ((= tem 3) (setq battery-status "charging"
 206                                      battery-status-symbol "+")))
 207               (setq load-percentage (match-string 7))
 208               (setq seconds (string-to-number (match-string 8)))
 209               (and (string-equal (match-string 9) "min")
 210                    (setq seconds (* 60 seconds)))
 211               (setq minutes (/ seconds 60)
 212                     hours (/ seconds 3600))
 213               (setq remaining-time
 214                     (format "%d:%02d" hours (- minutes (* 60 hours))))))))
 215     (list (cons ?v (or driver-version "N/A"))
 216           (cons ?V (or bios-version "N/A"))
 217           (cons ?I (or bios-interface "N/A"))
 218           (cons ?L (or line-status "N/A"))
 219           (cons ?B (or battery-status "N/A"))
 220           (cons ?b (or battery-status-symbol ""))
 221           (cons ?p (or load-percentage "N/A"))
 222           (cons ?s (or (and seconds (number-to-string seconds)) "N/A"))
 223           (cons ?m (or (and minutes (number-to-string minutes)) "N/A"))
 224           (cons ?h (or (and hours (number-to-string hours)) "N/A"))
 225           (cons ?t (or remaining-time "N/A")))))
 226
 227 \f
 228 ;;; `/proc/acpi/' interface for Linux.
 229
 230 (defun battery-linux-proc-acpi ()
 231   "Get ACPI status information from Linux kernel.
 232 This function works only with the new `/proc/acpi/' format introduced
 233 in Linux version 2.4.20 and 2.6.0.
 234
 235 The following %-sequences are provided:
 236 %c Current capacity (mAh)
 237 %B Battery status (verbose)
 238 %b Battery status, empty means high, `-' means low,
 239    `!' means critical, and `+' means charging
 240 %d Temperature (in degrees Celsius)
 241 %L AC line status (verbose)
 242 %p battery load percentage
 243 %m Remaining time in minutes
 244 %h Remaining time in hours
 245 %t Remaining time in the form `h:min'"
 246   (let (capacity design-capacity rate rate-type charging-state warn low
 247                  minutes hours)
 248     (when (file-directory-p "/proc/acpi/battery/")
 249       ;; ACPI provides information about each battery present in the system in
 250       ;; a separate subdirectory.  We are going to merge the available
 251       ;; information together since displaying for a variable amount of
 252       ;; batteries seems overkill for format-strings.
 253       (mapc
 254        (lambda (dir)
 255          (with-temp-buffer
 256            (insert-file-contents (expand-file-name "state" dir))
 257            (when (re-search-forward "present: +yes$" nil t)
 258              (and (re-search-forward "charging state: +\\(.*\\)$" nil t)
 259                   (or (null charging-state) (string= charging-state
 260                                                      "unknown"))
 261                   ;; On most multi-battery systems, most of the time only one
 262                   ;; battery is "charging"/"discharging", the others are
 263                   ;; "unknown".
 264                   (setq charging-state (match-string 1)))
 265              (when (re-search-forward "present rate: +\\([0-9]+\\) \\(m[AW]\\)$"
 266                                       nil t)
 267                (setq rate (+ (or rate 0) (string-to-int (match-string 1)))
 268                      rate-type (or (and rate-type
 269                                         (if (string= rate-type (match-string 2))
 270                                             rate-type
 271                                           (error
 272                                            "Inconsistent rate types (%s vs. %s)"
 273                                            rate-type (match-string 2))))
 274                                    (match-string 2))))
 275              (when (re-search-forward "remaining capacity: +\\([0-9]+\\) m[AW]h$"
 276                                       nil t)
 277                (setq capacity
 278                      (+ (or capacity 0) (string-to-int (match-string 1))))))
 279            (goto-char (point-max))
 280            (insert-file-contents (expand-file-name "info" dir))
 281            (when (re-search-forward "present: +yes$" nil t)
 282              (when (re-search-forward "design capacity: +\\([0-9]+\\) m[AW]h$"
 283                                       nil t)
 284                (setq design-capacity (+ (or design-capacity 0)
 285                                         (string-to-int (match-string 1)))))
 286              (when (re-search-forward "design capacity warning: +\\([0-9]+\\) m[AW]h$"
 287                                       nil t)
 288                (setq warn (+ (or warn 0) (string-to-int (match-string 1)))))
 289              (when (re-search-forward "design capacity low: +\\([0-9]+\\) m[AW]h$"
 290                                       nil t)
 291                (setq low (+ (or low 0)
 292                             (string-to-int (match-string 1))))))))
 293        (directory-files "/proc/acpi/battery/" t "BAT")))
 294     (and capacity rate
 295          (setq minutes (if (zerop rate) 0
 296                          (floor (* (/ (float (if (string= charging-state
 297                                                           "charging")
 298                                                  (- design-capacity capacity)
 299                                                capacity)) rate) 60)))
 300                hours (/ minutes 60)))
 301     (list (cons ?c (or (and capacity (number-to-string capacity)) "N/A"))
 302           (cons ?L (or (when (file-exists-p "/proc/acpi/ac_adapter/AC/state")
 303                          (with-temp-buffer
 304                            (insert-file-contents
 305                             "/proc/acpi/ac_adapter/AC/state")
 306                            (when (re-search-forward "state: +\\(.*\\)$" nil t)
 307                              (match-string 1))))
 308                        "N/A"))
 309           (cons ?d (or (when (file-exists-p
 310                               "/proc/acpi/thermal_zone/THRM/temperature")
 311                          (with-temp-buffer
 312                            (insert-file-contents
 313                             "/proc/acpi/thermal_zone/THRM/temperature")
 314                            (when (re-search-forward
 315                                   "temperature: +\\([0-9]+\\) C$" nil t)
 316                              (match-string 1))))
 317                        (when (file-exists-p
 318                               "/proc/acpi/thermal_zone/THM/temperature")
 319                          (with-temp-buffer
 320                            (insert-file-contents
 321                             "/proc/acpi/thermal_zone/THM/temperature")
 322                            (when (re-search-forward
 323                                   "temperature: +\\([0-9]+\\) C$" nil t)
 324                              (match-string 1))))
 325                        "N/A"))
 326           (cons ?r (or (and rate (concat (number-to-string rate) " "
 327                                          rate-type)) "N/A"))
 328           (cons ?B (or charging-state "N/A"))
 329           (cons ?b (or (and (string= charging-state "charging") "+")
 330                        (and low (< capacity low) "!")
 331                        (and warn (< capacity warn) "-")
 332                        ""))
 333           (cons ?h (or (and hours (number-to-string hours)) "N/A"))
 334           (cons ?m (or (and minutes (number-to-string minutes)) "N/A"))
 335           (cons ?t (or (and minutes
 336                             (format "%d:%02d" hours (- minutes (* 60 hours))))
 337                        "N/A"))
 338           (cons ?p (or (and design-capacity capacity
 339                             (number-to-string
 340                              (floor (/ capacity
 341                                        (/ (float design-capacity) 100)))))
 342                        "N/A")))))
 343
 344 \f
 345 ;;; Private functions.
 346
 347 (defun battery-format (format alist)
 348   "Substitute %-sequences in FORMAT."
 349   (let ((index 0)
 350         (length (length format))
 351         (result "")
 352         char flag elem)
 353     (while (< index length)
 354       (setq char (aref format index))
 355       (if (not flag)
 356           (if (char-equal char ?%)
 357               (setq flag t)
 358             (setq result (concat result (char-to-string char))))
 359         (cond ((char-equal char ?%)
 360                (setq result (concat result "%")))
 361               ((setq elem (assoc char alist))
 362                (setq result (concat result (cdr elem)))))
 363         (setq flag nil))
 364       (setq index (1+ index)))
 365     (or (null flag)
 366         (setq result (concat result "%")))
 367     result))
 368
 369 (defconst battery-hex-map '((?0 .  0) (?1 .  1) (?2 .  2) (?3 .  3)
 370                             (?4 .  4) (?5 .  5) (?6 .  6) (?7 .  7)
 371                             (?8 .  8) (?9 .  9) (?a . 10) (?b . 11)
 372                             (?c . 12) (?d . 13) (?e . 14) (?f . 15)))
 373
 374 (defun battery-hex-to-int (string)
 375   "Convert a hexadecimal number (a string) into a number."
 376   (save-match-data
 377     (and (string-match "^[ \t]+" string)
 378          (setq string (substring string (match-end 0))))
 379     (and (string-match "^0[xX]" string)
 380          (setq string (substring string (match-end 0)))))
 381   (battery-hex-to-int-2 string))
 382
 383 (defun battery-hex-to-int-2 (string)
 384   (let ((index 0)
 385         (length (length string))
 386         (value 0)
 387         (elem nil))
 388     (while (and (< index length)
 389                 (setq elem (assoc (downcase (aref string index))
 390                                   battery-hex-map)))
 391       (setq value (+ (* 16 value) (cdr elem))
 392             index (1+ index)))
 393     value))
 394
 395 \f
 396 (provide 'battery)
 397
 398 ;;; arch-tag: 65916f50-4754-4b6b-ac21-0b510f545a37
 399 ;;; battery.el ends here