lisp/cedet/cedet-cscope.el

   1 ;;; cedet-cscope.el --- CScope support for CEDET
   2
   3 ;;; Copyright (C) 2009, 2010 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric M. Ludlam <zappo@gnu.org>
   6 ;; Package: cedet
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24 ;;
  25 ;; Support using CScope for symbol lookups.
  26
  27 ;;; Code:
  28
  29 (declare-function inversion-check-version "inversion")
  30
  31 (defvar cedet-cscope-min-version "16.0"
  32   "Minimum version of CScope required.")
  33
  34 (defcustom cedet-cscope-command "cscope"
  35   "Command name for the CScope executable."
  36   :type 'string
  37   :group 'cedet)
  38
  39 (defun cedet-cscope-search (searchtext texttype type scope)
  40   "Perform a search with CScope, return the created buffer.
  41 SEARCHTEXT is text to find.
  42 TEXTTYPE is the type of text, such as 'regexp, 'string, 'tagname,
  43 'tagregexp, or 'tagcompletions.
  44 TYPE is the type of search, meaning that SEARCHTEXT is compared to
  45 filename, tagname (tags table), references (uses of a tag) , or
  46 symbol (uses of something not in the tag table.)
  47 SCOPE is the scope of the search, such as 'project or 'subdirs."
  48   ;; CScope is an interactive program.  It uses number flags
  49   ;; in order to perform command line searches.  Useful for this
  50   ;; tool are:
  51   ;;
  52   ;; -0 = Find C symbol
  53   ;; -1 = Find global definition
  54   ;; -3 = Find references
  55   ;; -6 = Find egrep pattern
  56   ;; -7 = Find file
  57   (let ((idx (cond ((eq type 'file)
  58                     "-7")
  59                    ;; Non files are symbols and such
  60                    ((eq texttype 'tagname)
  61                     "-1")
  62                    ((eq texttype 'tagregexp)
  63                     "-0")
  64                    ((eq texttype 'tagcompletions)
  65                     (setq searchtext (concat "^" searchtext ".*"))
  66                     "-1")
  67                    ((eq texttype 'regexp)
  68                     "-5")
  69                    (t
  70                     "-3")
  71                    )
  72              )
  73         )
  74     (cedet-cscope-call (list "-d" "-L" idx searchtext))))
  75
  76 (defun cedet-cscope-call (flags)
  77   "Call CScope with the list of FLAGS."
  78   (let ((b (get-buffer-create "*CEDET CScope*"))
  79         (cd default-directory)
  80         )
  81     (with-current-buffer b
  82       (setq default-directory cd)
  83       (erase-buffer))
  84     (apply 'call-process cedet-cscope-command
  85            nil b nil
  86            flags)
  87     b))
  88
  89 (defun cedet-cscope-expand-filename (filename)
  90   "Expand the FILENAME with CScope.
  91 Return a fully qualified filename."
  92   (interactive "sFile: ")
  93   (let* ((ans1 (with-current-buffer
  94                    (cedet-cscope-call (list "-d" "-L" "-7" filename))
  95                  (goto-char (point-min))
  96                  (if (looking-at "[^ \n]*cscope: ")
  97                      (error "CScope not available")
  98                    (split-string (buffer-string) "\n" t))))
  99          (ans2 (mapcar (lambda (hit)
 100                          (expand-file-name (car (split-string hit " "))))
 101                        ans1)))
 102     (when (called-interactively-p 'interactive)
 103       (if ans2
 104           (if (= (length ans2) 1)
 105               (message "%s" (car ans2))
 106             (message "%s + %d others" (car ans2)
 107                      (length (cdr ans2))))
 108         (error "No file found")))
 109     ans2))
 110
 111 (defun cedet-cscope-support-for-directory (&optional dir)
 112   "Return non-nil if CScope has a support file for DIR.
 113 If DIR is not supplied, use the current default directory.
 114 This works by running cscope on a bogus symbol, and looking for
 115 the error code."
 116   (save-excursion
 117     (let ((default-directory (or dir default-directory)))
 118       (set-buffer (cedet-cscope-call (list "-d" "-L" "-7" "moose")))
 119       (goto-char (point-min))
 120       (if (looking-at "[^ \n]*cscope: ")
 121           nil
 122         t))))
 123
 124 (defun cedet-cscope-version-check (&optional noerror)
 125   "Check the version of the installed CScope command.
 126 If optional programatic argument NOERROR is non-nil, then
 127 instead of throwing an error if CScope isn't available, then
 128 return nil."
 129   (interactive)
 130   (require 'inversion)
 131   (let ((b (condition-case nil
 132                (cedet-cscope-call (list "-V"))
 133              (error nil)))
 134         (rev nil))
 135     (if (not b)
 136         (progn
 137           (when (called-interactively-p 'interactive)
 138             (message "CScope not found."))
 139           nil)
 140       (with-current-buffer b
 141         (goto-char (point-min))
 142         (re-search-forward "cscope: version \\([0-9.]+\\)" nil t)
 143         (setq rev (match-string 1))
 144         (if (inversion-check-version rev nil cedet-cscope-min-version)
 145             (if noerror
 146                 nil
 147               (error "Version of CScope is %s.  Need at least %s"
 148                      rev cedet-cscope-min-version))
 149           ;; Else, return TRUE, as in good enough.
 150           (when (called-interactively-p 'interactive)
 151             (message "CScope %s  - Good enough for CEDET." rev))
 152           t)))))
 153
 154 (provide 'cedet-cscope)
 155
 156 ;; arch-tag: 9973f1ad-f13b-4399-bc67-7f488478d78d
 157 ;;; cedet-cscope.el ends here