lisp/help-fns.el

   1 ;;; help-fns.el --- Complex help functions
   2
   3 ;; Copyright (C) 1985, 1986, 1993, 1994, 1998, 1999, 2000, 2001, 2002,
   4 ;;   2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010
   5 ;;   Free Software Foundation, Inc.
   6
   7 ;; Maintainer: FSF
   8 ;; Keywords: help, internal
   9 ;; Package: emacs
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; This file contains those help commands which are complicated, and
  29 ;; which may not be used in every session.  For example
  30 ;; `describe-function' will probably be heavily used when doing elisp
  31 ;; programming, but not if just editing C files.  Simpler help commands
  32 ;; are in help.el
  33
  34 ;;; Code:
  35
  36 ;; Functions
  37
  38 ;;;###autoload
  39 (defun describe-function (function)
  40   "Display the full documentation of FUNCTION (a symbol)."
  41   (interactive
  42    (let ((fn (function-called-at-point))
  43          (enable-recursive-minibuffers t)
  44          val)
  45      (setq val (completing-read (if fn
  46                                     (format "Describe function (default %s): " fn)
  47                                   "Describe function: ")
  48                                 obarray 'fboundp t nil nil
  49                                 (and fn (symbol-name fn))))
  50      (list (if (equal val "")
  51                fn (intern val)))))
  52   (if (null function)
  53       (message "You didn't specify a function")
  54     (help-setup-xref (list #'describe-function function)
  55                      (called-interactively-p 'interactive))
  56     (save-excursion
  57       (with-help-window (help-buffer)
  58         (prin1 function)
  59         ;; Use " is " instead of a colon so that
  60         ;; it is easier to get out the function name using forward-sexp.
  61         (princ " is ")
  62         (describe-function-1 function)
  63         (with-current-buffer standard-output
  64           ;; Return the text we displayed.
  65           (buffer-string))))))
  66
  67 (defun help-split-fundoc (docstring def)
  68   "Split a function DOCSTRING into the actual doc and the usage info.
  69 Return (USAGE . DOC) or nil if there's no usage info.
  70 DEF is the function whose usage we're looking for in DOCSTRING."
  71   ;; Functions can get the calling sequence at the end of the doc string.
  72   ;; In cases where `function' has been fset to a subr we can't search for
  73   ;; function's name in the doc string so we use `fn' as the anonymous
  74   ;; function name instead.
  75   (when (and docstring (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring))
  76     (cons (format "(%s%s"
  77                   ;; Replace `fn' with the actual function name.
  78                   (if (consp def) "anonymous" def)
  79                   (match-string 1 docstring))
  80           (substring docstring 0 (match-beginning 0)))))
  81
  82 (defun help-add-fundoc-usage (docstring arglist)
  83   "Add the usage info to DOCSTRING.
  84 If DOCSTRING already has a usage info, then just return it unchanged.
  85 The usage info is built from ARGLIST.  DOCSTRING can be nil.
  86 ARGLIST can also be t or a string of the form \"(FUN ARG1 ARG2 ...)\"."
  87   (unless (stringp docstring) (setq docstring "Not documented"))
  88   (if (or (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring) (eq arglist t))
  89       docstring
  90     (concat docstring
  91             (if (string-match "\n?\n\\'" docstring)
  92                 (if (< (- (match-end 0) (match-beginning 0)) 2) "\n" "")
  93               "\n\n")
  94             (if (and (stringp arglist)
  95                      (string-match "\\`([^ ]+\\(.*\\))\\'" arglist))
  96                 (concat "(fn" (match-string 1 arglist) ")")
  97               (format "%S" (help-make-usage 'fn arglist))))))
  98
  99 (defun help-function-arglist (def)
 100   ;; Handle symbols aliased to other symbols.
 101   (if (and (symbolp def) (fboundp def)) (setq def (indirect-function def)))
 102   ;; If definition is a macro, find the function inside it.
 103   (if (eq (car-safe def) 'macro) (setq def (cdr def)))
 104   (cond
 105    ((byte-code-function-p def) (aref def 0))
 106    ((eq (car-safe def) 'lambda) (nth 1 def))
 107    ((and (eq (car-safe def) 'autoload) (not (eq (nth 4 def) 'keymap)))
 108     "[Arg list not available until function definition is loaded.]")
 109    (t t)))
 110
 111 (defun help-make-usage (function arglist)
 112   (cons (if (symbolp function) function 'anonymous)
 113         (mapcar (lambda (arg)
 114                   (if (not (symbolp arg))
 115                       (if (and (consp arg) (symbolp (car arg)))
 116                           ;; CL style default values for optional args.
 117                           (cons (intern (upcase (symbol-name (car arg))))
 118                                 (cdr arg))
 119                         arg)
 120                     (let ((name (symbol-name arg)))
 121                       (if (string-match "\\`&" name) arg
 122                         (intern (upcase name))))))
 123                 arglist)))
 124
 125 ;; Could be this, if we make symbol-file do the work below.
 126 ;; (defun help-C-file-name (subr-or-var kind)
 127 ;;   "Return the name of the C file where SUBR-OR-VAR is defined.
 128 ;; KIND should be `var' for a variable or `subr' for a subroutine."
 129 ;;   (symbol-file (if (symbolp subr-or-var) subr-or-var
 130 ;;               (subr-name subr-or-var))
 131 ;;             (if (eq kind 'var) 'defvar 'defun)))
 132 ;;;###autoload
 133 (defun help-C-file-name (subr-or-var kind)
 134   "Return the name of the C file where SUBR-OR-VAR is defined.
 135 KIND should be `var' for a variable or `subr' for a subroutine."
 136   (let ((docbuf (get-buffer-create " *DOC*"))
 137         (name (if (eq 'var kind)
 138                   (concat "V" (symbol-name subr-or-var))
 139                 (concat "F" (subr-name subr-or-var)))))
 140     (with-current-buffer docbuf
 141       (goto-char (point-min))
 142       (if (eobp)
 143           (insert-file-contents-literally
 144            (expand-file-name internal-doc-file-name doc-directory)))
 145       (let ((file (catch 'loop
 146                     (while t
 147                       (let ((pnt (search-forward (concat "\x1f" name "\n"))))
 148                         (re-search-backward "\x1fS\\(.*\\)")
 149                         (let ((file (match-string 1)))
 150                           (if (member file build-files)
 151                               (throw 'loop file)
 152                             (goto-char pnt))))))))
 153         (if (string-match "^ns.*\\(\\.o\\|obj\\)\\'" file)
 154             (setq file (replace-match ".m" t t file 1))
 155           (if (string-match "\\.\\(o\\|obj\\)\\'" file)
 156               (setq file (replace-match ".c" t t file))))
 157         (if (string-match "\\.\\(c\\|m\\)\\'" file)
 158             (concat "src/" file)
 159           file)))))
 160
 161 (defcustom help-downcase-arguments nil
 162   "If non-nil, argument names in *Help* buffers are downcased."
 163   :type 'boolean
 164   :group 'help
 165   :version "23.2")
 166
 167 (defun help-highlight-arg (arg)
 168   "Highlight ARG as an argument name for a *Help* buffer.
 169 Return ARG in face `help-argument-name'; ARG is also downcased
 170 if the variable `help-downcase-arguments' is non-nil."
 171   (propertize (if help-downcase-arguments (downcase arg) arg)
 172               'face 'help-argument-name))
 173
 174 (defun help-do-arg-highlight (doc args)
 175   (with-syntax-table (make-syntax-table emacs-lisp-mode-syntax-table)
 176     (modify-syntax-entry ?\- "w")
 177     (dolist (arg args doc)
 178       (setq doc (replace-regexp-in-string
 179                  ;; This is heuristic, but covers all common cases
 180                  ;; except ARG1-ARG2
 181                  (concat "\\<"                   ; beginning of word
 182                          "\\(?:[a-z-]*-\\)?"     ; for xxx-ARG
 183                          "\\("
 184                          (regexp-quote arg)
 185                          "\\)"
 186                          "\\(?:es\\|s\\|th\\)?"  ; for ARGth, ARGs
 187                          "\\(?:-[a-z0-9-]+\\)?"  ; for ARG-xxx, ARG-n
 188                          "\\(?:-[{([<`\"].*?\\)?"; for ARG-{x}, (x), <x>, [x], `x'
 189                          "\\>")                  ; end of word
 190                  (help-highlight-arg arg)
 191                  doc t t 1)))))
 192
 193 (defun help-highlight-arguments (usage doc &rest args)
 194   (when usage
 195     (with-temp-buffer
 196       (insert usage)
 197       (goto-char (point-min))
 198       (let ((case-fold-search nil)
 199             (next (not (or args (looking-at "\\["))))
 200             (opt nil))
 201         ;; Make a list of all arguments
 202         (skip-chars-forward "^ ")
 203         (while next
 204           (or opt (not (looking-at " &")) (setq opt t))
 205           (if (not (re-search-forward " \\([\\[(]*\\)\\([^] &)\.]+\\)" nil t))
 206               (setq next nil)
 207             (setq args (cons (match-string 2) args))
 208             (when (and opt (string= (match-string 1) "("))
 209               ;; A pesky CL-style optional argument with default value,
 210               ;; so let's skip over it
 211               (search-backward "(")
 212               (goto-char (scan-sexps (point) 1)))))
 213         ;; Highlight aguments in the USAGE string
 214         (setq usage (help-do-arg-highlight (buffer-string) args))
 215         ;; Highlight arguments in the DOC string
 216         (setq doc (and doc (help-do-arg-highlight doc args))))))
 217   ;; Return value is like the one from help-split-fundoc, but highlighted
 218   (cons usage doc))
 219
 220 ;; The following function was compiled from the former functions
 221 ;; `describe-simplify-lib-file-name' and `find-source-lisp-file' with
 222 ;; some excerpts from `describe-function-1' and `describe-variable'.
 223 ;; The only additional twists provided are (1) locate the defining file
 224 ;; for autoloaded functions, and (2) give preference to files in the
 225 ;; "install directory" (directories found via `load-path') rather than
 226 ;; to files in the "compile directory" (directories found by searching
 227 ;; the loaddefs.el file).  We autoload it because it's also used by
 228 ;; `describe-face' (instead of `describe-simplify-lib-file-name').
 229
 230 ;;;###autoload
 231 (defun find-lisp-object-file-name (object type)
 232   "Guess the file that defined the Lisp object OBJECT, of type TYPE.
 233 OBJECT should be a symbol associated with a function, variable, or face;
 234   alternatively, it can be a function definition.
 235 If TYPE is `defvar', search for a variable definition.
 236 If TYPE is `defface', search for a face definition.
 237 If TYPE is the value returned by `symbol-function' for a function symbol,
 238  search for a function definition.
 239
 240 The return value is the absolute name of a readable file where OBJECT is
 241 defined.  If several such files exist, preference is given to a file
 242 found via `load-path'.  The return value can also be `C-source', which
 243 means that OBJECT is a function or variable defined in C.  If no
 244 suitable file is found, return nil."
 245   (let* ((autoloaded (eq (car-safe type) 'autoload))
 246          (file-name (or (and autoloaded (nth 1 type))
 247                         (symbol-file
 248                          object (if (memq type (list 'defvar 'defface))
 249                                     type
 250                                   'defun)))))
 251     (cond
 252      (autoloaded
 253       ;; An autoloaded function: Locate the file since `symbol-function'
 254       ;; has only returned a bare string here.
 255       (setq file-name
 256             (locate-file file-name load-path '(".el" ".elc") 'readable)))
 257      ((and (stringp file-name)
 258            (string-match "[.]*loaddefs.el\\'" file-name))
 259       ;; An autoloaded variable or face.  Visit loaddefs.el in a buffer
 260       ;; and try to extract the defining file.  The following form is
 261       ;; from `describe-function-1' and `describe-variable'.
 262       (let ((location
 263              (condition-case nil
 264                  (find-function-search-for-symbol object nil file-name)
 265                (error nil))))
 266         (when (cdr location)
 267           (with-current-buffer (car location)
 268             (goto-char (cdr location))
 269             (when (re-search-backward
 270                    "^;;; Generated autoloads from \\(.*\\)" nil t)
 271               (setq file-name
 272                     (locate-file
 273                      (file-name-sans-extension
 274                       (match-string-no-properties 1))
 275                      load-path '(".el" ".elc") 'readable))))))))
 276
 277     (cond
 278      ((and (not file-name) (subrp type))
 279       ;; A built-in function.  The form is from `describe-function-1'.
 280       (if (get-buffer " *DOC*")
 281           (help-C-file-name type 'subr)
 282         'C-source))
 283      ((and (not file-name) (symbolp object)
 284            (integerp (get object 'variable-documentation)))
 285       ;; A variable defined in C.  The form is from `describe-variable'.
 286       (if (get-buffer " *DOC*")
 287           (help-C-file-name object 'var)
 288         'C-source))
 289      ((not (stringp file-name))
 290       ;; If we don't have a file-name string by now, we lost.
 291       nil)
 292      ((let ((lib-name
 293              (if (string-match "[.]elc\\'" file-name)
 294                  (substring-no-properties file-name 0 -1)
 295                file-name)))
 296         ;; When the Elisp source file can be found in the install
 297         ;; directory return the name of that file - `file-name' should
 298         ;; have become an absolute file name ny now.
 299         (or (and (file-readable-p lib-name) lib-name)
 300             ;; The library might be compressed.
 301             (and (file-readable-p (concat lib-name ".gz")) lib-name))))
 302      ((let* ((lib-name (file-name-nondirectory file-name))
 303              ;; The next form is from `describe-simplify-lib-file-name'.
 304              (file-name
 305               ;; Try converting the absolute file name to a library
 306               ;; name, convert that back to a file name and see if we
 307               ;; get the original one.  If so, they are equivalent.
 308               (if (equal file-name (locate-file lib-name load-path '("")))
 309                   (if (string-match "[.]elc\\'" lib-name)
 310                       (substring-no-properties lib-name 0 -1)
 311                     lib-name)
 312                 file-name))
 313              ;; The next three forms are from `find-source-lisp-file'.
 314              (elc-file (locate-file
 315                         (concat file-name
 316                                 (if (string-match "\\.el\\'" file-name)
 317                                     "c"
 318                                   ".elc"))
 319                         load-path nil 'readable))
 320              (str (when elc-file
 321                     (with-temp-buffer
 322                       (insert-file-contents-literally elc-file nil 0 256)
 323                       (buffer-string))))
 324              (src-file (and str
 325                             (string-match ";;; from file \\(.*\\.el\\)" str)
 326                             (match-string 1 str))))
 327         (and src-file (file-readable-p src-file) src-file))))))
 328
 329 (declare-function ad-get-advice-info "advice" (function))
 330
 331 ;;;###autoload
 332 (defun describe-function-1 (function)
 333   (let* ((advised (and (symbolp function) (featurep 'advice)
 334                        (ad-get-advice-info function)))
 335          ;; If the function is advised, use the symbol that has the
 336          ;; real definition, if that symbol is already set up.
 337          (real-function
 338           (or (and advised
 339                    (let ((origname (cdr (assq 'origname advised))))
 340                      (and (fboundp origname) origname)))
 341               function))
 342          ;; Get the real definition.
 343          (def (if (symbolp real-function)
 344                   (symbol-function real-function)
 345                 function))
 346          file-name string
 347          (beg (if (commandp def) "an interactive " "a "))
 348          (pt1 (with-current-buffer (help-buffer) (point)))
 349          errtype)
 350     (setq string
 351           (cond ((or (stringp def)
 352                      (vectorp def))
 353                  "a keyboard macro")
 354                 ((subrp def)
 355                  (if (eq 'unevalled (cdr (subr-arity def)))
 356                      (concat beg "special form")
 357                    (concat beg "built-in function")))
 358                 ((byte-code-function-p def)
 359                  (concat beg "compiled Lisp function"))
 360                 ((symbolp def)
 361                  (while (and (fboundp def)
 362                              (symbolp (symbol-function def)))
 363                    (setq def (symbol-function def)))
 364                  ;; Handle (defalias 'foo 'bar), where bar is undefined.
 365                  (or (fboundp def) (setq errtype 'alias))
 366                  (format "an alias for `%s'" def))
 367                 ((eq (car-safe def) 'lambda)
 368                  (concat beg "Lisp function"))
 369                 ((eq (car-safe def) 'macro)
 370                  "a Lisp macro")
 371                 ((eq (car-safe def) 'autoload)
 372                  (format "%s autoloaded %s"
 373                          (if (commandp def) "an interactive" "an")
 374                          (if (eq (nth 4 def) 'keymap) "keymap"
 375                            (if (nth 4 def) "Lisp macro" "Lisp function"))))
 376                 ((keymapp def)
 377                  (let ((is-full nil)
 378                        (elts (cdr-safe def)))
 379                    (while elts
 380                      (if (char-table-p (car-safe elts))
 381                          (setq is-full t
 382                                elts nil))
 383                      (setq elts (cdr-safe elts)))
 384                    (if is-full
 385                        "a full keymap"
 386                      "a sparse keymap")))
 387                 (t "")))
 388     (princ string)
 389     (if (eq errtype 'alias)
 390         (princ ",\nwhich is not defined.  Please make a bug report.")
 391       (with-current-buffer standard-output
 392         (save-excursion
 393           (save-match-data
 394             (when (re-search-backward "alias for `\\([^`']+\\)'" nil t)
 395               (help-xref-button 1 'help-function def)))))
 396
 397       (setq file-name (find-lisp-object-file-name function def))
 398       (when file-name
 399         (princ " in `")
 400         ;; We used to add .el to the file name,
 401         ;; but that's completely wrong when the user used load-file.
 402         (princ (if (eq file-name 'C-source)
 403                    "C source code"
 404                  (file-name-nondirectory file-name)))
 405         (princ "'")
 406         ;; Make a hyperlink to the library.
 407         (with-current-buffer standard-output
 408           (save-excursion
 409             (re-search-backward "`\\([^`']+\\)'" nil t)
 410             (help-xref-button 1 'help-function-def function file-name))))
 411       (princ ".")
 412       (with-current-buffer (help-buffer)
 413         (fill-region-as-paragraph (save-excursion (goto-char pt1) (forward-line 0) (point))
 414                                   (point)))
 415       (terpri)(terpri)
 416       (when (commandp function)
 417         (let ((pt2 (with-current-buffer (help-buffer) (point)))
 418               (remapped (command-remapping function)))
 419           (unless (memq remapped '(ignore undefined))
 420             (let ((keys (where-is-internal
 421                          (or remapped function) overriding-local-map nil nil))
 422                   non-modified-keys)
 423               (if (and (eq function 'self-insert-command)
 424                        (vectorp (car-safe keys))
 425                        (consp (aref (car keys) 0)))
 426                   (princ "It is bound to many ordinary text characters.\n")
 427                 ;; Which non-control non-meta keys run this command?
 428                 (dolist (key keys)
 429                   (if (member (event-modifiers (aref key 0)) '(nil (shift)))
 430                       (push key non-modified-keys)))
 431                 (when remapped
 432                   (princ "It is remapped to `")
 433                   (princ (symbol-name remapped))
 434                   (princ "'"))
 435
 436                 (when keys
 437                   (princ (if remapped ", which is bound to " "It is bound to "))
 438                   ;; If lots of ordinary text characters run this command,
 439                   ;; don't mention them one by one.
 440                   (if (< (length non-modified-keys) 10)
 441                       (princ (mapconcat 'key-description keys ", "))
 442                     (dolist (key non-modified-keys)
 443                       (setq keys (delq key keys)))
 444                     (if keys
 445                         (progn
 446                           (princ (mapconcat 'key-description keys ", "))
 447                           (princ ", and many ordinary text characters"))
 448                       (princ "many ordinary text characters"))))
 449                 (when (or remapped keys non-modified-keys)
 450                   (princ ".")
 451                   (terpri)))))
 452
 453           (with-current-buffer (help-buffer)
 454             (fill-region-as-paragraph pt2 (point))
 455             (unless (looking-back "\n\n")
 456               (terpri)))))
 457       ;; Note that list* etc do not get this property until
 458       ;; cl-hack-byte-compiler runs, after bytecomp is loaded.
 459       (when (and (symbolp function)
 460                  (eq (get function 'byte-compile)
 461                      'cl-byte-compile-compiler-macro))
 462         (princ "This function has a compiler macro")
 463         (let ((lib (get function 'compiler-macro-file)))
 464           (when (stringp lib)
 465             (princ (format " in `%s'" lib))
 466             (with-current-buffer standard-output
 467               (save-excursion
 468                 (re-search-backward "`\\([^`']+\\)'" nil t)
 469                 (help-xref-button 1 'help-function-cmacro function lib)))))
 470         (princ ".\n\n"))
 471       (let* ((advertised (gethash def advertised-signature-table t))
 472              (arglist (if (listp advertised)
 473                           advertised (help-function-arglist def)))
 474              (doc (documentation function))
 475              (usage (help-split-fundoc doc function)))
 476         (with-current-buffer standard-output
 477           ;; If definition is a keymap, skip arglist note.
 478           (unless (keymapp function)
 479             (if usage (setq doc (cdr usage)))
 480             (let* ((use (cond
 481                          ((and usage (not (listp advertised))) (car usage))
 482                          ((listp arglist)
 483                           (format "%S" (help-make-usage function arglist)))
 484                          ((stringp arglist) arglist)
 485                          ;; Maybe the arglist is in the docstring of a symbol
 486                          ;; this one is aliased to.
 487                          ((let ((fun real-function))
 488                             (while (and (symbolp fun)
 489                                         (setq fun (symbol-function fun))
 490                                         (not (setq usage (help-split-fundoc
 491                                                           (documentation fun)
 492                                                           function)))))
 493                             usage)
 494                           (car usage))
 495                          ((or (stringp def)
 496                               (vectorp def))
 497                           (format "\nMacro: %s" (format-kbd-macro def)))
 498                          (t "[Missing arglist.  Please make a bug report.]")))
 499                    (high (help-highlight-arguments use doc)))
 500               (let ((fill-begin (point)))
 501                 (insert (car high) "\n")
 502                 (fill-region fill-begin (point)))
 503               (setq doc (cdr high))))
 504           (let* ((obsolete (and
 505                             ;; function might be a lambda construct.
 506                             (symbolp function)
 507                             (get function 'byte-obsolete-info)))
 508                  (use (car obsolete)))
 509             (when obsolete
 510               (princ "\nThis function is obsolete")
 511               (when (nth 2 obsolete)
 512                 (insert (format " since %s" (nth 2 obsolete))))
 513               (insert (cond ((stringp use) (concat ";\n" use))
 514                             (use (format ";\nuse `%s' instead." use))
 515                             (t "."))
 516                       "\n"))
 517             (insert "\n"
 518                     (or doc "Not documented."))))))))
 519
 520 \f
 521 ;; Variables
 522
 523 ;;;###autoload
 524 (defun variable-at-point (&optional any-symbol)
 525   "Return the bound variable symbol found at or before point.
 526 Return 0 if there is no such symbol.
 527 If ANY-SYMBOL is non-nil, don't insist the symbol be bound."
 528   (with-syntax-table emacs-lisp-mode-syntax-table
 529     (or (condition-case ()
 530             (save-excursion
 531               (or (not (zerop (skip-syntax-backward "_w")))
 532                   (eq (char-syntax (following-char)) ?w)
 533                   (eq (char-syntax (following-char)) ?_)
 534                   (forward-sexp -1))
 535               (skip-chars-forward "'")
 536               (let ((obj (read (current-buffer))))
 537                 (and (symbolp obj) (boundp obj) obj)))
 538           (error nil))
 539         (let* ((str (find-tag-default))
 540                (sym (if str (intern-soft str))))
 541           (if (and sym (or any-symbol (boundp sym)))
 542               sym
 543             (save-match-data
 544               (when (and str (string-match "\\`\\W*\\(.*?\\)\\W*\\'" str))
 545                 (setq sym (intern-soft (match-string 1 str)))
 546                 (and (or any-symbol (boundp sym)) sym)))))
 547         0)))
 548
 549 (defun describe-variable-custom-version-info (variable)
 550   (let ((custom-version (get variable 'custom-version))
 551         (cpv (get variable 'custom-package-version))
 552         (output nil))
 553     (if custom-version
 554         (setq output
 555               (format "This variable was introduced, or its default value was changed, in\nversion %s of Emacs.\n"
 556                       custom-version))
 557       (when cpv
 558         (let* ((package (car-safe cpv))
 559                (version (if (listp (cdr-safe cpv))
 560                             (car (cdr-safe cpv))
 561                           (cdr-safe cpv)))
 562                (pkg-versions (assq package customize-package-emacs-version-alist))
 563                (emacsv (cdr (assoc version pkg-versions))))
 564           (if (and package version)
 565               (setq output
 566                     (format (concat "This variable was introduced, or its default value was changed, in\nversion %s of the %s package"
 567                                     (if emacsv
 568                                         (format " that is part of Emacs %s" emacsv))
 569                                     ".\n")
 570                             version package))))))
 571     output))
 572
 573 ;;;###autoload
 574 (defun describe-variable (variable &optional buffer frame)
 575   "Display the full documentation of VARIABLE (a symbol).
 576 Returns the documentation as a string, also.
 577 If VARIABLE has a buffer-local value in BUFFER or FRAME
 578 \(default to the current buffer and current frame),
 579 it is displayed along with the global value."
 580   (interactive
 581    (let ((v (variable-at-point))
 582          (enable-recursive-minibuffers t)
 583          val)
 584      (setq val (completing-read (if (symbolp v)
 585                                     (format
 586                                      "Describe variable (default %s): " v)
 587                                   "Describe variable: ")
 588                                 obarray
 589                                 '(lambda (vv)
 590                                    (or (boundp vv)
 591                                        (get vv 'variable-documentation)))
 592                                 t nil nil
 593                                 (if (symbolp v) (symbol-name v))))
 594      (list (if (equal val "")
 595                v (intern val)))))
 596   (let (file-name)
 597     (unless (buffer-live-p buffer) (setq buffer (current-buffer)))
 598     (unless (frame-live-p frame) (setq frame (selected-frame)))
 599     (if (not (symbolp variable))
 600         (message "You did not specify a variable")
 601       (save-excursion
 602         (let ((valvoid (not (with-current-buffer buffer (boundp variable))))
 603               val val-start-pos locus)
 604           ;; Extract the value before setting up the output buffer,
 605           ;; in case `buffer' *is* the output buffer.
 606           (unless valvoid
 607             (with-selected-frame frame
 608               (with-current-buffer buffer
 609                 (setq val (symbol-value variable)
 610                       locus (variable-binding-locus variable)))))
 611           (help-setup-xref (list #'describe-variable variable buffer)
 612                            (called-interactively-p 'interactive))
 613           (with-help-window (help-buffer)
 614             (with-current-buffer buffer
 615               (prin1 variable)
 616               (setq file-name (find-lisp-object-file-name variable 'defvar))
 617
 618               (if file-name
 619                   (progn
 620                     (princ " is a variable defined in `")
 621                     (princ (if (eq file-name 'C-source)
 622                                "C source code"
 623                              (file-name-nondirectory file-name)))
 624                     (princ "'.\n")
 625                     (with-current-buffer standard-output
 626                       (save-excursion
 627                         (re-search-backward "`\\([^`']+\\)'" nil t)
 628                         (help-xref-button 1 'help-variable-def
 629                                           variable file-name)))
 630                     (if valvoid
 631                         (princ "It is void as a variable.")
 632                       (princ "Its ")))
 633                 (if valvoid
 634                     (princ " is void as a variable.")
 635                   (princ "'s "))))
 636             (if valvoid
 637                 nil
 638               (with-current-buffer standard-output
 639                 (setq val-start-pos (point))
 640                 (princ "value is ")
 641                 (terpri)
 642                 (let ((from (point)))
 643                   (pp val)
 644                   ;; Hyperlinks in variable's value are quite frequently
 645                   ;; inappropriate e.g C-h v <RET> features <RET>
 646                   ;; (help-xref-on-pp from (point))
 647                   (if (< (point) (+ from 20))
 648                       (delete-region (1- from) from)))))
 649             (terpri)
 650
 651             (when locus
 652               (if (bufferp locus)
 653                   (princ (format "%socal in buffer %s; "
 654                                  (if (get variable 'permanent-local)
 655                                      "Permanently l" "L")
 656                                  (buffer-name)))
 657                 (princ (format "It is a frame-local variable; ")))
 658               (if (not (default-boundp variable))
 659                   (princ "globally void")
 660                 (let ((val (default-value variable)))
 661                   (with-current-buffer standard-output
 662                     (princ "global value is ")
 663                     (terpri)
 664                     ;; Fixme: pp can take an age if you happen to
 665                     ;; ask for a very large expression.  We should
 666                     ;; probably print it raw once and check it's a
 667                     ;; sensible size before prettyprinting.  -- fx
 668                     (let ((from (point)))
 669                       (pp val)
 670                       ;; See previous comment for this function.
 671                       ;; (help-xref-on-pp from (point))
 672                       (if (< (point) (+ from 20))
 673                           (delete-region (1- from) from))))))
 674               (terpri))
 675
 676             ;; If the value is large, move it to the end.
 677             (with-current-buffer standard-output
 678               (when (> (count-lines (point-min) (point-max)) 10)
 679                 ;; Note that setting the syntax table like below
 680                 ;; makes forward-sexp move over a `'s' at the end
 681                 ;; of a symbol.
 682                 (set-syntax-table emacs-lisp-mode-syntax-table)
 683                 (goto-char val-start-pos)
 684                 ;; The line below previously read as
 685                 ;; (delete-region (point) (progn (end-of-line) (point)))
 686                 ;; which suppressed display of the buffer local value for
 687                 ;; large values.
 688                 (when (looking-at "value is") (replace-match ""))
 689                 (save-excursion
 690                   (insert "\n\nValue:")
 691                   (set (make-local-variable 'help-button-cache)
 692                        (point-marker)))
 693                 (insert "value is shown ")
 694                 (insert-button "below"
 695                                'action help-button-cache
 696                                'follow-link t
 697                                'help-echo "mouse-2, RET: show value")
 698                 (insert ".\n")))
 699             (terpri)
 700
 701             (let* ((alias (condition-case nil
 702                               (indirect-variable variable)
 703                             (error variable)))
 704                    (obsolete (get variable 'byte-obsolete-variable))
 705                    (use (car obsolete))
 706                    (safe-var (get variable 'safe-local-variable))
 707                    (doc (or (documentation-property variable 'variable-documentation)
 708                             (documentation-property alias 'variable-documentation)))
 709                    (extra-line nil))
 710               ;; Add a note for variables that have been make-var-buffer-local.
 711               (when (and (local-variable-if-set-p variable)
 712                          (or (not (local-variable-p variable))
 713                              (with-temp-buffer
 714                                (local-variable-if-set-p variable))))
 715                 (setq extra-line t)
 716                 (princ "  Automatically becomes buffer-local when set in any fashion.\n"))
 717
 718               ;; Mention if it's an alias
 719               (unless (eq alias variable)
 720                 (setq extra-line t)
 721                 (princ (format "  This variable is an alias for `%s'.\n" alias)))
 722
 723               (when obsolete
 724                 (setq extra-line t)
 725                 (princ "  This variable is obsolete")
 726                 (if (cdr obsolete) (princ (format " since %s" (cdr obsolete))))
 727                 (princ (cond ((stringp use) (concat ";\n  " use))
 728                              (use (format ";\n  use `%s' instead." (car obsolete)))
 729                              (t ".")))
 730                 (terpri))
 731
 732               (when (member (cons variable val) file-local-variables-alist)
 733                 (setq extra-line t)
 734                 (if (member (cons variable val) dir-local-variables-alist)
 735                     (let ((file (and (buffer-file-name)
 736                                      (not (file-remote-p (buffer-file-name)))
 737                                      (dir-locals-find-file (buffer-file-name)))))
 738                       (princ "  This variable is a directory local variable")
 739                       (when file
 740                         (princ (concat "\n  from the file \""
 741                                        (if (consp file)
 742                                            (car file)
 743                                          file)
 744                                        "\"")))
 745                       (princ ".\n"))
 746                   (princ "  This variable is a file local variable.\n")))
 747
 748               (when (memq variable ignored-local-variables)
 749                 (setq extra-line t)
 750                 (princ "  This variable is ignored when used as a file local \
 751 variable.\n"))
 752
 753               ;; Can be both risky and safe, eg auto-fill-function.
 754               (when (risky-local-variable-p variable)
 755                 (setq extra-line t)
 756                 (princ "  This variable is potentially risky when used as a \
 757 file local variable.\n")
 758                 (when (assq variable safe-local-variable-values)
 759                   (princ "  However, you have added it to \
 760 `safe-local-variable-values'.\n")))
 761
 762               (when safe-var
 763                 (setq extra-line t)
 764                 (princ "  This variable is safe as a file local variable ")
 765                 (princ "if its value\n  satisfies the predicate ")
 766                 (princ (if (byte-code-function-p safe-var)
 767                            "which is byte-compiled expression.\n"
 768                          (format "`%s'.\n" safe-var))))
 769
 770               (if extra-line (terpri))
 771               (princ "Documentation:\n")
 772               (with-current-buffer standard-output
 773                 (insert (or doc "Not documented as a variable."))))
 774
 775             ;; Make a link to customize if this variable can be customized.
 776             (when (custom-variable-p variable)
 777               (let ((customize-label "customize"))
 778                 (terpri)
 779                 (terpri)
 780                 (princ (concat "You can " customize-label " this variable."))
 781                 (with-current-buffer standard-output
 782                   (save-excursion
 783                     (re-search-backward
 784                      (concat "\\(" customize-label "\\)") nil t)
 785                     (help-xref-button 1 'help-customize-variable variable))))
 786               ;; Note variable's version or package version
 787               (let ((output (describe-variable-custom-version-info variable)))
 788                 (when output
 789                   (terpri)
 790                   (terpri)
 791                   (princ output))))
 792
 793             (with-current-buffer standard-output
 794               ;; Return the text we displayed.
 795               (buffer-string))))))))
 796
 797
 798 ;;;###autoload
 799 (defun describe-syntax (&optional buffer)
 800   "Describe the syntax specifications in the syntax table of BUFFER.
 801 The descriptions are inserted in a help buffer, which is then displayed.
 802 BUFFER defaults to the current buffer."
 803   (interactive)
 804   (setq buffer (or buffer (current-buffer)))
 805   (help-setup-xref (list #'describe-syntax buffer)
 806                    (called-interactively-p 'interactive))
 807   (with-help-window (help-buffer)
 808     (let ((table (with-current-buffer buffer (syntax-table))))
 809       (with-current-buffer standard-output
 810         (describe-vector table 'internal-describe-syntax-value)
 811         (while (setq table (char-table-parent table))
 812           (insert "\nThe parent syntax table is:")
 813           (describe-vector table 'internal-describe-syntax-value))))))
 814
 815 (defun help-describe-category-set (value)
 816   (insert (cond
 817            ((null value) "default")
 818            ((char-table-p value) "deeper char-table ...")
 819            (t (condition-case err
 820                   (category-set-mnemonics value)
 821                 (error "invalid"))))))
 822
 823 ;;;###autoload
 824 (defun describe-categories (&optional buffer)
 825   "Describe the category specifications in the current category table.
 826 The descriptions are inserted in a buffer, which is then displayed.
 827 If BUFFER is non-nil, then describe BUFFER's category table instead.
 828 BUFFER should be a buffer or a buffer name."
 829   (interactive)
 830   (setq buffer (or buffer (current-buffer)))
 831   (help-setup-xref (list #'describe-categories buffer)
 832                    (called-interactively-p 'interactive))
 833   (with-help-window (help-buffer)
 834     (let* ((table (with-current-buffer buffer (category-table)))
 835            (docs (char-table-extra-slot table 0)))
 836       (if (or (not (vectorp docs)) (/= (length docs) 95))
 837           (error "Invalid first extra slot in this category table\n"))
 838       (with-current-buffer standard-output
 839         (insert "Legend of category mnemonics (see the tail for the longer description)\n")
 840         (let ((pos (point)) (items 0) lines n)
 841           (dotimes (i 95)
 842             (if (aref docs i) (setq items (1+ items))))
 843           (setq lines (1+ (/ (1- items) 4)))
 844           (setq n 0)
 845           (dotimes (i 95)
 846             (let ((elt (aref docs i)))
 847               (when elt
 848                 (string-match ".*" elt)
 849                 (setq elt (match-string 0 elt))
 850                 (if (>= (length elt) 17)
 851                     (setq elt (concat (substring elt 0 14) "...")))
 852                 (if (< (point) (point-max))
 853                     (move-to-column (* 20 (/ n lines)) t))
 854                 (insert (+ i ?\s) ?: elt)
 855                 (if (< (point) (point-max))
 856                     (forward-line 1)
 857                   (insert "\n"))
 858                 (setq n (1+ n))
 859                 (if (= (% n lines) 0)
 860                     (goto-char pos))))))
 861         (goto-char (point-max))
 862         (insert "\n"
 863                 "character(s)\tcategory mnemonics\n"
 864                 "------------\t------------------")
 865         (describe-vector table 'help-describe-category-set)
 866         (insert "Legend of category mnemonics:\n")
 867         (dotimes (i 95)
 868           (let ((elt (aref docs i)))
 869             (when elt
 870               (if (string-match "\n" elt)
 871                   (setq elt (substring elt (match-end 0))))
 872               (insert (+ i ?\s) ": " elt "\n"))))
 873         (while (setq table (char-table-parent table))
 874           (insert "\nThe parent category table is:")
 875           (describe-vector table 'help-describe-category-set))))))
 876
 877 (provide 'help-fns)
 878
 879 ;; arch-tag: 9e10331c-ae81-4d13-965d-c4819aaab0b3
 880 ;;; help-fns.el ends here