| blob | 88db62fc5b0708c197f7547025c4daaaf6285dde |
1 dnl Autoconf script for GNU Emacs
2 dnl To rebuild the `configure' script from this, execute the command
3 dnl autoconf
4 dnl in the directory containing this script.
5 dnl
6 dnl Copyright (C) 1994, 1995, 1996 Free Software Foundation, Inc.
7 dnl
8 dnl This file is part of GNU Emacs.
9 dnl
10 dnl GNU Emacs is free software; you can redistribute it and/or modify
11 dnl it under the terms of the GNU General Public License as published by
12 dnl the Free Software Foundation; either version 2, or (at your option)
13 dnl any later version.
14 dnl
15 dnl GNU Emacs is distributed in the hope that it will be useful,
16 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
17 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18 dnl GNU General Public License for more details.
19 dnl
20 dnl You should have received a copy of the GNU General Public License
21 dnl along with GNU Emacs; see the file COPYING. If not, write to the
22 dnl Free Software Foundation, Inc., 59 Temple Place - Suite 330,
23 dnl Boston, MA 02111-1307, USA.
25 AC_PREREQ(2.8)dnl
26 AC_INIT(src/lisp.h)
27 AC_CONFIG_HEADER(src/config.h:src/config.in)
29 lispdir='${datadir}/emacs/${version}/lisp'
30 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
31 '${datadir}/emacs/site-lisp:${datadir}/emacs/${version}/leim'
32 lisppath='${locallisppath}:${lispdir}'
33 etcdir='${datadir}/emacs/${version}/etc'
34 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
35 docdir='${datadir}/emacs/${version}/etc'
37 AC_ARG_WITH(gcc,
38 [ --with-gcc use GCC to compile Emacs])
39 AC_ARG_WITH(pop,
40 [ --with-pop support POP for mail retrieval],
41 [AC_DEFINE(MAIL_USE_POP)])
42 AC_ARG_WITH(kerberos,
43 [ --with-kerberos support Kerberos-authenticated POP],
44 [AC_DEFINE(KERBEROS)])
45 AC_ARG_WITH(kerberos5,
46 [ --with-kerberos5 support Kerberos version 5 authenticated POP],
47 [if test "${with_kerberos5+set}" = set; then
48 if test "${with_kerberos+set}" != set; then
49 with_kerberos=yes
50 AC_DEFINE(KERBEROS)
51 fi
52 fi
53 AC_DEFINE(KERBEROS5)])
54 AC_ARG_WITH(hesiod,
55 [ --with-hesiod support Hesiod to get the POP server host],
56 [AC_DEFINE(HESIOD)])
57 dnl This should be the last --with option, because --with-x is
58 dnl added later on when we find the path of X, and it's best to
59 dnl keep them together visually.
60 AC_ARG_WITH(x-toolkit,
61 [ --with-x-toolkit=KIT use an X toolkit (KIT = yes/lucid/athena/motif/no)],
62 [ case "${withval}" in
63 y | ye | yes ) val=athena ;;
64 n | no ) val=no ;;
65 l | lu | luc | luci | lucid ) val=lucid ;;
66 a | at | ath | athe | athen | athena ) val=athena ;;
67 m | mo | mot | moti | motif ) val=motif ;;
68 dnl These don't currently work.
69 dnl o | op | ope | open | open- | open-l | open-lo \
70 dnl | open-loo | open-look ) val=open-look ;;
71 * )
72 dnl AC_MSG_ERROR([the \`--with-x-toolkit' option is supposed to have a value
73 dnl which is \`yes', \`no', \`lucid', \`athena', \`motif' or \`open-look'.])
74 AC_MSG_ERROR([\`--with-x-toolkit=$withval' is invalid\;
75 this option's value should be \`yes', \`no', \`lucid', \`athena', or \`motif'.
76 Currently, \`yes', \`athena' and \`lucid' are synonyms.])
77 ;;
78 esac
79 with_x_toolkit=$val
80 ])
82 #### Make srcdir absolute, if it isn't already. It's important to
83 #### avoid running the path through pwd unnecessary, since pwd can
84 #### give you automounter prefixes, which can go away. We do all this
85 #### so Emacs can find its files when run uninstalled.
86 case "${srcdir}" in
87 /* ) ;;
88 . )
89 ## We may be able to use the $PWD environment variable to make this
90 ## absolute. But sometimes PWD is inaccurate.
91 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
92 unset CDPATH
93 if test "${PWD}" != "" && test "`(cd ${PWD} ; sh -c pwd)`" = "`pwd`" ;
94 then
95 srcdir="$PWD"
96 else
97 srcdir="`(cd ${srcdir}; pwd)`"
98 fi
99 ;;
100 * ) srcdir="`(cd ${srcdir}; pwd)`" ;;
101 esac
103 #### Check if the source directory already has a configured system in it.
104 if test `pwd` != `(cd ${srcdir} && pwd)` \
105 && test -f "${srcdir}/src/config.h" ; then
106 AC_MSG_WARN([The directory tree \`${srcdir}' is being used
107 as a build directory right now; it has been configured in its own
108 right. To configure in another directory as well, you MUST
109 use GNU make. If you do not have GNU make, then you must
110 now do \`make distclean' in ${srcdir},
111 and then run $0 again.])
113 changequote(, )dnl
114 extrasub='/^VPATH[ ]*=/c\
115 changequote([, ])dnl
116 vpath %.c $(srcdir)\
117 vpath %.h $(srcdir)\
118 vpath %.y $(srcdir)\
119 vpath %.l $(srcdir)\
120 vpath %.s $(srcdir)\
121 vpath %.in $(srcdir)\
122 vpath %.texi $(srcdir)'
123 fi
125 #### Given the configuration name, set machfile and opsysfile to the
126 #### names of the m/*.h and s/*.h files we should use.
128 ### Canonicalize the configuration name.
130 AC_CANONICAL_HOST
131 canonical=$host
132 configuration=$host_alias
134 changequote(, )dnl
136 ### If you add support for a new configuration, add code to this
137 ### switch statement to recognize your configuration name and select
138 ### the appropriate operating system and machine description files.
140 ### You would hope that you could choose an m/*.h file pretty much
141 ### based on the machine portion of the configuration name, and an s-
142 ### file based on the operating system portion. However, it turns out
143 ### that each m/*.h file is pretty manufacturer-specific - for
144 ### example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
145 ### all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
146 ### machines. So we basically have to have a special case for each
147 ### configuration name.
148 ###
149 ### As far as handling version numbers on operating systems is
150 ### concerned, make sure things will fail in a fixable way. If
151 ### /etc/MACHINES doesn't say anything about version numbers, be
152 ### prepared to handle anything reasonably. If version numbers
153 ### matter, be sure /etc/MACHINES says something about it.
154 ###
155 ### Eric Raymond says we should accept strings like "sysvr4" to mean
156 ### "System V Release 4"; he writes, "The old convention encouraged
157 ### confusion between `system' and `release' levels'."
159 machine='' opsys='' unported=no
160 case "${canonical}" in
162 ## NetBSD ports
163 *-*-netbsd* )
164 opsys=netbsd
165 case "${canonical}" in
166 alpha*-*-netbsd*) machine=alpha ;;
167 i[3456]86-*-netbsd*) machine=intel386 ;;
168 m68k-*-netbsd*)
169 # This is somewhat bogus.
170 machine=hp9000s300 ;;
171 powerpc-apple-netbsd*) machine=macppc ;;
172 mips-*-netbsd*) machine=pmax ;;
173 ns32k-*-netbsd*) machine=ns32000 ;;
174 sparc-*-netbsd*) machine=sparc ;;
175 vax-*-netbsd*) machine=vax ;;
176 esac
177 ;;
179 ## OpenBSD ports
180 *-*-openbsd* )
181 opsys=openbsd
182 case "${canonical}" in
183 alpha*-*-openbsd*) machine=alpha ;;
184 i386-*-openbsd*) machine=intel386 ;;
185 m68k-*-openbsd*) machine=hp9000s300 ;;
186 mipsel-*-openbsd*) machine=pmax ;;
187 ns32k-*-openbsd*) machine=ns32000 ;;
188 sparc-*-openbsd*) machine=sparc ;;
189 vax-*-openbsd*) machine=vax ;;
190 esac
191 ;;
193 ## Acorn RISCiX:
194 arm-acorn-riscix1.1* )
195 machine=acorn opsys=riscix1-1
196 ;;
197 arm-acorn-riscix1.2* | arm-acorn-riscix )
198 ## This name is riscix12 instead of riscix1.2
199 ## to avoid a file name conflict on MSDOS.
200 machine=acorn opsys=riscix12
201 ;;
203 ## BSDI ports
204 *-*-bsdi* )
205 opsys=bsdi
206 case "${canonical}" in
207 i[345]86-*-bsdi*) machine=intel386 ;;
208 sparc-*-bsdi*) machine=sparc ;;
209 powerpc-*-bsdi*) machine=powerpc ;;
210 esac
211 case "${canonical}" in
212 *-*-bsd386* | *-*-bsdi1* ) opsys=bsd386 ;;
213 *-*-bsdi2.0* ) opsys=bsdos2 ;;
214 *-*-bsdi2* ) opsys=bsdos2-1 ;;
215 *-*-bsdi3* ) opsys=bsdos3 ;;
216 *-*-bsdi4* ) opsys=bsdos4 ;;
217 esac
218 ;;
220 ## Alliant machines
221 ## Strictly speaking, we need the version of the alliant operating
222 ## system to choose the right machine file, but currently the
223 ## configuration name doesn't tell us enough to choose the right
224 ## one; we need to give alliants their own operating system name to
225 ## do this right. When someone cares, they can help us.
226 fx80-alliant-* )
227 machine=alliant4 opsys=bsd4-2
228 ;;
229 i860-alliant-* )
230 machine=alliant-2800 opsys=bsd4-3
231 ;;
233 ## Alpha (DEC) machines.
234 alpha*-dec-osf* )
235 machine=alpha opsys=osf1
236 # This is needed to find X11R6.1 libraries for certain tests.
237 NON_GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
238 GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
239 ;;
241 alpha*-*-linux-gnu* )
242 machine=alpha opsys=gnu-linux
243 ;;
245 ## Altos 3068
246 m68*-altos-sysv* )
247 machine=altos opsys=usg5-2
248 ;;
250 ## Amdahl UTS
251 580-amdahl-sysv* )
252 machine=amdahl opsys=usg5-2-2
253 ;;
255 ## Apollo, Domain/OS
256 m68*-apollo-* )
257 machine=apollo opsys=bsd4-3
258 ;;
260 ## AT&T 3b2, 3b5, 3b15, 3b20
261 we32k-att-sysv* )
262 machine=att3b opsys=usg5-2-2
263 ;;
265 ## AT&T 3b1 - The Mighty Unix PC!
266 m68*-att-sysv* )
267 machine=7300 opsys=usg5-2-2
268 ;;
270 ## Bull dpx20
271 rs6000-bull-bosx* )
272 machine=ibmrs6000 opsys=aix3-2
273 ;;
275 ## Bull dpx2
276 m68*-bull-sysv3* )
277 machine=dpx2 opsys=usg5-3
278 ;;
280 ## Bull sps7
281 m68*-bull-sysv2* )
282 machine=sps7 opsys=usg5-2
283 ;;
285 ## CCI 5/32, 6/32 -- see "Tahoe".
287 ## Celerity
288 ## I don't know what configuration name to use for this; config.sub
289 ## doesn't seem to know anything about it. Hey, Celerity users, get
290 ## in touch with us!
291 celerity-celerity-bsd* )
292 machine=celerity opsys=bsd4-2
293 ;;
295 ## Clipper
296 ## What operating systems does this chip run that Emacs has been
297 ## tested on?
298 clipper-* )
299 machine=clipper
300 ## We'll use the catch-all code at the bottom to guess the
301 ## operating system.
302 ;;
304 ## Convex
305 *-convex-bsd* | *-convex-convexos* )
306 machine=convex opsys=bsd4-3
307 ## Prevents spurious white space in makefiles - d.m.cooke@larc.nasa.gov
308 NON_GNU_CPP="cc -E -P"
309 ;;
311 ## Cubix QBx/386
312 i[3456]86-cubix-sysv* )
313 machine=intel386 opsys=usg5-3
314 ;;
316 ## Cydra 5
317 cydra*-cydrome-sysv* )
318 machine=cydra5 opsys=usg5-3
319 ;;
321 ## Data General AViiON Machines
322 ## DG changed naming conventions with the release of 5.4.4.10, they
323 ## dropped the initial 5.4 but left the intervening R. Because of the
324 ## R this shouldn't conflict with older versions of the OS (which I
325 ## think were named like dgux4.*). In addition, DG new AViiONs series
326 ## uses either Motorola M88k or Intel Pentium CPUs.
327 m88k-dg-dguxR4.* | m88k-dg-dgux4* )
328 machine=aviion opsys=dgux4
329 ;;
330 m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* )
331 ## This name is dgux5-4-3 instead of dgux5-4r3
332 ## to avoid a file name conflict on MSDOS.
333 machine=aviion opsys=dgux5-4-3
334 ;;
335 m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* )
336 machine=aviion opsys=dgux5-4r2
337 ;;
338 m88k-dg-dgux* )
339 machine=aviion opsys=dgux
340 ;;
342 ## Data General AViiON Intel (x86) Machines
343 ## Exists from 5.4.3 (current i586-dg-dguxR4.11)
344 ## Ehud Karni, 1998-may-30, ehud@unix.simonwiesel.co.il
345 i[345]86-dg-dguxR4* )
346 machine=aviion-intel opsys=dgux4
347 ;;
349 ## DECstations
350 mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
351 machine=pmax opsys=bsd4-2
352 ;;
353 mips-dec-ultrix4.[12]* | mips-dec-bsd* )
354 machine=pmax opsys=bsd4-3
355 ;;
356 mips-dec-ultrix* )
357 machine=pmax opsys=ultrix4-3
358 ;;
359 mips-dec-osf* )
360 machine=pmax opsys=osf1
361 ;;
362 mips-dec-mach_bsd4.3* )
363 machine=pmax opsys=mach-bsd4-3
364 ;;
366 ## Motorola Delta machines
367 m68k-motorola-sysv* | m68000-motorola-sysv* )
368 machine=delta opsys=usg5-3
369 if test -z "`type gnucc | grep 'not found'`"
370 then
371 if test -s /etc/167config
372 then CC="gnucc -m68040"
373 else CC="gnucc -m68881"
374 fi
375 else
376 if test -z "`type gcc | grep 'not found'`"
377 then CC=gcc
378 else CC=cc
379 fi
380 fi
381 ;;
382 m88k-motorola-sysv4* )
383 # jbotte@bnr.ca says that UNIX_System_V <hostName> 4.0 R40V4.3 m88k mc88110
384 # needs POSIX_SIGNALS and therefore needs usg5-4-2.
385 # I hope there are not other 4.0 versions for this machine
386 # which really need usg5-4 instead.
387 machine=delta88k opsys=usg5-4-2
388 ;;
389 m88k-motorola-sysv* | m88k-motorola-m88kbcs* )
390 machine=delta88k opsys=usg5-3
391 ;;
393 ## Dual machines
394 m68*-dual-sysv* )
395 machine=dual opsys=usg5-2
396 ;;
397 m68*-dual-uniplus* )
398 machine=dual opsys=unipl5-2
399 ;;
401 ## Elxsi 6400
402 elxsi-elxsi-sysv* )
403 machine=elxsi opsys=usg5-2
404 ;;
406 ## Encore machines
407 ns16k-encore-bsd* )
408 machine=ns16000 opsys=umax
409 ;;
411 ## The GEC 93 - apparently, this port isn't really finished yet.
413 ## Gould Power Node and NP1
414 pn-gould-bsd4.2* )
415 machine=gould opsys=bsd4-2
416 ;;
417 pn-gould-bsd4.3* )
418 machine=gould opsys=bsd4-3
419 ;;
420 np1-gould-bsd* )
421 machine=gould-np1 opsys=bsd4-3
422 ;;
424 ## Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
425 ## as far as Emacs is concerned).
426 m88k-harris-cxux* )
427 # Build needs to be different on 7.0 and later releases
428 case "`uname -r`" in
429 [56].[0-9] ) machine=nh4000 opsys=cxux ;;
430 [7].[0-9] ) machine=nh4000 opsys=cxux7 ;;
431 esac
432 NON_GNU_CPP="/lib/cpp"
433 ;;
434 ## Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
435 m68k-harris-cxux* )
436 machine=nh3000 opsys=cxux
437 ;;
438 ## Harris power pc NightHawk running Power UNIX (Series 6000)
439 powerpc-harris-powerunix )
440 machine=nh6000 opsys=powerunix
441 NON_GNU_CPP="cc -Xo -E -P"
442 ;;
443 ## SR2001/SR2201 running HI-UX/MPP
444 hppa1.1-hitachi-hiuxmpp* )
445 machine=sr2k opsys=hiuxmpp
446 ;;
447 ## Honeywell XPS100
448 xps*-honeywell-sysv* )
449 machine=xps100 opsys=usg5-2
450 ;;
452 ## HP 9000 series 200 or 300
453 m68*-hp-bsd* )
454 machine=hp9000s300 opsys=bsd4-3
455 ;;
456 ## HP/UX 7, 8, 9, and 10 are supported on these machines.
457 m68*-hp-hpux* )
458 case "`uname -r`" in
459 ## Someone's system reports A.B8.05 for this.
460 ## I wonder what other possibilities there are.
461 *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
462 *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
463 *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
464 *.1[0-9].* ) machine=hp9000s300 opsys=hpux9shr ;;
465 *) machine=hp9000s300 opsys=hpux ;;
466 esac
467 ;;
469 ## HP 9000 series 700 and 800, running HP/UX
470 hppa*-hp-hpux7* )
471 machine=hp800 opsys=hpux
472 ;;
473 hppa*-hp-hpux8* )
474 machine=hp800 opsys=hpux8
475 ;;
476 hppa*-hp-hpux9shr* )
477 machine=hp800 opsys=hpux9shr
478 ;;
479 hppa*-hp-hpux9* )
480 machine=hp800 opsys=hpux9
481 ;;
482 hppa*-hp-hpux1[0-9]* )
483 machine=hp800 opsys=hpux10
484 ;;
486 ## HP 9000 series 700 and 800, running HP/UX
487 hppa*-hp-hpux* )
488 ## Cross-compilation? Nah!
489 case "`uname -r`" in
490 ## Someone's system reports A.B8.05 for this.
491 ## I wonder what other possibilities there are.
492 *.B8.* ) machine=hp800 opsys=hpux8 ;;
493 *.08.* ) machine=hp800 opsys=hpux8 ;;
494 *.09.* ) machine=hp800 opsys=hpux9 ;;
495 *) machine=hp800 opsys=hpux10 ;;
496 esac
497 ;;
498 hppa*-*-nextstep* )
499 machine=hp800 opsys=nextstep
500 ;;
502 ## Orion machines
503 orion-orion-bsd* )
504 machine=orion opsys=bsd4-2
505 ;;
506 clipper-orion-bsd* )
507 machine=orion105 opsys=bsd4-2
508 ;;
510 ## IBM machines
511 i[3456]86-ibm-aix1.1* )
512 machine=ibmps2-aix opsys=usg5-2-2
513 ;;
514 i[3456]86-ibm-aix1.[23]* | i[3456]86-ibm-aix* )
515 machine=ibmps2-aix opsys=usg5-3
516 ;;
517 i370-ibm-aix*)
518 machine=ibm370aix opsys=usg5-3
519 ;;
520 rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1* )
521 machine=ibmrs6000 opsys=aix3-1
522 ;;
523 rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
524 machine=ibmrs6000 opsys=aix3-2-5
525 ;;
526 rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1* )
527 machine=ibmrs6000 opsys=aix4-1
528 ;;
529 rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2* )
530 machine=ibmrs6000 opsys=aix4-2
531 ;;
532 rs6000-ibm-aix4.0* | powerpc-ibm-aix4.0* )
533 machine=ibmrs6000 opsys=aix4
534 ;;
535 rs6000-ibm-aix4* | powerpc-ibm-aix4* )
536 machine=ibmrs6000 opsys=aix4-1
537 ;;
538 rs6000-ibm-aix* | powerpc-ibm-aix* )
539 machine=ibmrs6000 opsys=aix3-2
540 ;;
541 romp-ibm-bsd4.3* )
542 machine=ibmrt opsys=bsd4-3
543 ;;
544 romp-ibm-bsd4.2* )
545 machine=ibmrt opsys=bsd4-2
546 ;;
547 romp-ibm-aos4.3* )
548 machine=ibmrt opsys=bsd4-3
549 ;;
550 romp-ibm-aos4.2* )
551 machine=ibmrt opsys=bsd4-2
552 ;;
553 romp-ibm-aos* )
554 machine=ibmrt opsys=bsd4-3
555 ;;
556 romp-ibm-bsd* )
557 machine=ibmrt opsys=bsd4-3
558 ;;
559 romp-ibm-aix* )
560 machine=ibmrt-aix opsys=usg5-2-2
561 ;;
563 ## Integrated Solutions `Optimum V'
564 m68*-isi-bsd4.2* )
565 machine=isi-ov opsys=bsd4-2
566 ;;
567 m68*-isi-bsd4.3* )
568 machine=isi-ov opsys=bsd4-3
569 ;;
571 ## Intel 386 machines where we do care about the manufacturer
572 i[3456]86-intsys-sysv* )
573 machine=is386 opsys=usg5-2-2
574 ;;
576 ## Prime EXL
577 i[3456]86-prime-sysv* )
578 machine=i386 opsys=usg5-3
579 ;;
581 ## Sequent Symmetry running Dynix
582 i[3456]86-sequent-bsd* )
583 machine=symmetry opsys=bsd4-3
584 ;;
586 ## Sequent Symmetry running ptx 4, which is a modified SVR4.
587 i[3456]86-sequent-ptx4* | i[3456]86-sequent-sysv4* )
588 machine=sequent-ptx opsys=ptx4
589 NON_GNU_CPP=/lib/cpp
590 ;;
592 ## Sequent Symmetry running DYNIX/ptx
593 ## Use the old cpp rather than the newer ANSI one.
594 i[3456]86-sequent-ptx* )
595 machine=sequent-ptx opsys=ptx
596 NON_GNU_CPP="/lib/cpp"
597 ;;
599 ## ncr machine running svr4.3.
600 i[3456]86-ncr-sysv4.3 )
601 machine=ncr386 opsys=usg5-4-3
602 ;;
604 ## Unspecified sysv on an ncr machine defaults to svr4.2.
605 ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
606 i[3456]86-ncr-sysv* )
607 machine=ncr386 opsys=usg5-4-2
608 ;;
610 ## Intel Paragon OSF/1
611 i860-intel-osf1* )
612 machine=paragon opsys=osf1 NON_GNU_CPP=/usr/mach/lib/cpp
613 ;;
615 ## Intel 860
616 i860-*-sysv4* )
617 machine=i860 opsys=usg5-4
618 NON_GNU_CC="/bin/cc" # Ie, not the one in /usr/ucb/cc.
619 NON_GNU_CPP="/usr/ccs/lib/cpp" # cc -E tokenizes macro expansion.
620 ;;
622 ## Masscomp machines
623 m68*-masscomp-rtu* )
624 machine=masscomp opsys=rtu
625 ;;
627 ## Megatest machines
628 m68*-megatest-bsd* )
629 machine=mega68 opsys=bsd4-2
630 ;;
632 ## Workstations sold by MIPS
633 ## This is not necessarily all workstations using the MIPS processor -
634 ## Irises are produced by SGI, and DECstations by DEC.
636 ## etc/MACHINES lists mips.h and mips4.h as possible machine files,
637 ## and usg5-2-2 and bsd4-3 as possible OS files. The only guidance
638 ## it gives for choosing between the alternatives seems to be "Use
639 ## -machine=mips4 for RISCOS version 4; use -opsystem=bsd4-3 with
640 ## the BSD world." I'll assume that these are instructions for
641 ## handling two odd situations, and that every other situation
642 ## should use mips.h and usg5-2-2, they being listed first.
643 mips-mips-usg* )
644 machine=mips4
645 ## Fall through to the general code at the bottom to decide on the OS.
646 ;;
647 mips-mips-riscos4* )
648 machine=mips4 opsys=bsd4-3
649 NON_GNU_CC="cc -systype bsd43"
650 NON_GNU_CPP="cc -systype bsd43 -E"
651 ;;
652 mips-mips-riscos5* )
653 machine=mips4 opsys=riscos5
654 NON_GNU_CC="cc -systype bsd43"
655 NON_GNU_CPP="cc -systype bsd43 -E"
656 ;;
657 mips-mips-bsd* )
658 machine=mips opsys=bsd4-3
659 ;;
660 mips-mips-* )
661 machine=mips opsys=usg5-2-2
662 ;;
664 ## NeXT
665 m68*-next-* | m68k-*-nextstep* )
666 machine=m68k opsys=nextstep
667 ;;
669 ## The complete machine from National Semiconductor
670 ns32k-ns-genix* )
671 machine=ns32000 opsys=usg5-2
672 ;;
674 ## NCR machines
675 m68*-ncr-sysv2* | m68*-ncr-sysvr2* )
676 machine=tower32 opsys=usg5-2-2
677 ;;
678 m68*-ncr-sysv3* | m68*-ncr-sysvr3* )
679 machine=tower32v3 opsys=usg5-3
680 ;;
682 ## NEC EWS4800
683 mips-nec-sysv4*)
684 machine=ews4800 opsys=ux4800
685 ;;
687 ## Nixdorf Targon 31
688 m68*-nixdorf-sysv* )
689 machine=targon31 opsys=usg5-2-2
690 ;;
692 ## Nu (TI or LMI)
693 m68*-nu-sysv* )
694 machine=nu opsys=usg5-2
695 ;;
697 ## Plexus
698 m68*-plexus-sysv* )
699 machine=plexus opsys=usg5-2
700 ;;
702 ## PowerPC reference platform
703 powerpcle-*-solaris2* )
704 machine=prep
705 opsys=sol2-5
706 ;;
708 ## Pyramid machines
709 ## I don't really have any idea what sort of processor the Pyramid has,
710 ## so I'm assuming it is its own architecture.
711 pyramid-pyramid-bsd* )
712 machine=pyramid opsys=bsd4-2
713 ;;
715 ## Sequent Balance
716 ns32k-sequent-bsd4.2* )
717 machine=sequent opsys=bsd4-2
718 ;;
719 ns32k-sequent-bsd4.3* )
720 machine=sequent opsys=bsd4-3
721 ;;
723 ## Siemens Nixdorf
724 mips-siemens-sysv* | mips-sni-sysv*)
725 machine=mips-siemens opsys=usg5-4
726 NON_GNU_CC=/usr/ccs/bin/cc
727 NON_GNU_CPP=/usr/ccs/lib/cpp
728 ;;
730 ## Silicon Graphics machines
731 ## Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
732 m68*-sgi-iris3.5* )
733 machine=irist opsys=iris3-5
734 ;;
735 m68*-sgi-iris3.6* | m68*-sgi-iris*)
736 machine=irist opsys=iris3-6
737 ;;
738 ## Iris 4D
739 mips-sgi-irix3* )
740 machine=iris4d opsys=irix3-3
741 ;;
742 mips-sgi-irix4* )
743 machine=iris4d opsys=irix4-0
744 ;;
745 mips-sgi-irix6.5 )
746 machine=iris4d opsys=irix6-5
747 NON_GNU_CPP=/lib/cpp
748 NON_GCC_TEST_OPTIONS="-n32 -G0"
749 ;;
750 mips-sgi-irix6* )
751 machine=iris4d opsys=irix6-0
752 NON_GNU_CPP=/lib/cpp
753 NON_GCC_TEST_OPTIONS=-32
754 ;;
755 mips-sgi-irix5.[01]* )
756 machine=iris4d opsys=irix5-0
757 ;;
758 mips-sgi-irix5* | mips-sgi-irix* )
759 machine=iris4d opsys=irix5-2
760 ;;
762 ## SONY machines
763 m68*-sony-bsd4.2* )
764 machine=news opsys=bsd4-2
765 ;;
766 m68*-sony-bsd4.3* )
767 machine=news opsys=bsd4-3
768 ;;
769 m68*-sony-newsos3* | m68*-sony-news3*)
770 machine=news opsys=bsd4-3
771 ;;
772 mips-sony-bsd* | mips-sony-newsos4* | mips-sony-news4*)
773 machine=news-risc opsys=bsd4-3
774 ;;
775 mips-sony-newsos6* )
776 machine=news-r6 opsys=newsos6
777 ;;
778 mips-sony-news* )
779 machine=news-risc opsys=newsos5
780 ;;
782 ## Stride
783 m68*-stride-sysv* )
784 machine=stride opsys=usg5-2
785 ;;
787 ## Suns
788 sparc-*-linux-gnu* )
789 machine=sparc opsys=gnu-linux
790 ;;
792 *-sun-sunos* | *-sun-bsd* | *-sun-solaris* \
793 | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* | powerpc*-*-solaris2* \
794 | rs6000-*-solaris2*)
795 case "${canonical}" in
796 m68*-sunos1* ) machine=sun1 ;;
797 m68*-sunos2* ) machine=sun2 ;;
798 m68* ) machine=sun3 ;;
799 i[3456]86-sun-sunos[34]* ) machine=sun386 ;;
800 i[3456]86-*-* ) machine=intel386 ;;
801 powerpcle* ) machine=powerpcle ;;
802 powerpc* | rs6000* ) machine=ibmrs6000 ;;
803 sparc* ) machine=sparc ;;
804 * ) unported=yes ;;
805 esac
806 case "${canonical}" in
807 ## The Sun386 didn't get past 4.0.
808 i[3456]86-*-sunos4 ) opsys=sunos4-0 ;;
809 *-sunos4.0* ) opsys=sunos4-0 ;;
810 *-sunos4.1.[3-9]*noshare )
811 ## This name is sunos413 instead of sunos4-1-3
812 ## to avoid a file name conflict on MSDOS.
813 opsys=sunos413
814 NON_GNU_CPP=/usr/lib/cpp
815 NON_GCC_TEST_OPTIONS=-Bstatic
816 GCC_TEST_OPTIONS=-static
817 ;;
818 *-sunos4.1.[3-9]* | *-sunos4shr*)
819 opsys=sunos4shr
820 NON_GNU_CPP=/usr/lib/cpp
821 ;;
822 *-sunos4* | *-sunos )
823 opsys=sunos4-1
824 NON_GCC_TEST_OPTIONS=-Bstatic
825 GCC_TEST_OPTIONS=-static
826 ;;
827 *-sunos5.3* | *-solaris2.3* )
828 opsys=sol2-3
829 NON_GNU_CPP=/usr/ccs/lib/cpp
830 ;;
831 *-sunos5.4* | *-solaris2.4* )
832 opsys=sol2-4
833 NON_GNU_CPP=/usr/ccs/lib/cpp
834 RANLIB="ar -ts"
835 ;;
836 *-sunos5.5* | *-solaris2.5* )
837 opsys=sol2-5
838 NON_GNU_CPP=/usr/ccs/lib/cpp
839 RANLIB="ar -ts"
840 ;;
841 *-sunos5* | *-solaris* )
842 opsys=sol2-5
843 NON_GNU_CPP=/usr/ccs/lib/cpp
844 ;;
845 * ) opsys=bsd4-2 ;;
846 esac
847 ## Watch out for a compiler that we know will not work.
848 case "${canonical}" in
849 *-solaris* | *-sunos5* )
850 if [ "x$CC" = x/usr/ucb/cc ]; then
851 ## /usr/ucb/cc doesn't work;
852 ## we should find some other compiler that does work.
853 unset CC
854 fi
855 ;;
856 *) ;;
857 esac
858 ;;
859 sparc-*-nextstep* )
860 machine=sparc opsys=nextstep
861 ;;
863 ## Tadpole 68k
864 m68*-tadpole-sysv* )
865 machine=tad68k opsys=usg5-3
866 ;;
868 ## Tahoe machines
869 tahoe-tahoe-bsd4.2* )
870 machine=tahoe opsys=bsd4-2
871 ;;
872 tahoe-tahoe-bsd4.3* )
873 machine=tahoe opsys=bsd4-3
874 ;;
876 ## Tandem Integrity S2
877 mips-tandem-sysv* )
878 machine=tandem-s2 opsys=usg5-3
879 ;;
881 ## Tektronix XD88
882 m88k-tektronix-sysv3* )
883 machine=tekxd88 opsys=usg5-3
884 ;;
886 ## Tektronix 16000 box (6130?)
887 ns16k-tektronix-bsd* )
888 machine=ns16000 opsys=bsd4-2
889 ;;
890 ## Tektronix 4300
891 ## src/m/tek4300.h hints that this is a m68k machine.
892 m68*-tektronix-bsd* )
893 machine=tek4300 opsys=bsd4-3
894 ;;
896 ## Titan P2 or P3
897 ## We seem to have lost the machine-description file titan.h!
898 titan-titan-sysv* )
899 machine=titan opsys=usg5-3
900 ;;
902 ## Ustation E30 (SS5E)
903 m68*-unisys-uniplus* )
904 machine=ustation opsystem=unipl5-2
905 ;;
907 ## Vaxen.
908 vax-dec-* )
909 machine=vax
910 case "${canonical}" in
911 *-bsd4.1* ) opsys=bsd4-1 ;;
912 *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* ) opsys=bsd4-2 ;;
913 *-bsd4.3* | *-ultrix* ) opsys=bsd4-3 ;;
914 *-sysv[01]* | *-sysvr[01]* ) opsys=usg5-0 ;;
915 *-sysv2* | *-sysvr2* ) opsys=usg5-2 ;;
916 *-vms* ) opsys=vms ;;
917 * ) unported=yes
918 esac
919 ;;
921 ## Whitechapel MG1
922 ns16k-whitechapel-* )
923 machine=mg1
924 ## We don't know what sort of OS runs on these; we'll let the
925 ## operating system guessing code below try.
926 ;;
928 ## Wicat
929 m68*-wicat-sysv* )
930 machine=wicat opsys=usg5-2
931 ;;
933 ## Intel 386 machines where we don't care about the manufacturer
934 i[3456]86-*-* )
935 machine=intel386
936 case "${canonical}" in
937 *-isc1.* | *-isc2.[01]* ) opsys=386-ix ;;
938 *-isc2.2* ) opsys=isc2-2 ;;
939 *-isc4.0* ) opsys=isc4-0 ;;
940 *-isc4.* ) opsys=isc4-1
941 GCC_TEST_OPTIONS=-posix
942 NON_GCC_TEST_OPTIONS=-Xp
943 ;;
944 *-isc* ) opsys=isc3-0 ;;
945 *-esix5* ) opsys=esix5r4; NON_GNU_CPP=/usr/lib/cpp ;;
946 *-esix* ) opsys=esix ;;
947 *-xenix* ) opsys=xenix ;;
948 *-linux-gnu* ) opsys=gnu-linux ;;
949 *-sco3.2v4* ) opsys=sco4 ; NON_GNU_CPP=/lib/cpp ;;
950 *-sco3.2v5* ) opsys=sco5
951 NON_GNU_CPP=/lib/cpp
952 # Prevent -belf from being passed to $CPP.
953 # /lib/cpp does not accept it.
954 OVERRIDE_CPPFLAGS=" "
955 ;;
956 *-sysv4.2uw* ) opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
957 *-386bsd* ) opsys=386bsd ;;
958 *-freebsd* ) opsys=freebsd ;;
959 *-nextstep* ) opsys=nextstep ;;
960 ## Otherwise, we'll fall through to the generic opsys code at the bottom.
961 esac
962 ;;
964 ## m68k Linux-based GNU system
965 m68k-*-linux-gnu* )
966 machine=m68k opsys=gnu-linux
967 ;;
969 ## Mips Linux-based GNU system
970 mips-*-linux-gnu* )
971 machine=mips opsys=gnu-linux
972 ;;
974 ## UXP/DS
975 sparc-fujitsu-sysv4* )
976 machine=sparc opsys=uxpds
977 NON_GNU_CPP=/usr/ccs/lib/cpp
978 RANLIB="ar -ts"
979 ;;
981 * )
982 unported=yes
983 ;;
984 esac
986 ### If the code above didn't choose an operating system, just choose
987 ### an operating system based on the configuration name. You really
988 ### only want to use this when you have no idea what the right
989 ### operating system is; if you know what operating systems a machine
990 ### runs, it's cleaner to make it explicit in the case statement
991 ### above.
992 if test x"${opsys}" = x; then
993 case "${canonical}" in
994 *-gnu* ) opsys=gnu ;;
995 *-bsd4.[01] ) opsys=bsd4-1 ;;
996 *-bsd4.2 ) opsys=bsd4-2 ;;
997 *-bsd4.3 ) opsys=bsd4-3 ;;
998 *-sysv0 | *-sysvr0 ) opsys=usg5-0 ;;
999 *-sysv2 | *-sysvr2 ) opsys=usg5-2 ;;
1000 *-sysv2.2 | *-sysvr2.2 ) opsys=usg5-2-2 ;;
1001 *-sysv3* | *-sysvr3* ) opsys=usg5-3 ;;
1002 *-sysv4.2uw* ) opsys=unixware ;;
1003 *-sysv4.1* | *-sysvr4.1* )
1004 NON_GNU_CPP=/usr/lib/cpp
1005 opsys=usg5-4 ;;
1006 *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
1007 if [ x$NON_GNU_CPP = x ]; then
1008 if [ -f /usr/ccs/lib/cpp ]; then
1009 NON_GNU_CPP=/usr/ccs/lib/cpp
1010 else
1011 NON_GNU_CPP=/lib/cpp
1012 fi
1013 fi
1014 opsys=usg5-4-2 ;;
1015 *-sysv4* | *-sysvr4* ) opsys=usg5-4 ;;
1016 * )
1017 unported=yes
1018 ;;
1019 esac
1020 fi
1022 if test "x$RANLIB" = x; then
1023 RANLIB=ranlib
1024 fi
1026 changequote([, ])dnl
1028 if test $unported = yes; then
1029 AC_MSG_ERROR([Emacs hasn't been ported to \`${canonical}' systems.
1030 Check \`etc/MACHINES' for recognized configuration names.])
1031 fi
1033 machfile="m/${machine}.h"
1034 opsysfile="s/${opsys}.h"
1037 #### Choose a compiler.
1038 test -n "$CC" && cc_specified=yes
1040 # Save the value of CFLAGS that the user specified.
1041 SPECIFIED_CFLAGS="$CFLAGS"
1043 case ${with_gcc} in
1044 "yes" ) CC="gcc" GCC=yes ;;
1045 "no" ) : ${CC=cc} ;;
1046 * ) AC_PROG_CC
1047 esac
1049 # On Suns, sometimes $CPP names a directory.
1050 if test -n "$CPP" && test -d "$CPP"; then
1051 CPP=
1052 fi
1054 #### Some systems specify a CPP to use unless we are using GCC.
1055 #### Now that we know whether we are using GCC, we can decide whether
1056 #### to use that one.
1057 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
1058 then
1059 CPP="$NON_GNU_CPP"
1060 fi
1062 #### Some systems specify a CC to use unless we are using GCC.
1063 #### Now that we know whether we are using GCC, we can decide whether
1064 #### to use that one.
1065 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
1066 test x$cc_specified != xyes
1067 then
1068 CC="$NON_GNU_CC"
1069 fi
1071 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
1072 then
1073 CC="$CC $GCC_TEST_OPTIONS"
1074 fi
1076 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
1077 then
1078 CC="$CC $NON_GCC_TEST_OPTIONS"
1079 fi
1081 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
1082 then
1083 ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1084 fi
1086 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
1087 then
1088 ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1089 fi
1091 #### Some other nice autoconf tests. If you add a test here which
1092 #### should make an entry in src/config.h, don't forget to add an
1093 #### #undef clause to src/config.h.in for autoconf to modify.
1095 dnl checks for programs
1096 AC_PROG_LN_S
1097 AC_PROG_CPP
1098 AC_PROG_INSTALL
1099 AC_PROG_YACC
1101 dnl checks for Unix variants
1102 AC_AIX
1104 dnl checks for header files
1105 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h linux/version.h sys/systeminfo.h termios.h limits.h string.h)
1106 AC_HEADER_STDC
1107 AC_HEADER_TIME
1108 AC_DECL_SYS_SIGLIST
1110 dnl Some systems have utime.h but don't declare the struct anyplace.
1111 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1112 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1113 #include <sys/time.h>
1114 #include <time.h>
1115 #else
1116 #ifdef HAVE_SYS_TIME_H
1117 #include <sys/time.h>
1118 #else
1119 #include <time.h>
1120 #endif
1121 #endif
1122 #ifdef HAVE_UTIME_H
1123 #include <utime.h>
1124 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1125 emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1126 if test $emacs_cv_struct_utimbuf = yes; then
1127 AC_DEFINE(HAVE_STRUCT_UTIMBUF)
1128 fi
1130 dnl checks for typedefs
1131 AC_TYPE_SIGNAL
1133 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1134 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1135 #include <sys/time.h>
1136 #include <time.h>
1137 #else
1138 #ifdef HAVE_SYS_TIME_H
1139 #include <sys/time.h>
1140 #else
1141 #include <time.h>
1142 #endif
1143 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1144 emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1145 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1146 if test $emacs_cv_struct_timeval = yes; then
1147 AC_DEFINE(HAVE_TIMEVAL)
1148 fi
1150 dnl checks for structure members
1151 AC_STRUCT_TM
1152 AC_STRUCT_TIMEZONE
1154 dnl checks for compiler characteristics
1155 AC_C_CONST
1157 dnl check for Make feature
1158 AC_PROG_MAKE_SET
1160 dnl checks for operating system services
1161 AC_SYS_LONG_FILE_NAMES
1163 #### Choose a window system.
1165 AC_PATH_X
1166 if test "$no_x" = yes; then
1167 window_system=none
1168 else
1169 window_system=x11
1170 fi
1172 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1173 LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1174 LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1175 x_default_search_path=""
1176 for x_library in `echo ${x_libraries} | sed -e "s/:/ /g"`; do
1177 x_search_path="${x_library}/X11/%L/%T/%N%C%S:\
1178 ${x_library}/X11/%L/%T/%N%C%S:${x_libary}/X11/%l/%T/%N%C%S:\
1179 ${x_library}/X11/%T/%N%C%S:${x_library}/X11/%L/%T/%N%S:\
1180 ${x_library}/X11/%l/%T/%N%S:${x_library}/X11/%T/%N%S"
1181 if test x"${x_default_search_path}" = x; then
1182 x_default_search_path=${x_search_path}
1183 else
1184 x_default_search_path="${x_search_path}:${x_default_search_path}"
1185 fi
1186 done
1187 fi
1188 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1189 C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1190 fi
1192 if test x"${x_includes}" = x; then
1193 bitmapdir=/usr/include/X11/bitmaps
1194 else
1195 # accumulate include directories that have X11 bitmap subdirectories
1196 bmd_acc="dummyval"
1197 for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1198 if test -d "${bmd}/X11/bitmaps"; then
1199 bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1200 elif test -d "${bmd}/bitmaps"; then
1201 bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1202 fi
1203 done
1204 if test ${bmd_acc} != "dummyval"; then
1205 bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1206 fi
1207 fi
1209 case "${window_system}" in
1210 x11 )
1211 HAVE_X_WINDOWS=yes
1212 HAVE_X11=yes
1213 case "${with_x_toolkit}" in
1214 athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1215 motif ) USE_X_TOOLKIT=MOTIF ;;
1216 dnl open-look ) USE_X_TOOLKIT=OPEN_LOOK ;;
1217 no ) USE_X_TOOLKIT=none ;;
1218 dnl If user did not say whether to use a toolkit,
1219 dnl make this decision later: use the toolkit if we have X11R5 or newer.
1220 * ) USE_X_TOOLKIT=maybe ;;
1221 esac
1222 ;;
1223 none )
1224 HAVE_X_WINDOWS=no
1225 HAVE_X11=no
1226 USE_X_TOOLKIT=none
1227 ;;
1228 esac
1230 ### If we're using X11, we should use the X menu package.
1231 HAVE_MENUS=no
1232 case ${HAVE_X11} in
1233 yes ) HAVE_MENUS=yes ;;
1234 esac
1236 if test "${opsys}" = "hpux9"; then
1237 case "${x_libraries}" in
1238 *X11R4* )
1239 opsysfile="s/hpux9-x11r4.h"
1240 ;;
1241 esac
1242 fi
1244 if test "${opsys}" = "hpux9shr"; then
1245 case "${x_libraries}" in
1246 *X11R4* )
1247 opsysfile="s/hpux9shxr4.h"
1248 ;;
1249 esac
1250 fi
1252 #### Extract some information from the operating system and machine files.
1254 AC_CHECKING([the machine- and system-dependent files to find out
1255 - which libraries the lib-src programs will want, and
1256 - whether the GNU malloc routines are usable])
1258 ### First figure out CFLAGS (which we use for running the compiler here)
1259 ### and REAL_CFLAGS (which we use for real compilation).
1260 ### The two are the same except on a few systems, where they are made
1261 ### different to work around various lossages. For example,
1262 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
1263 ### as implying static linking.
1265 ### If the CFLAGS env var is specified, we use that value
1266 ### instead of the default.
1268 ### It's not important that this name contain the PID; you can't run
1269 ### two configures in the same directory and have anything work
1270 ### anyway.
1271 tempcname="conftest.c"
1273 echo '
1274 #include "'${srcdir}'/src/'${opsysfile}'"
1275 #include "'${srcdir}'/src/'${machfile}'"
1276 #ifndef LIBS_MACHINE
1277 #define LIBS_MACHINE
1278 #endif
1279 #ifndef LIBS_SYSTEM
1280 #define LIBS_SYSTEM
1281 #endif
1282 #ifndef C_SWITCH_SYSTEM
1283 #define C_SWITCH_SYSTEM
1284 #endif
1285 #ifndef C_SWITCH_MACHINE
1286 #define C_SWITCH_MACHINE
1287 #endif
1288 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
1289 configure___ c_switch_system=C_SWITCH_SYSTEM
1290 configure___ c_switch_machine=C_SWITCH_MACHINE
1292 #ifndef LIB_X11_LIB
1293 #define LIB_X11_LIB -lX11
1294 #endif
1296 #ifndef LIBX11_MACHINE
1297 #define LIBX11_MACHINE
1298 #endif
1300 #ifndef LIBX11_SYSTEM
1301 #define LIBX11_SYSTEM
1302 #endif
1303 configure___ LIBX=LIB_X11_LIB LIBX11_MACHINE LIBX11_SYSTEM
1305 #ifdef UNEXEC
1306 configure___ unexec=UNEXEC
1307 #else
1308 configure___ unexec=unexec.o
1309 #endif
1311 #ifdef SYSTEM_MALLOC
1312 configure___ system_malloc=yes
1313 #else
1314 configure___ system_malloc=no
1315 #endif
1317 #ifndef C_DEBUG_SWITCH
1318 #define C_DEBUG_SWITCH -g
1319 #endif
1321 #ifndef C_OPTIMIZE_SWITCH
1322 #define C_OPTIMIZE_SWITCH -O
1323 #endif
1325 #ifndef LD_SWITCH_MACHINE
1326 #define LD_SWITCH_MACHINE
1327 #endif
1329 #ifndef LD_SWITCH_SYSTEM
1330 #define LD_SWITCH_SYSTEM
1331 #endif
1333 #ifndef LD_SWITCH_X_SITE_AUX
1334 #define LD_SWITCH_X_SITE_AUX
1335 #endif
1337 configure___ ld_switch_system=LD_SWITCH_SYSTEM
1338 configure___ ld_switch_machine=LD_SWITCH_MACHINE
1340 #ifdef THIS_IS_CONFIGURE
1342 /* Get the CFLAGS for tests in configure. */
1343 #ifdef __GNUC__
1344 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1345 #else
1346 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1347 #endif
1349 #else /* not THIS_IS_CONFIGURE */
1351 /* Get the CFLAGS for real compilation. */
1352 #ifdef __GNUC__
1353 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1354 #else
1355 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1356 #endif
1358 #endif /* not THIS_IS_CONFIGURE */
1359 ' > ${tempcname}
1361 # The value of CPP is a quoted variable reference, so we need to do this
1362 # to get its actual value...
1363 CPP=`eval "echo $CPP"`
1364 changequote(, )dnl
1365 eval `${CPP} -Isrc ${tempcname} \
1366 | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1367 if test "x$SPECIFIED_CFLAGS" = x; then
1368 eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1369 | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1370 else
1371 REAL_CFLAGS="$CFLAGS"
1372 fi
1373 changequote([, ])dnl
1374 rm ${tempcname}
1376 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
1378 ### Compute the unexec source name from the object name.
1379 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1381 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1382 # Assume not, until told otherwise.
1383 GNU_MALLOC=yes
1384 doug_lea_malloc=yes
1385 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1386 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1387 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1388 emacs_cv_var___after_morecore_hook,
1389 AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1390 emacs_cv_var___after_morecore_hook=yes,
1391 emacs_cv_var___after_morecore_hook=no))
1392 if test $emacs_cv_var___after_morecore_hook = no; then
1393 doug_lea_malloc=no
1394 fi
1395 if test "${system_malloc}" = "yes"; then
1396 GNU_MALLOC=no
1397 GNU_MALLOC_reason="
1398 (The GNU allocators don't work with this system configuration.)"
1399 fi
1400 if test "$doug_lea_malloc" = "yes" ; then
1401 if test "$GNU_MALLOC" = yes ; then
1402 GNU_MALLOC_reason="
1403 (Using Doug Lea's new malloc from the GNU C Library.)"
1404 fi
1405 AC_DEFINE(DOUG_LEA_MALLOC)
1406 fi
1408 if test x"${REL_ALLOC}" = x; then
1409 REL_ALLOC=${GNU_MALLOC}
1410 fi
1412 LISP_FLOAT_TYPE=yes
1415 #### Add the libraries to LIBS and check for some functions.
1417 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1418 CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1419 else
1420 CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1421 fi
1423 LIBS="$libsrc_libs $LIBS"
1425 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1426 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1427 AC_CHECK_LIB(dnet, dnet_ntoa)
1428 dnl This causes -lresolv to get used in subsequent tests,
1429 dnl which causes failures on some systems such as HPUX 9.
1430 dnl AC_CHECK_LIB(resolv, gethostbyname)
1432 dnl FIXME replace main with a function we actually want from this library.
1433 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1435 AC_CHECK_LIB(pthreads, cma_open)
1437 AC_MSG_CHECKING(for XFree86 in /usr/X386)
1438 if test -d /usr/X386/include; then
1439 HAVE_XFREE386=yes
1440 : ${C_SWITCH_X_SITE="-I/usr/X386/include"}
1441 else
1442 HAVE_XFREE386=no
1443 fi
1444 AC_MSG_RESULT($HAVE_XFREE386)
1446 # Change CFLAGS temporarily so that C_SWITCH_X_SITE gets used
1447 # for the tests that follow. We set it back to REAL_CFLAGS later on.
1449 if test "${HAVE_X11}" = "yes"; then
1450 DEFS="$C_SWITCH_X_SITE $DEFS"
1451 LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1452 LIBS="$LIBX $LIBS"
1453 CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1455 # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1456 # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1457 # but it's more convenient here to set LD_RUN_PATH
1458 # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1459 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1460 LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1461 export LD_RUN_PATH
1462 fi
1464 if test "${opsys}" = "gnu-linux"; then
1465 AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1466 AC_TRY_LINK([],
1467 [XOpenDisplay ("foo");],
1468 [xlinux_first_failure=no],
1469 [xlinux_first_failure=yes])
1470 if test "${xlinux_first_failure}" = "yes"; then
1471 OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1472 OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1473 OLD_CPPFLAGS="$CPPFLAGS"
1474 OLD_LIBS="$LIBS"
1475 LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1476 C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1477 CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1478 LIBS="$LIBS -b i486-linuxaout"
1479 AC_TRY_LINK([],
1480 [XOpenDisplay ("foo");],
1481 [xlinux_second_failure=no],
1482 [xlinux_second_failure=yes])
1483 if test "${xlinux_second_failure}" = "yes"; then
1484 # If we get the same failure with -b, there is no use adding -b.
1485 # So take it out. This plays safe.
1486 LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1487 C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1488 CPPFLAGS="$OLD_CPPFLAGS"
1489 LIBS="$OLD_LIBS"
1490 AC_MSG_RESULT(no)
1491 else
1492 AC_MSG_RESULT(yes)
1493 fi
1494 else
1495 AC_MSG_RESULT(no)
1496 fi
1497 fi
1499 AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1500 XScreenNumberOfScreen XSetWMProtocols)
1501 fi
1503 if test "${window_system}" = "x11"; then
1504 AC_MSG_CHECKING(X11 version 6)
1505 AC_CACHE_VAL(emacs_cv_x11_version_6,
1506 AC_TRY_LINK([#include <X11/Xlib.h>],
1507 [#if XlibSpecificationRelease < 6
1508 fail;
1509 #endif
1510 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no))
1511 if test $emacs_cv_x11_version_6 = yes; then
1512 AC_MSG_RESULT(6 or newer)
1513 AC_DEFINE(HAVE_X11R6)
1514 else
1515 AC_MSG_RESULT(before 6)
1516 fi
1517 fi
1519 if test "${window_system}" = "x11"; then
1520 AC_MSG_CHECKING(X11 version 5)
1521 AC_CACHE_VAL(emacs_cv_x11_version_5,
1522 AC_TRY_LINK([#include <X11/Xlib.h>],
1523 [#if XlibSpecificationRelease < 5
1524 fail;
1525 #endif
1526 ], emacs_cv_x11_version_5=yes, emacs_cv_x11_version_5=no))
1527 if test $emacs_cv_x11_version_5 = yes; then
1528 AC_MSG_RESULT(5 or newer)
1529 HAVE_X11R5=yes
1530 AC_DEFINE(HAVE_X11R5)
1531 else
1532 HAVE_X11R5=no
1533 AC_MSG_RESULT(before 5)
1534 fi
1535 fi
1537 dnl Do not put whitespace before the #include statements below.
1538 dnl Older compilers (eg sunos4 cc) choke on it.
1539 if test x"${USE_X_TOOLKIT}" = xmaybe; then
1540 if test x"${HAVE_X11R5}" = xyes; then
1541 AC_MSG_CHECKING(X11 version 5 with Xaw)
1542 AC_CACHE_VAL(emacs_cv_x11_version_5_with_xaw,
1543 AC_TRY_LINK([
1544 #include <X11/Intrinsic.h>
1545 #include <X11/Xaw/Simple.h>],
1546 [],
1547 emacs_cv_x11_version_5_with_xaw=yes,
1548 emacs_cv_x11_version_5_with_xaw=no))
1549 if test $emacs_cv_x11_version_5_with_xaw = yes; then
1550 AC_MSG_RESULT([5 or newer, with Xaw; use toolkit by default])
1551 USE_X_TOOLKIT=LUCID
1552 else
1553 AC_MSG_RESULT(before 5 or no Xaw; do not use toolkit by default)
1554 USE_X_TOOLKIT=none
1555 fi
1556 else
1557 USE_X_TOOLKIT=none
1558 fi
1559 fi
1561 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1563 if test "${USE_X_TOOLKIT}" != "none"; then
1564 AC_MSG_CHECKING(X11 toolkit version)
1565 AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1566 AC_TRY_LINK([#include <X11/Intrinsic.h>],
1567 [#if XtSpecificationRelease < 6
1568 fail;
1569 #endif
1570 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no))
1571 HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1572 if test $emacs_cv_x11_toolkit_version_6 = yes; then
1573 AC_MSG_RESULT(6 or newer)
1574 AC_DEFINE(HAVE_X11XTR6)
1575 else
1576 AC_MSG_RESULT(before 6)
1577 fi
1579 dnl If using toolkit, check whether libXmu.a exists.
1580 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1581 OLDLIBS="$LIBS"
1582 if test x$HAVE_X11XTR6 = xyes; then
1583 LIBS="-lXt -lSM -lICE $LIBS"
1584 else
1585 LIBS="-lXt $LIBS"
1586 fi
1587 AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1588 LIBS="$OLDLIBS"
1589 fi
1591 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1592 AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1593 AC_TRY_COMPILE([#include <Xm/Xm.h>],
1594 [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1595 int x = 5;
1596 #else
1597 Motif version prior to 2.1.
1598 #endif],
1599 emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no))
1600 HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1601 if test $emacs_cv_motif_version_2_1 = yes; then
1602 AC_DEFINE(HAVE_MOTIF_2_1)
1603 fi
1604 fi
1606 # If netdb.h doesn't declare h_errno, we must declare it by hand.
1607 AC_CACHE_CHECK(whether netdb declares h_errno,
1608 emacs_cv_netdb_declares_h_errno,
1609 AC_TRY_LINK([#include <netdb.h>],
1610 [return h_errno;],
1611 emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no))
1612 if test $emacs_cv_netdb_declares_h_errno = yes; then
1613 AC_DEFINE(HAVE_H_ERRNO)
1614 fi
1616 AC_FUNC_ALLOCA
1618 # fmod, logb, and frexp are found in -lm on most systems.
1619 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
1620 AC_CHECK_LIB(m, sqrt)
1622 # Check for mail-locking functions in a "mail" library
1623 AC_CHECK_LIB(mail, maillock,
1624 AC_DEFINE(HAVE_LIBMAIL)
1625 AC_CHECK_FUNCS(touchlock)
1626 AC_CHECK_HEADERS(maillock.h))
1628 AC_CHECK_FUNCS(gettimeofday gethostname getdomainname dup2 \
1629 rename closedir mkdir rmdir sysinfo \
1630 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime res_init setsid \
1631 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
1632 utimes setrlimit setpgid getcwd shutdown strftime)
1634 # Check this now, so that we will NOT find the above functions in ncurses.
1635 # That is because we have not set up to link ncurses in lib-src.
1636 # It's better to believe a function is not available
1637 # than to expect to find it in ncurses.
1638 AC_CHECK_LIB(ncurses, tparm)
1640 # These tell us which Kerberos-related libraries to use.
1641 if test "${with_kerberos+set}" = set; then
1642 AC_CHECK_LIB(com_err, com_err)
1643 AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
1644 AC_CHECK_LIB(krb5, krb5_init_context)
1645 if test "${with_kerberos5+set}" != set; then
1646 AC_CHECK_LIB(des, des_cbc_encrypt,,
1647 AC_CHECK_LIB(des425, des_cbc_encrypt))
1648 AC_CHECK_LIB(krb, krb_get_cred,,
1649 AC_CHECK_LIB(krb4, krb_get_cred))
1650 fi
1652 if test "${with_kerberos5+set}" = set; then
1653 AC_CHECK_HEADERS(krb5.h)
1654 else
1655 AC_CHECK_HEADERS(des.h,,
1656 AC_CHECK_HEADERS(kerberosIV/des.h,,
1657 AC_CHECK_HEADERS(kerberos/des.h)))
1658 AC_CHECK_HEADERS(krb.h,,
1659 AC_CHECK_HEADERS(kerberosIV/krb.h,,
1660 AC_CHECK_HEADERS(kerberos/krb.h)))
1661 fi
1662 AC_CHECK_HEADERS(com_err.h)
1663 fi
1665 # Solaris requires -lintl if you want strerror (which calls dgettext)
1666 # to return localized messages.
1667 AC_CHECK_LIB(intl, dgettext)
1669 AC_MSG_CHECKING(whether localtime caches TZ)
1670 AC_CACHE_VAL(emacs_cv_localtime_cache,
1671 [if test x$ac_cv_func_tzset = xyes; then
1672 AC_TRY_RUN([#include <time.h>
1673 #if STDC_HEADERS
1674 # include <stdlib.h>
1675 #endif
1676 extern char **environ;
1677 unset_TZ ()
1678 {
1679 char **from, **to;
1680 for (to = from = environ; (*to = *from); from++)
1681 if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
1682 to++;
1683 }
1684 char TZ_GMT0[] = "TZ=GMT0";
1685 char TZ_PST8[] = "TZ=PST8";
1686 main()
1687 {
1688 time_t now = time ((time_t *) 0);
1689 int hour_GMT0, hour_unset;
1690 if (putenv (TZ_GMT0) != 0)
1691 exit (1);
1692 hour_GMT0 = localtime (&now)->tm_hour;
1693 unset_TZ ();
1694 hour_unset = localtime (&now)->tm_hour;
1695 if (putenv (TZ_PST8) != 0)
1696 exit (1);
1697 if (localtime (&now)->tm_hour == hour_GMT0)
1698 exit (1);
1699 unset_TZ ();
1700 if (localtime (&now)->tm_hour != hour_unset)
1701 exit (1);
1702 exit (0);
1703 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
1704 [# If we have tzset, assume the worst when cross-compiling.
1705 emacs_cv_localtime_cache=yes])
1706 else
1707 # If we lack tzset, report that localtime does not cache TZ,
1708 # since we can't invalidate the cache if we don't have tzset.
1709 emacs_cv_localtime_cache=no
1710 fi])dnl
1711 AC_MSG_RESULT($emacs_cv_localtime_cache)
1712 if test $emacs_cv_localtime_cache = yes; then
1713 AC_DEFINE(LOCALTIME_CACHE)
1714 fi
1716 if test "x$HAVE_TIMEVAL" = xyes; then
1717 AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
1718 emacs_cv_gettimeofday_two_arguments,
1719 AC_TRY_LINK([
1720 #ifdef TIME_WITH_SYS_TIME
1721 #include <sys/time.h>
1722 #include <time.h>
1723 #else
1724 #ifdef HAVE_SYS_TIME_H
1725 #include <sys/time.h>
1726 #else
1727 #include <time.h>
1728 #endif
1729 #endif
1730 ],
1731 [
1732 struct timeval time;
1733 struct timezone dummy;
1734 gettimeofday (&time, &dummy);
1735 ],
1736 emacs_cv_gettimeofday_two_arguments=yes,
1737 emacs_cv_gettimeofday_two_arguments=no))
1738 if test $emacs_cv_gettimeofday_two_arguments = no; then
1739 AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT)
1740 fi
1741 fi
1743 ok_so_far=yes
1744 AC_CHECK_FUNC(socket, , ok_so_far=no)
1745 if test $ok_so_far = yes; then
1746 AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
1747 fi
1748 if test $ok_so_far = yes; then
1749 AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
1750 fi
1751 if test $ok_so_far = yes; then
1752 AC_DEFINE(HAVE_INET_SOCKETS)
1753 fi
1755 if test -f /usr/lpp/X11/bin/smt.exp; then
1756 AC_DEFINE(HAVE_AIX_SMT_EXP)
1757 fi
1759 # Set up the CFLAGS for real compilation, so we can substitute it.
1760 CFLAGS="$REAL_CFLAGS"
1762 changequote(, )dnl
1763 #### Find out which version of Emacs this is.
1764 version=`grep 'defconst[ ]*emacs-version' ${srcdir}/lisp/version.el \
1765 | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`
1766 changequote([, ])dnl
1767 if test x"${version}" = x; then
1768 AC_MSG_ERROR(can't find current emacs version in \`${srcdir}/lisp/version.el'.)
1769 fi
1771 ### Specify what sort of things we'll be editing into Makefile and config.h.
1772 ### Use configuration here uncanonicalized to avoid exceeding size limits.
1773 AC_SUBST(version)
1774 AC_SUBST(configuration)
1775 AC_SUBST(canonical)
1776 AC_SUBST(srcdir)
1777 AC_SUBST(prefix)
1778 AC_SUBST(exec_prefix)
1779 AC_SUBST(bindir)
1780 AC_SUBST(datadir)
1781 AC_SUBST(sharedstatedir)
1782 AC_SUBST(libexecdir)
1783 AC_SUBST(mandir)
1784 AC_SUBST(infodir)
1785 AC_SUBST(lispdir)
1786 AC_SUBST(locallisppath)
1787 AC_SUBST(lisppath)
1788 AC_SUBST(x_default_search_path)
1789 AC_SUBST(etcdir)
1790 AC_SUBST(archlibdir)
1791 AC_SUBST(docdir)
1792 AC_SUBST(bitmapdir)
1793 AC_SUBST(c_switch_system)
1794 AC_SUBST(c_switch_machine)
1795 AC_SUBST(LD_SWITCH_X_SITE)
1796 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1797 AC_SUBST(C_SWITCH_X_SITE)
1798 AC_SUBST(CFLAGS)
1799 AC_SUBST(X_TOOLKIT_TYPE)
1800 AC_SUBST(machfile)
1801 AC_SUBST(opsysfile)
1802 AC_SUBST(RANLIB)
1804 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION, "${canonical}")
1805 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}")
1806 AC_DEFINE_UNQUOTED(config_machfile, "${machfile}")
1807 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}")
1808 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE})
1809 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX})
1810 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE, ${C_SWITCH_X_SITE})
1811 AC_DEFINE_UNQUOTED(UNEXEC_SRC, ${UNEXEC_SRC})
1813 if test "${HAVE_X_WINDOWS}" = "yes" ; then
1814 AC_DEFINE(HAVE_X_WINDOWS)
1815 fi
1816 if test "${USE_X_TOOLKIT}" != "none" ; then
1817 AC_DEFINE(USE_X_TOOLKIT)
1818 fi
1819 if test "${HAVE_X11}" = "yes" ; then
1820 AC_DEFINE(HAVE_X11)
1821 fi
1822 if test "${HAVE_XFREE386}" = "yes" ; then
1823 AC_DEFINE(HAVE_XFREE386)
1824 fi
1825 if test "${HAVE_MENUS}" = "yes" ; then
1826 AC_DEFINE(HAVE_MENUS)
1827 fi
1828 if test "${GNU_MALLOC}" = "yes" ; then
1829 AC_DEFINE(GNU_MALLOC)
1830 fi
1831 if test "${REL_ALLOC}" = "yes" ; then
1832 AC_DEFINE(REL_ALLOC)
1833 fi
1834 if test "${LISP_FLOAT_TYPE}" = "yes" ; then
1835 AC_DEFINE(LISP_FLOAT_TYPE)
1836 fi
1838 #### Report on what we decided to do.
1839 echo "
1840 Configured for \`${canonical}'.
1842 Where should the build process find the source code? ${srcdir}
1843 What operating system and machine description files should Emacs use?
1844 \`${opsysfile}' and \`${machfile}'
1845 What compiler should emacs be built with? ${CC} ${CFLAGS}
1846 Should Emacs use the GNU version of malloc? ${GNU_MALLOC}${GNU_MALLOC_reason}
1847 Should Emacs use the relocating allocator for buffers? ${REL_ALLOC}
1848 What window system should Emacs use? ${window_system}
1849 What toolkit should Emacs use? ${USE_X_TOOLKIT}"
1851 if test -n "${x_includes}"; then
1852 echo " Where do we find X Windows header files? ${x_includes}"
1853 else
1854 echo " Where do we find X Windows header files? Standard dirs"
1855 fi
1856 if test -n "${x_libraries}"; then
1857 echo " Where do we find X Windows libraries? ${x_libraries}"
1858 else
1859 echo " Where do we find X Windows libraries? Standard dirs"
1860 fi
1862 echo
1864 # Remove any trailing slashes in these variables.
1865 changequote(, )dnl
1866 test "${prefix}" != NONE &&
1867 prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
1868 test "${exec_prefix}" != NONE &&
1869 exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`
1870 changequote([, ])dnl
1872 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
1873 man/Makefile lwlib/Makefile src/Makefile.c:src/Makefile.in \
1874 leim/Makefile, [
1876 ### Make the necessary directories, if they don't exist.
1877 for dir in etc lisp ; do
1878 test -d ${dir} || mkdir ${dir}
1879 done
1881 # Build src/Makefile from ${srcdir}/src/Makefile.c
1882 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
1883 # This must be done after src/config.h is built, since we rely on that file.
1885 changequote(, )dnl The horror, the horror.
1886 # Now get this: Some word that is part of the ${srcdir} directory name
1887 # or the ${configuration} value might, just might, happen to be an
1888 # identifier like `sun4' or `i386' or something, and be predefined by
1889 # the C preprocessor to some helpful value like 1, or maybe the empty
1890 # string. Needless to say consequent macro substitutions are less
1891 # than conducive to the makefile finding the correct directory.
1892 undefs="`echo $top_srcdir $configuration $canonical |
1893 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/ *$//' \
1894 -e 's/ */ -U/g' -e 's/-U[0-9][^ ]*//g' \
1895 `"
1896 changequote([, ])dnl
1898 echo creating src/paths.h
1899 make paths-force
1901 echo creating lib-src/Makefile
1902 ( cd lib-src
1903 rm -f junk.c junk1.c junk2.c
1904 sed -e '/start of cpp stuff/q' \
1905 < Makefile.c > junk1.c
1906 sed -e '1,/start of cpp stuff/d'\
1907 -e 's@/\*\*/#\(.*\)$@/* \1 */@' \
1908 < Makefile.c > junk.c
1909 $CPP $undefs -I. -I$top_srcdir/src $CPPFLAGS junk.c | \
1910 sed -e 's/^ / /' -e '/^#/d' -e '/^[ \f]*$/d' > junk2.c
1911 cat junk1.c junk2.c > Makefile.new
1912 rm -f junk.c junk1.c junk2.c
1913 chmod 444 Makefile.new
1914 mv -f Makefile.new Makefile
1915 )
1917 echo creating src/Makefile
1918 ( cd src
1919 rm -f junk.c junk1.c junk2.c
1920 sed -e '/start of cpp stuff/q' \
1921 < Makefile.c > junk1.c
1922 sed -e '1,/start of cpp stuff/d'\
1923 -e 's@/\*\*/#\(.*\)$@/* \1 */@' \
1924 < Makefile.c > junk.c
1925 $CPP $undefs -I. -I$top_srcdir/src $CPPFLAGS junk.c | \
1926 sed -e 's/^ / /' -e '/^#/d' -e '/^[ \f]*$/d' > junk2.c
1927 cat junk1.c junk2.c > Makefile.new
1928 rm -f junk.c junk1.c junk2.c
1929 chmod 444 Makefile.new
1930 mv -f Makefile.new Makefile
1931 )
1933 if test ! -f src/.gdbinit && test -f $top_srcdir/src/.gdbinit; then
1934 echo creating src/.gdbinit
1935 echo source $top_srcdir/src/.gdbinit > src/.gdbinit
1936 fi
1938 # This is how we know whether to re-run configure in certain cases.
1939 touch src/config.stamp
1941 ], [CPP="$CPP" CPPFLAGS="$CPPFLAGS"])