lisp/help-fns.el

   1 ;;; help-fns.el --- Complex help functions
   2
   3 ;; Copyright (C) 1985, 1986, 1993, 1994, 1998, 1999, 2000, 2001, 2002,
   4 ;;   2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010
   5 ;;   Free Software Foundation, Inc.
   6
   7 ;; Maintainer: FSF
   8 ;; Keywords: help, internal
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; This file contains those help commands which are complicated, and
  28 ;; which may not be used in every session.  For example
  29 ;; `describe-function' will probably be heavily used when doing elisp
  30 ;; programming, but not if just editing C files.  Simpler help commands
  31 ;; are in help.el
  32
  33 ;;; Code:
  34
  35 ;; Functions
  36
  37 ;;;###autoload
  38 (defun describe-function (function)
  39   "Display the full documentation of FUNCTION (a symbol)."
  40   (interactive
  41    (let ((fn (function-called-at-point))
  42          (enable-recursive-minibuffers t)
  43          val)
  44      (setq val (completing-read (if fn
  45                                     (format "Describe function (default %s): " fn)
  46                                   "Describe function: ")
  47                                 obarray 'fboundp t nil nil
  48                                 (and fn (symbol-name fn))))
  49      (list (if (equal val "")
  50                fn (intern val)))))
  51   (if (null function)
  52       (message "You didn't specify a function")
  53     (help-setup-xref (list #'describe-function function)
  54                      (called-interactively-p 'interactive))
  55     (save-excursion
  56       (with-help-window (help-buffer)
  57         (prin1 function)
  58         ;; Use " is " instead of a colon so that
  59         ;; it is easier to get out the function name using forward-sexp.
  60         (princ " is ")
  61         (describe-function-1 function)
  62         (with-current-buffer standard-output
  63           ;; Return the text we displayed.
  64           (buffer-string))))))
  65
  66 (defun help-split-fundoc (docstring def)
  67   "Split a function DOCSTRING into the actual doc and the usage info.
  68 Return (USAGE . DOC) or nil if there's no usage info.
  69 DEF is the function whose usage we're looking for in DOCSTRING."
  70   ;; Functions can get the calling sequence at the end of the doc string.
  71   ;; In cases where `function' has been fset to a subr we can't search for
  72   ;; function's name in the doc string so we use `fn' as the anonymous
  73   ;; function name instead.
  74   (when (and docstring (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring))
  75     (cons (format "(%s%s"
  76                   ;; Replace `fn' with the actual function name.
  77                   (if (consp def) "anonymous" def)
  78                   (match-string 1 docstring))
  79           (substring docstring 0 (match-beginning 0)))))
  80
  81 (defun help-add-fundoc-usage (docstring arglist)
  82   "Add the usage info to DOCSTRING.
  83 If DOCSTRING already has a usage info, then just return it unchanged.
  84 The usage info is built from ARGLIST.  DOCSTRING can be nil.
  85 ARGLIST can also be t or a string of the form \"(FUN ARG1 ARG2 ...)\"."
  86   (unless (stringp docstring) (setq docstring "Not documented"))
  87   (if (or (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring) (eq arglist t))
  88       docstring
  89     (concat docstring
  90             (if (string-match "\n?\n\\'" docstring)
  91                 (if (< (- (match-end 0) (match-beginning 0)) 2) "\n" "")
  92               "\n\n")
  93             (if (and (stringp arglist)
  94                      (string-match "\\`([^ ]+\\(.*\\))\\'" arglist))
  95                 (concat "(fn" (match-string 1 arglist) ")")
  96               (format "%S" (help-make-usage 'fn arglist))))))
  97
  98 (defun help-function-arglist (def)
  99   ;; Handle symbols aliased to other symbols.
 100   (if (and (symbolp def) (fboundp def)) (setq def (indirect-function def)))
 101   ;; If definition is a macro, find the function inside it.
 102   (if (eq (car-safe def) 'macro) (setq def (cdr def)))
 103   ;; and do the same for interpreted closures
 104   (if (eq (car-safe def) 'closure) (setq def (cddr def)))
 105   (cond
 106    ((byte-code-function-p def) (aref def 0))
 107    ((eq (car-safe def) 'lambda) (nth 1 def))
 108    ((and (eq (car-safe def) 'autoload) (not (eq (nth 4 def) 'keymap)))
 109     "[Arg list not available until function definition is loaded.]")
 110    (t t)))
 111
 112 (defun help-make-usage (function arglist)
 113   (cons (if (symbolp function) function 'anonymous)
 114         (mapcar (lambda (arg)
 115                   (if (not (symbolp arg))
 116                       (if (and (consp arg) (symbolp (car arg)))
 117                           ;; CL style default values for optional args.
 118                           (cons (intern (upcase (symbol-name (car arg))))
 119                                 (cdr arg))
 120                         arg)
 121                     (let ((name (symbol-name arg)))
 122                       (if (string-match "\\`&" name) arg
 123                         (intern (upcase name))))))
 124                 arglist)))
 125
 126 ;; Could be this, if we make symbol-file do the work below.
 127 ;; (defun help-C-file-name (subr-or-var kind)
 128 ;;   "Return the name of the C file where SUBR-OR-VAR is defined.
 129 ;; KIND should be `var' for a variable or `subr' for a subroutine."
 130 ;;   (symbol-file (if (symbolp subr-or-var) subr-or-var
 131 ;;               (subr-name subr-or-var))
 132 ;;             (if (eq kind 'var) 'defvar 'defun)))
 133 ;;;###autoload
 134 (defun help-C-file-name (subr-or-var kind)
 135   "Return the name of the C file where SUBR-OR-VAR is defined.
 136 KIND should be `var' for a variable or `subr' for a subroutine."
 137   (let ((docbuf (get-buffer-create " *DOC*"))
 138         (name (if (eq 'var kind)
 139                   (concat "V" (symbol-name subr-or-var))
 140                 (concat "F" (subr-name subr-or-var)))))
 141     (with-current-buffer docbuf
 142       (goto-char (point-min))
 143       (if (eobp)
 144           (insert-file-contents-literally
 145            (expand-file-name internal-doc-file-name doc-directory)))
 146       (let ((file (catch 'loop
 147                     (while t
 148                       (let ((pnt (search-forward (concat "\x1f" name "\n"))))
 149                         (re-search-backward "\x1fS\\(.*\\)")
 150                         (let ((file (match-string 1)))
 151                           (if (member file build-files)
 152                               (throw 'loop file)
 153                             (goto-char pnt))))))))
 154         (if (string-match "^ns.*\\(\\.o\\|obj\\)\\'" file)
 155             (setq file (replace-match ".m" t t file 1))
 156           (if (string-match "\\.\\(o\\|obj\\)\\'" file)
 157               (setq file (replace-match ".c" t t file))))
 158         (if (string-match "\\.\\(c\\|m\\)\\'" file)
 159             (concat "src/" file)
 160           file)))))
 161
 162 (defcustom help-downcase-arguments nil
 163   "If non-nil, argument names in *Help* buffers are downcased."
 164   :type 'boolean
 165   :group 'help
 166   :version "23.2")
 167
 168 (defun help-highlight-arg (arg)
 169   "Highlight ARG as an argument name for a *Help* buffer.
 170 Return ARG in face `help-argument-name'; ARG is also downcased
 171 if the variable `help-downcase-arguments' is non-nil."
 172   (propertize (if help-downcase-arguments (downcase arg) arg)
 173               'face 'help-argument-name))
 174
 175 (defun help-do-arg-highlight (doc args)
 176   (with-syntax-table (make-syntax-table emacs-lisp-mode-syntax-table)
 177     (modify-syntax-entry ?\- "w")
 178     (dolist (arg args doc)
 179       (setq doc (replace-regexp-in-string
 180                  ;; This is heuristic, but covers all common cases
 181                  ;; except ARG1-ARG2
 182                  (concat "\\<"                   ; beginning of word
 183                          "\\(?:[a-z-]*-\\)?"     ; for xxx-ARG
 184                          "\\("
 185                          (regexp-quote arg)
 186                          "\\)"
 187                          "\\(?:es\\|s\\|th\\)?"  ; for ARGth, ARGs
 188                          "\\(?:-[a-z0-9-]+\\)?"  ; for ARG-xxx, ARG-n
 189                          "\\(?:-[{([<`\"].*?\\)?"; for ARG-{x}, (x), <x>, [x], `x'
 190                          "\\>")                  ; end of word
 191                  (help-highlight-arg arg)
 192                  doc t t 1)))))
 193
 194 (defun help-highlight-arguments (usage doc &rest args)
 195   (when (and usage (string-match "^(" usage))
 196     (with-temp-buffer
 197       (insert usage)
 198       (goto-char (point-min))
 199       (let ((case-fold-search nil)
 200             (next (not (or args (looking-at "\\["))))
 201             (opt nil))
 202         ;; Make a list of all arguments
 203         (skip-chars-forward "^ ")
 204         (while next
 205           (or opt (not (looking-at " &")) (setq opt t))
 206           (if (not (re-search-forward " \\([\\[(]*\\)\\([^] &)\.]+\\)" nil t))
 207               (setq next nil)
 208             (setq args (cons (match-string 2) args))
 209             (when (and opt (string= (match-string 1) "("))
 210               ;; A pesky CL-style optional argument with default value,
 211               ;; so let's skip over it
 212               (search-backward "(")
 213               (goto-char (scan-sexps (point) 1)))))
 214         ;; Highlight aguments in the USAGE string
 215         (setq usage (help-do-arg-highlight (buffer-string) args))
 216         ;; Highlight arguments in the DOC string
 217         (setq doc (and doc (help-do-arg-highlight doc args))))))
 218   ;; Return value is like the one from help-split-fundoc, but highlighted
 219   (cons usage doc))
 220
 221 ;; The following function was compiled from the former functions
 222 ;; `describe-simplify-lib-file-name' and `find-source-lisp-file' with
 223 ;; some excerpts from `describe-function-1' and `describe-variable'.
 224 ;; The only additional twists provided are (1) locate the defining file
 225 ;; for autoloaded functions, and (2) give preference to files in the
 226 ;; "install directory" (directories found via `load-path') rather than
 227 ;; to files in the "compile directory" (directories found by searching
 228 ;; the loaddefs.el file).  We autoload it because it's also used by
 229 ;; `describe-face' (instead of `describe-simplify-lib-file-name').
 230
 231 ;;;###autoload
 232 (defun find-lisp-object-file-name (object type)
 233   "Guess the file that defined the Lisp object OBJECT, of type TYPE.
 234 OBJECT should be a symbol associated with a function, variable, or face;
 235   alternatively, it can be a function definition.
 236 If TYPE is `defvar', search for a variable definition.
 237 If TYPE is `defface', search for a face definition.
 238 If TYPE is the value returned by `symbol-function' for a function symbol,
 239  search for a function definition.
 240
 241 The return value is the absolute name of a readable file where OBJECT is
 242 defined.  If several such files exist, preference is given to a file
 243 found via `load-path'.  The return value can also be `C-source', which
 244 means that OBJECT is a function or variable defined in C.  If no
 245 suitable file is found, return nil."
 246   (let* ((autoloaded (eq (car-safe type) 'autoload))
 247          (file-name (or (and autoloaded (nth 1 type))
 248                         (symbol-file
 249                          object (if (memq type (list 'defvar 'defface))
 250                                     type
 251                                   'defun)))))
 252     (cond
 253      (autoloaded
 254       ;; An autoloaded function: Locate the file since `symbol-function'
 255       ;; has only returned a bare string here.
 256       (setq file-name
 257             (locate-file file-name load-path '(".el" ".elc") 'readable)))
 258      ((and (stringp file-name)
 259            (string-match "[.]*loaddefs.el\\'" file-name))
 260       ;; An autoloaded variable or face.  Visit loaddefs.el in a buffer
 261       ;; and try to extract the defining file.  The following form is
 262       ;; from `describe-function-1' and `describe-variable'.
 263       (let ((location
 264              (condition-case nil
 265                  (find-function-search-for-symbol object nil file-name)
 266                (error nil))))
 267         (when (cdr location)
 268           (with-current-buffer (car location)
 269             (goto-char (cdr location))
 270             (when (re-search-backward
 271                    "^;;; Generated autoloads from \\(.*\\)" nil t)
 272               (setq file-name
 273                     (locate-file
 274                      (file-name-sans-extension
 275                       (match-string-no-properties 1))
 276                      load-path '(".el" ".elc") 'readable))))))))
 277
 278     (cond
 279      ((and (not file-name) (subrp type))
 280       ;; A built-in function.  The form is from `describe-function-1'.
 281       (if (get-buffer " *DOC*")
 282           (help-C-file-name type 'subr)
 283         'C-source))
 284      ((and (not file-name) (symbolp object)
 285            (integerp (get object 'variable-documentation)))
 286       ;; A variable defined in C.  The form is from `describe-variable'.
 287       (if (get-buffer " *DOC*")
 288           (help-C-file-name object 'var)
 289         'C-source))
 290      ((not (stringp file-name))
 291       ;; If we don't have a file-name string by now, we lost.
 292       nil)
 293      ((let ((lib-name
 294              (if (string-match "[.]elc\\'" file-name)
 295                  (substring-no-properties file-name 0 -1)
 296                file-name)))
 297         ;; When the Elisp source file can be found in the install
 298         ;; directory return the name of that file - `file-name' should
 299         ;; have become an absolute file name ny now.
 300         (or (and (file-readable-p lib-name) lib-name)
 301             ;; The library might be compressed.
 302             (and (file-readable-p (concat lib-name ".gz")) lib-name))))
 303      ((let* ((lib-name (file-name-nondirectory file-name))
 304              ;; The next form is from `describe-simplify-lib-file-name'.
 305              (file-name
 306               ;; Try converting the absolute file name to a library
 307               ;; name, convert that back to a file name and see if we
 308               ;; get the original one.  If so, they are equivalent.
 309               (if (equal file-name (locate-file lib-name load-path '("")))
 310                   (if (string-match "[.]elc\\'" lib-name)
 311                       (substring-no-properties lib-name 0 -1)
 312                     lib-name)
 313                 file-name))
 314              ;; The next three forms are from `find-source-lisp-file'.
 315              (elc-file (locate-file
 316                         (concat file-name
 317                                 (if (string-match "\\.el\\'" file-name)
 318                                     "c"
 319                                   ".elc"))
 320                         load-path nil 'readable))
 321              (str (when elc-file
 322                     (with-temp-buffer
 323                       (insert-file-contents-literally elc-file nil 0 256)
 324                       (buffer-string))))
 325              (src-file (and str
 326                             (string-match ";;; from file \\(.*\\.el\\)" str)
 327                             (match-string 1 str))))
 328         (and src-file (file-readable-p src-file) src-file))))))
 329
 330 (declare-function ad-get-advice-info "advice" (function))
 331
 332 ;;;###autoload
 333 (defun describe-function-1 (function)
 334   (let* ((advised (and (symbolp function) (featurep 'advice)
 335                        (ad-get-advice-info function)))
 336          ;; If the function is advised, use the symbol that has the
 337          ;; real definition, if that symbol is already set up.
 338          (real-function
 339           (or (and advised
 340                    (let ((origname (cdr (assq 'origname advised))))
 341                      (and (fboundp origname) origname)))
 342               function))
 343          ;; Get the real definition.
 344          (def (if (symbolp real-function)
 345                   (symbol-function real-function)
 346                 function))
 347          file-name string
 348          (beg (if (commandp def) "an interactive " "a "))
 349          (pt1 (with-current-buffer (help-buffer) (point)))
 350          errtype)
 351     (setq string
 352           (cond ((or (stringp def) (vectorp def))
 353                  "a keyboard macro")
 354                 ((subrp def)
 355                  (if (eq 'unevalled (cdr (subr-arity def)))
 356                      (concat beg "special form")
 357                    (concat beg "built-in function")))
 358                 ((byte-code-function-p def)
 359                  (concat beg "compiled Lisp function"))
 360                 ((and (funvecp def) (eq (aref def 0) 'curry))
 361                  (if (symbolp (aref def 1))
 362                      (format "a curried function calling `%s'" (aref def 1))
 363                    "a curried function"))
 364                 ((funvecp def)
 365                  (format "a function-vector (funvec) of type `%s'"
 366                          (aref def 0)))
 367                 ((symbolp def)
 368                  (while (and (fboundp def)
 369                              (symbolp (symbol-function def)))
 370                    (setq def (symbol-function def)))
 371                  ;; Handle (defalias 'foo 'bar), where bar is undefined.
 372                  (or (fboundp def) (setq errtype 'alias))
 373                  (format "an alias for `%s'" def))
 374                 ((eq (car-safe def) 'lambda)
 375                  (concat beg "Lisp function"))
 376                 ((eq (car-safe def) 'macro)
 377                  "a Lisp macro")
 378                 ((eq (car-safe def) 'closure)
 379                  (concat beg "Lisp closure"))
 380                 ((eq (car-safe def) 'autoload)
 381                  (format "%s autoloaded %s"
 382                          (if (commandp def) "an interactive" "an")
 383                          (if (eq (nth 4 def) 'keymap) "keymap"
 384                            (if (nth 4 def) "Lisp macro" "Lisp function"))))
 385                 ((keymapp def)
 386                  (let ((is-full nil)
 387                        (elts (cdr-safe def)))
 388                    (while elts
 389                      (if (char-table-p (car-safe elts))
 390                          (setq is-full t
 391                                elts nil))
 392                      (setq elts (cdr-safe elts)))
 393                    (if is-full
 394                        "a full keymap"
 395                      "a sparse keymap")))
 396                 (t "")))
 397     (princ string)
 398     (if (eq errtype 'alias)
 399         (princ ",\nwhich is not defined.  Please make a bug report.")
 400       (with-current-buffer standard-output
 401         (save-excursion
 402           (save-match-data
 403             (when (re-search-backward "alias for `\\([^`']+\\)'" nil t)
 404               (help-xref-button 1 'help-function def)))))
 405
 406       (setq file-name (find-lisp-object-file-name function def))
 407       (when file-name
 408         (princ " in `")
 409         ;; We used to add .el to the file name,
 410         ;; but that's completely wrong when the user used load-file.
 411         (princ (if (eq file-name 'C-source)
 412                    "C source code"
 413                  (file-name-nondirectory file-name)))
 414         (princ "'")
 415         ;; Make a hyperlink to the library.
 416         (with-current-buffer standard-output
 417           (save-excursion
 418             (re-search-backward "`\\([^`']+\\)'" nil t)
 419             (help-xref-button 1 'help-function-def function file-name))))
 420       (princ ".")
 421       (with-current-buffer (help-buffer)
 422         (fill-region-as-paragraph (save-excursion (goto-char pt1) (forward-line 0) (point))
 423                                   (point)))
 424       (terpri)(terpri)
 425       (when (commandp function)
 426         (let ((pt2 (with-current-buffer (help-buffer) (point)))
 427               (remapped (command-remapping function)))
 428           (unless (memq remapped '(ignore undefined))
 429             (let ((keys (where-is-internal
 430                          (or remapped function) overriding-local-map nil nil))
 431                   non-modified-keys)
 432               (if (and (eq function 'self-insert-command)
 433                        (vectorp (car-safe keys))
 434                        (consp (aref (car keys) 0)))
 435                   (princ "It is bound to many ordinary text characters.\n")
 436                 ;; Which non-control non-meta keys run this command?
 437                 (dolist (key keys)
 438                   (if (member (event-modifiers (aref key 0)) '(nil (shift)))
 439                       (push key non-modified-keys)))
 440                 (when remapped
 441                   (princ "It is remapped to `")
 442                   (princ (symbol-name remapped))
 443                   (princ "'"))
 444
 445                 (when keys
 446                   (princ (if remapped ", which is bound to " "It is bound to "))
 447                   ;; If lots of ordinary text characters run this command,
 448                   ;; don't mention them one by one.
 449                   (if (< (length non-modified-keys) 10)
 450                       (princ (mapconcat 'key-description keys ", "))
 451                     (dolist (key non-modified-keys)
 452                       (setq keys (delq key keys)))
 453                     (if keys
 454                         (progn
 455                           (princ (mapconcat 'key-description keys ", "))
 456                           (princ ", and many ordinary text characters"))
 457                       (princ "many ordinary text characters"))))
 458                 (when (or remapped keys non-modified-keys)
 459                   (princ ".")
 460                   (terpri)))))
 461
 462           (with-current-buffer (help-buffer)
 463             (fill-region-as-paragraph pt2 (point))
 464             (unless (looking-back "\n\n")
 465               (terpri)))))
 466       ;; Note that list* etc do not get this property until
 467       ;; cl-hack-byte-compiler runs, after bytecomp is loaded.
 468       (when (and (symbolp function)
 469                  (eq (get function 'byte-compile)
 470                      'cl-byte-compile-compiler-macro))
 471         (princ "This function has a compiler macro")
 472         (let ((lib (get function 'compiler-macro-file)))
 473           (when (stringp lib)
 474             (princ (format " in `%s'" lib))
 475             (with-current-buffer standard-output
 476               (save-excursion
 477                 (re-search-backward "`\\([^`']+\\)'" nil t)
 478                 (help-xref-button 1 'help-function-cmacro function lib)))))
 479         (princ ".\n\n"))
 480       (let* ((advertised (gethash def advertised-signature-table t))
 481              (arglist (if (listp advertised)
 482                           advertised (help-function-arglist def)))
 483              (doc (documentation function))
 484              (usage (help-split-fundoc doc function)))
 485         (with-current-buffer standard-output
 486           ;; If definition is a keymap, skip arglist note.
 487           (unless (keymapp function)
 488             (if usage (setq doc (cdr usage)))
 489             (let* ((use (cond
 490                          ((and usage (not (listp advertised))) (car usage))
 491                          ((listp arglist)
 492                           (format "%S" (help-make-usage function arglist)))
 493                          ((stringp arglist) arglist)
 494                          ;; Maybe the arglist is in the docstring of a symbol
 495                          ;; this one is aliased to.
 496                          ((let ((fun real-function))
 497                             (while (and (symbolp fun)
 498                                         (setq fun (symbol-function fun))
 499                                         (not (setq usage (help-split-fundoc
 500                                                           (documentation fun)
 501                                                           function)))))
 502                             usage)
 503                           (car usage))
 504                          ((or (stringp def)
 505                               (vectorp def))
 506                           (format "\nMacro: %s" (format-kbd-macro def)))
 507                          ((and (funvecp def) (eq (aref def 0) 'curry))
 508                           ;; Describe a curried-function's function and args
 509                           (let ((slot 0))
 510                             (mapconcat (lambda (arg)
 511                                          (setq slot (1+ slot))
 512                                          (cond
 513                                           ((= slot 1) "")
 514                                           ((= slot 2)
 515                                            (format "  Function: %S" arg))
 516                                           (t
 517                                            (format "Argument %d: %S"
 518                                                    (- slot 3) arg))))
 519                                        def
 520                                        "\n")))
 521                          ((funvecp def) nil)
 522                          (t "[Missing arglist.  Please make a bug report.]")))
 523                    (high (help-highlight-arguments use doc)))
 524               (let ((fill-begin (point)))
 525                 (insert (car high) "\n")
 526                 (fill-region fill-begin (point))))
 527             (setq doc (cdr high))))
 528         (let* ((obsolete (and
 529                           ;; function might be a lambda construct.
 530                           (symbolp function)
 531                           (get function 'byte-obsolete-info)))
 532                (use (car obsolete)))
 533           (when obsolete
 534             (princ "\nThis function is obsolete")
 535             (when (nth 2 obsolete)
 536               (insert (format " since %s" (nth 2 obsolete))))
 537             (insert (cond ((stringp use) (concat ";\n" use))
 538                           (use (format ";\nuse `%s' instead." use))
 539                           (t "."))
 540                     "\n"))
 541           (insert "\n"
 542                   (or doc "Not documented.")))))))
 543
 544 \f
 545 ;; Variables
 546
 547 ;;;###autoload
 548 (defun variable-at-point (&optional any-symbol)
 549   "Return the bound variable symbol found at or before point.
 550 Return 0 if there is no such symbol.
 551 If ANY-SYMBOL is non-nil, don't insist the symbol be bound."
 552   (with-syntax-table emacs-lisp-mode-syntax-table
 553     (or (condition-case ()
 554             (save-excursion
 555               (or (not (zerop (skip-syntax-backward "_w")))
 556                   (eq (char-syntax (following-char)) ?w)
 557                   (eq (char-syntax (following-char)) ?_)
 558                   (forward-sexp -1))
 559               (skip-chars-forward "'")
 560               (let ((obj (read (current-buffer))))
 561                 (and (symbolp obj) (boundp obj) obj)))
 562           (error nil))
 563         (let* ((str (find-tag-default))
 564                (sym (if str (intern-soft str))))
 565           (if (and sym (or any-symbol (boundp sym)))
 566               sym
 567             (save-match-data
 568               (when (and str (string-match "\\`\\W*\\(.*?\\)\\W*\\'" str))
 569                 (setq sym (intern-soft (match-string 1 str)))
 570                 (and (or any-symbol (boundp sym)) sym)))))
 571         0)))
 572
 573 (defun describe-variable-custom-version-info (variable)
 574   (let ((custom-version (get variable 'custom-version))
 575         (cpv (get variable 'custom-package-version))
 576         (output nil))
 577     (if custom-version
 578         (setq output
 579               (format "This variable was introduced, or its default value was changed, in\nversion %s of Emacs.\n"
 580                       custom-version))
 581       (when cpv
 582         (let* ((package (car-safe cpv))
 583                (version (if (listp (cdr-safe cpv))
 584                             (car (cdr-safe cpv))
 585                           (cdr-safe cpv)))
 586                (pkg-versions (assq package customize-package-emacs-version-alist))
 587                (emacsv (cdr (assoc version pkg-versions))))
 588           (if (and package version)
 589               (setq output
 590                     (format (concat "This variable was introduced, or its default value was changed, in\nversion %s of the %s package"
 591                                     (if emacsv
 592                                         (format " that is part of Emacs %s" emacsv))
 593                                     ".\n")
 594                             version package))))))
 595     output))
 596
 597 ;;;###autoload
 598 (defun describe-variable (variable &optional buffer frame)
 599   "Display the full documentation of VARIABLE (a symbol).
 600 Returns the documentation as a string, also.
 601 If VARIABLE has a buffer-local value in BUFFER or FRAME
 602 \(default to the current buffer and current frame),
 603 it is displayed along with the global value."
 604   (interactive
 605    (let ((v (variable-at-point))
 606          (enable-recursive-minibuffers t)
 607          val)
 608      (setq val (completing-read (if (symbolp v)
 609                                     (format
 610                                      "Describe variable (default %s): " v)
 611                                   "Describe variable: ")
 612                                 obarray
 613                                 '(lambda (vv)
 614                                    (or (boundp vv)
 615                                        (get vv 'variable-documentation)))
 616                                 t nil nil
 617                                 (if (symbolp v) (symbol-name v))))
 618      (list (if (equal val "")
 619                v (intern val)))))
 620   (let (file-name)
 621     (unless (buffer-live-p buffer) (setq buffer (current-buffer)))
 622     (unless (frame-live-p frame) (setq frame (selected-frame)))
 623     (if (not (symbolp variable))
 624         (message "You did not specify a variable")
 625       (save-excursion
 626         (let ((valvoid (not (with-current-buffer buffer (boundp variable))))
 627               val val-start-pos locus)
 628           ;; Extract the value before setting up the output buffer,
 629           ;; in case `buffer' *is* the output buffer.
 630           (unless valvoid
 631             (with-selected-frame frame
 632               (with-current-buffer buffer
 633                 (setq val (symbol-value variable)
 634                       locus (variable-binding-locus variable)))))
 635           (help-setup-xref (list #'describe-variable variable buffer)
 636                            (called-interactively-p 'interactive))
 637           (with-help-window (help-buffer)
 638             (with-current-buffer buffer
 639               (prin1 variable)
 640               (setq file-name (find-lisp-object-file-name variable 'defvar))
 641
 642               (if file-name
 643                   (progn
 644                     (princ " is a variable defined in `")
 645                     (princ (if (eq file-name 'C-source)
 646                                "C source code"
 647                              (file-name-nondirectory file-name)))
 648                     (princ "'.\n")
 649                     (with-current-buffer standard-output
 650                       (save-excursion
 651                         (re-search-backward "`\\([^`']+\\)'" nil t)
 652                         (help-xref-button 1 'help-variable-def
 653                                           variable file-name)))
 654                     (if valvoid
 655                         (princ "It is void as a variable.")
 656                       (princ "Its ")))
 657                 (if valvoid
 658                     (princ " is void as a variable.")
 659                   (princ "'s "))))
 660             (if valvoid
 661                 nil
 662               (with-current-buffer standard-output
 663                 (setq val-start-pos (point))
 664                 (princ "value is ")
 665                 (terpri)
 666                 (let ((from (point)))
 667                   (pp val)
 668                   ;; Hyperlinks in variable's value are quite frequently
 669                   ;; inappropriate e.g C-h v <RET> features <RET>
 670                   ;; (help-xref-on-pp from (point))
 671                   (if (< (point) (+ from 20))
 672                       (delete-region (1- from) from)))))
 673             (terpri)
 674
 675             (when locus
 676               (if (bufferp locus)
 677                   (princ (format "%socal in buffer %s; "
 678                                  (if (get variable 'permanent-local)
 679                                      "Permanently l" "L")
 680                                  (buffer-name)))
 681                 (princ (format "It is a frame-local variable; ")))
 682               (if (not (default-boundp variable))
 683                   (princ "globally void")
 684                 (let ((val (default-value variable)))
 685                   (with-current-buffer standard-output
 686                     (princ "global value is ")
 687                     (terpri)
 688                     ;; Fixme: pp can take an age if you happen to
 689                     ;; ask for a very large expression.  We should
 690                     ;; probably print it raw once and check it's a
 691                     ;; sensible size before prettyprinting.  -- fx
 692                     (let ((from (point)))
 693                       (pp val)
 694                       ;; See previous comment for this function.
 695                       ;; (help-xref-on-pp from (point))
 696                       (if (< (point) (+ from 20))
 697                           (delete-region (1- from) from))))))
 698               (terpri))
 699
 700             ;; If the value is large, move it to the end.
 701             (with-current-buffer standard-output
 702               (when (> (count-lines (point-min) (point-max)) 10)
 703                 ;; Note that setting the syntax table like below
 704                 ;; makes forward-sexp move over a `'s' at the end
 705                 ;; of a symbol.
 706                 (set-syntax-table emacs-lisp-mode-syntax-table)
 707                 (goto-char val-start-pos)
 708                 ;; The line below previously read as
 709                 ;; (delete-region (point) (progn (end-of-line) (point)))
 710                 ;; which suppressed display of the buffer local value for
 711                 ;; large values.
 712                 (when (looking-at "value is") (replace-match ""))
 713                 (save-excursion
 714                   (insert "\n\nValue:")
 715                   (set (make-local-variable 'help-button-cache)
 716                        (point-marker)))
 717                 (insert "value is shown ")
 718                 (insert-button "below"
 719                                'action help-button-cache
 720                                'follow-link t
 721                                'help-echo "mouse-2, RET: show value")
 722                 (insert ".\n")))
 723             (terpri)
 724
 725             (let* ((alias (condition-case nil
 726                               (indirect-variable variable)
 727                             (error variable)))
 728                    (obsolete (get variable 'byte-obsolete-variable))
 729                    (use (car obsolete))
 730                    (safe-var (get variable 'safe-local-variable))
 731                    (doc (or (documentation-property variable 'variable-documentation)
 732                             (documentation-property alias 'variable-documentation)))
 733                    (extra-line nil))
 734               ;; Add a note for variables that have been make-var-buffer-local.
 735               (when (and (local-variable-if-set-p variable)
 736                          (or (not (local-variable-p variable))
 737                              (with-temp-buffer
 738                                (local-variable-if-set-p variable))))
 739                 (setq extra-line t)
 740                 (princ "  Automatically becomes buffer-local when set in any fashion.\n"))
 741
 742               ;; Mention if it's an alias
 743               (unless (eq alias variable)
 744                 (setq extra-line t)
 745                 (princ (format "  This variable is an alias for `%s'.\n" alias)))
 746
 747               (when obsolete
 748                 (setq extra-line t)
 749                 (princ "  This variable is obsolete")
 750                 (if (cdr obsolete) (princ (format " since %s" (cdr obsolete))))
 751                 (princ (cond ((stringp use) (concat ";\n  " use))
 752                              (use (format ";\n  use `%s' instead." (car obsolete)))
 753                              (t ".")))
 754                 (terpri))
 755
 756               (when (member (cons variable val) file-local-variables-alist)
 757                 (setq extra-line t)
 758                 (if (member (cons variable val) dir-local-variables-alist)
 759                     (let ((file (and (buffer-file-name)
 760                                      (not (file-remote-p (buffer-file-name)))
 761                                      (dir-locals-find-file (buffer-file-name)))))
 762                       (princ "  This variable is a directory local variable")
 763                       (when file
 764                         (princ (concat "\n  from the file \""
 765                                        (if (consp file)
 766                                            (car file)
 767                                          file)
 768                                        "\"")))
 769                       (princ ".\n"))
 770                   (princ "  This variable is a file local variable.\n")))
 771
 772               (when (memq variable ignored-local-variables)
 773                 (setq extra-line t)
 774                 (princ "  This variable is ignored when used as a file local \
 775 variable.\n"))
 776
 777               ;; Can be both risky and safe, eg auto-fill-function.
 778               (when (risky-local-variable-p variable)
 779                 (setq extra-line t)
 780                 (princ "  This variable is potentially risky when used as a \
 781 file local variable.\n")
 782                 (when (assq variable safe-local-variable-values)
 783                   (princ "  However, you have added it to \
 784 `safe-local-variable-values'.\n")))
 785
 786               (when safe-var
 787                 (setq extra-line t)
 788                 (princ "  This variable is safe as a file local variable ")
 789                 (princ "if its value\n  satisfies the predicate ")
 790                 (princ (if (byte-code-function-p safe-var)
 791                            "which is byte-compiled expression.\n"
 792                          (format "`%s'.\n" safe-var))))
 793
 794               (if extra-line (terpri))
 795               (princ "Documentation:\n")
 796               (with-current-buffer standard-output
 797                 (insert (or doc "Not documented as a variable."))))
 798
 799             ;; Make a link to customize if this variable can be customized.
 800             (when (custom-variable-p variable)
 801               (let ((customize-label "customize"))
 802                 (terpri)
 803                 (terpri)
 804                 (princ (concat "You can " customize-label " this variable."))
 805                 (with-current-buffer standard-output
 806                   (save-excursion
 807                     (re-search-backward
 808                      (concat "\\(" customize-label "\\)") nil t)
 809                     (help-xref-button 1 'help-customize-variable variable))))
 810               ;; Note variable's version or package version
 811               (let ((output (describe-variable-custom-version-info variable)))
 812                 (when output
 813                   (terpri)
 814                   (terpri)
 815                   (princ output))))
 816
 817             (with-current-buffer standard-output
 818               ;; Return the text we displayed.
 819               (buffer-string))))))))
 820
 821
 822 ;;;###autoload
 823 (defun describe-syntax (&optional buffer)
 824   "Describe the syntax specifications in the syntax table of BUFFER.
 825 The descriptions are inserted in a help buffer, which is then displayed.
 826 BUFFER defaults to the current buffer."
 827   (interactive)
 828   (setq buffer (or buffer (current-buffer)))
 829   (help-setup-xref (list #'describe-syntax buffer)
 830                    (called-interactively-p 'interactive))
 831   (with-help-window (help-buffer)
 832     (let ((table (with-current-buffer buffer (syntax-table))))
 833       (with-current-buffer standard-output
 834         (describe-vector table 'internal-describe-syntax-value)
 835         (while (setq table (char-table-parent table))
 836           (insert "\nThe parent syntax table is:")
 837           (describe-vector table 'internal-describe-syntax-value))))))
 838
 839 (defun help-describe-category-set (value)
 840   (insert (cond
 841            ((null value) "default")
 842            ((char-table-p value) "deeper char-table ...")
 843            (t (condition-case err
 844                   (category-set-mnemonics value)
 845                 (error "invalid"))))))
 846
 847 ;;;###autoload
 848 (defun describe-categories (&optional buffer)
 849   "Describe the category specifications in the current category table.
 850 The descriptions are inserted in a buffer, which is then displayed.
 851 If BUFFER is non-nil, then describe BUFFER's category table instead.
 852 BUFFER should be a buffer or a buffer name."
 853   (interactive)
 854   (setq buffer (or buffer (current-buffer)))
 855   (help-setup-xref (list #'describe-categories buffer)
 856                    (called-interactively-p 'interactive))
 857   (with-help-window (help-buffer)
 858     (let* ((table (with-current-buffer buffer (category-table)))
 859            (docs (char-table-extra-slot table 0)))
 860       (if (or (not (vectorp docs)) (/= (length docs) 95))
 861           (error "Invalid first extra slot in this category table\n"))
 862       (with-current-buffer standard-output
 863         (insert "Legend of category mnemonics (see the tail for the longer description)\n")
 864         (let ((pos (point)) (items 0) lines n)
 865           (dotimes (i 95)
 866             (if (aref docs i) (setq items (1+ items))))
 867           (setq lines (1+ (/ (1- items) 4)))
 868           (setq n 0)
 869           (dotimes (i 95)
 870             (let ((elt (aref docs i)))
 871               (when elt
 872                 (string-match ".*" elt)
 873                 (setq elt (match-string 0 elt))
 874                 (if (>= (length elt) 17)
 875                     (setq elt (concat (substring elt 0 14) "...")))
 876                 (if (< (point) (point-max))
 877                     (move-to-column (* 20 (/ n lines)) t))
 878                 (insert (+ i ?\s) ?: elt)
 879                 (if (< (point) (point-max))
 880                     (forward-line 1)
 881                   (insert "\n"))
 882                 (setq n (1+ n))
 883                 (if (= (% n lines) 0)
 884                     (goto-char pos))))))
 885         (goto-char (point-max))
 886         (insert "\n"
 887                 "character(s)\tcategory mnemonics\n"
 888                 "------------\t------------------")
 889         (describe-vector table 'help-describe-category-set)
 890         (insert "Legend of category mnemonics:\n")
 891         (dotimes (i 95)
 892           (let ((elt (aref docs i)))
 893             (when elt
 894               (if (string-match "\n" elt)
 895                   (setq elt (substring elt (match-end 0))))
 896               (insert (+ i ?\s) ": " elt "\n"))))
 897         (while (setq table (char-table-parent table))
 898           (insert "\nThe parent category table is:")
 899           (describe-vector table 'help-describe-category-set))))))
 900
 901 (provide 'help-fns)
 902
 903 ;; arch-tag: 9e10331c-ae81-4d13-965d-c4819aaab0b3
 904 ;;; help-fns.el ends here