lisp/emacs-lisp/derived.el

   1 ;;; derived.el --- allow inheritance of major modes
   2 ;; (formerly mode-clone.el)
   3
   4 ;; Copyright (C) 1993, 1994, 1999, 2001, 2002, 2003, 2004, 2005, 2006,
   5 ;;   2007, 2008, 2009, 2010  Free Software Foundation, Inc.
   6
   7 ;; Author: David Megginson (dmeggins@aix1.uottawa.ca)
   8 ;; Maintainer: FSF
   9 ;; Keywords: extensions
  10 ;; Package: emacs
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26 \f
  27 ;;; Commentary:
  28
  29 ;; GNU Emacs is already, in a sense, object oriented -- each object
  30 ;; (buffer) belongs to a class (major mode), and that class defines
  31 ;; the relationship between messages (input events) and methods
  32 ;; (commands) by means of a keymap.
  33 ;;
  34 ;; The only thing missing is a good scheme of inheritance.  It is
  35 ;; possible to simulate a single level of inheritance with generous
  36 ;; use of hooks and a bit of work -- sgml-mode, for example, also runs
  37 ;; the hooks for text-mode, and keymaps can inherit from other keymaps
  38 ;; -- but generally, each major mode ends up reinventing the wheel.
  39 ;; Ideally, someone should redesign all of Emacs's major modes to
  40 ;; follow a more conventional object-oriented system: when defining a
  41 ;; new major mode, the user should need only to name the existing mode
  42 ;; it is most similar to, then list the (few) differences.
  43 ;;
  44 ;; In the mean time, this package offers most of the advantages of
  45 ;; full inheritance with the existing major modes.  The macro
  46 ;; `define-derived-mode' allows the user to make a variant of an existing
  47 ;; major mode, with its own keymap.  The new mode will inherit the key
  48 ;; bindings of its parent, and will, in fact, run its parent first
  49 ;; every time it is called.  For example, the commands
  50 ;;
  51 ;;  (define-derived-mode hypertext-mode text-mode "Hypertext"
  52 ;;    "Major mode for hypertext.\n\n\\{hypertext-mode-map}"
  53 ;;    (setq case-fold-search nil))
  54 ;;
  55 ;;  (define-key hypertext-mode-map [down-mouse-3] 'do-hyper-link)
  56 ;;
  57 ;; will create a function `hypertext-mode' with its own (sparse)
  58 ;; keymap `hypertext-mode-map.'  The command M-x hypertext-mode will
  59 ;; perform the following actions:
  60 ;;
  61 ;; - run the command (text-mode) to get its default setup
  62 ;; - replace the current keymap with 'hypertext-mode-map,' which will
  63 ;;   inherit from 'text-mode-map'.
  64 ;; - replace the current syntax table with
  65 ;;   'hypertext-mode-syntax-table', which will borrow its defaults
  66 ;;   from the current text-mode-syntax-table.
  67 ;; - replace the current abbrev table with
  68 ;;   'hypertext-mode-abbrev-table', which will borrow its defaults
  69 ;;   from the current text-mode-abbrev table
  70 ;; - change the mode line to read "Hypertext"
  71 ;; - assign the value 'hypertext-mode' to the 'major-mode' variable
  72 ;; - run the body of commands provided in the macro -- in this case,
  73 ;;   set the local variable `case-fold-search' to nil.
  74 ;;
  75 ;; The advantages of this system are threefold.  First, text mode is
  76 ;; untouched -- if you had added the new keystroke to `text-mode-map,'
  77 ;; possibly using hooks, you would have added it to all text buffers
  78 ;; -- here, it appears only in hypertext buffers, where it makes
  79 ;; sense.  Second, it is possible to build even further, and make
  80 ;; a derived mode from a derived mode.  The commands
  81 ;;
  82 ;;   (define-derived-mode html-mode hypertext-mode "HTML")
  83 ;;   [various key definitions]
  84 ;;
  85 ;; will add a new major mode for HTML with very little fuss.
  86 ;;
  87 ;; Note also the function `derived-mode-p' which can tell if the current
  88 ;; mode derives from another.  In a hypertext-mode, buffer, for example,
  89 ;; (derived-mode-p 'text-mode) would return non-nil.  This should always
  90 ;; be used in place of (eq major-mode 'text-mode).
  91 \f
  92 ;;; Code:
  93
  94 (eval-when-compile (require 'cl))
  95
  96 ;;; PRIVATE: defsubst must be defined before they are first used
  97
  98 (defsubst derived-mode-hook-name (mode)
  99   "Construct a mode-hook name based on a MODE name."
 100   (intern (concat (symbol-name mode) "-hook")))
 101
 102 (defsubst derived-mode-map-name (mode)
 103   "Construct a map name based on a MODE name."
 104   (intern (concat (symbol-name mode) "-map")))
 105
 106 (defsubst derived-mode-syntax-table-name (mode)
 107   "Construct a syntax-table name based on a MODE name."
 108   (intern (concat (symbol-name mode) "-syntax-table")))
 109
 110 (defsubst derived-mode-abbrev-table-name (mode)
 111   "Construct an abbrev-table name based on a MODE name."
 112   (intern (concat (symbol-name mode) "-abbrev-table")))
 113
 114 ;; PUBLIC: define a new major mode which inherits from an existing one.
 115
 116 ;;;###autoload
 117 (defmacro define-derived-mode (child parent name &optional docstring &rest body)
 118   "Create a new mode as a variant of an existing mode.
 119
 120 The arguments to this command are as follow:
 121
 122 CHILD:     the name of the command for the derived mode.
 123 PARENT:    the name of the command for the parent mode (e.g. `text-mode')
 124            or nil if there is no parent.
 125 NAME:      a string which will appear in the status line (e.g. \"Hypertext\")
 126 DOCSTRING: an optional documentation string--if you do not supply one,
 127            the function will attempt to invent something useful.
 128 BODY:      forms to execute just before running the
 129            hooks for the new mode.  Do not use `interactive' here.
 130
 131 BODY can start with a bunch of keyword arguments.  The following keyword
 132   arguments are currently understood:
 133 :group GROUP
 134         Declare the customization group that corresponds to this mode.
 135         The command `customize-mode' uses this.
 136 :syntax-table TABLE
 137         Use TABLE instead of the default.
 138         A nil value means to simply use the same syntax-table as the parent.
 139 :abbrev-table TABLE
 140         Use TABLE instead of the default.
 141         A nil value means to simply use the same abbrev-table as the parent.
 142
 143 Here is how you could define LaTeX-Thesis mode as a variant of LaTeX mode:
 144
 145   (define-derived-mode LaTeX-thesis-mode LaTeX-mode \"LaTeX-Thesis\")
 146
 147 You could then make new key bindings for `LaTeX-thesis-mode-map'
 148 without changing regular LaTeX mode.  In this example, BODY is empty,
 149 and DOCSTRING is generated by default.
 150
 151 On a more complicated level, the following command uses `sgml-mode' as
 152 the parent, and then sets the variable `case-fold-search' to nil:
 153
 154   (define-derived-mode article-mode sgml-mode \"Article\"
 155     \"Major mode for editing technical articles.\"
 156     (setq case-fold-search nil))
 157
 158 Note that if the documentation string had been left out, it would have
 159 been generated automatically, with a reference to the keymap.
 160
 161 The new mode runs the hook constructed by the function
 162 `derived-mode-hook-name'.
 163
 164 See Info node `(elisp)Derived Modes' for more details."
 165   (declare (debug (&define name symbolp sexp [&optional stringp]
 166                            [&rest keywordp sexp] def-body))
 167            (doc-string 4))
 168
 169   (when (and docstring (not (stringp docstring)))
 170     ;; Some trickiness, since what appears to be the docstring may really be
 171     ;; the first element of the body.
 172     (push docstring body)
 173     (setq docstring nil))
 174
 175   (when (eq parent 'fundamental-mode) (setq parent nil))
 176
 177   (let ((map (derived-mode-map-name child))
 178         (syntax (derived-mode-syntax-table-name child))
 179         (abbrev (derived-mode-abbrev-table-name child))
 180         (declare-abbrev t)
 181         (declare-syntax t)
 182         (hook (derived-mode-hook-name child))
 183         (group nil))
 184
 185     ;; Process the keyword args.
 186     (while (keywordp (car body))
 187       (case (pop body)
 188         (:group (setq group (pop body)))
 189         (:abbrev-table (setq abbrev (pop body)) (setq declare-abbrev nil))
 190         (:syntax-table (setq syntax (pop body)) (setq declare-syntax nil))
 191         (t (pop body))))
 192
 193     (setq docstring (derived-mode-make-docstring
 194                      parent child docstring syntax abbrev))
 195
 196     `(progn
 197        (unless (get ',hook 'variable-documentation)
 198          (put ',hook 'variable-documentation
 199               (purecopy ,(format "Hook run when entering %s mode.
 200 No problems result if this variable is not bound.
 201 `add-hook' automatically binds it.  (This is true for all hook variables.)"
 202                        name))))
 203        (unless (boundp ',map)
 204          (put ',map 'definition-name ',child))
 205        (defvar ,map (make-sparse-keymap))
 206        (unless (get ',map 'variable-documentation)
 207          (put ',map 'variable-documentation
 208               (purecopy ,(format "Keymap for `%s'." child))))
 209        ,(if declare-syntax
 210             `(progn
 211                (unless (boundp ',syntax)
 212                  (put ',syntax 'definition-name ',child))
 213                (defvar ,syntax (make-syntax-table))
 214                (unless (get ',syntax 'variable-documentation)
 215                  (put ',syntax 'variable-documentation
 216                       (purecopy ,(format "Syntax table for `%s'." child))))))
 217        ,(if declare-abbrev
 218             `(progn
 219                (put ',abbrev 'definition-name ',child)
 220                (defvar ,abbrev
 221                  (progn (define-abbrev-table ',abbrev nil) ,abbrev))
 222                (unless (get ',abbrev 'variable-documentation)
 223                  (put ',abbrev 'variable-documentation
 224                       (purecopy ,(format "Abbrev table for `%s'." child))))))
 225        (put ',child 'derived-mode-parent ',parent)
 226        ,(if group `(put ',child 'custom-mode-group ,group))
 227
 228        (defun ,child ()
 229          ,docstring
 230          (interactive)
 231                                         ; Run the parent.
 232          (delay-mode-hooks
 233
 234           (,(or parent 'fundamental-mode))
 235                                         ; Identify the child mode.
 236           (setq major-mode (quote ,child))
 237           (setq mode-name ,name)
 238                                         ; Identify special modes.
 239           ,(when parent
 240              `(progn
 241                 (if (get (quote ,parent) 'mode-class)
 242                     (put (quote ,child) 'mode-class
 243                          (get (quote ,parent) 'mode-class)))
 244                                         ; Set up maps and tables.
 245                 (unless (keymap-parent ,map)
 246                   ;; It would probably be better to set the keymap's parent
 247                   ;; at the toplevel rather than inside the mode function,
 248                   ;; but this is not easy for at least the following reasons:
 249                   ;; - the parent (and its keymap) may not yet be loaded.
 250                   ;; - the parent's keymap name may be called something else
 251                   ;;   than <parent>-mode-map.
 252                   (set-keymap-parent ,map (current-local-map)))
 253                 ,(when declare-syntax
 254                    `(let ((parent (char-table-parent ,syntax)))
 255                       (unless (and parent
 256                                    (not (eq parent (standard-syntax-table))))
 257                         (set-char-table-parent ,syntax (syntax-table)))))))
 258
 259           (use-local-map ,map)
 260           ,(when syntax `(set-syntax-table ,syntax))
 261           ,(when abbrev `(setq local-abbrev-table ,abbrev))
 262                                         ; Splice in the body (if any).
 263           ,@body
 264           )
 265          ;; Run the hooks, if any.
 266          (run-mode-hooks ',hook)))))
 267
 268 ;; PUBLIC: find the ultimate class of a derived mode.
 269
 270 (defun derived-mode-class (mode)
 271   "Find the class of a major MODE.
 272 A mode's class is the first ancestor which is NOT a derived mode.
 273 Use the `derived-mode-parent' property of the symbol to trace backwards.
 274 Since major-modes might all derive from `fundamental-mode', this function
 275 is not very useful."
 276   (while (get mode 'derived-mode-parent)
 277     (setq mode (get mode 'derived-mode-parent)))
 278   mode)
 279 (make-obsolete 'derived-mode-class 'derived-mode-p "22.1")
 280
 281 \f
 282 ;;; PRIVATE
 283
 284 (defun derived-mode-make-docstring (parent child &optional
 285                                            docstring syntax abbrev)
 286   "Construct a docstring for a new mode if none is provided."
 287
 288   (let ((map (derived-mode-map-name child))
 289         (hook (derived-mode-hook-name child)))
 290
 291     (unless (stringp docstring)
 292       ;; Use a default docstring.
 293       (setq docstring
 294             (if (null parent)
 295                 (format "Major-mode.
 296 Uses keymap `%s', abbrev table `%s' and syntax-table `%s'." map abbrev syntax)
 297               (format "Major mode derived from `%s' by `define-derived-mode'.
 298 It inherits all of the parent's attributes, but has its own keymap,
 299 abbrev table and syntax table:
 300
 301   `%s', `%s' and `%s'
 302
 303 which more-or-less shadow %s's corresponding tables."
 304                       parent map abbrev syntax parent))))
 305
 306     (unless (string-match (regexp-quote (symbol-name hook)) docstring)
 307       ;; Make sure the docstring mentions the mode's hook.
 308       (setq docstring
 309             (concat docstring
 310                     (if (null parent)
 311                         "\n\nThis mode "
 312                       (concat
 313                        "\n\nIn addition to any hooks its parent mode "
 314                        (if (string-match (regexp-quote (format "`%s'" parent))
 315                                          docstring) nil
 316                          (format "`%s' " parent))
 317                        "might have run,\nthis mode "))
 318                     (format "runs the hook `%s'" hook)
 319                     ", as the final step\nduring initialization.")))
 320
 321     (unless (string-match "\\\\[{[]" docstring)
 322       ;; And don't forget to put the mode's keymap.
 323       (setq docstring (concat docstring "\n\n\\{" (symbol-name map) "}")))
 324
 325     docstring))
 326
 327 \f
 328 ;;; OBSOLETE
 329 ;; The functions below are only provided for backward compatibility with
 330 ;; code byte-compiled with versions of derived.el prior to Emacs-21.
 331
 332 (defsubst derived-mode-setup-function-name (mode)
 333   "Construct a setup-function name based on a MODE name."
 334   (intern (concat (symbol-name mode) "-setup")))
 335
 336 \f
 337 ;; Utility functions for defining a derived mode.
 338
 339 ;;;###autoload
 340 (defun derived-mode-init-mode-variables (mode)
 341   "Initialize variables for a new MODE.
 342 Right now, if they don't already exist, set up a blank keymap, an
 343 empty syntax table, and an empty abbrev table -- these will be merged
 344 the first time the mode is used."
 345
 346   (if (boundp (derived-mode-map-name mode))
 347       t
 348     (eval `(defvar ,(derived-mode-map-name mode)
 349                (make-sparse-keymap)
 350                ,(format "Keymap for %s." mode)))
 351     (put (derived-mode-map-name mode) 'derived-mode-unmerged t))
 352
 353   (if (boundp (derived-mode-syntax-table-name mode))
 354       t
 355     (eval `(defvar ,(derived-mode-syntax-table-name mode)
 356              ;; Make a syntax table which doesn't specify anything
 357              ;; for any char.  Valid data will be merged in by
 358              ;; derived-mode-merge-syntax-tables.
 359              (make-char-table 'syntax-table nil)
 360              ,(format "Syntax table for %s." mode)))
 361     (put (derived-mode-syntax-table-name mode) 'derived-mode-unmerged t))
 362
 363   (if (boundp (derived-mode-abbrev-table-name mode))
 364       t
 365     (eval `(defvar ,(derived-mode-abbrev-table-name mode)
 366              (progn
 367                (define-abbrev-table (derived-mode-abbrev-table-name mode) nil)
 368                (make-abbrev-table))
 369              ,(format "Abbrev table for %s." mode)))))
 370 \f
 371 ;; Utility functions for running a derived mode.
 372
 373 (defun derived-mode-set-keymap (mode)
 374   "Set the keymap of the new MODE, maybe merging with the parent."
 375   (let* ((map-name (derived-mode-map-name mode))
 376          (new-map (eval map-name))
 377          (old-map (current-local-map)))
 378     (and old-map
 379          (get map-name 'derived-mode-unmerged)
 380          (derived-mode-merge-keymaps old-map new-map))
 381     (put map-name 'derived-mode-unmerged nil)
 382     (use-local-map new-map)))
 383
 384 (defun derived-mode-set-syntax-table (mode)
 385   "Set the syntax table of the new MODE, maybe merging with the parent."
 386   (let* ((table-name (derived-mode-syntax-table-name mode))
 387          (old-table (syntax-table))
 388          (new-table (eval table-name)))
 389     (if (get table-name 'derived-mode-unmerged)
 390         (derived-mode-merge-syntax-tables old-table new-table))
 391     (put table-name 'derived-mode-unmerged nil)
 392     (set-syntax-table new-table)))
 393
 394 (defun derived-mode-set-abbrev-table (mode)
 395   "Set the abbrev table for MODE if it exists.
 396 Always merge its parent into it, since the merge is non-destructive."
 397   (let* ((table-name (derived-mode-abbrev-table-name mode))
 398          (old-table local-abbrev-table)
 399          (new-table (eval table-name)))
 400     (derived-mode-merge-abbrev-tables old-table new-table)
 401     (setq local-abbrev-table new-table)))
 402
 403 (defun derived-mode-run-hooks (mode)
 404    "Run the mode hook for MODE."
 405    (let ((hooks-name (derived-mode-hook-name mode)))
 406      (if (boundp hooks-name)
 407          (run-hooks hooks-name))))
 408
 409 ;; Functions to merge maps and tables.
 410
 411 (defun derived-mode-merge-keymaps (old new)
 412   "Merge an OLD keymap into a NEW one.
 413 The old keymap is set to be the last cdr of the new one, so that there will
 414 be automatic inheritance."
 415   ;; ?? Can this just use `set-keymap-parent'?
 416   (let ((tail new))
 417     ;; Scan the NEW map for prefix keys.
 418     (while (consp tail)
 419       (and (consp (car tail))
 420            (let* ((key (vector (car (car tail))))
 421                   (subnew (lookup-key new key))
 422                   (subold (lookup-key old key)))
 423              ;; If KEY is a prefix key in both OLD and NEW, merge them.
 424              (and (keymapp subnew) (keymapp subold)
 425                   (derived-mode-merge-keymaps subold subnew))))
 426       (and (vectorp (car tail))
 427            ;; Search a vector of ASCII char bindings for prefix keys.
 428            (let ((i (1- (length (car tail)))))
 429              (while (>= i 0)
 430                (let* ((key (vector i))
 431                       (subnew (lookup-key new key))
 432                       (subold (lookup-key old key)))
 433                  ;; If KEY is a prefix key in both OLD and NEW, merge them.
 434                  (and (keymapp subnew) (keymapp subold)
 435                       (derived-mode-merge-keymaps subold subnew)))
 436                (setq i (1- i)))))
 437       (setq tail (cdr tail))))
 438   (setcdr (nthcdr (1- (length new)) new) old))
 439
 440 (defun derived-mode-merge-syntax-tables (old new)
 441   "Merge an OLD syntax table into a NEW one.
 442 Where the new table already has an entry, nothing is copied from the old one."
 443   (set-char-table-parent new old))
 444
 445 ;; Merge an old abbrev table into a new one.
 446 ;; This function requires internal knowledge of how abbrev tables work,
 447 ;; presuming that they are obarrays with the abbrev as the symbol, the expansion
 448 ;; as the value of the symbol, and the hook as the function definition.
 449 (defun derived-mode-merge-abbrev-tables (old new)
 450   (if old
 451       (mapatoms
 452        (lambda (symbol)
 453          (or (intern-soft (symbol-name symbol) new)
 454              (define-abbrev new (symbol-name symbol)
 455                (symbol-value symbol) (symbol-function symbol))))
 456        old)))
 457
 458 (provide 'derived)
 459
 460 ;; arch-tag: 630be248-47d1-4f02-afa0-8207de0ebea0
 461 ;;; derived.el ends here