lisp/hi-lock.el

   1 ;;; hi-lock.el --- minor mode for interactive automatic highlighting  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2000-2013 Free Software Foundation, Inc.
   4
   5 ;; Author: David M. Koppelman <koppel@ece.lsu.edu>
   6 ;; Keywords: faces, minor-mode, matching, display
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24 ;;
  25 ;;  With the hi-lock commands text matching interactively entered
  26 ;;  regexp's can be highlighted.  For example, `M-x highlight-regexp
  27 ;;  RET clearly RET RET' will highlight all occurrences of `clearly'
  28 ;;  using a yellow background face.  New occurrences of `clearly' will
  29 ;;  be highlighted as they are typed.  `M-x unhighlight-regexp RET'
  30 ;;  will remove the highlighting.  Any existing face can be used for
  31 ;;  highlighting and a set of appropriate faces is provided.  The
  32 ;;  regexps can be written into the current buffer in a form that will
  33 ;;  be recognized the next time the corresponding file is read (when
  34 ;;  file patterns is turned on).
  35 ;;
  36 ;;  Applications:
  37 ;;
  38 ;;    In program source code highlight a variable to quickly see all
  39 ;;    places it is modified or referenced:
  40 ;;    M-x highlight-regexp ground_contact_switches_closed RET RET
  41 ;;
  42 ;;    In a shell or other buffer that is showing lots of program
  43 ;;    output, highlight the parts of the output you're interested in:
  44 ;;    M-x highlight-regexp Total execution time [0-9]+ RET hi-blue-b RET
  45 ;;
  46 ;;    In buffers displaying tables, highlight the lines you're interested in:
  47 ;;    M-x highlight-lines-matching-regexp January 2000 RET hi-black-b RET
  48 ;;
  49 ;;    When writing text, highlight personal cliches.  This can be
  50 ;;    amusing.
  51 ;;    M-x highlight-phrase as can be seen RET RET
  52 ;;
  53 ;;  Setup:
  54 ;;
  55 ;;    Put the following code in your init file.  This turns on
  56 ;;    hi-lock mode and adds a "Regexp Highlighting" entry
  57 ;;    to the edit menu.
  58 ;;
  59 ;;    (global-hi-lock-mode 1)
  60 ;;
  61 ;;    To enable the use of patterns found in files (presumably placed
  62 ;;    there by hi-lock) include the following in your init file:
  63 ;;
  64 ;;    (setq hi-lock-file-patterns-policy 'ask)
  65 ;;
  66 ;;    If you get tired of being asked each time a file is loaded replace
  67 ;;    `ask' with a function that returns t if patterns should be read.
  68 ;;
  69 ;;    You might also want to bind the hi-lock commands to more
  70 ;;    finger-friendly sequences:
  71
  72 ;;    (define-key hi-lock-map "\C-z\C-h" 'highlight-lines-matching-regexp)
  73 ;;    (define-key hi-lock-map "\C-zi" 'hi-lock-find-patterns)
  74 ;;    (define-key hi-lock-map "\C-zh" 'highlight-regexp)
  75 ;;    (define-key hi-lock-map "\C-zp" 'highlight-phrase)
  76 ;;    (define-key hi-lock-map "\C-zr" 'unhighlight-regexp)
  77 ;;    (define-key hi-lock-map "\C-zb" 'hi-lock-write-interactive-patterns))
  78
  79 ;;    See the documentation for hi-lock-mode `C-h f hi-lock-mode' for
  80 ;;    additional instructions.
  81
  82 ;; Sample file patterns:
  83
  84 ; Hi-lock: (("^;;; .*" (0 (quote hi-black-hb) t)))
  85 ; Hi-lock: ( ("make-variable-buffer-\\(local\\)" (0 font-lock-keyword-face)(1 'italic append)))))
  86 ; Hi-lock: end
  87
  88 ;;; Code:
  89
  90 (require 'font-lock)
  91
  92 (defgroup hi-lock nil
  93   "Interactively add and remove font-lock patterns for highlighting text."
  94   :link '(custom-manual "(emacs)Highlight Interactively")
  95   :group 'font-lock)
  96
  97 (defcustom hi-lock-file-patterns-range 10000
  98   "Limit of search in a buffer for hi-lock patterns.
  99 When a file is visited and hi-lock mode is on, patterns starting
 100 up to this limit are added to font-lock's patterns.  See documentation
 101 of functions `hi-lock-mode' and `hi-lock-find-patterns'."
 102   :type 'integer
 103   :group 'hi-lock)
 104
 105 (defcustom hi-lock-highlight-range 200000
 106   "Size of area highlighted by hi-lock when font-lock not active.
 107 Font-lock is not active in buffers that do their own highlighting,
 108 such as the buffer created by `list-colors-display'.  In those buffers
 109 hi-lock patterns will only be applied over a range of
 110 `hi-lock-highlight-range' characters.  If font-lock is active then
 111 highlighting will be applied throughout the buffer."
 112   :type 'integer
 113   :group 'hi-lock)
 114
 115 (defcustom hi-lock-exclude-modes
 116   '(rmail-mode mime/viewer-mode gnus-article-mode)
 117   "List of major modes in which hi-lock will not run.
 118 For security reasons since font lock patterns can specify function
 119 calls."
 120   :type '(repeat symbol)
 121   :group 'hi-lock)
 122
 123 (defcustom hi-lock-file-patterns-policy 'ask
 124   "Specify when hi-lock should use patterns found in file.
 125 If `ask', prompt when patterns found in buffer; if bound to a function,
 126 use patterns when function returns t (function is called with patterns
 127 as first argument); if nil or `never' or anything else, don't use file
 128 patterns."
 129   :type '(choice (const :tag "Do not use file patterns" never)
 130                  (const :tag "Ask about file patterns" ask)
 131                  (function :tag "Function to check file patterns"))
 132   :group 'hi-lock
 133   :version "22.1")
 134
 135 ;; It can have a function value.
 136 (put 'hi-lock-file-patterns-policy 'risky-local-variable t)
 137
 138 (defcustom hi-lock-auto-select-face nil
 139   "Non-nil if highlighting commands should not prompt for face names.
 140 When non-nil, each hi-lock command will cycle through faces in
 141 `hi-lock-face-defaults' without prompting."
 142   :type 'boolean
 143   :version "24.4")
 144
 145 (defgroup hi-lock-faces nil
 146   "Faces for hi-lock."
 147   :group 'hi-lock
 148   :group 'faces)
 149
 150 (defface hi-yellow
 151   '((((min-colors 88) (background dark))
 152      (:background "yellow1" :foreground "black"))
 153     (((background dark)) (:background "yellow" :foreground "black"))
 154     (((min-colors 88)) (:background "yellow1"))
 155     (t (:background "yellow")))
 156   "Default face for hi-lock mode."
 157   :group 'hi-lock-faces)
 158
 159 (defface hi-pink
 160   '((((background dark)) (:background "pink" :foreground "black"))
 161     (t (:background "pink")))
 162   "Face for hi-lock mode."
 163   :group 'hi-lock-faces)
 164
 165 (defface hi-green
 166   '((((min-colors 88) (background dark))
 167      (:background "green1" :foreground "black"))
 168     (((background dark)) (:background "green" :foreground "black"))
 169     (((min-colors 88)) (:background "green1"))
 170     (t (:background "green")))
 171   "Face for hi-lock mode."
 172   :group 'hi-lock-faces)
 173
 174 (defface hi-blue
 175   '((((background dark)) (:background "light blue" :foreground "black"))
 176     (t (:background "light blue")))
 177   "Face for hi-lock mode."
 178   :group 'hi-lock-faces)
 179
 180 (defface hi-black-b
 181   '((t (:weight bold)))
 182   "Face for hi-lock mode."
 183   :group 'hi-lock-faces)
 184
 185 (defface hi-blue-b
 186   '((((min-colors 88)) (:weight bold :foreground "blue1"))
 187     (t (:weight bold :foreground "blue")))
 188   "Face for hi-lock mode."
 189   :group 'hi-lock-faces)
 190
 191 (defface hi-green-b
 192   '((((min-colors 88)) (:weight bold :foreground "green1"))
 193     (t (:weight bold :foreground "green")))
 194   "Face for hi-lock mode."
 195   :group 'hi-lock-faces)
 196
 197 (defface hi-red-b
 198   '((((min-colors 88)) (:weight bold :foreground "red1"))
 199     (t (:weight bold :foreground "red")))
 200   "Face for hi-lock mode."
 201   :group 'hi-lock-faces)
 202
 203 (defface hi-black-hb
 204   '((t (:weight bold :height 1.67 :inherit variable-pitch)))
 205   "Face for hi-lock mode."
 206   :group 'hi-lock-faces)
 207
 208 (defvar-local hi-lock-file-patterns nil
 209   "Patterns found in file for hi-lock.  Should not be changed.")
 210 (put 'hi-lock-file-patterns 'permanent-local t)
 211
 212 (defvar-local hi-lock-interactive-patterns nil
 213   "Patterns provided to hi-lock by user.  Should not be changed.")
 214 (put 'hi-lock-interactive-patterns 'permanent-local t)
 215
 216 (define-obsolete-variable-alias 'hi-lock-face-history
 217                                 'hi-lock-face-defaults "23.1")
 218 (defvar hi-lock-face-defaults
 219   '("hi-yellow" "hi-pink" "hi-green" "hi-blue" "hi-black-b"
 220     "hi-blue-b" "hi-red-b" "hi-green-b" "hi-black-hb")
 221   "Default faces for hi-lock interactive functions.")
 222
 223 (define-obsolete-variable-alias 'hi-lock-regexp-history
 224                                 'regexp-history
 225                                 "23.1")
 226
 227 (defvar hi-lock-file-patterns-prefix "Hi-lock"
 228   "Search target for finding hi-lock patterns at top of file.")
 229
 230 (defvar hi-lock-archaic-interface-message-used nil
 231   "True if user alerted that `global-hi-lock-mode' is now the global switch.
 232 Earlier versions of hi-lock used `hi-lock-mode' as the global switch;
 233 the message is issued if it appears that `hi-lock-mode' is used assuming
 234 that older functionality.  This variable avoids multiple reminders.")
 235
 236 (defvar hi-lock-archaic-interface-deduce nil
 237   "If non-nil, sometimes assume that `hi-lock-mode' means `global-hi-lock-mode'.
 238 Assumption is made if `hi-lock-mode' used in the *scratch* buffer while
 239 a library is being loaded.")
 240
 241 (defvar hi-lock-menu
 242   (let ((map (make-sparse-keymap "Hi Lock")))
 243     (define-key-after map [highlight-regexp]
 244       '(menu-item "Highlight Regexp..." highlight-regexp
 245         :help "Highlight text matching PATTERN (a regexp)."))
 246
 247     (define-key-after map [highlight-phrase]
 248       '(menu-item "Highlight Phrase..." highlight-phrase
 249         :help "Highlight text matching PATTERN (a regexp processed to match phrases)."))
 250
 251     (define-key-after map [highlight-lines-matching-regexp]
 252       '(menu-item "Highlight Lines..." highlight-lines-matching-regexp
 253         :help "Highlight lines containing match of PATTERN (a regexp)."))
 254
 255     (define-key-after map [unhighlight-regexp]
 256       '(menu-item "Remove Highlighting..." unhighlight-regexp
 257         :help "Remove previously entered highlighting pattern."
 258         :enable hi-lock-interactive-patterns))
 259
 260     (define-key-after map [hi-lock-write-interactive-patterns]
 261       '(menu-item "Patterns to Buffer" hi-lock-write-interactive-patterns
 262         :help "Insert interactively added REGEXPs into buffer at point."
 263         :enable hi-lock-interactive-patterns))
 264
 265     (define-key-after map [hi-lock-find-patterns]
 266       '(menu-item "Patterns from Buffer" hi-lock-find-patterns
 267         :help "Use patterns (if any) near top of buffer."))
 268     map)
 269   "Menu for hi-lock mode.")
 270
 271 (defvar hi-lock-map
 272   (let ((map (make-sparse-keymap "Hi Lock")))
 273     (define-key map "\C-xwi" 'hi-lock-find-patterns)
 274     (define-key map "\C-xwl" 'highlight-lines-matching-regexp)
 275     (define-key map "\C-xwp" 'highlight-phrase)
 276     (define-key map "\C-xwh" 'highlight-regexp)
 277     (define-key map "\C-xwr" 'unhighlight-regexp)
 278     (define-key map "\C-xwb" 'hi-lock-write-interactive-patterns)
 279     map)
 280   "Key map for hi-lock.")
 281
 282 ;; Visible Functions
 283
 284 ;;;###autoload
 285 (define-minor-mode hi-lock-mode
 286   "Toggle selective highlighting of patterns (Hi Lock mode).
 287 With a prefix argument ARG, enable Hi Lock mode if ARG is
 288 positive, and disable it otherwise.  If called from Lisp, enable
 289 the mode if ARG is omitted or nil.
 290
 291 Hi Lock mode is automatically enabled when you invoke any of the
 292 highlighting commands listed below, such as \\[highlight-regexp].
 293 To enable Hi Lock mode in all buffers, use `global-hi-lock-mode'
 294 or add (global-hi-lock-mode 1) to your init file.
 295
 296 In buffers where Font Lock mode is enabled, patterns are
 297 highlighted using font lock.  In buffers where Font Lock mode is
 298 disabled, patterns are applied using overlays; in this case, the
 299 highlighting will not be updated as you type.
 300
 301 When Hi Lock mode is enabled, a \"Regexp Highlighting\" submenu
 302 is added to the \"Edit\" menu.  The commands in the submenu,
 303 which can be called interactively, are:
 304
 305 \\[highlight-regexp] REGEXP FACE
 306   Highlight matches of pattern REGEXP in current buffer with FACE.
 307
 308 \\[highlight-phrase] PHRASE FACE
 309   Highlight matches of phrase PHRASE in current buffer with FACE.
 310   (PHRASE can be any REGEXP, but spaces will be replaced by matches
 311   to whitespace and initial lower-case letters will become case insensitive.)
 312
 313 \\[highlight-lines-matching-regexp] REGEXP FACE
 314   Highlight lines containing matches of REGEXP in current buffer with FACE.
 315
 316 \\[unhighlight-regexp] REGEXP
 317   Remove highlighting on matches of REGEXP in current buffer.
 318
 319 \\[hi-lock-write-interactive-patterns]
 320   Write active REGEXPs into buffer as comments (if possible).  They may
 321   be read the next time file is loaded or when the \\[hi-lock-find-patterns] command
 322   is issued.  The inserted regexps are in the form of font lock keywords.
 323   (See `font-lock-keywords'.)  They may be edited and re-loaded with \\[hi-lock-find-patterns],
 324   any valid `font-lock-keywords' form is acceptable.  When a file is
 325   loaded the patterns are read if `hi-lock-file-patterns-policy' is
 326   'ask and the user responds y to the prompt, or if
 327   `hi-lock-file-patterns-policy' is bound to a function and that
 328   function returns t.
 329
 330 \\[hi-lock-find-patterns]
 331   Re-read patterns stored in buffer (in the format produced by \\[hi-lock-write-interactive-patterns]).
 332
 333 When hi-lock is started and if the mode is not excluded or patterns
 334 rejected, the beginning of the buffer is searched for lines of the
 335 form:
 336   Hi-lock: FOO
 337
 338 where FOO is a list of patterns.  The patterns must start before
 339 position \(number of characters into buffer)
 340 `hi-lock-file-patterns-range'.  Patterns will be read until
 341 Hi-lock: end is found.  A mode is excluded if it's in the list
 342 `hi-lock-exclude-modes'."
 343   :group 'hi-lock
 344   :lighter (:eval (if (or hi-lock-interactive-patterns
 345                           hi-lock-file-patterns)
 346                       " Hi" ""))
 347   :global nil
 348   :keymap hi-lock-map
 349   (when (and (equal (buffer-name) "*scratch*")
 350              load-in-progress
 351              (not (called-interactively-p 'interactive))
 352              (not hi-lock-archaic-interface-message-used))
 353     (setq hi-lock-archaic-interface-message-used t)
 354     (if hi-lock-archaic-interface-deduce
 355         (global-hi-lock-mode hi-lock-mode)
 356       (warn
 357        "Possible archaic use of (hi-lock-mode).
 358 Use (global-hi-lock-mode 1) in .emacs to enable hi-lock for all buffers,
 359 use (hi-lock-mode 1) for individual buffers.  For compatibility with Emacs
 360 versions before 22 use the following in your init file:
 361
 362         (if (functionp 'global-hi-lock-mode)
 363             (global-hi-lock-mode 1)
 364           (hi-lock-mode 1))
 365 ")))
 366   (if hi-lock-mode
 367       ;; Turned on.
 368       (progn
 369         (define-key-after menu-bar-edit-menu [hi-lock]
 370           (cons "Regexp Highlighting" hi-lock-menu))
 371         (hi-lock-find-patterns)
 372         (add-hook 'font-lock-mode-hook 'hi-lock-font-lock-hook nil t))
 373     ;; Turned off.
 374     (when (or hi-lock-interactive-patterns
 375               hi-lock-file-patterns)
 376       (when hi-lock-interactive-patterns
 377         (font-lock-remove-keywords nil hi-lock-interactive-patterns)
 378         (setq hi-lock-interactive-patterns nil))
 379       (when hi-lock-file-patterns
 380         (font-lock-remove-keywords nil hi-lock-file-patterns)
 381         (setq hi-lock-file-patterns nil))
 382       (remove-overlays nil nil 'hi-lock-overlay t)
 383       (when font-lock-fontified (font-lock-fontify-buffer)))
 384     (define-key-after menu-bar-edit-menu [hi-lock] nil)
 385     (remove-hook 'font-lock-mode-hook 'hi-lock-font-lock-hook t)))
 386
 387 ;;;###autoload
 388 (define-globalized-minor-mode global-hi-lock-mode
 389   hi-lock-mode turn-on-hi-lock-if-enabled
 390   :group 'hi-lock)
 391
 392 (defun turn-on-hi-lock-if-enabled ()
 393   (setq hi-lock-archaic-interface-message-used t)
 394   (unless (memq major-mode hi-lock-exclude-modes)
 395     (hi-lock-mode 1)))
 396
 397 ;;;###autoload
 398 (defalias 'highlight-lines-matching-regexp 'hi-lock-line-face-buffer)
 399 ;;;###autoload
 400 (defun hi-lock-line-face-buffer (regexp &optional face)
 401   "Set face of all lines containing a match of REGEXP to FACE.
 402 Interactively, prompt for REGEXP then FACE, using a buffer-local
 403 history list for REGEXP and a global history list for FACE.
 404
 405 If Font Lock mode is enabled in the buffer, it is used to
 406 highlight REGEXP.  If Font Lock mode is disabled, overlays are
 407 used for highlighting; in this case, the highlighting will not be
 408 updated as you type."
 409   (interactive
 410    (list
 411     (hi-lock-regexp-okay
 412      (read-regexp "Regexp to highlight line" (car regexp-history)))
 413     (hi-lock-read-face-name)))
 414   (or (facep face) (setq face 'hi-yellow))
 415   (unless hi-lock-mode (hi-lock-mode 1))
 416   (hi-lock-set-pattern
 417    ;; The \\(?:...\\) grouping construct ensures that a leading ^, +, * or ?
 418    ;; or a trailing $ in REGEXP will be interpreted correctly.
 419    (concat "^.*\\(?:" regexp "\\).*$") face))
 420
 421
 422 ;;;###autoload
 423 (defalias 'highlight-regexp 'hi-lock-face-buffer)
 424 ;;;###autoload
 425 (defun hi-lock-face-buffer (regexp &optional face)
 426   "Set face of each match of REGEXP to FACE.
 427 Interactively, prompt for REGEXP then FACE, using a buffer-local
 428 history list for REGEXP and a global history list for FACE.
 429
 430 If Font Lock mode is enabled in the buffer, it is used to
 431 highlight REGEXP.  If Font Lock mode is disabled, overlays are
 432 used for highlighting; in this case, the highlighting will not be
 433 updated as you type."
 434   (interactive
 435    (list
 436     (hi-lock-regexp-okay
 437      (read-regexp "Regexp to highlight" (car regexp-history)))
 438     (hi-lock-read-face-name)))
 439   (or (facep face) (setq face 'hi-yellow))
 440   (unless hi-lock-mode (hi-lock-mode 1))
 441   (hi-lock-set-pattern regexp face))
 442
 443 ;;;###autoload
 444 (defalias 'highlight-phrase 'hi-lock-face-phrase-buffer)
 445 ;;;###autoload
 446 (defun hi-lock-face-phrase-buffer (regexp &optional face)
 447   "Set face of each match of phrase REGEXP to FACE.
 448 If called interactively, replaces whitespace in REGEXP with
 449 arbitrary whitespace and makes initial lower-case letters case-insensitive.
 450
 451 If Font Lock mode is enabled in the buffer, it is used to
 452 highlight REGEXP.  If Font Lock mode is disabled, overlays are
 453 used for highlighting; in this case, the highlighting will not be
 454 updated as you type."
 455   (interactive
 456    (list
 457     (hi-lock-regexp-okay
 458      (hi-lock-process-phrase
 459       (read-regexp "Phrase to highlight" (car regexp-history))))
 460     (hi-lock-read-face-name)))
 461   (or (facep face) (setq face 'hi-yellow))
 462   (unless hi-lock-mode (hi-lock-mode 1))
 463   (hi-lock-set-pattern regexp face))
 464
 465 (defun hi-lock-keyword->face (keyword)
 466   (cadr (cadr (cadr keyword))))    ; Keyword looks like (REGEXP (0 'FACE) ...).
 467
 468 (declare-function x-popup-menu "menu.c" (position menu))
 469
 470 (defun hi-lock--regexps-at-point ()
 471   (let ((regexps '()))
 472     ;; When using overlays, there is no ambiguity on the best
 473     ;; choice of regexp.
 474     (let ((regexp (get-char-property (point) 'hi-lock-overlay-regexp)))
 475       (when regexp (push regexp regexps)))
 476     ;; With font-locking on, check if the cursor is on a highlighted text.
 477     (let ((face-after (get-text-property (point) 'face))
 478           (face-before
 479            (unless (bobp) (get-text-property (1- (point)) 'face)))
 480           (faces (mapcar #'hi-lock-keyword->face
 481                          hi-lock-interactive-patterns)))
 482       (unless (memq face-before faces) (setq face-before nil))
 483       (unless (memq face-after faces) (setq face-after nil))
 484       (when (and face-before face-after (not (eq face-before face-after)))
 485         (setq face-before nil))
 486       (when (or face-after face-before)
 487         (let* ((hi-text
 488                 (buffer-substring-no-properties
 489                  (if face-before
 490                      (or (previous-single-property-change (point) 'face)
 491                          (point-min))
 492                    (point))
 493                  (if face-after
 494                      (or (next-single-property-change (point) 'face)
 495                          (point-max))
 496                    (point)))))
 497           ;; Compute hi-lock patterns that match the
 498           ;; highlighted text at point.  Use this later in
 499           ;; during completing-read.
 500           (dolist (hi-lock-pattern hi-lock-interactive-patterns)
 501             (let ((regexp (car hi-lock-pattern)))
 502               (if (string-match regexp hi-text)
 503                   (push regexp regexps)))))))
 504     regexps))
 505
 506 (defvar-local hi-lock--unused-faces nil
 507   "List of faces that is not used and is available for highlighting new text.
 508 Face names from this list come from `hi-lock-face-defaults'.")
 509
 510 ;;;###autoload
 511 (defalias 'unhighlight-regexp 'hi-lock-unface-buffer)
 512 ;;;###autoload
 513 (defun hi-lock-unface-buffer (regexp)
 514   "Remove highlighting of each match to REGEXP set by hi-lock.
 515 Interactively, prompt for REGEXP, accepting only regexps
 516 previously inserted by hi-lock interactive functions.
 517 If REGEXP is t (or if \\[universal-argument] was specified interactively),
 518 then remove all hi-lock highlighting."
 519   (interactive
 520    (cond
 521     (current-prefix-arg (list t))
 522     ((and (display-popup-menus-p)
 523           (listp last-nonmenu-event)
 524           use-dialog-box)
 525      (catch 'snafu
 526        (or
 527         (x-popup-menu
 528          t
 529          (cons
 530           `keymap
 531           (cons "Select Pattern to Unhighlight"
 532                 (mapcar (lambda (pattern)
 533                           (list (car pattern)
 534                                 (format
 535                                  "%s (%s)" (car pattern)
 536                                  (hi-lock-keyword->face pattern))
 537                                 (cons nil nil)
 538                                 (car pattern)))
 539                         hi-lock-interactive-patterns))))
 540         ;; If the user clicks outside the menu, meaning that they
 541         ;; change their mind, x-popup-menu returns nil, and
 542         ;; interactive signals a wrong number of arguments error.
 543         ;; To prevent that, we return an empty string, which will
 544         ;; effectively disable the rest of the function.
 545         (throw 'snafu '("")))))
 546     (t
 547      ;; Un-highlighting triggered via keyboard action.
 548      (unless hi-lock-interactive-patterns
 549        (error "No highlighting to remove"))
 550      ;; Infer the regexp to un-highlight based on cursor position.
 551      (let* ((defaults (or (hi-lock--regexps-at-point)
 552                           (mapcar #'car hi-lock-interactive-patterns))))
 553        (list
 554         (completing-read (if (null defaults)
 555                              "Regexp to unhighlight: "
 556                            (format "Regexp to unhighlight (default %s): "
 557                                    (car defaults)))
 558                          hi-lock-interactive-patterns
 559                          nil t nil nil defaults))))))
 560   (dolist (keyword (if (eq regexp t) hi-lock-interactive-patterns
 561                      (list (assoc regexp hi-lock-interactive-patterns))))
 562     (when keyword
 563       (let ((face (hi-lock-keyword->face keyword)))
 564         ;; Make `face' the next one to use by default.
 565         (add-to-list 'hi-lock--unused-faces (face-name face)))
 566       (font-lock-remove-keywords nil (list keyword))
 567       (setq hi-lock-interactive-patterns
 568             (delq keyword hi-lock-interactive-patterns))
 569       (remove-overlays
 570        nil nil 'hi-lock-overlay-regexp (hi-lock--hashcons (car keyword)))
 571       (when font-lock-fontified (font-lock-fontify-buffer)))))
 572
 573 ;;;###autoload
 574 (defun hi-lock-write-interactive-patterns ()
 575   "Write interactively added patterns, if any, into buffer at point.
 576
 577 Interactively added patterns are those normally specified using
 578 `highlight-regexp' and `highlight-lines-matching-regexp'; they can
 579 be found in variable `hi-lock-interactive-patterns'."
 580   (interactive)
 581   (if (null hi-lock-interactive-patterns)
 582       (error "There are no interactive patterns"))
 583   (let ((beg (point)))
 584     (mapc
 585      (lambda (pattern)
 586        (insert (format "%s: (%s)\n"
 587                        hi-lock-file-patterns-prefix
 588                        (prin1-to-string pattern))))
 589      hi-lock-interactive-patterns)
 590     (comment-region beg (point)))
 591   (when (> (point) hi-lock-file-patterns-range)
 592     (warn "Inserted keywords not close enough to top of file")))
 593
 594 ;; Implementation Functions
 595
 596 (defun hi-lock-process-phrase (phrase)
 597   "Convert regexp PHRASE to a regexp that matches phrases.
 598
 599 Blanks in PHRASE replaced by regexp that matches arbitrary whitespace
 600 and initial lower-case letters made case insensitive."
 601   (let ((mod-phrase nil))
 602     ;; FIXME fragile; better to just bind case-fold-search?  (Bug#7161)
 603     (setq mod-phrase
 604           (replace-regexp-in-string
 605            "\\(^\\|\\s-\\)\\([a-z]\\)"
 606            (lambda (m) (format "%s[%s%s]"
 607                                (match-string 1 m)
 608                                (upcase (match-string 2 m))
 609                                (match-string 2 m))) phrase))
 610     ;; FIXME fragile; better to use search-spaces-regexp?
 611     (setq mod-phrase
 612           (replace-regexp-in-string
 613            "\\s-+" "[ \t\n]+" mod-phrase nil t))))
 614
 615 (defun hi-lock-regexp-okay (regexp)
 616   "Return REGEXP if it appears suitable for a font-lock pattern.
 617
 618 Otherwise signal an error.  A pattern that matches the null string is
 619 not suitable."
 620   (if (string-match regexp "")
 621       (error "Regexp cannot match an empty string")
 622     regexp))
 623
 624 (defun hi-lock-read-face-name ()
 625   "Return face for interactive highlighting.
 626 When `hi-lock-auto-select-face' is non-nil, just return the next face.
 627 Otherwise, read face name from minibuffer with completion and history."
 628   (unless hi-lock-interactive-patterns
 629     (setq hi-lock--unused-faces hi-lock-face-defaults))
 630   (let* ((last-used-face
 631           (when hi-lock-interactive-patterns
 632             (face-name (hi-lock-keyword->face
 633                         (car hi-lock-interactive-patterns)))))
 634          (defaults (append hi-lock--unused-faces
 635                            (cdr (member last-used-face hi-lock-face-defaults))
 636                            hi-lock-face-defaults))
 637          face)
 638           (if (and hi-lock-auto-select-face (not current-prefix-arg))
 639         (setq face (or (pop hi-lock--unused-faces) (car defaults)))
 640       (setq face (completing-read
 641                   (format "Highlight using face (default %s): "
 642                           (car defaults))
 643                   obarray 'facep t nil 'face-name-history defaults))
 644       ;; Update list of un-used faces.
 645       (setq hi-lock--unused-faces (remove face hi-lock--unused-faces))
 646       ;; Grow the list of defaults.
 647       (add-to-list 'hi-lock-face-defaults face t))
 648     (intern face)))
 649
 650 (defun hi-lock-set-pattern (regexp face)
 651   "Highlight REGEXP with face FACE."
 652   ;; Hashcons the regexp, so it can be passed to remove-overlays later.
 653   (setq regexp (hi-lock--hashcons regexp))
 654   (let ((pattern (list regexp (list 0 (list 'quote face) t))))
 655     ;; Refuse to highlight a text that is already highlighted.
 656     (unless (assoc regexp hi-lock-interactive-patterns)
 657       (push pattern hi-lock-interactive-patterns)
 658       (if font-lock-mode
 659           (progn
 660             (font-lock-add-keywords nil (list pattern) t)
 661             (font-lock-fontify-buffer))
 662         (let* ((range-min (- (point) (/ hi-lock-highlight-range 2)))
 663                (range-max (+ (point) (/ hi-lock-highlight-range 2)))
 664                (search-start
 665                 (max (point-min)
 666                      (- range-min (max 0 (- range-max (point-max))))))
 667                (search-end
 668                 (min (point-max)
 669                      (+ range-max (max 0 (- (point-min) range-min))))))
 670           (save-excursion
 671             (goto-char search-start)
 672             (while (re-search-forward regexp search-end t)
 673               (let ((overlay (make-overlay (match-beginning 0) (match-end 0))))
 674                 (overlay-put overlay 'hi-lock-overlay t)
 675                 (overlay-put overlay 'hi-lock-overlay-regexp regexp)
 676                 (overlay-put overlay 'face face))
 677               (goto-char (match-end 0)))))))))
 678
 679 (defun hi-lock-set-file-patterns (patterns)
 680   "Replace file patterns list with PATTERNS and refontify."
 681   (when (or hi-lock-file-patterns patterns)
 682     (font-lock-remove-keywords nil hi-lock-file-patterns)
 683     (setq hi-lock-file-patterns patterns)
 684     (font-lock-add-keywords nil hi-lock-file-patterns t)
 685     (font-lock-fontify-buffer)))
 686
 687 (defun hi-lock-find-patterns ()
 688   "Find patterns in current buffer for hi-lock."
 689   (interactive)
 690   (unless (memq major-mode hi-lock-exclude-modes)
 691     (let ((all-patterns nil)
 692           (target-regexp (concat "\\<" hi-lock-file-patterns-prefix ":")))
 693       (save-excursion
 694         (save-restriction
 695           (widen)
 696           (goto-char (point-min))
 697           (re-search-forward target-regexp
 698                              (+ (point) hi-lock-file-patterns-range) t)
 699           (beginning-of-line)
 700           (while (and (re-search-forward target-regexp (+ (point) 100) t)
 701                       (not (looking-at "\\s-*end")))
 702             (condition-case nil
 703                 (setq all-patterns (append (read (current-buffer)) all-patterns))
 704               (error (message "Invalid pattern list expression at %d"
 705                               (line-number-at-pos)))))))
 706       (when (and all-patterns
 707                  hi-lock-mode
 708                  (cond
 709                   ((eq this-command 'hi-lock-find-patterns) t)
 710                   ((functionp hi-lock-file-patterns-policy)
 711                    (funcall hi-lock-file-patterns-policy all-patterns))
 712                   ((eq hi-lock-file-patterns-policy 'ask)
 713                    (y-or-n-p "Add patterns from this buffer to hi-lock? "))
 714                   (t nil)))
 715         (hi-lock-set-file-patterns all-patterns)
 716         (if (called-interactively-p 'interactive)
 717             (message "Hi-lock added %d patterns." (length all-patterns)))))))
 718
 719 (defun hi-lock-font-lock-hook ()
 720   "Add hi-lock patterns to font-lock's."
 721   (when font-lock-fontified
 722     (font-lock-add-keywords nil hi-lock-file-patterns t)
 723     (font-lock-add-keywords nil hi-lock-interactive-patterns t)))
 724
 725 (defvar hi-lock--hashcons-hash
 726   (make-hash-table :test 'equal :weakness t)
 727   "Hash table used to hash cons regexps.")
 728
 729 (defun hi-lock--hashcons (string)
 730   "Return unique object equal to STRING."
 731   (or (gethash string hi-lock--hashcons-hash)
 732       (puthash string string hi-lock--hashcons-hash)))
 733
 734 (defun hi-lock-unload-function ()
 735   "Unload the Hi-Lock library."
 736   (global-hi-lock-mode -1)
 737   ;; continue standard unloading
 738   nil)
 739
 740 (provide 'hi-lock)
 741
 742 ;;; hi-lock.el ends here