lisp/term/w32-win.el

   1 ;;; w32-win.el --- parse switches controlling interface with W32 window system
   2
   3 ;; Copyright (C) 1993, 1994, 2001, 2002, 2003, 2004, 2005, 2006, 2007,
   4 ;;   2008, 2009, 2010  Free Software Foundation, Inc.
   5
   6 ;; Author: Kevin Gallo
   7 ;; Keywords: terminals
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; w32-win.el:  this file is loaded from ../lisp/startup.el when it recognizes
  27 ;; that W32 windows are to be used.  Command line switches are parsed and those
  28 ;; pertaining to W32 are processed and removed from the command line.  The
  29 ;; W32 display is opened and hooks are set for popping up the initial window.
  30
  31 ;; startup.el will then examine startup files, and eventually call the hooks
  32 ;; which create the first window (s).
  33
  34 ;;; Code:
  35 \f
  36
  37 ;; These are the standard X switches from the Xt Initialize.c file of
  38 ;; Release 4.
  39
  40 ;; Command line         Resource Manager string
  41
  42 ;; +rv                  *reverseVideo
  43 ;; +synchronous         *synchronous
  44 ;; -background          *background
  45 ;; -bd                  *borderColor
  46 ;; -bg                  *background
  47 ;; -bordercolor         *borderColor
  48 ;; -borderwidth         .borderWidth
  49 ;; -bw                  .borderWidth
  50 ;; -display             .display
  51 ;; -fg                  *foreground
  52 ;; -fn                  *font
  53 ;; -font                *font
  54 ;; -foreground          *foreground
  55 ;; -geometry            .geometry
  56 ;; -i                   .iconType
  57 ;; -itype               .iconType
  58 ;; -iconic              .iconic
  59 ;; -name                .name
  60 ;; -reverse             *reverseVideo
  61 ;; -rv                  *reverseVideo
  62 ;; -selectionTimeout    .selectionTimeout
  63 ;; -synchronous         *synchronous
  64 ;; -xrm
  65
  66 ;; An alist of X options and the function which handles them.  See
  67 ;; ../startup.el.
  68
  69 ;; (if (not (eq window-system 'w32))
  70 ;;     (error "%s: Loading w32-win.el but not compiled for w32" (invocation-name)))
  71
  72 (require 'frame)
  73 (require 'mouse)
  74 (require 'scroll-bar)
  75 (require 'faces)
  76 (require 'select)
  77 (require 'menu-bar)
  78 (require 'dnd)
  79 (require 'w32-vars)
  80
  81 ;; Keep an obsolete alias for w32-focus-frame and w32-select-font in case
  82 ;; they are used by code outside Emacs.
  83 (define-obsolete-function-alias 'w32-focus-frame 'x-focus-frame "23.1")
  84 (declare-function x-select-font "w32font.c"
  85                   (&optional frame exclude-proportional))
  86 (define-obsolete-function-alias 'w32-select-font 'x-select-font "23.1")
  87
  88 (defvar w32-color-map) ;; defined in w32fns.c
  89
  90 (declare-function w32-send-sys-command "w32fns.c")
  91 (declare-function set-message-beep "w32console.c")
  92
  93 ;; Conditional on new-fontset so bootstrapping works on non-GUI compiles
  94 (if (fboundp 'new-fontset)
  95     (require 'fontset))
  96
  97 ;; The following definition is used for debugging scroll bar events.
  98 ;(defun w32-handle-scroll-bar-event (event) (interactive "e") (princ event))
  99
 100 ;; (defun w32-drag-n-drop-debug (event)
 101 ;;   "Print the drag-n-drop EVENT in a readable form."
 102 ;;   (interactive "e")
 103 ;;   (princ event))
 104
 105 (defun w32-drag-n-drop (event)
 106   "Edit the files listed in the drag-n-drop EVENT.
 107 Switch to a buffer editing the last file dropped."
 108   (interactive "e")
 109   (save-excursion
 110     ;; Make sure the drop target has positive co-ords
 111     ;; before setting the selected frame - otherwise it
 112     ;; won't work.  <skx@tardis.ed.ac.uk>
 113     (let* ((window (posn-window (event-start event)))
 114            (coords (posn-x-y (event-start event)))
 115            (x (car coords))
 116            (y (cdr coords)))
 117       (if (and (> x 0) (> y 0))
 118           (set-frame-selected-window nil window))
 119       (mapc (lambda (file-name)
 120                 (let ((f (subst-char-in-string ?\\ ?/ file-name))
 121                       (coding (or file-name-coding-system
 122                                   default-file-name-coding-system)))
 123                   (setq file-name
 124                         (mapconcat 'url-hexify-string
 125                                    (split-string (encode-coding-string f coding)
 126                                                  "/")
 127                                    "/")))
 128                 (dnd-handle-one-url window 'private
 129                                     (concat "file:" file-name)))
 130                 (car (cdr (cdr event)))))
 131   (raise-frame)))
 132
 133 (defun w32-drag-n-drop-other-frame (event)
 134   "Edit the files listed in the drag-n-drop EVENT, in other frames.
 135 May create new frames, or reuse existing ones.  The frame editing
 136 the last file dropped is selected."
 137   (interactive "e")
 138   (mapcar 'find-file-other-frame (car (cdr (cdr event)))))
 139
 140 ;; Bind the drag-n-drop event.
 141 (global-set-key [drag-n-drop] 'w32-drag-n-drop)
 142 (global-set-key [C-drag-n-drop] 'w32-drag-n-drop-other-frame)
 143
 144 ;; Keyboard layout/language change events
 145 ;; For now ignore language-change events; in the future
 146 ;; we should switch the Emacs Input Method to match the
 147 ;; new layout/language selected by the user.
 148 (global-set-key [language-change] 'ignore)
 149
 150 (defvar x-resource-name)
 151 (defvar x-colors)
 152
 153 \f
 154 (defun xw-defined-colors (&optional frame)
 155   "Internal function called by `defined-colors', which see."
 156   (or frame (setq frame (selected-frame)))
 157   (let ((defined-colors nil))
 158     (dolist (this-color (or (mapcar 'car w32-color-map) x-colors))
 159       (and (color-supported-p this-color frame t)
 160            (setq defined-colors (cons this-color defined-colors))))
 161     defined-colors))
 162 \f
 163 ;;;; Function keys
 164
 165  ;;; make f10 activate the real menubar rather than the mini-buffer menu
 166  ;;; navigation feature.
 167  (defun w32-menu-bar-open (&optional frame)
 168    "Start key navigation of the menu bar in FRAME.
 169
 170 This initially activates the first menu-bar item, and you can then navigate
 171 with the arrow keys, select a menu entry with the Return key or cancel with
 172 the Escape key.  If FRAME has no menu bar, this function does nothing.
 173
 174 If FRAME is nil or not given, use the selected frame.
 175 If FRAME does not have the menu bar enabled, display a text menu using
 176 `tmm-menubar'."
 177    (interactive "i")
 178    (if menu-bar-mode
 179        (w32-send-sys-command ?\xf100 frame)
 180      (with-selected-frame (or frame (selected-frame))
 181        (tmm-menubar))))
 182 \f
 183
 184 ;; W32 systems have different fonts than commonly found on X, so
 185 ;; we define our own standard fontset here.
 186 (defvar w32-standard-fontset-spec
 187  "-*-Courier New-normal-r-*-*-13-*-*-*-c-*-fontset-standard"
 188  "String of fontset spec of the standard fontset.
 189 This defines a fontset consisting of the Courier New variations for
 190 European languages which are distributed with Windows as
 191 \"Multilanguage Support\".
 192
 193 See the documentation of `create-fontset-from-fontset-spec' for the format.")
 194
 195 (defun x-win-suspend-error ()
 196   "Report an error when a suspend is attempted."
 197   (error "Suspending an Emacs running under W32 makes no sense"))
 198
 199 (defvar image-library-alist)
 200
 201 ;;; Set default known names for image libraries
 202 (setq image-library-alist
 203       '((xpm "libxpm.dll" "xpm4.dll" "libXpm-nox4.dll")
 204         (png "libpng12d.dll" "libpng12.dll" "libpng.dll"
 205          ;; these are libpng 1.2.8 from GTK+
 206          "libpng13d.dll" "libpng13.dll")
 207         (jpeg "jpeg62.dll" "libjpeg.dll" "jpeg-62.dll" "jpeg.dll")
 208         (tiff "libtiff3.dll" "libtiff.dll")
 209         (gif "giflib4.dll" "libungif4.dll" "libungif.dll")
 210         (svg "librsvg-2-2.dll")
 211         (gdk-pixbuf "libgdk_pixbuf-2.0-0.dll")
 212         (glib "libglib-2.0-0.dll")
 213         (gobject "libgobject-2.0-0.dll")))
 214
 215 ;;; multi-tty support
 216 (defvar w32-initialized nil
 217   "Non-nil if the w32 window system has been initialized.")
 218
 219 (declare-function x-open-connection "w32fns.c"
 220                   (display &optional xrm-string must-succeed))
 221 (declare-function create-fontset-from-fontset-spec "fontset"
 222                   (fontset-spec &optional style-variant noerror))
 223 (declare-function create-fontset-from-x-resource "fontset" ())
 224 (declare-function x-get-resource "frame.c"
 225                   (attribute class &optional component subclass))
 226 (declare-function x-handle-args "common-win" (args))
 227 (declare-function x-parse-geometry "frame.c" (string))
 228 (defvar x-command-line-resources)
 229
 230 (defun w32-initialize-window-system ()
 231   "Initialize Emacs for W32 GUI frames."
 232
 233   ;; Do the actual Windows setup here; the above code just defines
 234   ;; functions and variables that we use now.
 235
 236   (setq command-line-args (x-handle-args command-line-args))
 237
 238   ;; Make sure we have a valid resource name.
 239   (or (stringp x-resource-name)
 240       (setq x-resource-name
 241             ;; Change any . or * characters in x-resource-name to hyphens,
 242             ;; so as not to choke when we use it in X resource queries.
 243             (replace-regexp-in-string "[.*]" "-" (invocation-name))))
 244
 245   (x-open-connection "" x-command-line-resources
 246                      ;; Exit with a fatal error if this fails and we
 247                      ;; are the initial display
 248                      (eq initial-window-system 'w32))
 249
 250   ;; Create the default fontset.
 251   (create-default-fontset)
 252   ;; Create the standard fontset.
 253   (condition-case err
 254       (create-fontset-from-fontset-spec w32-standard-fontset-spec t)
 255     (error (display-warning
 256             'initialization
 257             (format "Creation of the standard fontset failed: %s" err)
 258             :error)))
 259   ;; Create fontset specified in X resources "Fontset-N" (N is 0, 1,...).
 260   (create-fontset-from-x-resource)
 261
 262   ;; Apply a geometry resource to the initial frame.  Put it at the end
 263   ;; of the alist, so that anything specified on the command line takes
 264   ;; precedence.
 265   (let* ((res-geometry (x-get-resource "geometry" "Geometry"))
 266          parsed)
 267     (if res-geometry
 268         (progn
 269           (setq parsed (x-parse-geometry res-geometry))
 270           ;; If the resource specifies a position,
 271           ;; call the position and size "user-specified".
 272           (if (or (assq 'top parsed) (assq 'left parsed))
 273               (setq parsed (cons '(user-position . t)
 274                                  (cons '(user-size . t) parsed))))
 275           ;; All geometry parms apply to the initial frame.
 276           (setq initial-frame-alist (append initial-frame-alist parsed))
 277           ;; The size parms apply to all frames.
 278           (if (and (assq 'height parsed)
 279                    (not (assq 'height default-frame-alist)))
 280               (setq default-frame-alist
 281                     (cons (cons 'height (cdr (assq 'height parsed)))
 282                           default-frame-alist))
 283           (if (and (assq 'width parsed)
 284                    (not (assq 'width default-frame-alist)))
 285               (setq default-frame-alist
 286                     (cons (cons 'width (cdr (assq 'width parsed)))
 287                           default-frame-alist)))))))
 288
 289   ;; Check the reverseVideo resource.
 290   (let ((case-fold-search t))
 291     (let ((rv (x-get-resource "reverseVideo" "ReverseVideo")))
 292       (if (and rv (string-match "^\\(true\\|yes\\|on\\)$" rv))
 293           (setq default-frame-alist
 294                 (cons '(reverse . t) default-frame-alist)))))
 295
 296   ;; Don't let Emacs suspend under w32 gui
 297   (add-hook 'suspend-hook 'x-win-suspend-error)
 298
 299   ;; Turn off window-splitting optimization; w32 is usually fast enough
 300   ;; that this is only annoying.
 301   (setq split-window-keep-point t)
 302
 303   ;; W32 expects the menu bar cut and paste commands to use the clipboard.
 304   (menu-bar-enable-clipboard)
 305
 306   ;; Don't show the frame name; that's redundant.
 307   (setq-default mode-line-frame-identification "  ")
 308
 309   ;; Set to a system sound if you want a fancy bell.
 310   (set-message-beep 'ok)
 311   (setq w32-initialized t))
 312
 313 (add-to-list 'handle-args-function-alist '(w32 . x-handle-args))
 314 (add-to-list 'frame-creation-function-alist '(w32 . x-create-frame-with-faces))
 315 (add-to-list 'window-system-initialization-alist '(w32 . w32-initialize-window-system))
 316
 317 (provide 'w32-win)
 318
 319 ;; arch-tag: 69fb1701-28c2-4890-b351-3d1fe4b4f166
 320 ;;; w32-win.el ends here