lisp/composite.el

   1 ;;; composite.el --- support character composition
   2
   3 ;; Copyright (C) 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007,
   4 ;;   2008, 2009, 2010
   5 ;;   National Institute of Advanced Industrial Science and Technology (AIST)
   6 ;;   Registration Number H14PRO021
   7
   8 ;; Author: Kenichi HANDA <handa@etl.go.jp>
   9 ;; (according to ack.texi)
  10 ;; Keywords: mule, multilingual, character composition
  11 ;; Package: emacs
  12
  13 ;; This file is part of GNU Emacs.
  14
  15 ;; GNU Emacs is free software: you can redistribute it and/or modify
  16 ;; it under the terms of the GNU General Public License as published by
  17 ;; the Free Software Foundation, either version 3 of the License, or
  18 ;; (at your option) any later version.
  19
  20 ;; GNU Emacs is distributed in the hope that it will be useful,
  21 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 ;; GNU General Public License for more details.
  24
  25 ;; You should have received a copy of the GNU General Public License
  26 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  27
  28 ;;; Commentary:
  29
  30 ;;; Code:
  31
  32 (eval-when-compile (require 'cl))
  33
  34 (defconst reference-point-alist
  35   '((tl . 0) (tc . 1) (tr . 2)
  36     (Bl . 3) (Bc . 4) (Br . 5)
  37     (bl . 6) (bc . 7) (br . 8)
  38     (cl . 9) (cc . 10) (cr . 11)
  39     (top-left . 0) (top-center . 1) (top-right . 2)
  40     (base-left . 3) (base-center . 4) (base-right . 5)
  41     (bottom-left . 6) (bottom-center . 7) (bottom-right . 8)
  42     (center-left . 9) (center-center . 10) (center-right . 11)
  43     ;; For backward compatibility...
  44     (ml . 3) (mc . 10) (mr . 5)
  45     (mid-left . 3) (mid-center . 10) (mid-right . 5))
  46   "Alist of symbols vs integer codes of glyph reference points.
  47 A glyph reference point symbol is to be used to specify a composition
  48 rule in COMPONENTS argument to such functions as `compose-region'.
  49
  50 The meaning of glyph reference point codes is as follows:
  51
  52     0----1----2 <---- ascent    0:tl or top-left
  53     |         |                 1:tc or top-center
  54     |         |                 2:tr or top-right
  55     |         |                 3:Bl or base-left     9:cl or center-left
  56     9   10   11 <---- center    4:Bc or base-center  10:cc or center-center
  57     |         |                 5:Br or base-right   11:cr or center-right
  58   --3----4----5-- <-- baseline  6:bl or bottom-left
  59     |         |                 7:bc or bottom-center
  60     6----7----8 <---- descent   8:br or bottom-right
  61
  62 Glyph reference point symbols are to be used to specify composition
  63 rule of the form \(GLOBAL-REF-POINT . NEW-REF-POINT), where
  64 GLOBAL-REF-POINT is a reference point in the overall glyphs already
  65 composed, and NEW-REF-POINT is a reference point in the new glyph to
  66 be added.
  67
  68 For instance, if GLOBAL-REF-POINT is `br' (bottom-right) and
  69 NEW-REF-POINT is `tc' (top-center), the overall glyph is updated as
  70 follows (the point `*' corresponds to both reference points):
  71
  72     +-------+--+ <--- new ascent
  73     |       |  |
  74     | global|  |
  75     | glyph |  |
  76  -- |       |  |-- <--- baseline \(doesn't change)
  77     +----+--*--+
  78     |    | new |
  79     |    |glyph|
  80     +----+-----+ <--- new descent
  81
  82 A composition rule may have the form \(GLOBAL-REF-POINT
  83 NEW-REF-POINT XOFF YOFF), where XOFF and YOFF specify how much
  84 to shift NEW-REF-POINT from GLOBAL-REF-POINT.  In this case, XOFF
  85 and YOFF are integers in the range -100..100 representing the
  86 shifting percentage against the font size.")
  87
  88
  89 ;;;###autoload
  90 (defun encode-composition-rule (rule)
  91   "Encode composition rule RULE into an integer value.
  92 RULE is a cons of global and new reference point symbols
  93 \(see `reference-point-alist')."
  94
  95   ;; This must be compatible with C macro COMPOSITION_ENCODE_RULE
  96   ;; defined in composite.h.
  97
  98   (if (and (integerp rule) (< rule 144))
  99       ;; Already encoded.
 100       rule
 101     (if (consp rule)
 102         (let ((gref (car rule))
 103               (nref (cdr rule))
 104               xoff yoff)
 105           (if (consp nref)              ; (GREF NREF XOFF YOFF)
 106               (progn
 107                 (setq xoff (nth 1 nref)
 108                       yoff (nth 2 nref)
 109                       nref (car nref))
 110                 (or (and (>= xoff -100) (<= xoff 100)
 111                          (>= yoff -100) (<= yoff 100))
 112                     (error "Invalid composition rule: %s" rule))
 113                 (setq xoff (+ xoff 128) yoff (+ yoff 128)))
 114             ;; (GREF . NREF)
 115             (setq xoff 0 yoff 0))
 116           (or (integerp gref)
 117               (setq gref (cdr (assq gref reference-point-alist))))
 118           (or (integerp nref)
 119               (setq nref (cdr (assq nref reference-point-alist))))
 120           (or (and (>= gref 0) (< gref 12) (>= nref 0) (< nref 12))
 121               (error "Invalid composition rule: %S" rule))
 122           (logior (lsh xoff 16) (lsh yoff 8) (+ (* gref 12) nref)))
 123       (error "Invalid composition rule: %S" rule))))
 124
 125 ;; Decode encoded composition rule RULE-CODE.  The value is a cons of
 126 ;; global and new reference point symbols.
 127 ;; This must be compatible with C macro COMPOSITION_DECODE_RULE
 128 ;; defined in composite.h.
 129
 130 (defun decode-composition-rule (rule-code)
 131   (or (and (natnump rule-code) (< rule-code #x1000000))
 132       (error "Invalid encoded composition rule: %S" rule-code))
 133   (let ((xoff (lsh rule-code -16))
 134         (yoff (logand (lsh rule-code -8) #xFF))
 135         gref nref)
 136     (setq rule-code (logand rule-code #xFF)
 137           gref (car (rassq (/ rule-code 12) reference-point-alist))
 138           nref (car (rassq (% rule-code 12) reference-point-alist)))
 139     (or (and gref (symbolp gref) nref (symbolp nref))
 140         (error "Invalid composition rule code: %S" rule-code))
 141     (if (and (= xoff 0) (= yoff 0))
 142         (cons gref nref)
 143       (setq xoff (- xoff 128) yoff (- yoff 128))
 144       (list gref xoff yoff nref))))
 145
 146 ;; Encode composition rules in composition components COMPONENTS.  The
 147 ;; value is a copy of COMPONENTS, where composition rules (cons of
 148 ;; global and new glyph reference point symbols) are replaced with
 149 ;; encoded composition rules.  Optional 2nd argument NOCOPY non-nil
 150 ;; means don't make a copy but modify COMPONENTS directly.
 151
 152 (defun encode-composition-components (components &optional nocopy)
 153   (or nocopy
 154       (setq components (copy-sequence components)))
 155   (if (vectorp components)
 156       (let ((len (length components))
 157             (i 1))
 158         (while (< i len)
 159           (aset components i
 160                 (encode-composition-rule (aref components i)))
 161           (setq i (+ i 2))))
 162     (let ((tail (cdr components)))
 163       (while tail
 164         (setcar tail
 165                 (encode-composition-rule (car tail)))
 166         (setq tail (nthcdr 2 tail)))))
 167   components)
 168
 169 ;; Decode composition rule codes in composition components COMPONENTS.
 170 ;; The value is a copy of COMPONENTS, where composition rule codes are
 171 ;; replaced with composition rules (cons of global and new glyph
 172 ;; reference point symbols).  Optional 2nd argument NOCOPY non-nil
 173 ;; means don't make a copy but modify COMPONENTS directly.
 174 ;; It is assumed that COMPONENTS is a vector and is for rule-base
 175 ;; composition, thus (2N+1)th elements are rule codes.
 176
 177 (defun decode-composition-components (components &optional nocopy)
 178   (or nocopy
 179       (setq components (copy-sequence components)))
 180   (let ((len (length components))
 181         (i 1))
 182     (while (< i len)
 183       (aset components i
 184             (decode-composition-rule (aref components i)))
 185       (setq i (+ i 2))))
 186   components)
 187
 188 (defun compose-region (start end &optional components modification-func)
 189   "Compose characters in the current region.
 190
 191 Characters are composed relatively, i.e. composed by overstriking
 192 or stacking depending on ascent, descent and other metrics of
 193 glyphs.
 194
 195 For instance, if the region has three characters \"XYZ\", X is
 196 regarded as BASE glyph, and Y is displayed:
 197   (1) above BASE if Y's descent value is not positive
 198   (2) below BASE if Y's ascent value is not positive
 199   (3) on BASE (i.e. at the BASE position) otherwise
 200 and Z is displayed with the same rule while regarding the whole
 201 XY glyphs as BASE.
 202
 203 When called from a program, expects these four arguments.
 204
 205 First two arguments START and END are positions (integers or markers)
 206 specifying the region.
 207
 208 Optional 3rd argument COMPONENTS, if non-nil, is a character, a string
 209 or a vector or list of integers and rules.
 210
 211 If it is a character, it is an alternate character to display instead
 212 of the text in the region.
 213
 214 If it is a string, the elements are alternate characters.  In
 215 this case, TAB element has a special meaning.  If the first
 216 characer is TAB, the glyphs are displayed with left padding space
 217 so that no pixel overlaps with the previous column.  If the last
 218 character is TAB, the glyphs are displayed with right padding
 219 space so that no pixel overlaps with the following column.
 220
 221 If it is a vector or list, it is a sequence of alternate characters and
 222 composition rules, where (2N)th elements are characters and (2N+1)th
 223 elements are composition rules to specify how to compose (2N+2)th
 224 elements with previously composed N glyphs.
 225
 226 A composition rule is a cons of global and new glyph reference point
 227 symbols.  See the documentation of `reference-point-alist' for more
 228 details.
 229
 230 Optional 4th argument MODIFICATION-FUNC is a function to call to
 231 adjust the composition when it gets invalid because of a change of
 232 text in the composition."
 233   (interactive "r")
 234   (let ((modified-p (buffer-modified-p))
 235         (inhibit-read-only t))
 236     (if (or (vectorp components) (listp components))
 237         (setq components (encode-composition-components components)))
 238     (compose-region-internal start end components modification-func)
 239     (restore-buffer-modified-p modified-p)))
 240
 241 (defun decompose-region (start end)
 242   "Decompose text in the current region.
 243
 244 When called from a program, expects two arguments,
 245 positions (integers or markers) specifying the region."
 246   (interactive "r")
 247   (let ((modified-p (buffer-modified-p))
 248         (inhibit-read-only t))
 249     (remove-text-properties start end '(composition nil))
 250     (restore-buffer-modified-p modified-p)))
 251
 252 (defun compose-string (string &optional start end components modification-func)
 253   "Compose characters in string STRING.
 254
 255 The return value is STRING with the `composition' property put on all
 256 the characters in it.
 257
 258 Optional 2nd and 3rd arguments START and END specify the range of
 259 STRING to be composed.  They default to the beginning and the end of
 260 STRING respectively.
 261
 262 Optional 4th argument COMPONENTS, if non-nil, is a character or a
 263 sequence (vector, list, or string) of integers.  See the function
 264 `compose-region' for more detail.
 265
 266 Optional 5th argument MODIFICATION-FUNC is a function to call to
 267 adjust the composition when it gets invalid because of a change of
 268 text in the composition."
 269   (if (or (vectorp components) (listp components))
 270       (setq components (encode-composition-components components)))
 271   (or start (setq start 0))
 272   (or end (setq end (length string)))
 273   (compose-string-internal string start end components modification-func)
 274   string)
 275
 276 (defun decompose-string (string)
 277   "Return STRING where `composition' property is removed."
 278   (remove-text-properties 0 (length string) '(composition nil) string)
 279   string)
 280
 281 (defun compose-chars (&rest args)
 282   "Return a string from arguments in which all characters are composed.
 283 For relative composition, arguments are characters.
 284 For rule-based composition, Mth \(where M is odd) arguments are
 285 characters, and Nth \(where N is even) arguments are composition rules.
 286 A composition rule is a cons of glyph reference points of the form
 287 \(GLOBAL-REF-POINT . NEW-REF-POINT).  See the documentation of
 288 `reference-point-alist' for more detail."
 289   (let (str components)
 290     (if (consp (car (cdr args)))
 291         ;; Rule-base composition.
 292         (let ((len (length args))
 293               (tail (encode-composition-components args 'nocopy)))
 294
 295           (while tail
 296             (setq str (cons (car tail) str))
 297             (setq tail (nthcdr 2 tail)))
 298           (setq str (concat (nreverse str))
 299                 components args))
 300       ;; Relative composition.
 301       (setq str (concat args)))
 302     (compose-string-internal str 0 (length str) components)))
 303
 304 (defun find-composition (pos &optional limit string detail-p)
 305   "Return information about a composition at or near buffer position POS.
 306
 307 If the character at POS has `composition' property, the value is a list
 308 \(FROM TO VALID-P).
 309
 310 FROM and TO specify the range of text that has the same `composition'
 311 property, VALID-P is t if this composition is valid, and nil if not.
 312
 313 If there's no composition at POS, and the optional 2nd argument LIMIT
 314 is non-nil, search for a composition toward the position given by LIMIT.
 315
 316 If no composition is found, return nil.
 317
 318 Optional 3rd argument STRING, if non-nil, is a string to look for a
 319 composition in; nil means the current buffer.
 320
 321 If a valid composition is found and the optional 4th argument DETAIL-P
 322 is non-nil, the return value is a list of the form
 323
 324    (FROM TO COMPONENTS RELATIVE-P MOD-FUNC WIDTH)
 325
 326 COMPONENTS is a vector of integers, the meaning depends on RELATIVE-P.
 327
 328 RELATIVE-P is t if the composition method is relative, else nil.
 329
 330 If RELATIVE-P is t, COMPONENTS is a vector of characters to be
 331 composed.  If RELATIVE-P is nil, COMPONENTS is a vector of characters
 332 and composition rules as described in `compose-region'.
 333
 334 MOD-FUNC is a modification function of the composition.
 335
 336 WIDTH is a number of columns the composition occupies on the screen.
 337
 338 When Automatic Composition mode is on, this function also finds a
 339 chunk of text that is automatically composed.  If such a chunk is
 340 found closer to POS than the position that has `composition'
 341 property, the value is a list of FROM, TO, and a glyph-string
 342 that specifies how the chunk is to be composed.  See the function
 343 `composition-get-gstring' for the format of the glyph-string."
 344   (let ((result (find-composition-internal pos limit string detail-p)))
 345     (if (and detail-p (> (length result) 3) (nth 2 result) (not (nth 3 result)))
 346         ;; This is a valid rule-base composition.
 347         (decode-composition-components (nth 2 result) 'nocopy))
 348     result))
 349
 350 \f
 351 (defun compose-chars-after (pos &optional limit object)
 352   "Compose characters in current buffer after position POS.
 353
 354 It looks up the char-table `composition-function-table' (which
 355 see) by a character at POS, and compose characters after POS
 356 according to the contents of `composition-function-table'.
 357
 358 Optional 2nd arg LIMIT, if non-nil, limits characters to compose.
 359
 360 Optional 3rd arg OBJECT, if non-nil, is a string that contains the
 361 text to compose.  In that case, POS and LIMIT index into the string.
 362
 363 This function is the default value of `compose-chars-after-function'."
 364   (let ((tail (aref composition-function-table (char-after pos)))
 365         (font-obj (and (display-multi-font-p)
 366                        (and (not (stringp object))
 367                             (font-at pos (selected-window)))))
 368         pattern func result)
 369     (or limit
 370         (setq limit (if (stringp object) (length object) (point-max))))
 371     (when (and font-obj tail)
 372       (save-match-data
 373         (save-excursion
 374           (while tail
 375             (if (functionp (car tail))
 376                 (setq pattern nil func (car tail))
 377               (setq pattern (car (car tail))
 378                     func (cdr (car tail))))
 379             (goto-char pos)
 380             (if pattern
 381                 (if (and (if (stringp object)
 382                              (eq (string-match pattern object) 0)
 383                            (looking-at pattern))
 384                          (<= (match-end 0) limit))
 385                     (setq result
 386                           (funcall func pos (match-end 0) font-obj object)))
 387               (setq result (funcall func pos limit font-obj  object)))
 388             (if result (setq tail nil))))))
 389     result))
 390
 391 (defun compose-last-chars (args)
 392   "Compose last characters.
 393 The argument is a parameterized event of the form
 394         \(compose-last-chars N COMPONENTS),
 395 where N is the number of characters before point to compose,
 396 COMPONENTS, if non-nil, is the same as the argument to `compose-region'
 397 \(which see).  If it is nil, `compose-chars-after' is called,
 398 and that function finds a proper rule to compose the target characters.
 399 This function is intended to be used from input methods.
 400 The global keymap binds special event `compose-last-chars' to this
 401 function.  Input method may generate an event (compose-last-chars N COMPONENTS)
 402 after a sequence of character events."
 403   (interactive "e")
 404   (let ((chars (nth 1 args)))
 405     (if (and (numberp chars)
 406              (>= (- (point) (point-min)) chars))
 407         (if (nth 2 args)
 408             (compose-region (- (point) chars) (point) (nth 2 args))
 409           (compose-chars-after (- (point) chars) (point))))))
 410
 411 (global-set-key [compose-last-chars] 'compose-last-chars)
 412
 413 \f
 414 ;;; Automatic character composition.
 415
 416 ;; Copied from font-lock.el.
 417 (eval-when-compile
 418   ;; Borrowed from lazy-lock.el.
 419   ;; We use this to preserve or protect things when modifying text properties.
 420   (defmacro save-buffer-state (varlist &rest body)
 421     "Bind variables according to VARLIST and eval BODY restoring buffer state."
 422     `(let* ,(append varlist
 423                     '((modified (buffer-modified-p)) (buffer-undo-list t)
 424                       (inhibit-read-only t) (inhibit-point-motion-hooks t)
 425                       (inhibit-modification-hooks t)
 426                       deactivate-mark buffer-file-name buffer-file-truename))
 427        ,@body
 428        (unless modified
 429          (restore-buffer-modified-p nil))))
 430   ;; Fixme: This makes bootstrapping fail with this error.
 431   ;;   Symbol's function definition is void: eval-defun
 432   ;;(def-edebug-spec save-buffer-state let)
 433   )
 434
 435 (put 'save-buffer-state 'lisp-indent-function 1)
 436
 437 ;; These macros must match with C macros LGSTRING_XXX and LGLYPH_XXX in font.h
 438 (defsubst lgstring-header (gstring) (aref gstring 0))
 439 (defsubst lgstring-set-header (gstring header) (aset gstring 0 header))
 440 (defsubst lgstring-font (gstring) (aref (lgstring-header gstring) 0))
 441 (defsubst lgstring-char (gstring i) (aref (lgstring-header gstring) (1+ i)))
 442 (defsubst lgstring-char-len (gstring) (1- (length (lgstring-header gstring))))
 443 (defsubst lgstring-shaped-p (gstring) (aref gstring 1))
 444 (defsubst lgstring-set-id (gstring id) (aset gstring 1 id))
 445 (defsubst lgstring-glyph (gstring i) (aref gstring (+ i 2)))
 446 (defsubst lgstring-glyph-len (gstring) (- (length gstring) 2))
 447 (defsubst lgstring-set-glyph (gstring i glyph) (aset gstring (+ i 2) glyph))
 448
 449 (defsubst lglyph-from (glyph) (aref glyph 0))
 450 (defsubst lglyph-to (glyph) (aref glyph 1))
 451 (defsubst lglyph-char (glyph) (aref glyph 2))
 452 (defsubst lglyph-code (glyph) (aref glyph 3))
 453 (defsubst lglyph-width (glyph) (aref glyph 4))
 454 (defsubst lglyph-lbearing (glyph) (aref glyph 5))
 455 (defsubst lglyph-rbearing (glyph) (aref glyph 6))
 456 (defsubst lglyph-ascent (glyph) (aref glyph 7))
 457 (defsubst lglyph-descent (glyph) (aref glyph 8))
 458 (defsubst lglyph-adjustment (glyph) (aref glyph 9))
 459
 460 (defsubst lglyph-set-from-to (glyph from to)
 461   (progn (aset glyph 0 from) (aset glyph 1 to)))
 462 (defsubst lglyph-set-char (glyph char) (aset glyph 2 char))
 463 (defsubst lglyph-set-code (glyph code) (aset glyph 3 code))
 464 (defsubst lglyph-set-width (glyph width) (aset glyph 4 width))
 465 (defsubst lglyph-set-adjustment (glyph &optional xoff yoff wadjust)
 466   (aset glyph 9 (vector (or xoff 0) (or yoff 0) (or wadjust 0))))
 467
 468 (defsubst lglyph-copy (glyph) (copy-sequence glyph))
 469
 470 (defun lgstring-insert-glyph (gstring idx glyph)
 471   (let ((nglyphs (lgstring-glyph-len gstring))
 472         (i idx) g)
 473     (while (and (< i nglyphs) (setq g (lgstring-glyph gstring i)))
 474       (setq i (1+ i)))
 475     (if (= i nglyphs)
 476         (setq gstring (vconcat gstring (vector glyph)))
 477       (if (< (1+ i) nglyphs)
 478           (lgstring-set-glyph gstring (1+ i) nil)))
 479     (while (> i idx)
 480       (lgstring-set-glyph gstring i (lgstring-glyph gstring (1- i)))
 481       (setq i (1- i)))
 482     (lgstring-set-glyph gstring i glyph)
 483     gstring))
 484
 485 (defun compose-glyph-string (gstring from to)
 486   (let ((glyph (lgstring-glyph gstring from))
 487         from-pos to-pos
 488         ascent descent lbearing rbearing)
 489     (setq from-pos (lglyph-from glyph)
 490           to-pos (lglyph-to (lgstring-glyph gstring (1- to))))
 491     (lglyph-set-from-to glyph from-pos to-pos)
 492     (setq from (1+ from))
 493     (while (and (< from to)
 494                 (setq glyph (lgstring-glyph gstring from)))
 495       (lglyph-set-from-to glyph from-pos to-pos)
 496       (let ((xoff (if (<= (lglyph-rbearing glyph) 0) 0
 497                     (- (lglyph-width glyph)))))
 498         (lglyph-set-adjustment glyph xoff 0 0))
 499       (setq from (1+ from)))
 500     gstring))
 501
 502 (defun compose-glyph-string-relative (gstring from to &optional gap)
 503   (let ((font-object (lgstring-font gstring))
 504         (glyph (lgstring-glyph gstring from))
 505         from-pos to-pos
 506         ascent descent lbearing rbearing)
 507     (if gap
 508         (setq gap (floor (* (font-get font-object :size) gap)))
 509       (setq gap 0))
 510     (setq from-pos (lglyph-from glyph)
 511           to-pos (lglyph-to (lgstring-glyph gstring (1- to)))
 512           ascent (lglyph-ascent glyph)
 513           descent (lglyph-descent glyph))
 514     (lglyph-set-from-to glyph from-pos to-pos)
 515     (setq from (1+ from))
 516     (while (< from to)
 517       (setq glyph (lgstring-glyph gstring from))
 518       (lglyph-set-from-to glyph from-pos to-pos)
 519       (let ((this-ascent (lglyph-ascent glyph))
 520             (this-descent (lglyph-descent glyph))
 521             xoff yoff wadjust)
 522         (setq xoff (if (<= (lglyph-rbearing glyph) 0) 0
 523                      (- (lglyph-width glyph))))
 524         (if (> this-ascent 0)
 525             (if (< this-descent 0)
 526                 (setq yoff (- 0 ascent gap this-descent)
 527                       ascent (+ ascent gap this-ascent this-descent))
 528               (setq yoff 0))
 529           (setq yoff (+ descent gap this-ascent)
 530                 descent (+ descent gap this-ascent this-descent)))
 531         (if (or (/= xoff 0) (/= yoff 0))
 532             (lglyph-set-adjustment glyph xoff yoff 0)))
 533       (setq from (1+ from)))
 534     gstring))
 535
 536 (defun compose-gstring-for-graphic (gstring)
 537   "Compose glyph-string GSTRING for graphic display.
 538 Combining characters are composed with the preceding base
 539 character.  If the preceding character is not a base character,
 540 each combining character is composed as a spacing character by
 541 a padding space before and/or after the character.
 542
 543 All non-spacing characters have this function in
 544 `composition-function-table' unless overwritten."
 545   (let* ((header (lgstring-header gstring))
 546          (nchars (lgstring-char-len gstring))
 547          (nglyphs (lgstring-glyph-len gstring))
 548          (glyph (lgstring-glyph gstring 0)))
 549     (cond
 550      ;; A non-spacing character not following a proper base character.
 551      ((= nchars 1)
 552       (let ((lbearing (lglyph-lbearing glyph))
 553             (rbearing (lglyph-rbearing glyph))
 554             (width (lglyph-width glyph))
 555             xoff wadjust)
 556         (if (< lbearing 0)
 557             (setq xoff (- lbearing))
 558           (setq xoff 0 lbearing 0))
 559         (if (< rbearing width)
 560             (setq rbearing width))
 561         (lglyph-set-adjustment glyph xoff 0 (- rbearing lbearing))
 562         gstring))
 563
 564      ;; This sequence doesn't start with a proper base character.
 565      ((memq (get-char-code-property (lgstring-char gstring 0)
 566                                     'general-category)
 567             '(Mn Mc Me Zs Zl Zp Cc Cf Cs))
 568       nil)
 569
 570      ;; A base character and the following non-spacing characters.
 571      (t
 572       (let ((gstr (font-shape-gstring gstring)))
 573         (if (and gstr
 574                  (> (lglyph-to (lgstring-glyph gstr 0)) 0))
 575             gstr
 576           ;; The shaper of the font couldn't shape the gstring.
 577           ;; Shape them according to canonical-combining-class.
 578           (lgstring-set-id gstring nil)
 579           (let* ((width (lglyph-width glyph))
 580                  (ascent (lglyph-ascent glyph))
 581                  (descent (lglyph-descent glyph))
 582                  (rbearing (lglyph-rbearing glyph))
 583                  (lbearing (lglyph-lbearing glyph))
 584                  (center (/ (+ lbearing rbearing) 2))
 585                  (gap (round (* (font-get (lgstring-font gstring) :size) 0.1)))
 586                  xoff yoff)
 587             (dotimes (i nchars)
 588               (setq glyph (lgstring-glyph gstring i))
 589               (when (> i 0)
 590                 (let* ((class (get-char-code-property
 591                                (lglyph-char glyph) 'canonical-combining-class))
 592                        (lb (lglyph-lbearing glyph))
 593                        (rb (lglyph-rbearing glyph))
 594                        (as (lglyph-ascent glyph))
 595                        (de (lglyph-descent glyph))
 596                        (ce (/ (+ lb rb) 2))
 597                        xoff yoff)
 598                   (when (and class (>= class 200) (<= class 240))
 599                     (setq xoff 0 yoff 0)
 600                     (cond
 601                      ((= class 200)
 602                       (setq xoff (- lbearing ce)
 603                             yoff (if (> as 0) 0 (+ descent as))))
 604                      ((= class 202)
 605                       (if (> as 0) (setq as 0))
 606                       (setq xoff (- center ce)
 607                             yoff (if (> as 0) 0 (+ descent as))))
 608                      ((= class 204)
 609                       (if (> as 0) (setq as 0))
 610                       (setq xoff (- rbearing ce)
 611                             yoff (if (> as 0) 0 (+ descent as))))
 612                      ((= class 208)
 613                       (setq xoff (- lbearing rb)))
 614                      ((= class 210)
 615                       (setq xoff (- rbearing lb)))
 616                      ((= class 212)
 617                       (setq xoff (- lbearing ce)
 618                             yoff (if (>= de 0) 0 (- (- ascent) de))))
 619                      ((= class 214)
 620                       (setq xoff (- center ce)
 621                             yoff (if (>= de 0) 0 (- (- ascent) de))))
 622                      ((= class 216)
 623                       (setq xoff (- rbearing ce)
 624                             yoff (if (>= de 0) 0 (- (- ascent) de))))
 625                      ((= class 218)
 626                       (setq xoff (- lbearing ce)
 627                             yoff (if (> as 0) 0 (+ descent as gap))))
 628                      ((= class 220)
 629                       (setq xoff (- center ce)
 630                             yoff (if (> as 0) 0 (+ descent as gap))))
 631                      ((= class 222)
 632                       (setq xoff (- rbearing ce)
 633                             yoff (if (> as 0) 0 (+ descent as gap))))
 634                      ((= class 224)
 635                       (setq xoff (- lbearing rb)))
 636                      ((= class 226)
 637                       (setq xoff (- rbearing lb)))
 638                      ((= class 228)
 639                       (setq xoff (- lbearing ce)
 640                             yoff (if (>= de 0) 0 (- (- ascent) de gap))))
 641                      ((= class 230)
 642                       (setq xoff (- center ce)
 643                             yoff (if (>= de 0) 0 (- (- ascent) de gap))))
 644                      ((= class 232)
 645                       (setq xoff (- rbearing ce)
 646                             yoff (if (>= de 0) 0 (- (+ ascent de) gap)))))
 647                     (lglyph-set-adjustment glyph (- xoff width) yoff)
 648                     (setq lb (+ lb xoff)
 649                           rb (+ lb xoff)
 650                           as (- as yoff)
 651                           de (+ de yoff)))
 652                   (if (< ascent as)
 653                       (setq ascent as))
 654                   (if (< descent de)
 655                       (setq descent de))))))
 656           (let ((i 0))
 657             (while (and (< i nglyphs) (setq glyph (lgstring-glyph gstring i)))
 658               (lglyph-set-from-to glyph 0 (1- nchars))
 659               (setq i (1+ i))))
 660           gstring))))))
 661
 662 (let ((elt `([,(purecopy "\\c.\\c^+") 1 compose-gstring-for-graphic]
 663              [nil 0 compose-gstring-for-graphic])))
 664   (map-char-table
 665    #'(lambda (key val)
 666        (if (memq val '(Mn Mc Me))
 667            (set-char-table-range composition-function-table key elt)))
 668    unicode-category-table))
 669
 670 (defun compose-gstring-for-terminal (gstring)
 671   "Compose glyph string GSTRING for terminal display.
 672 Non-spacing characters are composed with the preceding base
 673 character.  If the preceding character is not a base character,
 674 each non-spacing character is composed as a spacing character by
 675 prepending a space before it."
 676   (let* ((header (lgstring-header gstring))
 677          (nchars (lgstring-char-len gstring))
 678          (nglyphs (lgstring-glyph-len gstring))
 679          (i 0)
 680          (coding (lgstring-font gstring))
 681          glyph)
 682     (while (and (< i nglyphs)
 683                 (setq glyph (lgstring-glyph gstring i)))
 684       (if (not (char-charset (lglyph-char glyph) coding))
 685           (progn
 686             ;; As the terminal doesn't support this glyph, return a
 687             ;; gstring in which each glyph is its own graphme-cluster
 688             ;; of width 1..
 689             (setq i 0)
 690             (while (and (< i nglyphs)
 691                         (setq glyph (lgstring-glyph gstring i)))
 692               (if (< (lglyph-width glyph) 1)
 693                   (lglyph-set-width glyph 1))
 694               (lglyph-set-from-to glyph i i)
 695               (setq i (1+ i))))
 696         (if (= (lglyph-width glyph) 0)
 697             (if (eq (get-char-code-property (lglyph-char glyph)
 698                                             'general-category)
 699                     'Cf)
 700                 (progn
 701                   ;; Compose by replacing with a space.
 702                   (lglyph-set-char glyph 32)
 703                   (lglyph-set-width glyph 1)
 704                   (setq i (1+ i)))
 705               ;; Compose by prepending a space.
 706               (setq gstring (lgstring-insert-glyph gstring i
 707                                                    (lglyph-copy glyph))
 708                     nglyphs (lgstring-glyph-len gstring))
 709               (setq glyph (lgstring-glyph gstring i))
 710               (lglyph-set-char glyph 32)
 711               (lglyph-set-width glyph 1)
 712               (setq i (+ 2)))
 713           (let ((from (lglyph-from glyph))
 714                 (to (lglyph-to glyph))
 715                 (j (1+ i)))
 716             (while (and (< j nglyphs)
 717                         (setq glyph (lgstring-glyph gstring j))
 718                         (char-charset (lglyph-char glyph) coding)
 719                         (= (lglyph-width glyph) 0))
 720               (setq to (lglyph-to glyph)
 721                     j (1+ j)))
 722             (while (< i j)
 723               (setq glyph (lgstring-glyph gstring i))
 724               (lglyph-set-from-to glyph from to)
 725               (setq i (1+ i)))))))
 726     gstring))
 727
 728
 729 (defun auto-compose-chars (func from to font-object string)
 730   "Compose the characters at FROM by FUNC.
 731 FUNC is called with one argument GSTRING which is built for characters
 732 in the region FROM (inclusive) and TO (exclusive).
 733
 734 If the character are composed on a graphic display, FONT-OBJECT
 735 is a font to use.  Otherwise, FONT-OBJECT is nil, and the function
 736 `compose-gstring-for-terminal' is used instead of FUNC.
 737
 738 If STRING is non-nil, it is a string, and FROM and TO are indices
 739 into the string.  In that case, compose characters in the string.
 740
 741 The value is a gstring containing information for shaping the characters.
 742
 743 This function is the default value of `auto-composition-function' (which see)."
 744   (let ((gstring (composition-get-gstring from to font-object string)))
 745     (if (lgstring-shaped-p gstring)
 746         gstring
 747       (or (fontp font-object 'font-object)
 748           (setq func 'compose-gstring-for-terminal))
 749       (funcall func gstring))))
 750
 751 (put 'auto-composition-mode 'permanent-local t)
 752
 753 (make-variable-buffer-local 'auto-composition-function)
 754 (setq-default auto-composition-function 'auto-compose-chars)
 755
 756 ;;;###autoload
 757 (define-minor-mode auto-composition-mode
 758   "Toggle Auto Composition mode.
 759 With ARG, turn Auto Composition mode off if and only if ARG is a non-positive
 760 number; if ARG is nil, toggle Auto Composition mode; anything else turns Auto
 761 Composition on.
 762
 763 When Auto Composition is enabled, text characters are automatically composed
 764 by functions registered in `composition-function-table' (which see).
 765
 766 You can use `global-auto-composition-mode' to turn on
 767 Auto Composition mode in all buffers (this is the default).")
 768
 769 ;;;###autoload
 770 (define-minor-mode global-auto-composition-mode
 771   "Toggle Auto-Composition mode in every possible buffer.
 772 With prefix arg, turn Global-Auto-Composition mode on if and only if arg
 773 is positive.
 774 See `auto-composition-mode' for more information on Auto-Composition mode."
 775   :variable (default-value 'auto-composition-mode))
 776
 777 (defalias 'toggle-auto-composition 'auto-composition-mode)
 778
 779 \f
 780 ;; The following codes are only for backward compatibility with Emacs
 781 ;; 20.4 and earlier.
 782
 783 (defun decompose-composite-char (char &optional type with-composition-rule)
 784   "Convert CHAR to string.
 785
 786 If optional 2nd arg TYPE is non-nil, it is `string', `list', or
 787 `vector'.  In this case, CHAR is converted to string, list of CHAR, or
 788 vector of CHAR respectively.
 789 Optional 3rd arg WITH-COMPOSITION-RULE is ignored."
 790   (cond ((or (null type) (eq type 'string)) (char-to-string char))
 791         ((eq type 'list) (list char))
 792         (t (vector char))))
 793
 794 (make-obsolete 'decompose-composite-char 'char-to-string "21.1")
 795
 796 \f
 797
 798 ;; arch-tag: ee703d77-1723-45d4-a31f-e9f0f867aa33
 799 ;;; composite.el ends here