lisp/log-edit.el

   1 ;;; log-edit.el --- Major mode for editing CVS commit messages
   2
   3 ;; Copyright (C) 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007,
   4 ;;   2008, 2009, 2010, 2011  Free Software Foundation, Inc.
   5
   6 ;; Author: Stefan Monnier <monnier@iro.umontreal.ca>
   7 ;; Keywords: pcl-cvs cvs commit log
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Todo:
  27
  28 ;; - Move in VC's code
  29 ;; - Add compatibility for VC's hook variables
  30
  31 ;;; Code:
  32
  33 (eval-when-compile (require 'cl))
  34 (require 'add-log)                      ; for all the ChangeLog goodies
  35 (require 'pcvs-util)
  36 (require 'ring)
  37
  38 ;;;;
  39 ;;;; Global Variables
  40 ;;;;
  41
  42 (defgroup log-edit nil
  43   "Major mode for editing RCS and CVS commit messages."
  44   :group 'pcl-cvs
  45   :group 'vc                            ; It's used by VC.
  46   :version "21.1"
  47   :prefix "log-edit-")
  48
  49 ;; compiler pacifiers
  50 (defvar cvs-buffer)
  51
  52 \f
  53 ;; The main keymap
  54
  55 (easy-mmode-defmap log-edit-mode-map
  56   `(("\C-c\C-c" . log-edit-done)
  57     ("\C-c\C-a" . log-edit-insert-changelog)
  58     ("\C-c\C-d" . log-edit-show-diff)
  59     ("\C-c\C-f" . log-edit-show-files)
  60     ("\M-n"     . log-edit-next-comment)
  61     ("\M-p"     . log-edit-previous-comment)
  62     ("\M-r"     . log-edit-comment-search-backward)
  63     ("\M-s"     . log-edit-comment-search-forward)
  64     ("\C-c?"    . log-edit-mode-help))
  65   "Keymap for the `log-edit-mode' (to edit version control log messages)."
  66   :group 'log-edit)
  67
  68 ;; Compatibility with old names.  Should we bother ?
  69 (defvar vc-log-mode-map log-edit-mode-map)
  70 (defvar vc-log-entry-mode vc-log-mode-map)
  71
  72 (easy-menu-define log-edit-menu log-edit-mode-map
  73   "Menu used for `log-edit-mode'."
  74   '("Log-Edit"
  75     ["Done" log-edit-done
  76      :help "Exit log-edit and proceed with the actual action."]
  77     "--"
  78     ["Insert ChangeLog" log-edit-insert-changelog
  79      :help "Insert a log message by looking at the ChangeLog"]
  80     ["Add to ChangeLog" log-edit-add-to-changelog
  81      :help "Insert this log message into the appropriate ChangeLog file"]
  82     "--"
  83     ["Show diff" log-edit-show-diff
  84      :help "Show the diff for the files to be committed."]
  85     ["List files" log-edit-show-files
  86      :help "Show the list of relevant files."]
  87     "--"
  88     ["Previous comment"         log-edit-previous-comment
  89      :help "Cycle backwards through comment history"]
  90     ["Next comment"             log-edit-next-comment
  91      :help "Cycle forwards through comment history."]
  92     ["Search comment forward"   log-edit-comment-search-forward
  93      :help "Search forwards through comment history for a substring match of str"]
  94     ["Search comment backward"  log-edit-comment-search-backward
  95      :help "Search backwards through comment history for substring match of str"]))
  96
  97 (defcustom log-edit-confirm 'changed
  98   "If non-nil, `log-edit-done' will request confirmation.
  99 If 'changed, only request confirmation if the list of files has
 100   changed since the beginning of the log-edit session."
 101   :group 'log-edit
 102   :type '(choice (const changed) (const t) (const nil)))
 103
 104 (defcustom log-edit-keep-buffer nil
 105   "If non-nil, don't hide the buffer after `log-edit-done'."
 106   :group 'log-edit
 107   :type 'boolean)
 108
 109 (defvar cvs-commit-buffer-require-final-newline t)
 110 (make-obsolete-variable 'cvs-commit-buffer-require-final-newline
 111                         'log-edit-require-final-newline
 112                         "21.1")
 113
 114 (defcustom log-edit-require-final-newline
 115   cvs-commit-buffer-require-final-newline
 116   "Enforce a newline at the end of commit log messages.
 117 Enforce it silently if t, query if non-nil and don't do anything if nil."
 118   :group 'log-edit
 119   :type '(choice (const ask) (const t) (const nil)))
 120
 121 (defcustom log-edit-setup-invert nil
 122   "Non-nil means `log-edit' should invert the meaning of its SETUP arg.
 123 If SETUP is 'force, this variable has no effect."
 124   :group 'log-edit
 125   :type 'boolean)
 126
 127 (defcustom log-edit-hook '(log-edit-insert-cvs-template
 128                            log-edit-show-files
 129                            log-edit-insert-changelog)
 130   "Hook run at the end of `log-edit'."
 131   :group 'log-edit
 132   :type '(hook :options (log-edit-insert-changelog
 133                          log-edit-insert-cvs-rcstemplate
 134                          log-edit-insert-cvs-template
 135                          log-edit-insert-filenames)))
 136
 137 (defcustom log-edit-mode-hook (if (boundp 'vc-log-mode-hook) vc-log-mode-hook)
 138   "Hook run when entering `log-edit-mode'."
 139   :group 'log-edit
 140   :type 'hook)
 141
 142 (defcustom log-edit-done-hook nil
 143   "Hook run before doing the actual commit.
 144 This hook can be used to cleanup the message, enforce various
 145 conventions, or to allow recording the message in some other database,
 146 such as a bug-tracking system.  The list of files about to be committed
 147 can be obtained from `log-edit-files'."
 148   :group 'log-edit
 149   :type '(hook :options (log-edit-set-common-indentation
 150                          log-edit-add-to-changelog)))
 151
 152 (defcustom log-edit-strip-single-file-name t
 153   "If non-nil, remove file name from single-file log entries."
 154   :type 'boolean
 155   :safe 'booleanp
 156   :group 'log-edit
 157   :version "23.2")
 158
 159 (defvar cvs-changelog-full-paragraphs t)
 160 (make-obsolete-variable 'cvs-changelog-full-paragraphs
 161                         'log-edit-changelog-full-paragraphs
 162                         "21.1")
 163
 164 (defvar log-edit-changelog-full-paragraphs cvs-changelog-full-paragraphs
 165   "*If non-nil, include full ChangeLog paragraphs in the log.
 166 This may be set in the ``local variables'' section of a ChangeLog, to
 167 indicate the policy for that ChangeLog.
 168
 169 A ChangeLog paragraph is a bunch of log text containing no blank lines;
 170 a paragraph usually describes a set of changes with a single purpose,
 171 but perhaps spanning several functions in several files.  Changes in
 172 different paragraphs are unrelated.
 173
 174 You could argue that the log entry for a file should contain the
 175 full ChangeLog paragraph mentioning the change to the file, even though
 176 it may mention other files, because that gives you the full context you
 177 need to understand the change.  This is the behavior you get when this
 178 variable is set to t.
 179
 180 On the other hand, you could argue that the log entry for a change
 181 should contain only the text for the changes which occurred in that
 182 file, because the log is per-file.  This is the behavior you get
 183 when this variable is set to nil.")
 184
 185 ;;;; Internal global or buffer-local vars
 186
 187 (defconst log-edit-files-buf "*log-edit-files*")
 188 (defvar log-edit-initial-files nil)
 189 (defvar log-edit-callback nil)
 190 (defvar log-edit-diff-function nil)
 191 (defvar log-edit-listfun nil)
 192
 193 (defvar log-edit-parent-buffer nil)
 194
 195 ;;; Originally taken from VC-Log mode
 196
 197 (defconst log-edit-maximum-comment-ring-size 32
 198   "Maximum number of saved comments in the comment ring.")
 199 (defvar log-edit-comment-ring (make-ring log-edit-maximum-comment-ring-size))
 200 (defvar log-edit-comment-ring-index nil)
 201 (defvar log-edit-last-comment-match "")
 202
 203 (defun log-edit-new-comment-index (stride len)
 204   "Return the comment index STRIDE elements from the current one.
 205 LEN is the length of `log-edit-comment-ring'."
 206   (mod (cond
 207         (log-edit-comment-ring-index (+ log-edit-comment-ring-index stride))
 208         ;; Initialize the index on the first use of this command
 209         ;; so that the first M-p gets index 0, and the first M-n gets
 210         ;; index -1.
 211         ((> stride 0) (1- stride))
 212         (t stride))
 213        len))
 214
 215 (defun log-edit-previous-comment (arg)
 216   "Cycle backwards through comment history.
 217 With a numeric prefix ARG, go back ARG comments."
 218   (interactive "*p")
 219   (let ((len (ring-length log-edit-comment-ring)))
 220     (if (<= len 0)
 221         (progn (message "Empty comment ring") (ding))
 222       ;; Don't use `erase-buffer' because we don't want to `widen'.
 223       (delete-region (point-min) (point-max))
 224       (setq log-edit-comment-ring-index (log-edit-new-comment-index arg len))
 225       (message "Comment %d" (1+ log-edit-comment-ring-index))
 226       (insert (ring-ref log-edit-comment-ring log-edit-comment-ring-index)))))
 227
 228 (defun log-edit-next-comment (arg)
 229   "Cycle forwards through comment history.
 230 With a numeric prefix ARG, go forward ARG comments."
 231   (interactive "*p")
 232   (log-edit-previous-comment (- arg)))
 233
 234 (defun log-edit-comment-search-backward (str &optional stride)
 235   "Search backwards through comment history for substring match of STR.
 236 If the optional argument STRIDE is present, that is a step-width to use
 237 when going through the comment ring."
 238   ;; Why substring rather than regexp ?   -sm
 239   (interactive
 240    (list (read-string "Comment substring: " nil nil log-edit-last-comment-match)))
 241   (unless stride (setq stride 1))
 242   (if (string= str "")
 243       (setq str log-edit-last-comment-match)
 244     (setq log-edit-last-comment-match str))
 245   (let* ((str (regexp-quote str))
 246          (len (ring-length log-edit-comment-ring))
 247          (n (log-edit-new-comment-index stride len)))
 248     (while (progn (when (or (>= n len) (< n 0)) (error "Not found"))
 249                   (not (string-match str (ring-ref log-edit-comment-ring n))))
 250       (setq n (+ n stride)))
 251     (setq log-edit-comment-ring-index n)
 252     (log-edit-previous-comment 0)))
 253
 254 (defun log-edit-comment-search-forward (str)
 255   "Search forwards through comment history for a substring match of STR."
 256   (interactive
 257    (list (read-string "Comment substring: " nil nil log-edit-last-comment-match)))
 258   (log-edit-comment-search-backward str -1))
 259
 260 (defun log-edit-comment-to-change-log (&optional whoami file-name)
 261   "Enter last VC comment into the change log for the current file.
 262 WHOAMI (interactive prefix) non-nil means prompt for user name
 263 and site.  FILE-NAME is the name of the change log; if nil, use
 264 `change-log-default-name'.
 265
 266 This may be useful as a `log-edit-checkin-hook' to update change logs
 267 automatically."
 268   (interactive (if current-prefix-arg
 269                    (list current-prefix-arg
 270                          (prompt-for-change-log-name))))
 271   (let (;; Extract the comment first so we get any error before doing anything.
 272         (comment (ring-ref log-edit-comment-ring 0))
 273         ;; Don't let add-change-log-entry insert a defun name.
 274         (add-log-current-defun-function 'ignore)
 275         end)
 276     ;; Call add-log to do half the work.
 277     (add-change-log-entry whoami file-name t t)
 278     ;; Insert the VC comment, leaving point before it.
 279     (setq end (save-excursion (insert comment) (point-marker)))
 280     (if (looking-at "\\s *\\s(")
 281         ;; It starts with an open-paren, as in "(foo): Frobbed."
 282         ;; So remove the ": " add-log inserted.
 283         (delete-char -2))
 284     ;; Canonicalize the white space between the file name and comment.
 285     (just-one-space)
 286     ;; Indent rest of the text the same way add-log indented the first line.
 287     (let ((indentation (current-indentation)))
 288       (save-excursion
 289         (while (< (point) end)
 290           (forward-line 1)
 291           (indent-to indentation))
 292         (setq end (point))))
 293     ;; Fill the inserted text, preserving open-parens at bol.
 294     (let ((paragraph-start (concat paragraph-start "\\|\\s *\\s(")))
 295       (beginning-of-line)
 296       (fill-region (point) end))
 297     ;; Canonicalize the white space at the end of the entry so it is
 298     ;; separated from the next entry by a single blank line.
 299     (skip-syntax-forward " " end)
 300     (delete-char (- (skip-syntax-backward " ")))
 301     (or (eobp) (looking-at "\n\n")
 302         (insert "\n"))))
 303
 304 ;; Compatibility with old names.
 305 (define-obsolete-variable-alias 'vc-comment-ring 'log-edit-comment-ring "22.1")
 306 (define-obsolete-variable-alias 'vc-comment-ring-index 'log-edit-comment-ring-index "22.1")
 307 (define-obsolete-function-alias 'vc-previous-comment 'log-edit-previous-comment "22.1")
 308 (define-obsolete-function-alias 'vc-next-comment 'log-edit-next-comment "22.1")
 309 (define-obsolete-function-alias 'vc-comment-search-reverse 'log-edit-comment-search-backward "22.1")
 310 (define-obsolete-function-alias 'vc-comment-search-forward 'log-edit-comment-search-forward "22.1")
 311 (define-obsolete-function-alias 'vc-comment-to-change-log 'log-edit-comment-to-change-log "22.1")
 312
 313 ;;;
 314 ;;; Actual code
 315 ;;;
 316
 317 (defface log-edit-summary '((t :inherit font-lock-function-name-face))
 318   "Face for the summary in `log-edit-mode' buffers.")
 319
 320 (defface log-edit-header '((t :inherit font-lock-keyword-face))
 321   "Face for the headers in `log-edit-mode' buffers.")
 322
 323 (defface log-edit-unknown-header '((t :inherit font-lock-comment-face))
 324   "Face for unknown headers in `log-edit-mode' buffers.")
 325
 326 (defvar log-edit-headers-alist '(("Summary" . log-edit-summary)
 327                                  ("Fixes") ("Author"))
 328   "AList of known headers and the face to use to highlight them.")
 329
 330 (defconst log-edit-header-contents-regexp
 331   "[ \t]*\\(.*\\(\n[ \t].*\\)*\\)\n?")
 332
 333 (defun log-edit-match-to-eoh (limit)
 334   ;; FIXME: copied from message-match-to-eoh.
 335   (let ((start (point)))
 336     (rfc822-goto-eoh)
 337     ;; Typical situation: some temporary change causes the header to be
 338     ;; incorrect, so EOH comes earlier than intended: the last lines of the
 339     ;; intended headers are now not considered part of the header any more,
 340     ;; so they don't have the multiline property set.  When the change is
 341     ;; completed and the header has its correct shape again, the lack of the
 342     ;; multiline property means we won't rehighlight the last lines of
 343     ;; the header.
 344     (if (< (point) start)
 345         nil                             ;No header within start..limit.
 346       ;; Here we disregard LIMIT so that we may extend the area again.
 347       (set-match-data (list start (point)))
 348       (point))))
 349
 350 (defvar log-edit-font-lock-keywords
 351   ;; Copied/inspired by message-font-lock-keywords.
 352   `((log-edit-match-to-eoh
 353      (,(concat "^\\(\\([a-z]+\\):\\)" log-edit-header-contents-regexp)
 354       (progn (goto-char (match-beginning 0)) (match-end 0)) nil
 355       (1 (if (assoc (match-string 2) log-edit-headers-alist)
 356              'log-edit-header
 357            'log-edit-unknown-header)
 358          nil lax)
 359       ;; From `log-edit-header-contents-regexp':
 360       (3 (or (cdr (assoc (match-string 2) log-edit-headers-alist))
 361              'log-edit-header)
 362          nil lax)))))
 363
 364 ;;;###autoload
 365 (defun log-edit (callback &optional setup params buffer mode &rest ignore)
 366   "Setup a buffer to enter a log message.
 367 \\<log-edit-mode-map>The buffer will be put in mode MODE or `log-edit-mode'
 368 if MODE is nil.
 369 If SETUP is non-nil, the buffer is then erased and `log-edit-hook' is run.
 370 Mark and point will be set around the entire contents of the buffer so
 371 that it is easy to kill the contents of the buffer with \\[kill-region].
 372 Once you're done editing the message, pressing \\[log-edit-done] will call
 373 `log-edit-done' which will end up calling CALLBACK to do the actual commit.
 374
 375 PARAMS if non-nil is an alist.  Possible keys and associated values:
 376  `log-edit-listfun' -- function taking no arguments that returns the list of
 377  files that are concerned by the current operation (using relative names);
 378  `log-edit-diff-function' -- function taking no arguments that
 379  displays a diff of the files concerned by the current operation.
 380
 381 If BUFFER is non-nil `log-edit' will jump to that buffer, use it to edit the
 382 log message and go back to the current buffer when done.  Otherwise, it
 383 uses the current buffer."
 384   (let ((parent (current-buffer)))
 385     (if buffer (pop-to-buffer buffer))
 386     (when (and log-edit-setup-invert (not (eq setup 'force)))
 387       (setq setup (not setup)))
 388     (when setup
 389       (erase-buffer)
 390       (insert "Summary: ")
 391       (save-excursion (insert "\n\n")))
 392     (if mode
 393         (funcall mode)
 394       (log-edit-mode))
 395     (set (make-local-variable 'log-edit-callback) callback)
 396     (if (listp params)
 397         (dolist (crt params)
 398           (set (make-local-variable (car crt)) (cdr crt)))
 399       ;; For backward compatibility with log-edit up to version 22.2
 400       ;; accept non-list PARAMS to mean `log-edit-list'.
 401       (set (make-local-variable 'log-edit-listfun) params))
 402
 403     (if buffer (set (make-local-variable 'log-edit-parent-buffer) parent))
 404     (set (make-local-variable 'log-edit-initial-files) (log-edit-files))
 405     (when setup (run-hooks 'log-edit-hook))
 406     (goto-char (point-min)) (push-mark (point-max))
 407     (message "%s" (substitute-command-keys
 408               "Press \\[log-edit-done] when you are done editing."))))
 409
 410 (define-derived-mode log-edit-mode text-mode "Log-Edit"
 411   "Major mode for editing version-control log messages.
 412 When done editing the log entry, just type \\[log-edit-done] which
 413 will trigger the actual commit of the file(s).
 414 Several other handy support commands are provided of course and
 415 the package from which this is used might also provide additional
 416 commands (under C-x v for VC, for example).
 417
 418 \\{log-edit-mode-map}"
 419   (set (make-local-variable 'font-lock-defaults)
 420        '(log-edit-font-lock-keywords t t))
 421   (make-local-variable 'log-edit-comment-ring-index))
 422
 423 (defun log-edit-hide-buf (&optional buf where)
 424   (when (setq buf (get-buffer (or buf log-edit-files-buf)))
 425     (let ((win (get-buffer-window buf where)))
 426       (if win (ignore-errors (delete-window win))))
 427     (bury-buffer buf)))
 428
 429 (defun log-edit-done ()
 430   "Finish editing the log message and commit the files.
 431 If you want to abort the commit, simply delete the buffer."
 432   (interactive)
 433   ;; Clean up empty headers.
 434   (goto-char (point-min))
 435   (while (looking-at (concat "^[a-z]*:" log-edit-header-contents-regexp))
 436     (let ((beg (match-beginning 0)))
 437       (goto-char (match-end 0))
 438       (if (string-match "\\`[ \n\t]*\\'" (match-string 1))
 439           (delete-region beg (point)))))
 440   ;; Get rid of leading empty lines.
 441   (goto-char (point-min))
 442   (when (looking-at "\\([ \t]*\n\\)+")
 443     (delete-region (match-beginning 0) (match-end 0)))
 444   ;; Get rid of trailing empty lines
 445   (goto-char (point-max))
 446   (skip-syntax-backward " ")
 447   (when (equal (char-after) ?\n) (forward-char 1))
 448   (delete-region (point) (point-max))
 449   ;; Check for final newline
 450   (if (and (> (point-max) (point-min))
 451            (/= (char-before (point-max)) ?\n)
 452            (or (eq log-edit-require-final-newline t)
 453                (and log-edit-require-final-newline
 454                     (y-or-n-p
 455                      (format "Buffer %s does not end in newline.  Add one? "
 456                              (buffer-name))))))
 457       (save-excursion
 458         (goto-char (point-max))
 459         (insert ?\n)))
 460   (let ((comment (buffer-string)))
 461     (when (or (ring-empty-p log-edit-comment-ring)
 462               (not (equal comment (ring-ref log-edit-comment-ring 0))))
 463       (ring-insert log-edit-comment-ring comment)))
 464   (let ((win (get-buffer-window log-edit-files-buf)))
 465     (if (and log-edit-confirm
 466              (not (and (eq log-edit-confirm 'changed)
 467                        (equal (log-edit-files) log-edit-initial-files)))
 468              (progn
 469                (log-edit-show-files)
 470                (not (y-or-n-p "Really commit? "))))
 471         (progn (when (not win) (log-edit-hide-buf))
 472                (message "Oh, well!  Later maybe?"))
 473       (run-hooks 'log-edit-done-hook)
 474       (log-edit-hide-buf)
 475       (unless (or log-edit-keep-buffer (not log-edit-parent-buffer))
 476         (cvs-bury-buffer (current-buffer) log-edit-parent-buffer))
 477       (call-interactively log-edit-callback))))
 478
 479 (defun log-edit-files ()
 480   "Return the list of files that are about to be committed."
 481   (ignore-errors (funcall log-edit-listfun)))
 482
 483 (defun log-edit-mode-help ()
 484   "Provide help for the `log-edit-mode-map'."
 485   (interactive)
 486   (if (eq last-command 'log-edit-mode-help)
 487       (describe-function major-mode)
 488     (message "%s"
 489      (substitute-command-keys
 490       "Type `\\[log-edit-done]' to finish commit.  Try `\\[describe-function] log-edit-done' for more help."))))
 491
 492 (defcustom log-edit-common-indent 0
 493   "Minimum indentation to use in `log-edit-set-common-indentation'."
 494   :group 'log-edit
 495   :type 'integer)
 496
 497 (defun log-edit-set-common-indentation ()
 498   "(Un)Indent the current buffer rigidly to `log-edit-common-indent'."
 499   (save-excursion
 500     (let ((common (point-max)))
 501       (rfc822-goto-eoh)
 502       (while (< (point) (point-max))
 503         (if (not (looking-at "^[ \t]*$"))
 504             (setq common (min common (current-indentation))))
 505         (forward-line 1))
 506       (rfc822-goto-eoh)
 507       (indent-rigidly (point) (point-max)
 508                       (- log-edit-common-indent common)))))
 509
 510 (defun log-edit-show-diff ()
 511   "Show the diff for the files to be committed."
 512   (interactive)
 513   (if (functionp log-edit-diff-function)
 514       (funcall log-edit-diff-function)
 515     (error "Diff functionality has not been setup")))
 516
 517 (defun log-edit-show-files ()
 518   "Show the list of files to be committed."
 519   (interactive)
 520   (let* ((files (log-edit-files))
 521          (buf (get-buffer-create log-edit-files-buf)))
 522     (with-current-buffer buf
 523       (log-edit-hide-buf buf 'all)
 524       (setq buffer-read-only nil)
 525       (erase-buffer)
 526       (cvs-insert-strings files)
 527       (setq buffer-read-only t)
 528       (goto-char (point-min))
 529       (save-selected-window
 530         (cvs-pop-to-buffer-same-frame buf)
 531         (shrink-window-if-larger-than-buffer)
 532         (selected-window)))))
 533
 534 (defun log-edit-insert-cvs-template ()
 535   "Insert the template specified by the CVS administrator, if any.
 536 This simply uses the local CVS/Template file."
 537   (interactive)
 538   (when (or (called-interactively-p 'interactive)
 539             (= (point-min) (point-max)))
 540     (when (file-readable-p "CVS/Template")
 541       (insert-file-contents "CVS/Template"))))
 542
 543 (defun log-edit-insert-cvs-rcstemplate ()
 544   "Insert the rcstemplate from the CVS repository.
 545 This contacts the repository to get the rcstemplate file and
 546 can thus take some time."
 547   (interactive)
 548   (when (or (called-interactively-p 'interactive)
 549             (= (point-min) (point-max)))
 550     (when (file-readable-p "CVS/Root")
 551       ;; Ignore the stderr stuff, even if it's an error.
 552       (call-process "cvs" nil '(t nil) nil
 553                     "checkout" "-p" "CVSROOT/rcstemplate"))))
 554
 555 (defun log-edit-insert-filenames ()
 556   "Insert the list of files that are to be committed."
 557   (interactive)
 558   (insert "Affected files:  \n"
 559           (mapconcat 'identity (log-edit-files) "  \n")))
 560
 561 (defun log-edit-add-to-changelog ()
 562   "Insert this log message into the appropriate ChangeLog file."
 563   (interactive)
 564   ;; Yuck!
 565   (unless (string= (buffer-string) (ring-ref log-edit-comment-ring 0))
 566     (ring-insert log-edit-comment-ring (buffer-string)))
 567   (dolist (f (log-edit-files))
 568     (let ((buffer-file-name (expand-file-name f)))
 569       (save-excursion
 570         (log-edit-comment-to-change-log)))))
 571
 572 (defvar log-edit-changelog-use-first nil)
 573
 574 (defvar log-edit-rewrite-fixes nil
 575   "Rule to rewrite bug numbers into Fixes: headers.
 576 The value should be of the form (REGEXP . REPLACEMENT)
 577 where REGEXP should match the expression referring to a bug number
 578 in the text, and REPLACEMENT is an expression to pass to `replace-match'
 579 to build the Fixes: header.")
 580 (put 'log-edit-rewrite-fixes 'safe-local-variable
 581      (lambda (v) (and (stringp (car-safe v)) (stringp (cdr v)))))
 582
 583 (defun log-edit-insert-changelog (&optional use-first)
 584   "Insert a log message by looking at the ChangeLog.
 585 The idea is to write your ChangeLog entries first, and then use this
 586 command to commit your changes.
 587
 588 To select default log text, we:
 589 - find the ChangeLog entries for the files to be checked in,
 590 - verify that the top entry in the ChangeLog is on the current date
 591   and by the current user; if not, we don't provide any default text,
 592 - search the ChangeLog entry for paragraphs containing the names of
 593   the files we're checking in, and finally
 594 - use those paragraphs as the log text.
 595
 596 If the optional prefix arg USE-FIRST is given (via \\[universal-argument]),
 597 or if the command is repeated a second time in a row, use the first log entry
 598 regardless of user name or time."
 599   (interactive "P")
 600   (let ((eoh (save-excursion (rfc822-goto-eoh) (point))))
 601     (when (<= (point) eoh)
 602       (goto-char eoh)
 603       (if (looking-at "\n") (forward-char 1))))
 604   (let ((author
 605          (let ((log-edit-changelog-use-first
 606                 (or use-first (eq last-command 'log-edit-insert-changelog))))
 607            (log-edit-insert-changelog-entries (log-edit-files)))))
 608     (log-edit-set-common-indentation)
 609     ;; Add an Author: field if appropriate.
 610     (when author
 611       (rfc822-goto-eoh)
 612       (insert "Author: " author "\n" (if (looking-at "\n") "" "\n")))
 613     ;; Add a Fixes: field if applicable.
 614     (when (consp log-edit-rewrite-fixes)
 615       (rfc822-goto-eoh)
 616       (when (re-search-forward (car log-edit-rewrite-fixes) nil t)
 617         (let ((start (match-beginning 0))
 618               (end (match-end 0))
 619               (fixes (match-substitute-replacement
 620                       (cdr log-edit-rewrite-fixes))))
 621           (delete-region start end)
 622           (rfc822-goto-eoh)
 623           (insert "Fixes: " fixes "\n" (if (looking-at "\n") "" "\n")))))
 624     (and log-edit-strip-single-file-name
 625          (progn (rfc822-goto-eoh)
 626                 (if (looking-at "\n") (forward-char 1))
 627                 (looking-at "\\*\\s-+"))
 628          (let ((start (point)))
 629            (forward-line 1)
 630            (when (not (re-search-forward "^\\*\\s-+" nil t))
 631              (goto-char start)
 632              (skip-chars-forward "^():")
 633              (skip-chars-forward ": ")
 634              (delete-region start (point)))))
 635     (goto-char (point-min))))
 636
 637 ;;;;
 638 ;;;; functions for getting commit message from ChangeLog a file...
 639 ;;;; Courtesy Jim Blandy
 640 ;;;;
 641
 642 (defun log-edit-narrow-changelog ()
 643   "Narrow to the top page of the current buffer, a ChangeLog file.
 644 Actually, the narrowed region doesn't include the date line.
 645 A \"page\" in a ChangeLog file is the area between two dates."
 646   (or (eq major-mode 'change-log-mode)
 647       (error "log-edit-narrow-changelog: current buffer isn't a ChangeLog"))
 648
 649   (goto-char (point-min))
 650
 651   ;; Skip date line and subsequent blank lines.
 652   (forward-line 1)
 653   (if (looking-at "[ \t\n]*\n")
 654       (goto-char (match-end 0)))
 655
 656   (let ((start (point)))
 657     (forward-page 1)
 658     (narrow-to-region start (point))
 659     (goto-char (point-min))))
 660
 661 (defun log-edit-changelog-paragraph ()
 662   "Return the bounds of the ChangeLog paragraph containing point.
 663 If we are between paragraphs, return the previous paragraph."
 664   (beginning-of-line)
 665   (if (looking-at "^[ \t]*$")
 666       (skip-chars-backward " \t\n" (point-min)))
 667   (list (progn
 668           (if (re-search-backward "^[ \t]*\n" nil 'or-to-limit)
 669               (goto-char (match-end 0)))
 670           (point))
 671         (if (re-search-forward "^[ \t\n]*$" nil t)
 672             (match-beginning 0)
 673           (point-max))))
 674
 675 (defun log-edit-changelog-subparagraph ()
 676   "Return the bounds of the ChangeLog subparagraph containing point.
 677 A subparagraph is a block of non-blank lines beginning with an asterisk.
 678 If we are between sub-paragraphs, return the previous subparagraph."
 679     (end-of-line)
 680     (if (search-backward "*" nil t)
 681         (list (progn (beginning-of-line) (point))
 682               (progn
 683                 (forward-line 1)
 684                 (if (re-search-forward "^[ \t]*[\n*]" nil t)
 685                     (match-beginning 0)
 686                   (point-max))))
 687     (list (point) (point))))
 688
 689 (defun log-edit-changelog-entry ()
 690   "Return the bounds of the ChangeLog entry containing point.
 691 The variable `log-edit-changelog-full-paragraphs' decides whether an
 692 \"entry\" is a paragraph or a subparagraph; see its documentation string
 693 for more details."
 694   (save-excursion
 695     (if log-edit-changelog-full-paragraphs
 696         (log-edit-changelog-paragraph)
 697       (log-edit-changelog-subparagraph))))
 698
 699 (defvar user-full-name)
 700 (defvar user-mail-address)
 701
 702 (defvar log-edit-author)                ;Dynamically scoped.
 703
 704 (defun log-edit-changelog-ours-p ()
 705   "See if ChangeLog entry at point is for the current user, today.
 706 Return non-nil if it is."
 707   ;; Code adapted from add-change-log-entry.
 708   (let ((name (or (and (boundp 'add-log-full-name) add-log-full-name)
 709                   (and (fboundp 'user-full-name) (user-full-name))
 710                   (and (boundp 'user-full-name) user-full-name)))
 711         (mail (or (and (boundp 'add-log-mailing-address) add-log-mailing-address)
 712                   ;;(and (fboundp 'user-mail-address) (user-mail-address))
 713                   (and (boundp 'user-mail-address) user-mail-address)))
 714         (time (or (and (boundp 'add-log-time-format)
 715                        (functionp add-log-time-format)
 716                        (funcall add-log-time-format))
 717                   (format-time-string "%Y-%m-%d"))))
 718     (if (null log-edit-changelog-use-first)
 719         (looking-at (regexp-quote (format "%s  %s  <%s>" time name mail)))
 720       ;; Check the author, to potentially add it as a "Author: " header.
 721       (when (looking-at "[^ \t]")
 722         (when (and (boundp 'log-edit-author)
 723                    (not (looking-at (format ".+  .+  <%s>"
 724                                             (regexp-quote mail))))
 725                    (looking-at ".+  \\(.+  <.+>\\)"))
 726           (let ((author (replace-regexp-in-string "  " " "
 727                                                   (match-string 1))))
 728             (unless (and log-edit-author
 729                          (string-match (regexp-quote author) log-edit-author))
 730               (setq log-edit-author
 731                     (if log-edit-author
 732                         (concat log-edit-author ", " author)
 733                       author)))))
 734         t))))
 735
 736 (defun log-edit-changelog-entries (file)
 737   "Return the ChangeLog entries for FILE, and the ChangeLog they came from.
 738 The return value looks like this:
 739   (LOGBUFFER (ENTRYSTART ENTRYEND) ...)
 740 where LOGBUFFER is the name of the ChangeLog buffer, and each
 741 \(ENTRYSTART . ENTRYEND\) pair is a buffer region."
 742   (let ((changelog-file-name
 743          (let ((default-directory
 744                  (file-name-directory (expand-file-name file)))
 745                (visiting-buffer (find-buffer-visiting file)))
 746            ;; If there is a buffer visiting FILE, and it has a local
 747            ;; value for `change-log-default-name', use that.
 748            (if (and visiting-buffer
 749                     (local-variable-p 'change-log-default-name
 750                                       visiting-buffer))
 751                (with-current-buffer visiting-buffer
 752                  change-log-default-name)
 753              ;; `find-change-log' uses `change-log-default-name' if set
 754              ;; and sets it before exiting, so we need to work around
 755              ;; that memoizing which is undesired here
 756              (setq change-log-default-name nil)
 757              (find-change-log)))))
 758     (with-current-buffer (find-file-noselect changelog-file-name)
 759       (unless (eq major-mode 'change-log-mode) (change-log-mode))
 760       (goto-char (point-min))
 761       (if (looking-at "\\s-*\n") (goto-char (match-end 0)))
 762       (if (not (log-edit-changelog-ours-p))
 763           (list (current-buffer))
 764         (save-restriction
 765           (log-edit-narrow-changelog)
 766           (goto-char (point-min))
 767
 768           ;; Search for the name of FILE relative to the ChangeLog.  If that
 769           ;; doesn't occur anywhere, they're not using full relative
 770           ;; filenames in the ChangeLog, so just look for FILE; we'll accept
 771           ;; some false positives.
 772           (let ((pattern (file-relative-name
 773                           file (file-name-directory changelog-file-name))))
 774             (if (or (string= pattern "")
 775                     (not (save-excursion
 776                            (search-forward pattern nil t))))
 777                 (setq pattern (file-name-nondirectory file)))
 778
 779             (setq pattern (concat "\\(^\\|[^[:alnum:]]\\)"
 780                                   (regexp-quote pattern)
 781                                   "\\($\\|[^[:alnum:]]\\)"))
 782
 783             (let (texts
 784                   (pos (point)))
 785               (while (and (not (eobp)) (re-search-forward pattern nil t))
 786                 (let ((entry (log-edit-changelog-entry)))
 787                   (if (< (elt entry 1) (max (1+ pos) (point)))
 788                       ;; This is not relevant, actually.
 789                       nil
 790                     (push entry texts))
 791                   ;; Make sure we make progress.
 792                   (setq pos (max (1+ pos) (elt entry 1)))
 793                   (goto-char pos)))
 794
 795               (cons (current-buffer) texts))))))))
 796
 797 (defun log-edit-changelog-insert-entries (buffer beg end &rest files)
 798   "Insert the text from BUFFER between BEG and END.
 799 Rename relative filenames in the ChangeLog entry as FILES."
 800   (let ((opoint (point))
 801         (log-name (buffer-file-name buffer))
 802         (case-fold-search nil)
 803         bound)
 804     (insert-buffer-substring buffer beg end)
 805     (setq bound (point-marker))
 806     (when log-name
 807       (dolist (f files)
 808         (save-excursion
 809           (goto-char opoint)
 810           (when (re-search-forward
 811                  (concat "\\(^\\|[ \t]\\)\\("
 812                          (file-relative-name f (file-name-directory log-name))
 813                          "\\)[, :\n]")
 814                  bound t)
 815             (replace-match f t t nil 2)))))
 816     ;; Eliminate tabs at the beginning of the line.
 817     (save-excursion
 818       (goto-char opoint)
 819       (while (re-search-forward "^\\(\t+\\)" bound t)
 820         (replace-match "")))))
 821
 822 (defun log-edit-insert-changelog-entries (files)
 823   "Given a list of files FILES, insert the ChangeLog entries for them."
 824   (let ((log-entries nil)
 825         (log-edit-author nil))
 826     ;; Note that any ChangeLog entry can apply to more than one file.
 827     ;; Here we construct a log-entries list with elements of the form
 828     ;;   ((LOGBUFFER ENTRYSTART ENTRYEND) FILE1 FILE2...)
 829     (dolist (file files)
 830       (let* ((entries (log-edit-changelog-entries file))
 831              (buf (car entries))
 832              key entry)
 833         (dolist (region (cdr entries))
 834           (setq key (cons buf region))
 835           (if (setq entry (assoc key log-entries))
 836               (setcdr entry (append (cdr entry) (list file)))
 837             (push (list key file) log-entries)))))
 838     ;; Now map over log-entries, and extract the strings.
 839     (dolist (log-entry (nreverse log-entries))
 840       (apply 'log-edit-changelog-insert-entries
 841              (append (car log-entry) (cdr log-entry)))
 842       (insert "\n"))
 843     log-edit-author))
 844
 845 (defun log-edit-extract-headers (headers comment)
 846   "Extract headers from COMMENT to form command line arguments.
 847 HEADERS should be an alist with elements of the form (HEADER . CMDARG)
 848 associating header names to the corresponding cmdline option name and the
 849 result is then a list of the form (MSG CMDARG1 HDRTEXT1 CMDARG2 HDRTEXT2...).
 850 where MSG is the remaining text from STRING.
 851 If \"Summary\" is not in HEADERS, then the \"Summary\" header is extracted
 852 anyway and put back as the first line of MSG."
 853   (with-temp-buffer
 854     (insert comment)
 855     (rfc822-goto-eoh)
 856     (narrow-to-region (point-min) (point))
 857     (let ((case-fold-search t)
 858           (summary ())
 859           (res ()))
 860       (dolist (header (if (assoc "Summary" headers) headers
 861                         (cons '("Summary" . t) headers)))
 862         (goto-char (point-min))
 863         (while (re-search-forward (concat "^" (car header)
 864                                           ":" log-edit-header-contents-regexp)
 865                                   nil t)
 866           (if (eq t (cdr header))
 867               (setq summary (match-string 1))
 868             (push (match-string 1) res)
 869             (push (or (cdr header) (car header)) res))
 870           (replace-match "" t t)))
 871       ;; Remove header separator if the header is empty.
 872       (widen)
 873       (goto-char (point-min))
 874       (when (looking-at "\\([ \t]*\n\\)+")
 875         (delete-region (match-beginning 0) (match-end 0)))
 876       (if summary (insert summary "\n"))
 877       (cons (buffer-string) res))))
 878
 879 (provide 'log-edit)
 880
 881 ;; arch-tag: 8089b39c-983b-4e83-93cd-ed0a64c7fdcc
 882 ;;; log-edit.el ends here