lisp/ebuff-menu.el

   1 ;;; ebuff-menu.el --- electric-buffer-list mode
   2
   3 ; buggestions to mly@ai.mit.edu
   4
   5 ;; who says one can't have typeout windows in gnu emacs?
   6 ;; like ^r select buffer from its emacs lunar or tmacs libraries.
   7
   8 ;; Copyright (C) 1985, 1986 Free Software Foundation, Inc.
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 1, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  24 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  25
  26
  27 (require 'electric)
  28
  29 ;; this depends on the format of list-buffers (from src/buffer.c) and
  30 ;; on stuff in lisp/buff-menu.el
  31
  32 (defvar electric-buffer-menu-mode-map nil)
  33
  34 ;;;###autoload
  35 (defun electric-buffer-list (arg)
  36   "Pops up a buffer describing the set of Emacs buffers.
  37 Vaguely like ITS lunar select buffer; combining typeoutoid buffer
  38 listing with menuoid buffer selection.
  39
  40 If the very next character typed is a space then the buffer list
  41 window disappears.  Otherwise, one may move around in the buffer list
  42 window, marking buffers to be selected, saved or deleted.
  43
  44 To exit and select a new buffer, type a space when the cursor is on
  45 the appropriate line of the buffer-list window.  Other commands are
  46 much like those of buffer-menu-mode.
  47
  48 Calls value of `electric-buffer-menu-mode-hook' on entry if non-nil.
  49
  50 \\{electric-buffer-menu-mode-map}"
  51   (interactive "P")
  52   (let (select buffer)
  53     (save-window-excursion
  54       (save-window-excursion (list-buffers arg))
  55       (setq buffer (window-buffer (Electric-pop-up-window "*Buffer List*")))
  56       (unwind-protect
  57           (progn
  58             (set-buffer buffer)
  59             (Electric-buffer-menu-mode)
  60             (setq select
  61                   (catch 'electric-buffer-menu-select
  62                     (message "<<< Press Space to bury the buffer list >>>")
  63                     (if (= (setq unread-command-char (read-char)) ?\ )
  64                         (progn (setq unread-command-char -1)
  65                                (throw 'electric-buffer-menu-select nil)))
  66                     (let ((first (progn (goto-char (point-min))
  67                                         (forward-line 2)
  68                                         (point)))
  69                           (last (progn (goto-char (point-max))
  70                                        (forward-line -1)
  71                                        (point)))
  72                           (goal-column 0))
  73                       (goto-char first)
  74                       (Electric-command-loop 'electric-buffer-menu-select
  75                                              nil
  76                                              t
  77                                              'electric-buffer-menu-looper
  78                                              (cons first last))))))
  79         (set-buffer buffer)
  80         (Buffer-menu-mode)
  81         (bury-buffer buffer)
  82         (message "")))
  83     (if select
  84         (progn (set-buffer buffer)
  85                (let ((opoint (point-marker)))
  86                  (Buffer-menu-execute)
  87                  (goto-char (point-min))
  88                  (if (prog1 (search-forward "\n>" nil t)
  89                        (goto-char opoint) (set-marker opoint nil))
  90                      (Buffer-menu-select)
  91                      (switch-to-buffer (Buffer-menu-buffer t))))))))
  92
  93 (defun electric-buffer-menu-looper (state condition)
  94   (cond ((and condition
  95               (not (memq (car condition) '(buffer-read-only
  96                                            end-of-buffer
  97                                            beginning-of-buffer))))
  98          (signal (car condition) (cdr condition)))
  99         ((< (point) (car state))
 100          (goto-char (point-min))
 101          (forward-line 2))
 102         ((> (point) (cdr state))
 103          (goto-char (point-max))
 104          (forward-line -1)
 105          (if (pos-visible-in-window-p (point-max))
 106              (recenter -1)))))
 107
 108 (put 'Electric-buffer-menu-mode 'mode-class 'special)
 109 (defun Electric-buffer-menu-mode ()
 110   "Major mode for editing a list of buffers.
 111 Each line describes one of the buffers in Emacs.
 112 Letters do not insert themselves; instead, they are commands.
 113 \\<electric-buffer-menu-mode-map>
 114 \\[keyboard-quit] or \\[Electric-buffer-menu-quit] -- exit buffer menu, returning to previous window and buffer
 115   configuration.  If the very first character typed is a space, it
 116   also has this effect.
 117 \\[Electric-buffer-menu-select] -- select buffer of line point is on.
 118   Also show buffers marked with m in other windows,
 119   deletes buffers marked with \"D\", and saves those marked with \"S\".
 120 \\[Buffer-menu-mark] -- mark buffer to be displayed.
 121 \\[Buffer-menu-not-modified] -- clear modified-flag on that buffer.
 122 \\[Buffer-menu-save] -- mark that buffer to be saved.
 123 \\[Buffer-menu-delete] or \\[Buffer-menu-delete-backwards] -- mark that buffer to be deleted.
 124 \\[Buffer-menu-unmark] -- remove all kinds of marks from current line.
 125 \\[Electric-buffer-menu-mode-view-buffer] -- view buffer, returning when done.
 126 \\[Buffer-menu-backup-unmark] -- back up a line and remove marks.
 127
 128 \\{electric-buffer-menu-mode-map}
 129
 130 Entry to this mode via command electric-buffer-list calls the value of
 131 electric-buffer-menu-mode-hook if it is non-nil."
 132   (kill-all-local-variables)
 133   (use-local-map electric-buffer-menu-mode-map)
 134   (setq mode-name "Electric Buffer Menu")
 135   (setq mode-line-buffer-identification "Electric Buffer List")
 136   (make-local-variable 'Helper-return-blurb)
 137   (setq Helper-return-blurb "return to buffer editing")
 138   (setq truncate-lines t)
 139   (setq buffer-read-only t)
 140   (setq major-mode 'Electric-buffer-menu-mode)
 141   (goto-char (point-min))
 142   (if (search-forward "\n." nil t) (forward-char -1))
 143   (run-hooks 'electric-buffer-menu-mode-hook))
 144
 145 ;; generally the same as Buffer-menu-mode-map
 146 ;;  (except we don't indirect to global-map)
 147 (put 'Electric-buffer-menu-undefined 'suppress-keymap t)
 148 (if electric-buffer-menu-mode-map
 149     nil
 150   (let ((map (make-keymap)))
 151     (fillarray map 'Electric-buffer-menu-undefined)
 152     (define-key map "\e" (make-keymap))
 153     (fillarray (lookup-key map "\e") 'Electric-buffer-menu-undefined)
 154     (define-key map "\C-z" 'suspend-emacs)
 155     (define-key map "v" 'Electric-buffer-menu-mode-view-buffer)
 156     (define-key map "\C-h" 'Helper-help)
 157     (define-key map "?" 'Helper-describe-bindings)
 158     (define-key map "\C-c" nil)
 159     (define-key map "\C-c\C-c" 'Electric-buffer-menu-quit)
 160     (define-key map "\C-]" 'Electric-buffer-menu-quit)
 161     (define-key map "q" 'Electric-buffer-menu-quit)
 162     (define-key map " " 'Electric-buffer-menu-select)
 163     (define-key map "\C-l" 'recenter)
 164     (define-key map "s" 'Buffer-menu-save)
 165     (define-key map "d" 'Buffer-menu-delete)
 166     (define-key map "k" 'Buffer-menu-delete)
 167     (define-key map "\C-d" 'Buffer-menu-delete-backwards)
 168     ;(define-key map "\C-k" 'Buffer-menu-delete)
 169     (define-key map "\177" 'Buffer-menu-backup-unmark)
 170     (define-key map "~" 'Buffer-menu-not-modified)
 171     (define-key map "u" 'Buffer-menu-unmark)
 172     (let ((i ?0))
 173       (while (<= i ?9)
 174         (define-key map (char-to-string i) 'digit-argument)
 175         (define-key map (concat "\e" (char-to-string i)) 'digit-argument)
 176         (setq i (1+ i))))
 177     (define-key map "-" 'negative-argument)
 178     (define-key map "\e-" 'negative-argument)
 179     (define-key map "m" 'Buffer-menu-mark)
 180     (define-key map "\C-u" 'universal-argument)
 181     (define-key map "\C-p" 'previous-line)
 182     (define-key map "\C-n" 'next-line)
 183     (define-key map "p" 'previous-line)
 184     (define-key map "n" 'next-line)
 185     (define-key map "\C-v" 'scroll-up)
 186     (define-key map "\ev" 'scroll-down)
 187     (define-key map ">" 'scroll-right)
 188     (define-key map "<" 'scroll-left)
 189     (define-key map "\e\C-v" 'scroll-other-window)
 190     (define-key map "\e>" 'end-of-buffer)
 191     (define-key map "\e<" 'beginning-of-buffer)
 192     (setq electric-buffer-menu-mode-map map)))
 193
 194 (defun Electric-buffer-menu-exit ()
 195   (interactive)
 196   (setq unread-command-char last-input-char)
 197   ;; for robustness
 198   (condition-case ()
 199       (throw 'electric-buffer-menu-select nil)
 200     (error (Buffer-menu-mode)
 201            (other-buffer))))
 202
 203 (defun Electric-buffer-menu-select ()
 204   "Leave Electric Buffer Menu, selecting buffers and executing changes.
 205 Saves buffers marked \"S\".  Deletes buffers marked \"K\".
 206 Selects buffer at point and displays buffers marked \">\" in other windows."
 207   (interactive)
 208   (throw 'electric-buffer-menu-select (point)))
 209
 210 (defun Electric-buffer-menu-quit ()
 211   "Leave Electric Buffer Menu, restoring previous window configuration.
 212 Does not execute select, save, or delete commands."
 213   (interactive)
 214   (throw 'electric-buffer-menu-select nil))
 215
 216 (defun Electric-buffer-menu-undefined ()
 217   (interactive)
 218   (ding)
 219   (message (if (and (eq (key-binding "\C-c\C-c") 'Electric-buffer-menu-quit)
 220                     (eq (key-binding " ") 'Electric-buffer-menu-select)
 221                     (eq (key-binding "\C-h") 'Helper-help)
 222                     (eq (key-binding "?") 'Helper-describe-bindings))
 223                "Type C-c C-c to exit, Space to select, C-h for help, ? for commands"
 224              (substitute-command-keys "\
 225 Type \\[Electric-buffer-menu-quit] to exit, \
 226 \\[Electric-buffer-menu-select] to select, \
 227 \\[Helper-help] for help, \\[Helper-describe-bindings] for commands.")))
 228   (sit-for 4))
 229
 230 (defun Electric-buffer-menu-mode-view-buffer ()
 231   "View buffer on current line in Electric Buffer Menu.
 232 Returns to Electric Buffer Menu when done."
 233   (interactive)
 234   (let ((bufnam (Buffer-menu-buffer nil)))
 235     (if bufnam
 236         (view-buffer bufnam)
 237       (ding)
 238       (message "Buffer %s does not exist!" bufnam)
 239       (sit-for 4))))
 240
 241 ;;; ebuff-menu.el ends here