lisp/textmodes/conf-mode.el

   1 ;;; conf-mode.el --- Simple major mode for editing conf/ini/properties files
   2
   3 ;; Copyright (C) 2004 by Daniel Pfeiffer <occitan@esperanto.org>
   4 ;; Keywords: conf ini windows java
   5
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24 ;;
  25 ;; This mode is designed to edit many similar varieties of Conf/Ini files and
  26 ;; Java properties.  It started out from Aurélien Tisné's ini-mode.
  27 ;; `conf-space-keywords' were inspired by Robert Fitzgerald's any-ini-mode.
  28
  29
  30 ;;; Code:
  31
  32 (require 'newcomment)
  33
  34 ;; Variables:
  35
  36 (defgroup conf nil
  37   "Configuration files."
  38   :group 'data
  39   :version "22.1")
  40
  41 (defcustom conf-assignment-column 24
  42   "Align assignments to this column by default with \\[conf-align-assignments].
  43 If this number is negative, the `=' comes before the whitespace.  Use 0 to
  44 not align (only setting space according to `conf-assignment-space')."
  45   :type 'integer
  46   :group 'conf)
  47
  48 (defcustom conf-javaprop-assignment-column 32
  49   "Value for `conf-assignment-column' in Java properties buffers."
  50   :type 'integer
  51   :group 'conf)
  52
  53 (defcustom conf-colon-assignment-column (- (abs conf-assignment-column))
  54   "Value for `conf-assignment-column' in Java properties buffers."
  55   :type 'integer
  56   :group 'conf)
  57
  58 (defcustom conf-assignment-space t
  59   "Put at least one space around assignments when aligning."
  60   :type 'boolean
  61   :group 'conf)
  62
  63 (defcustom conf-colon-assignment-space nil
  64   "Value for `conf-assignment-space' in colon style Conf mode buffers."
  65   :type 'boolean
  66   :group 'conf)
  67
  68
  69 (defvar conf-mode-map
  70   (let ((map (make-sparse-keymap)))
  71     (define-key map "\C-c\C-u" 'conf-unix-mode)
  72     (define-key map "\C-c\C-w" 'conf-windows-mode)
  73     (define-key map "\C-c\C-j" 'conf-javaprop-mode)
  74     (define-key map "\C-c\C-s" 'conf-space-mode)
  75     (define-key map "\C-c " 'conf-space-mode)
  76     (define-key map "\C-c\C-c" 'conf-colon-mode)
  77     (define-key map "\C-c:" 'conf-colon-mode)
  78     (define-key map "\C-c\C-x" 'conf-xdefaults-mode)
  79     (define-key map "\C-c\C-p" 'conf-ppd-mode)
  80     (define-key map "\C-c\C-q" 'conf-quote-normal)
  81     (define-key map "\C-c\"" 'conf-quote-normal)
  82     (define-key map "\C-c'" 'conf-quote-normal)
  83     (define-key map "\C-c\C-a" 'conf-align-assignments)
  84     map)
  85   "Local keymap for conf-mode buffers.")
  86
  87 (defvar conf-mode-syntax-table
  88   (let ((table (make-syntax-table)))
  89     (modify-syntax-entry ?=  "." table)
  90     (modify-syntax-entry ?_  "_" table)
  91     (modify-syntax-entry ?-  "_" table)
  92     (modify-syntax-entry ?.  "_" table)
  93     (modify-syntax-entry ?\' "\"" table)
  94     (modify-syntax-entry ?\; "<" table)
  95     (modify-syntax-entry ?\n ">" table)
  96     (modify-syntax-entry ?\r ">" table)
  97     table)
  98   "Syntax table in use in Windows style conf-mode buffers.")
  99
 100 (defvar conf-unix-mode-syntax-table
 101   (let ((table (make-syntax-table conf-mode-syntax-table)))
 102     (modify-syntax-entry ?\# "<" table)
 103     ;; override
 104     (modify-syntax-entry ?\; "." table)
 105     table)
 106   "Syntax table in use in Unix style conf-mode buffers.")
 107
 108 (defvar conf-javaprop-mode-syntax-table
 109   (let ((table (make-syntax-table conf-unix-mode-syntax-table)))
 110     (modify-syntax-entry ?/  ". 124" table)
 111     (modify-syntax-entry ?*  ". 23b" table)
 112     table)
 113   "Syntax table in use in Java prperties buffers.")
 114
 115 (defvar conf-ppd-mode-syntax-table
 116   (let ((table (make-syntax-table conf-mode-syntax-table)))
 117     (modify-syntax-entry ?*  ". 1" table)
 118     (modify-syntax-entry ?%  ". 2" table)
 119     ;; override
 120     (modify-syntax-entry ?\' "." table)
 121     (modify-syntax-entry ?\; "." table)
 122     table)
 123   "Syntax table in use in PPD conf-mode buffers.")
 124
 125 (defvar conf-xdefaults-mode-syntax-table
 126   (let ((table (make-syntax-table conf-mode-syntax-table)))
 127     (modify-syntax-entry ?!  "<" table)
 128     ;; override
 129     (modify-syntax-entry ?\; "." table)
 130     table)
 131   "Syntax table in use in Xdefaults style conf-mode buffers.")
 132
 133
 134 (defvar conf-font-lock-keywords
 135   `(;; [section] (do this first because it may look like a parameter)
 136     ("^[ \t]*\\[\\(.+\\)\\]" 1 'font-lock-type-face)
 137     ;; var=val or var[index]=val
 138     ("^[ \t]*\\(.+?\\)\\(?:\\[\\(.*?\\)\\]\\)?[ \t]*="
 139      (1 'font-lock-variable-name-face)
 140      (2 'font-lock-constant-face nil t))
 141     ;; section { ... } (do this last because some assign ...{...)
 142     ("^[ \t]*\\([^=:\n]+?\\)[ \t\n]*{[^{}]*?$" 1 'font-lock-type-face prepend))
 143   "Keywords to hilight in Conf mode")
 144
 145 (defvar conf-javaprop-font-lock-keywords
 146   '(;; var=val
 147     ("^[ \t]*\\(.+?\\)\\(?:\\.\\([0-9]+\\)\\(?:\\.\\(.+?\\)\\(?:\\.\\([0-9]+\\)\\(?:\\.\\(.+?\\)\\(?:\\.\\([0-9]+\\)\\(\\..+?\\)?\\)?\\)?\\)?\\)?\\)?\\([:= \t]\\|$\\)"
 148      (1 'font-lock-variable-name-face)
 149      (2 'font-lock-constant-face nil t)
 150      (3 'font-lock-variable-name-face nil t)
 151      (4 'font-lock-constant-face nil t)
 152      (5 'font-lock-variable-name-face nil t)
 153      (6 'font-lock-constant-face nil t)
 154      (7 'font-lock-variable-name-face nil t)))
 155   "Keywords to hilight in Conf Java Properties mode")
 156
 157 (defvar conf-space-keywords-alist
 158   '(("\\`/etc/gpm/" . "key\\|name\\|foreground\\|background\\|border\\|head")
 159     ("\\`/etc/magic\\'" . "[^ \t]+[ \t]+\\(?:[bl]?e?\\(?:short\\|long\\)\\|byte\\|string\\)[^ \t]*")
 160     ("/mod\\(?:ules\\|probe\\)\\.conf" . "alias\\|in\\(?:clude\\|stall\\)\\|options\\|remove")
 161     ("/manpath\\.config" . "MAN\\(?:DATORY_MANPATH\\|PATH_MAP\\|DB_MAP\\)")
 162     ("/sensors\\.conf" . "chip\\|bus\\|label\\|compute\\|set\\|ignore")
 163     ("/sane\\(\\.d\\)?/" . "option\\|device\\|port\\|usb\\|sc\\(?:si\\|anner\\)")
 164     ("/resmgr\\.conf" . "class\\|add\\|allow\\|deny")
 165     ("/dictionary\\.lst\\'" . "DICT\\|HYPH\\|THES")
 166     ("/tuxracer/options" . "set"))
 167   "File name based settings for `conf-space-keywords'.")
 168
 169 (defvar conf-space-keywords nil
 170   "Regexps for functions that may come before a space assignment.
 171 This allows constructs such as
 172 keyword var value
 173 This variable is best set in the file local variables, or through
 174 `conf-space-keywords-alist'.")
 175
 176 (defvar conf-space-font-lock-keywords
 177   `(;; [section] (do this first because it may look like a parameter)
 178     ("^[ \t]*\\[\\(.+\\)\\]" 1 'font-lock-type-face)
 179     ;; section { ... } (do this first because it looks like a parameter)
 180     ("^[ \t]*\\(.+?\\)[ \t\n]*{[^{}]*?$" 1 'font-lock-type-face)
 181     ;; var val
 182     (eval if conf-space-keywords
 183           (list (concat "^[ \t]*\\(" conf-space-keywords "\\)[ \t]+\\([^\000- ]+\\)")
 184                 '(1 'font-lock-keyword-face)
 185                 '(2 'font-lock-variable-name-face))
 186           '("^[ \t]*\\([^\000- ]+\\)" 1 'font-lock-variable-name-face)))
 187   "Keywords to hilight in Conf Space mode")
 188
 189 (defvar conf-colon-font-lock-keywords
 190   `(;; [section] (do this first because it may look like a parameter)
 191     ("^[ \t]*\\[\\(.+\\)\\]" 1 'font-lock-type-face)
 192     ;; var: val
 193     ("^[ \t]*\\(.+?\\)[ \t]*:"
 194      (1 'font-lock-variable-name-face))
 195     ;; section { ... } (do this last because some assign ...{...)
 196     ("^[ \t]*\\([^:\n]+\\)[ \t\n]*{[^{}]*?$" 1 'font-lock-type-face prepend))
 197   "Keywords to hilight in Conf Colon mode")
 198
 199 (defvar conf-assignment-sign ?=
 200   "What sign is used for assignments.")
 201
 202 (defvar conf-assignment-regexp ".+?\\([ \t]*=[ \t]*\\)"
 203   "Regexp to recognize assignments.
 204 It is anchored after the first sexp on a line.  There must a
 205 grouping for the assignment sign, including leading and trailing
 206 whitespace.")
 207
 208
 209 ;; If anybody can figure out how to get the same effect by configuring
 210 ;; `align', I'd be glad to hear.
 211 (defun conf-align-assignments (&optional arg)
 212   (interactive "P")
 213   (setq arg (if arg
 214                 (prefix-numeric-value arg)
 215               conf-assignment-column))
 216   (save-excursion
 217     (goto-char (point-min))
 218     (while (not (eobp))
 219       (let ((cs (comment-beginning)))   ; go before comment if within
 220         (if cs (goto-char cs)))
 221       (while (forward-comment 9))       ; max-int?
 222       (when (and (not (eobp))
 223                  (looking-at conf-assignment-regexp))
 224         (goto-char (match-beginning 1))
 225         (delete-region (point) (match-end 1))
 226         (if conf-assignment-sign
 227             (if (>= arg 0)
 228                 (progn
 229                   (indent-to-column arg)
 230                   (or (not conf-assignment-space) (memq (char-before (point)) '(?  ?\t)) (insert ? ))
 231                   (insert conf-assignment-sign (if (and conf-assignment-space (not (eolp))) ?\  "")))
 232               (insert (if conf-assignment-space ?\  "") conf-assignment-sign)
 233               (unless (eolp)
 234                 (indent-to-column (- arg))
 235                 (or (not conf-assignment-space) (memq (char-before (point)) '(?  ?\t)) (insert ? ))))
 236           (unless (eolp)
 237             (if (>= (current-column) (abs arg))
 238                 (insert ? )
 239               (indent-to-column (abs arg))))))
 240       (forward-line))))
 241
 242
 243 (defun conf-quote-normal (arg)
 244   "Set the syntax of ' and \" to punctuation.
 245 With prefix arg, only do it for ' if 1, or only for \" if 2.
 246 This only affects the current buffer.  Some conf files use quotes
 247 to delimit strings, while others allow quotes as simple parts of
 248 the assigned value.  In those files font locking will be wrong,
 249 and you can correct it with this command.  (Some files even do
 250 both, i.e. quotes delimit strings, except when they are
 251 unbalanced, but hey...)"
 252   (interactive "P")
 253   (let ((table (copy-syntax-table (syntax-table))))
 254     (if (or (not arg) (= (prefix-numeric-value arg) 1)) (modify-syntax-entry ?\' "." table))
 255     (if (or (not arg) (= (prefix-numeric-value arg) 2)) (modify-syntax-entry ?\" "." table))
 256     (set-syntax-table table)
 257     (and (boundp 'font-lock-mode)
 258          font-lock-mode
 259          (font-lock-fontify-buffer))))
 260
 261
 262 (defun conf-outline-level ()
 263   (let ((depth 0)
 264         (pt (match-end 0)))
 265     (condition-case nil
 266         (while (setq pt (scan-lists pt -1 1)
 267                      depth (1+ depth)))
 268       (scan-error depth))))
 269
 270 \f
 271
 272 ;;;###autoload
 273 (defun conf-mode (&optional comment syntax-table name)
 274   "Mode for Unix and Windows Conf files and Java properties.
 275 Most conf files know only three kinds of constructs: parameter
 276 assignments optionally grouped into sections and comments.  Yet
 277 there is a great range of variation in the exact syntax of conf
 278 files.  See below for various wrapper commands that set up the
 279 details for some of the most widespread variants.
 280
 281 This mode sets up font locking, outline, imenu and it provides
 282 alignment support through `conf-align-assignments'.  If strings
 283 come out wrong, try `conf-quote-normal'.
 284
 285 Some files allow continuation lines, either with a backslash at
 286 the end of line, or by indenting the next line (further).  These
 287 constructs cannot currently be recognized.
 288
 289 Because of this great variety of nuances, which are often not
 290 even clearly specified, please don't expect it to get every file
 291 quite right.  Patches that clearly identify some special case,
 292 without breaking the general ones, are welcome.
 293
 294 If instead you start this mode with the generic `conf-mode'
 295 command, it will parse the buffer.  It will generally well
 296 identify the first four cases listed below.  If the buffer
 297 doesn't have enough contents to decide, this is identical to
 298 `conf-windows-mode' on Windows, elsewhere to `conf-unix-mode'.
 299 See also `conf-space-mode', `conf-colon-mode', `conf-javaprop-mode',
 300 `conf-ppd-mode' and `conf-xdefaults-mode'.
 301
 302 \\{conf-mode-map}"
 303
 304   (interactive)
 305   (if (not comment)
 306       (let ((unix 0) (win 0) (equal 0) (colon 0) (space 0) (jp 0))
 307         (save-excursion
 308           (goto-char (point-min))
 309           (while (not (eobp))
 310             (skip-chars-forward " \t\f")
 311             (cond ((eq (char-after) ?\#) (setq unix (1+ unix)))
 312                   ((eq (char-after) ?\;) (setq win (1+ win)))
 313                   ((eq (char-after) ?\[))       ; nop
 314                   ((eolp))                      ; nop
 315                   ((eq (char-after) ?}))        ; nop
 316                   ;; recognize at most double spaces within names
 317                   ((looking-at "[^ \t\n=:]+\\(?:  ?[^ \t\n=:]+\\)*[ \t]*[=:]")
 318                    (if (eq (char-before (match-end 0)) ?=)
 319                        (setq equal (1+ equal))
 320                      (setq colon (1+ colon))))
 321                   ((looking-at "/[/*]") (setq jp (1+ jp)))
 322                   ((looking-at ".*{"))          ; nop
 323                   ((setq space (1+ space))))
 324             (forward-line)))
 325         (if (> jp (max unix win 3))
 326             (conf-javaprop-mode)
 327           (if (> colon (max equal space))
 328               (conf-colon-mode)
 329             (if (> space (max equal colon))
 330                 (conf-space-mode)
 331               (if (or (> win unix)
 332                       (and (= win unix) (eq system-type 'windows-nt)))
 333                   (conf-windows-mode)
 334                 (conf-unix-mode))))))
 335     (kill-all-local-variables)
 336     (use-local-map conf-mode-map)
 337
 338     (setq major-mode 'conf-mode
 339           mode-name name)
 340     (set (make-local-variable 'comment-start) comment)
 341     (set (make-local-variable 'comment-start-skip)
 342          (concat (regexp-quote comment-start) "+\\s *"))
 343     (set (make-local-variable 'comment-use-syntax) t)
 344     (set (make-local-variable 'parse-sexp-ignore-comments) t)
 345     (set (make-local-variable 'outline-regexp)
 346          "[ \t]*\\(?:\\[\\|.+[ \t\n]*{\\)")
 347     (set (make-local-variable 'outline-heading-end-regexp)
 348          "[\n}]")
 349     (set (make-local-variable 'outline-level)
 350          'conf-outline-level)
 351     (set-syntax-table syntax-table)
 352     (setq imenu-generic-expression
 353           '(("Parameters" "^[ \t]*\\(.+?\\)[ \t]*=" 1)
 354             ;; [section]
 355             (nil "^[ \t]*\\[[ \t]*\\(.+\\)[ \t]*\\]" 1)
 356             ;; section { ... }
 357             (nil "^[ \t]*\\([^=:{} \t\n][^=:{}\n]+\\)[ \t\n]*{" 1)))
 358
 359     (run-mode-hooks 'conf-mode-hook)))
 360
 361 ;;;###autoload
 362 (defun conf-unix-mode ()
 363   "Conf Mode starter for Unix style Conf files.
 364 Comments start with `#'.
 365 For details see `conf-mode'.  Example:
 366
 367 # Conf mode font-locks this right on Unix and with C-c C-u
 368
 369 \[Desktop Entry]
 370          Encoding=UTF-8
 371          Name=The GIMP
 372          Name[ca]=El GIMP
 373          Name[cs]=GIMP"
 374   (interactive)
 375   (conf-mode "#" conf-unix-mode-syntax-table "Conf[Unix]"))
 376
 377 ;;;###autoload
 378 (defun conf-windows-mode ()
 379   "Conf Mode starter for Windows style Conf files.
 380 Comments start with `;'.
 381 For details see `conf-mode'.  Example:
 382
 383 ; Conf mode font-locks this right on Windows and with C-c C-w
 384
 385 \[ExtShellFolderViews]
 386 Default={5984FFE0-28D4-11CF-AE66-08002B2E1262}
 387 {5984FFE0-28D4-11CF-AE66-08002B2E1262}={5984FFE0-28D4-11CF-AE66-08002B2E1262}
 388
 389 \[{5984FFE0-28D4-11CF-AE66-08002B2E1262}]
 390 PersistMoniker=file://Folder.htt"
 391   (interactive)
 392   (conf-mode ";" conf-mode-syntax-table "Conf[WinIni]"))
 393
 394 ;; Here are a few more or less widespread styles.  There are others, so
 395 ;; obscure, they are not covered.  E.g. RFC 2614 allows both Unix and Windows
 396 ;; comments.  Or the donkey has (* Pascal comments *) -- roll your own starter
 397 ;; if you need it.
 398
 399 ;;;###autoload
 400 (defun conf-javaprop-mode ()
 401   "Conf Mode starter for Java properties files.
 402 Comments start with `#' but are also recognized with `//' or
 403 between `/*' and `*/'.
 404 For details see `conf-mode'.  Example:
 405
 406 # Conf mode font-locks this right with C-c C-j (Java properties)
 407 // another kind of comment
 408 /* yet another */
 409
 410 name:value
 411 name=value
 412 name value
 413 x.1 =
 414 x.2.y.1.z.1 =
 415 x.2.y.1.z.2.zz ="
 416   (interactive)
 417   (conf-mode "#" conf-javaprop-mode-syntax-table "Conf[JavaProp]")
 418   (set (make-local-variable 'conf-assignment-column)
 419        conf-javaprop-assignment-column)
 420   (set (make-local-variable 'conf-assignment-regexp)
 421        ".+?\\([ \t]*[=: \t][ \t]*\\|$\\)")
 422   (set (make-local-variable 'conf-font-lock-keywords)
 423        conf-javaprop-font-lock-keywords)
 424   (setq comment-start-skip "\\(?:#+\\|/[/*]+\\)\\s *")
 425   (setq imenu-generic-expression
 426         '(("Parameters" "^[ \t]*\\(.+?\\)[=: \t]" 1))))
 427
 428 ;;;###autoload
 429 (defun conf-space-mode (&optional keywords)
 430   "Conf Mode starter for space separated conf files.
 431 \"Assignments\" are with ` '.  Keywords before the parameters are
 432 recognized according to `conf-space-keywords'.  Interactively
 433 with a prefix ARG of `0' no keywords will be recognized.  With
 434 any other prefix arg you will be prompted for a regexp to match
 435 the keywords.  Programmatically you can pass such a regexp as
 436 KEYWORDS, or any non-nil non-string for no keywords.
 437
 438 For details see `conf-mode'.  Example:
 439
 440 # Conf mode font-locks this right with C-c C-s (space separated)
 441
 442 image/jpeg                      jpeg jpg jpe
 443 image/png                       png
 444 image/tiff                      tiff tif
 445
 446 # Or with keywords (from a recognized file name):
 447 class desktop
 448 # Standard multimedia devices
 449 add /dev/audio          desktop
 450 add /dev/mixer          desktop"
 451   (interactive
 452    (list (if current-prefix-arg
 453              (if (> (prefix-numeric-value current-prefix-arg) 0)
 454                  (read-string "Regexp to match keywords: ")
 455                t))))
 456   (conf-unix-mode)
 457   (setq mode-name "Conf[Space]")
 458   (set (make-local-variable 'conf-assignment-sign)
 459        nil)
 460   (set (make-local-variable 'conf-font-lock-keywords)
 461        conf-space-font-lock-keywords)
 462   ;; This doesn't seem right, but the next two depend on conf-space-keywords
 463   ;; being set, while after-change-major-mode-hook might set up imenu, needing
 464   ;; the following result:
 465   (hack-local-variables-prop-line)
 466   (hack-local-variables)
 467   (if keywords
 468       (set (make-local-variable 'conf-space-keywords)
 469            (if (stringp keywords) keywords))
 470     (or conf-space-keywords
 471         (not buffer-file-name)
 472         (set (make-local-variable 'conf-space-keywords)
 473              (assoc-default buffer-file-name conf-space-keywords-alist
 474                             'string-match))))
 475   (set (make-local-variable 'conf-assignment-regexp)
 476        (if conf-space-keywords
 477            (concat "\\(?:" conf-space-keywords "\\)[ \t]+.+?\\([ \t]+\\|$\\)")
 478          ".+?\\([ \t]+\\|$\\)"))
 479   (setq imenu-generic-expression
 480         `(,@(cdr imenu-generic-expression)
 481           ("Parameters"
 482            ,(if conf-space-keywords
 483                 (concat "^[ \t]*\\(?:" conf-space-keywords
 484                         "\\)[ \t]+\\([^ \t\n]+\\)\\(?:[ \t]\\|$\\)")
 485               "^[ \t]*\\([^ \t\n[]+\\)\\(?:[ \t]\\|$\\)")
 486            1))))
 487
 488 ;;;###autoload
 489 (defun conf-colon-mode (&optional comment syntax-table name)
 490   "Conf Mode starter for Colon files.
 491 \"Assignments\" are with `:'.
 492 For details see `conf-mode'.  Example:
 493
 494 # Conf mode font-locks this right with C-c C-c (colon)
 495
 496 <Multi_key> <exclam> <exclam>           : \"\\241\"     exclamdown
 497 <Multi_key> <c> <slash>                 : \"\\242\"     cent"
 498   (interactive)
 499   (if comment
 500       (conf-mode comment syntax-table name)
 501     (conf-unix-mode)
 502     (setq mode-name "Conf[Colon]"))
 503   (set (make-local-variable 'conf-assignment-space)
 504        conf-colon-assignment-space)
 505   (set (make-local-variable 'conf-assignment-column)
 506        conf-colon-assignment-column)
 507   (set (make-local-variable 'conf-assignment-sign)
 508        ?:)
 509   (set (make-local-variable 'conf-assignment-regexp)
 510        ".+?\\([ \t]*:[ \t]*\\)")
 511   (set (make-local-variable 'conf-font-lock-keywords)
 512        conf-colon-font-lock-keywords)
 513   (setq imenu-generic-expression
 514         `(("Parameters" "^[ \t]*\\(.+?\\)[ \t]*:" 1)
 515           ,@(cdr imenu-generic-expression))))
 516
 517 ;;;###autoload
 518 (defun conf-ppd-mode ()
 519   "Conf Mode starter for Adobe/CUPS PPD files.
 520 Comments start with `*%' and \"assignments\" are with `:'.
 521 For details see `conf-mode'.  Example:
 522
 523 *% Conf mode font-locks this right with C-c C-p (PPD)
 524
 525 *DefaultTransfer: Null
 526 *Transfer Null.Inverse: \"{ 1 exch sub }\""
 527   (interactive)
 528   (conf-colon-mode "*%" conf-ppd-mode-syntax-table "Conf[PPD]")
 529   ;; no sections, they match within PostScript code
 530   (setq imenu-generic-expression (list (car imenu-generic-expression))))
 531
 532 ;;;###autoload
 533 (defun conf-xdefaults-mode ()
 534   "Conf Mode starter for Xdefaults files.
 535 Comments start with `!' and \"assignments\" are with `:'.
 536 For details see `conf-mode'.  Example:
 537
 538 ! Conf mode font-locks this right with C-c C-x (.Xdefaults)
 539
 540 *background:                    gray99
 541 *foreground:                    black"
 542   (interactive)
 543   (conf-colon-mode "!" conf-xdefaults-mode-syntax-table "Conf[Xdefaults]"))
 544
 545
 546 ;; font lock support
 547 (if (boundp 'font-lock-defaults-alist)
 548     (add-to-list
 549      'font-lock-defaults-alist
 550      (cons 'conf-mode
 551            (list 'conf-font-lock-keywords nil t nil nil))))
 552
 553
 554 (provide 'conf-mode)
 555
 556 ;; arch-tag: 0a3805b2-0371-4d3a-8498-8897116b2356
 557 ;;; conf-mode.el ends here